iris-pex-embedded-python 3.5.5b4__py3-none-any.whl

iop/cls/IOP/Duplex/Process.cls

@@ -0,0 +1,229 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.DuplexProcess Extends IOP.BusinessProcess [ ClassType = persistent, ProcedureBlock, System = 4 ]
+{
+
+/// Domain for Text localization
+Parameter DOMAIN = "PrivateSession";
+
+/// The Duplex Service name. This property is set at runtime after receiving the primary request
+Property ServiceDuplexName As %String;
+
+/// Indicates if a given ConfigItem is in private session or not
+Property %IsInPrivateSession As array Of %Boolean(STORAGEDEFAULT = "list");
+
+/// This method is always called asynchronously ONCE at the beginning of the process
+Method OnRequest(
+	pRequest As %Library.Persistent,
+	Output pResponse As Ens.Response) As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If $IsObject(pRequest)&&($classname(pRequest)="IOP.PrivateSession.Message.Start") {
+			Set tSC=..Reply(##class(IOP.PrivateSession.Message.Ack).%New()) Quit:$$$ISERR(tSC)
+			Set ..ServiceDuplexName = ..%PrimaryRequestHeader.SourceConfigName
+			Do ..IsInPrivateSessionSet(..ServiceDuplexName,1)
+			Set tSC=..SendRequestAsync(..ServiceDuplexName,##class(IOP.PrivateSession.Message.Poll).%New(),1) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStarted(..ServiceDuplexName,0) Quit:$$$ISERR(tSC)
+		} Else {
+			Set tSC=..OnDocument(..%PrimaryRequestHeader.SourceConfigName,pRequest)
+		}
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+/// Handle a 'Response'
+Method OnResponse(
+	request As %Library.Persistent,
+	ByRef response As %Library.Persistent,
+	callrequest As %Library.Persistent,
+	callresponse As %Library.Persistent,
+	pCompletionKey As %String) As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim tSourceConfigName, tOneConfigName As %String
+	try {
+		; get the SourceConfigName of this message
+		Set tSourceConfigName=..%CurrentResponseHeader.SourceConfigName
+		; handle SessionStop message
+		If $IsObject(callresponse)&&($classname(callresponse)="IOP.PrivateSession.Message.Ack") {
+			Do ..IsInPrivateSessionSet(tSourceConfigName,1)
+			Set tSC=..SendRequestAsync(tSourceConfigName,##class(IOP.PrivateSession.Message.Poll).%New(),1) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStarted(tSourceConfigName,1) Quit:$$$ISERR(tSC)
+			Quit
+		}
+		; handle SessionStop message
+		If $IsObject(callresponse)&&($classname(callresponse)="IOP.PrivateSession.Message.Stop") {
+			Set tSC=..UnRegisterPrivateSession(tSourceConfigName) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStopped(tSourceConfigName,0,callresponse.AttachedMessage) Quit:$$$ISERR(tSC)
+			Quit
+		}
+		; send poll request again back to the same ConfigItem if this this is in response to a poll request
+		If $IsObject(callrequest)&&($classname(callrequest)="IOP.PrivateSession.Message.Poll") {
+			If ..IsInPrivateSession(tSourceConfigName) {
+				Set tSC=..SendRequestAsync(tSourceConfigName,##class(IOP.PrivateSession.Message.Poll).%New(),1) If $$$ISERR(tSC)
+			}
+		}
+		; call OnDocument
+		Set tSC=..OnDocument(tSourceConfigName,callresponse) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StartPrivateSession(pDuplexConfigName As %String = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If pDuplexConfigName="" Set tSC=$$$EnsError($$$EnsErrGeneral,"Duplex configuration name is missing") Quit
+		If ..IsInPrivateSession(pDuplexConfigName) Quit
+		Set tSC=..SendRequestAsync(pDuplexConfigName,##class(IOP.PrivateSession.Message.Start).%New()) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StopPrivateSession(
+	pDuplexConfigName As %String = "",
+	pAttachedMessage As %Persistent = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If pDuplexConfigName="" Set tSC=$$$EnsError($$$EnsErrGeneral,"Duplex configuration name is missing") Quit
+		If '..IsInPrivateSession(pDuplexConfigName) Quit
+		Set tSC=..SendRequestAsync(pDuplexConfigName,##class(IOP.PrivateSession.Message.Stop).%New(pAttachedMessage),0) Quit:$$$ISERR(tSC)
+		Set tSC=..UnRegisterPrivateSession(pDuplexConfigName)
+		Set tSC=..OnPrivateSessionStopped(pDuplexConfigName,1) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StopAllPrivateSessions(pAttachedMessage As %Persistent = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim tItem As %String
+	try {
+		Set tItem="" For  {
+			Set tItem=..%IsInPrivateSession.Next(tItem) Quit:tItem=""
+			Set tSC=..StopPrivateSession(tItem,pAttachedMessage) Quit:$$$ISERR(tSC)
+		}
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method UnRegisterPrivateSession(pDuplexConfigName As %String) As %String
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		For i=..%MasterPendingResponses.Count():-1:1 {
+			Set tRequestHeader=##class(Ens.MessageHeader).%OpenId($li(..%MasterPendingResponses.GetAt(i),1))
+			If $IsObject(tRequestHeader),tRequestHeader.TargetConfigName=pDuplexConfigName,tRequestHeader.MessageBodyClassName="IOP.PrivateSession.Message.Poll" {
+				Do ..%MasterPendingResponses.RemoveAt(i)
+			}
+		}
+		Do ..IsInPrivateSessionSet(pDuplexConfigName,0)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method IsInPrivateSessionSet(
+	pDuplexConfigName As %String,
+	pInPrivateSession As %Boolean)
+{
+	If pInPrivateSession {
+		Do ..%IsInPrivateSession.SetAt(1,pDuplexConfigName)
+	} Else {
+		Do ..%IsInPrivateSession.RemoveAt(pDuplexConfigName)
+	}
+	Quit
+}
+
+Method IsInPrivateSession(pDuplexConfigName As %String) As %Boolean
+{
+	If pDuplexConfigName="" Quit 0
+	Quit ..%IsInPrivateSession.IsDefined(pDuplexConfigName)
+}
+
+Method OnDocument(
+	pSourceConfigName As %String,
+	pInput As %Library.Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_document"($this,pSourceConfigName,pInput)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnPrivateSessionStarted(
+	pSourceConfigName As %String,
+	pSelfGenerated As %Boolean) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_started"($this,pSourceConfigName,pSelfGenerated)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnPrivateSessionStopped(
+	pSourceConfigName As %String,
+	pSelfGenerated As %Boolean,
+	pAttachedMessage As %Persistent = "") As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_stopped"($this,pSourceConfigName,pSelfGenerated,pAttachedMessage)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Storage Default
+{
+<Data name="ProcessDefaultData">
+<Subscript>"Process"</Subscript>
+<Value name="1">
+<Value>ServiceDuplexName</Value>
+</Value>
+<Value name="2">
+<Value>%IsInPrivateSession</Value>
+</Value>
+<Value name="3">
+<Value>%classpaths</Value>
+</Value>
+<Value name="4">
+<Value>%classname</Value>
+</Value>
+<Value name="5">
+<Value>%module</Value>
+</Value>
+<Value name="6">
+<Value>%settings</Value>
+</Value>
+<Value name="7">
+<Value>%class</Value>
+</Value>
+</Data>
+<DefaultData>ProcessDefaultData</DefaultData>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/Duplex/Service.cls

@@ -0,0 +1,9 @@
+Class IOP.DuplexService Extends IOP.PrivateSessionDuplex
+{
+
+ClassMethod OnBusinessType(pItem As Ens.Config.Item) As %Integer
+{
+    Quit $$$eHostTypeService
+}
+
+}

iop/cls/IOP/Generator/Message/Ack.cls

@@ -0,0 +1,31 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.Generator.Message.Ack Extends (%Persistent, Ens.Util.MessageBodyMethods) [ ClassType = persistent, Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter DOMAIN = "Generator";
+
+/// From 'Ens.Util.MessageBodyMethods'
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	Write $$$Text("(session-ack)")
+}
+
+Storage Default
+{
+<Data name="AckDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.Generator.Message.AckD</DataLocation>
+<DefaultData>AckDefaultData</DefaultData>
+<IdLocation>^IOP.Generator.Message.AckD</IdLocation>
+<IndexLocation>^IOP.Generator.Message.AckI</IndexLocation>
+<StreamLocation>^IOP.Generator.Message.AckS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/Generator/Message/Poll.cls

@@ -0,0 +1,31 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.Generator.Message.Poll Extends (%Persistent, Ens.Util.MessageBodyMethods) [ ClassType = persistent, Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter DOMAIN = "Generator";
+
+/// From 'Ens.Util.MessageBodyMethods'
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	Write $$$Text("(poll-data)")
+}
+
+Storage Default
+{
+<Data name="PollDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.PrivateS9756.PollD</DataLocation>
+<DefaultData>PollDefaultData</DefaultData>
+<IdLocation>^IOP.PrivateS9756.PollD</IdLocation>
+<IndexLocation>^IOP.PrivateS9756.PollI</IndexLocation>
+<StreamLocation>^IOP.PrivateS9756.PollS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/Generator/Message/Start.cls

@@ -0,0 +1,15 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.Generator.Message.Start Extends IOP.Message [ ClassType = persistent, Inheritance = right, ProcedureBlock ]
+{
+
+Parameter DOMAIN = "Generator";
+
+Storage Default
+{
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/Generator/Message/StartPickle.cls

@@ -0,0 +1,15 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.Generator.Message.StartPickle Extends IOP.PickleMessage [ ClassType = persistent, Inheritance = right, ProcedureBlock ]
+{
+
+Parameter DOMAIN = "Generator";
+
+Storage Default
+{
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/Generator/Message/Stop.cls

@@ -0,0 +1,32 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.Generator.Message.Stop Extends (%Persistent, Ens.Util.MessageBodyMethods) [ ClassType = persistent, Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter DOMAIN = "PrivateSession";
+
+/// From 'Ens.Util.MessageBodyMethods'
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+
+		Write $$$Text("(session-stop)")
+}
+
+Storage Default
+{
+<Data name="StopDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.Generator.Message.StopD</DataLocation>
+<DefaultData>StopDefaultData</DefaultData>
+<IdLocation>^IOP.Generator.Message.StopD</IdLocation>
+<IndexLocation>^IOP.Generator.Message.StopI</IndexLocation>
+<StreamLocation>^IOP.Generator.Message.StopS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/InboundAdapter.cls

@@ -0,0 +1,22 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.InboundAdapter Extends (Ens.InboundAdapter, IOP.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter SETTINGS = "%classname:Python InboundAdapter,%module:Python InboundAdapter,%settings:Python InboundAdapter,%classpaths:Python InboundAdapter";
+
+Method OnTask() As %Status
+{
+	set tSC = $$$OK
+	try {
+		$$$ThrowOnError(..Connect())
+		do ..%class."on_task"()
+	} catch ex {
+		set tSC = ..DisplayTraceback(ex)
+	}
+	quit tSC
+}
+
+}

iop/cls/IOP/Message/JSONSchema.cls

@@ -0,0 +1,125 @@
+Class IOP.Message.JSONSchema Extends %Persistent
+{
+
+Property Name As %String;
+
+Property Category As %String;
+
+Property JSONSchema As %String(MAXLEN = "");
+
+Index NameIndex On Name [ IdKey, Unique ];
+
+/// Import a JSON Schema from file
+ClassMethod ImportFromFile(
+	pFileName As %String,
+	pCategory As %String = "",
+	pName As %String) As %Status
+{
+    Set pStatus = $$$OK
+    Try {
+        If '##class(%File).Exists(pFileName) {
+            Set pStatus = $$$ERROR($$$GeneralError, "File not found")
+            Return pStatus
+        }
+        Set tFile = ##class(%File).%New(pFileName)
+        $$$ThrowOnError(tFile.Open("R"))
+        Set tSchema = ""
+        While 'tFile.AtEnd {
+            Set tSchema = tSchema _ tFile.ReadLine()
+        }
+        Set pStatus = ..Import(tSchema, pCategory, pName)
+    } Catch ex {
+        Set pStatus = ex.AsStatus()
+    }
+    Return pStatus
+}
+
+/// Store the JSON Schema in this object
+ClassMethod Import(
+	pSchema As %String,
+	pCategory As %String = "",
+	pName As %String) As %Status
+{
+    Set pStatus = $$$OK
+    Try {
+        if ##class(IOP.Message.JSONSchema).%ExistsId(pName) {
+            Set tThis = ##class(IOP.Message.JSONSchema).%OpenId(pName)
+            Set tThis.Category = pCategory
+            Set tThis.JSONSchema = pSchema
+            $$$ThrowOnError(tThis.%Save())
+        } Else {
+            Set tThis = ##class(IOP.Message.JSONSchema).%New()
+            Set tThis.Name = pName
+            Set tThis.Category = pCategory
+            Set tThis.JSONSchema = pSchema
+            $$$ThrowOnError(tThis.%Save())
+        }
+    } Catch ex {
+        Set pStatus = ex.AsStatus()
+    }
+    Quit pStatus
+}
+
+/// Get a stored schema by category and name
+ClassMethod GetSchema(
+	pName As %String = "",
+	Output pSchema As %String) As %Status
+{
+    Set pStatus = $$$OK
+    Try {
+        Set tSql = "SELECT JSONSchema FROM IOP_Message.JSONSchema WHERE Name = ?"
+        Set tStatement = ##class(%SQL.Statement).%New()
+        Do tStatement.%Prepare(tSql)
+        set rs = tStatement.%Execute(pName)
+        If rs.%Next() {
+            Set pSchema = rs.%Get("JSONSchema")
+        } Else {
+            Set pStatus = $$$ERROR($$$GeneralError, "Schema not found")
+        }
+    } Catch ex {
+        Set pStatus = ex.AsStatus()
+    }
+    Return pStatus
+}
+
+/// Validate JSON data against a stored schema
+ClassMethod ValidateJSONSchema(
+	pJSON As %String,
+	pName As %String) As %Status
+{
+    Set tSC = $$$OK
+    Try {
+        Set tSchema = ""
+        Set tSC = ..GetSchema(pName, .tSchema)
+        If $$$ISERR(tSC) Return tSC
+        // Validate JSON data against schema
+        // To be implemented
+        Set tSC = $$$OK
+    } Catch ex {
+        Set tSC = ex.AsStatus()
+    }
+    Return tSC
+}
+
+Storage Default
+{
+<Data name="JSONSchemaDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+<Value name="2">
+<Value>JSONSchema</Value>
+</Value>
+<Value name="3">
+<Value>Category</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.Message.JSONSchemaD</DataLocation>
+<DefaultData>JSONSchemaDefaultData</DefaultData>
+<IdLocation>^IOP.Message.JSONSchemaD</IdLocation>
+<IndexLocation>^IOP.Message.JSONSchemaI</IndexLocation>
+<StreamLocation>^IOP.Message.JSONSchemaS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}