passagemath-glpk 10.6.46__cp314-cp314t-win_amd64.whl

sage/numerical/backends/glpk_backend_test.py

@@ -0,0 +1,13 @@
+# sage_setup: distribution = sagemath-glpk
+import pytest
+
+from sage.numerical.backends.generic_backend_test import GenericBackendTests
+from sage.numerical.backends.generic_backend import GenericBackend
+from sage.numerical.mip import MixedIntegerLinearProgram
+
+
+class TestGLPKBackend(GenericBackendTests):
+
+    @pytest.fixture
+    def backend(self) -> GenericBackend:
+        return MixedIntegerLinearProgram(solver='GLPK').get_backend()

sage/numerical/backends/glpk_exact_backend.pxd

@@ -0,0 +1,17 @@
+# sage_setup: distribution = sagemath-glpk
+#*****************************************************************************
+#       Copyright (C) 2016 Matthias Koeppe
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation, either version 2 of the License, or
+# (at your option) any later version.
+#                  http://www.gnu.org/licenses/
+#*****************************************************************************
+
+from sage.numerical.backends.glpk_backend cimport GLPKBackend
+
+cdef class GLPKExactBackend(GLPKBackend):
+    cpdef int add_variable(self, lower_bound=*, upper_bound=*, binary=*, continuous=*, integer=*, obj=*, name=*) except -1
+    cpdef int add_variables(self, int, lower_bound=*, upper_bound=*, binary=*, continuous=*, integer=*, obj=*, names=*) except -1
+    cpdef set_variable_type(self, int variable, int vtype)

sage/numerical/backends/glpk_exact_backend.pyx

@@ -0,0 +1,190 @@
+# sage_setup: distribution = sagemath-glpk
+
+"""
+GLPK/exact Backend (simplex method in exact rational arithmetic)
+
+AUTHORS:
+
+- Matthias Koeppe (2016-03)
+"""
+
+##############################################################################
+#       Copyright (C) 2016 Matthias Koeppe
+#  Distributed under the terms of the GNU General Public License (GPL)
+#  The full text of the GPL is available at:
+#                  http://www.gnu.org/licenses/
+##############################################################################
+
+cdef class GLPKExactBackend(GLPKBackend):
+    """
+    MIP Backend that runs the GLPK solver in exact rational simplex mode.
+
+    The only access to data is via double-precision floats, which
+    means that rationals in the input data may be rounded before
+    the exact solver sees them. Thus, it is unreasonable to expect
+    that arbitrary LPs with rational coefficients are solved exactly.
+    Once the LP has been read into the backend, it reconstructs
+    rationals from doubles and does solve exactly over the rationals,
+    but results are returned as as doubles.
+
+    There is no support for integer variables.
+    """
+    def __cinit__(self, maximization=True):
+        """
+        Constructor.
+
+        EXAMPLES::
+
+            sage: p = MixedIntegerLinearProgram(solver='GLPK/exact')
+        """
+        # inherited __cinit__ is called automatically
+        import sage.numerical.backends.glpk_backend as glpk_backend
+        self.solver_parameter(glpk_backend.glp_simplex_or_intopt, glpk_backend.glp_exact_simplex_only)
+
+    cpdef int add_variable(self, lower_bound=0.0, upper_bound=None, binary=False, continuous=False, integer=False, obj=0.0, name=None) except -1:
+        """
+        Add a variable.
+
+        This amounts to adding a new column to the matrix. By default,
+        the variable is both nonnegative and real.
+
+        In this backend, variables are always continuous (real).
+        If integer variables are requested via the parameters
+        ``binary`` and ``integer``, an error will be raised.
+
+        INPUT:
+
+        - ``lower_bound`` -- the lower bound of the variable (default: 0)
+
+        - ``upper_bound`` -- the upper bound of the variable (default: ``None``)
+
+        - ``binary`` -- ``True`` if the variable is binary (default: ``False``)
+
+        - ``continuous`` -- ``True`` if the variable is continuous (default: ``True``)
+
+        - ``integer`` -- ``True`` if the variable is integer (default: ``False``)
+
+        - ``obj`` -- (optional) coefficient of this variable in the objective function (default: 0.0)
+
+        - ``name`` -- an optional name for the newly added variable (default: ``None``)
+
+        OUTPUT: the index of the newly created variable
+
+        EXAMPLES::
+
+            sage: from sage.numerical.backends.generic_backend import get_solver
+            sage: p = get_solver(solver = "GLPK/exact")
+            sage: p.ncols()
+            0
+            sage: p.add_variable()
+            0
+            sage: p.ncols()
+            1
+            sage: p.add_variable()
+            1
+            sage: p.add_variable(lower_bound=-2.0)
+            2
+            sage: p.add_variable(continuous=True)
+            3
+            sage: p.add_variable(name='x',obj=1.0)
+            4
+            sage: p.objective_coefficient(4)
+            1.0
+
+        TESTS::
+
+            sage: p.add_variable(integer=True)
+            Traceback (most recent call last):
+            ...
+            ValueError: GLPK/exact only supports continuous variables
+            sage: p.add_variable(binary=True)
+            Traceback (most recent call last):
+            ...
+            ValueError: GLPK/exact only supports continuous variables
+        """
+        if binary or integer:
+            raise ValueError("GLPK/exact only supports continuous variables")
+        return GLPKBackend.add_variable(self, lower_bound, upper_bound, binary, continuous,
+                                        integer, obj, name)
+
+    cpdef int add_variables(self, int number, lower_bound=0.0, upper_bound=None, binary=False, continuous=False, integer=False, obj=0.0, names=None) except -1:
+        """
+        Add ``number`` variables.
+
+        This amounts to adding new columns to the matrix. By default,
+        the variables are both nonnegative and real.
+
+        In this backend, variables are always continuous (real).
+        If integer variables are requested via the parameters
+        ``binary`` and ``integer``, an error will be raised.
+
+        INPUT:
+
+        - ``n`` -- the number of new variables (must be > 0)
+
+        - ``lower_bound`` -- the lower bound of the variable (default: 0)
+
+        - ``upper_bound`` -- the upper bound of the variable (default: ``None``)
+
+        - ``binary`` -- ``True`` if the variable is binary (default: ``False``)
+
+        - ``continuous`` -- ``True`` if the variable is binary (default: ``True``)
+
+        - ``integer`` -- ``True`` if the variable is binary (default: ``False``)
+
+        - ``obj`` -- coefficient of all variables in the objective function (default: 0.0)
+
+        - ``names`` -- list of names (default: ``None``)
+
+        OUTPUT: the index of the variable created last
+
+        EXAMPLES::
+
+            sage: from sage.numerical.backends.generic_backend import get_solver
+            sage: p = get_solver(solver = "GLPK/exact")
+            sage: p.ncols()
+            0
+            sage: p.add_variables(5)
+            4
+            sage: p.ncols()
+            5
+            sage: p.add_variables(2, lower_bound=-2.0, obj=42.0, names=['a','b'])
+            6
+        """
+        if binary or integer:
+            raise ValueError("GLPK/exact only supports continuous variables")
+        return GLPKBackend.add_variables(self, number, lower_bound, upper_bound, binary, continuous,
+                                        integer, obj, names)
+
+    cpdef set_variable_type(self, int variable, int vtype):
+        """
+        Set the type of a variable.
+
+        In this backend, variables are always continuous (real).
+        If integer or binary variables are requested via the parameter
+        ``vtype``, an error will be raised.
+
+        INPUT:
+
+        - ``variable`` -- integer; the variable's id
+
+        - ``vtype`` -- integer:
+
+            *  1  Integer
+            *  0  Binary
+            * -1 Real
+
+        EXAMPLES::
+
+            sage: from sage.numerical.backends.generic_backend import get_solver
+            sage: p = get_solver(solver = "GLPK/exact")
+            sage: p.add_variables(5)
+            4
+            sage: p.set_variable_type(3, -1)
+            sage: p.set_variable_type(3, -2)
+            Traceback (most recent call last):
+            ...
+            ValueError: ...
+        """
+        if vtype != -1:
+            raise ValueError("GLPK/exact only supports continuous variables")

sage/numerical/backends/glpk_exact_backend_test.py

@@ -0,0 +1,12 @@
+# sage_setup: distribution = sagemath-glpk
+import pytest
+from sage.numerical.backends.generic_backend_test import GenericBackendTests
+from sage.numerical.backends.generic_backend import GenericBackend
+from sage.numerical.mip import MixedIntegerLinearProgram
+
+
+class TestGLPKExactBackend(GenericBackendTests):
+
+    @pytest.fixture
+    def backend(self) -> GenericBackend:
+        return MixedIntegerLinearProgram(solver='GLPK/exact').get_backend()

sage/numerical/backends/glpk_graph_backend.pxd

@@ -0,0 +1,56 @@
+# sage_setup: distribution = sagemath-glpk
+#*****************************************************************************
+#       Copyright (C) 2012 Christian Kuper <christian.kuper@t-online.de>
+#       Copyright (C) 2015 Jeroen Demeyer <jdemeyer@cage.ugent.be>
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation, either version 2 of the License, or
+# (at your option) any later version.
+#                  http://www.gnu.org/licenses/
+#*****************************************************************************
+
+from sage.libs.glpk.types cimport glp_graph
+
+ctypedef struct c_v_data:
+         double rhs
+         double pi
+         double es
+         double ls
+         long cut
+
+ctypedef struct c_a_data:
+         double low
+         double cap
+         double cost
+         double x
+
+
+cdef class GLPKGraphBackend():
+    cdef glp_graph * graph
+    cpdef add_vertex(self, name=?)
+    cpdef list add_vertices(self, vertices)
+    cpdef __add_vertices_sage(self, g)
+    cpdef dict get_vertex(self, vertex)
+    cpdef dict get_vertices(self, verts)
+    cpdef set_vertex_demand(self, vertex, param)
+    cpdef set_vertices_demand(self, list pairs)
+    cpdef list vertices(self)
+    cpdef add_edge(self, u, v, dict params=?)
+    cpdef __add_edges_sage(self, g)
+    cpdef list add_edges(self, edges)
+    cpdef delete_edge(self, u, v, dict params=?)
+    cpdef tuple get_edge(self, u, v)
+    cpdef list edges(self)
+    cpdef delete_vertex(self, vert)
+    cpdef delete_vertices(self, list verts)
+    cpdef int _find_vertex(self, vert) noexcept
+    cpdef int write_graph(self, fname) noexcept
+    cpdef int write_ccdata(self, fname) noexcept
+    cpdef int write_mincost(self, fname) noexcept
+    cpdef double mincost_okalg(self) except -1
+    cdef int s
+    cdef int t
+    cpdef int write_maxflow(self, fname) except -1
+    cpdef double maxflow_ffalg(self, u=?, v=?) except -1
+    cpdef double cpp(self) noexcept