iris-pex-embedded-python 2.3.3__py3-none-any.whl → 2.3.5__py3-none-any.whl

grongier/pex/data/PEX/Utils.cls

@@ -0,0 +1,363 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Include Ensemble
+
+Class Grongier.PEX.Utils Extends %RegisteredObject
+{
+
+ClassMethod dispatchRegisterComponent(
+	pModule As %String,
+	pRemoteClassname As %String,
+	pCLASSPATHS As %String = "",
+	pOverwrite As %Boolean = 0,
+	pProxyClassname As %String = "") As %Status
+{
+	set tSc = $$$OK
+	$$$ThrowOnError(##class(Grongier.PEX.Utils).RegisterComponent(pModule, pRemoteClassname, pCLASSPATHS, pOverwrite , pProxyClassname))
+	return tSc
+}
+
+/// "bo","Duplex","/irisdev/app/src/python/demo/duplex/",1,"Duplex.Duplex"
+ClassMethod RegisterComponent(
+	pModule As %String,
+	pRemoteClassname As %String,
+	pCLASSPATHS As %String = "",
+	pOverwrite As %Boolean = 0,
+	pProxyClassname As %String = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim ex As %Exception.AbstractException
+	#dim tLanguage,tExtraClasspaths,tDelimiter,tOnePath As %String = ""
+	#dim tClassDetails,tRemoteSettings As %String = ""
+	#dim tClasspaths As %ListOfDataTypes
+	
+	Quit:(""=pRemoteClassname) $$$ERROR($$$EnsErrGeneral,"Remote Classname must be specified in order to register a Production EXtensions component")
+	Quit:(""=pModule) $$$ERROR($$$EnsErrGeneral,"Must specify the module of the remote code.")
+		
+	Try {
+
+		$$$ThrowOnError(..GetRemoteClassInfo(pRemoteClassname,pModule,pCLASSPATHS,.tClassDetails,.tRemoteSettings))
+
+		Set tConnectionSettings("Classpaths") = pCLASSPATHS
+		Set tConnectionSettings("Module") = pModule
+		Set tConnectionSettings("Classname") = pRemoteClassname
+		Set:(""=pProxyClassname) pProxyClassname = "User."_pRemoteClassname
+		
+		$$$ThrowOnError(..GenerateProxyClass(pProxyClassname,.tConnectionSettings,tClassDetails,tRemoteSettings,pOverwrite))
+
+	} Catch ex {
+		set msg = $System.Status.GetOneStatusText(ex.AsStatus(),1)
+		set tSC = $$$ERROR($$$EnsErrGeneral,msg)
+	}
+
+	Quit tSC
+}
+
+ClassMethod DeleteComponentProxy(pClassname As %String = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim ex As %Exception.AbstractException
+	#dim tIsPEX As %Boolean = 0
+	#dim tClass As %Dictionary.CompiledClass
+	
+	Quit:(""=pClassname) $$$ERROR($$$EnsErrGeneral,"Remote class name must be specified.")
+	
+	Try {
+		
+		If '##class(%Dictionary.ClassDefinition).%ExistsId(pClassname) {
+			Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("No proxy class defined for remote class '%1'.",pClassname))
+			Quit
+		}
+		If $classmethod(pClassname,"%Extends","Grongier.PEX.Common") {
+			Set tClass = ##class(%Dictionary.CompiledClass).%OpenId(pClassname,,.tSC)
+			Quit:$$$ISERR(tSC)
+			If '$IsObject(tClass) {
+				Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Proxy class for remote class '%1' could not be opened.",pClassname))
+				Quit
+			}
+			Set tIsPEX = ("Grongier.PEX.Utils" = tClass.GeneratedBy)
+		}
+		If tIsPEX {
+			Set tSC = ##class(%Dictionary.ClassDefinition).%DeleteId(pClassname)
+			If $$$ISERR(tSC) {
+				Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Unable to delete proxy class for remote class '%1' : '%2'.",pClassname,$System.Status.GetErrorText(tSC)))
+				Quit
+			}
+		} Else {
+			Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Cannot delete class '%1' because it is not a PEX proxy class.",pClassname))
+			Quit
+		}
+		
+	} Catch ex {
+		Set tSC = ex.AsStatus()
+	}
+	
+	Quit tSC
+}
+
+// ..GetRemoteClassInfo(pRemoteClassname,pModule,pCLASSPATHS,.tClassDetails,.tRemoteSettings)
+
+ClassMethod GetRemoteClassInfo(
+	pRemoteClassname As %String,
+	pModule As %String,
+	pClasspaths As %String,
+	ByRef pClassDetails,
+	ByRef pRemoteSettings) As %Status [ Internal, Private ]
+{
+	#dim tSC As %Status = $$$OK
+	#dim ex As %Exception.AbstractException
+	#dim tGateway As %External.Gateway
+	#dim tGatewayProxy As %Net.Remote.Object
+	
+	Try {
+		if pClasspaths '="" {
+			set sys = ##class(%SYS.Python).Import("sys")
+			set delimiter = $s($system.Version.GetOS()="Windows":";",1:":")
+			set extraClasspaths = $tr(pClasspaths,delimiter,"|")
+			for i=1:1:$l(extraClasspaths,"|") {
+				set onePath = $p(extraClasspaths,"|",i)
+				set onePath = ##class(%File).NormalizeDirectory(onePath)
+				if onePath?1"$$IRISHOME"1P.E set onePath = $e($system.Util.InstallDirectory(),1,*-1)_$e(onePath,11,*)
+				if onePath'="" do sys.path.append(onePath)
+			}
+		}
+		;
+
+		set importlib = ##class(%SYS.Python).Import("importlib")
+		set builtins = ##class(%SYS.Python).Import("builtins")
+		set module = importlib."import_module"(pModule)
+		set class = builtins.getattr(module, pRemoteClassname)
+		set tClass = class."__new__"(class)
+
+
+		If $IsObject(tClass) {
+			#; List of information about the class as a whole - $lb(SuperClass, Description, InfoURL, IconURL, Adapter)
+			Set pClassDetails = tClass."_get_info"()
+			#; List of information about the various properties of the class
+			#; List of lists of form $lb(propName,dataType,defaultVal,required,category,description)
+			Set pRemoteSettings = tClass."_get_properties"()
+		} Else {
+			Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Error opening gateway proxy for class '%1'"),pRemoteClassname)
+		}
+	} Catch ex {
+		set msg = $System.Status.GetOneStatusText(ex.AsStatus(),1)
+		set tSC = $$$ERROR($$$EnsErrGeneral,msg)
+	}
+	
+	Quit tSC
+}
+
+/// Set tConnectionSettings("Classpaths") = pCLASSPATHS
+/// Set tConnectionSettings("Module") = pModule
+/// Set tConnectionSettings("Classname") = pRemoteClassname
+/// Set:(""=pProxyClassname) pProxyClassname = pRemoteClassname
+/// 
+/// Set tSC = ..GenerateProxyClass(pProxyClassname,.tConnectionSettings,tClassDetails,tRemoteSettings,pOverwrite)
+/// "bo","Duplex","/irisdev/app/src/python/demo/duplex/",1,"Duplex.Duplex"
+ClassMethod GenerateProxyClass(
+	pClassname As %String,
+	ByRef pConnectionSettings,
+	pClassDetails As %String = "",
+	pRemoteSettings As %String = "",
+	pOverwrite As %Boolean = 0) As %Status [ Internal, Private ]
+{
+	#dim tSC As %Status = $$$OK
+	#dim ex As %Exception.AbstractException
+	
+	Quit:(""=pClassname) $$$ERROR($$$EnsErrGeneral,"Class name must be specified in order to generate a proxy class for this Production EXtensions component")
+	
+	Try {
+
+		If ##class(%Dictionary.ClassDefinition).%ExistsId(pClassname) {
+			If 'pOverwrite {
+				Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Proxy class '%1' already exists.",pClassname))
+				Quit
+			} Else {
+				#dim tIsPEX As %Boolean = 0
+				If $classmethod(pClassname,"%Extends","Grongier.PEX.Common") {
+					#dim tClass As %Dictionary.CompiledClass = ##class(%Dictionary.CompiledClass).%OpenId(pClassname)
+					If '$IsObject(tClass) {
+						Set tSC = $$$ERROR($$$EnsErrGeneral,"Class not found")
+						Quit
+					}
+					Set tIsPEX = ("Grongier.PEX.Utils" = tClass.GeneratedBy)
+				}
+				If tIsPEX {
+					Set tSC = ##class(%Dictionary.ClassDefinition).%DeleteId(pClassname)
+					If $$$ISERR(tSC) {
+						Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Unable to delete existing proxy class '%1' : '%2'.",pClassname,$System.Status.GetErrorText(tSC)))
+						Quit
+					}
+				} Else {
+					Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Cannot overwrite class '%1' because it is not a PEX proxy class.",pClassname))
+					Quit
+				}
+			}
+		}
+		
+		#; create subclass of the ObjectScript Business Host
+		#dim tCOSClass As %Dictionary.ClassDefinition
+		Set tCOSClass = ##class(%Dictionary.ClassDefinition).%New()
+		Set tCOSClass.Name = pClassname
+
+		#dim tSuperClass As %String = pClassDetails."__getitem__"(0)
+		If (""=tSuperClass) {
+			Set tSC = $$$ERROR($$$EnsErrGeneral,"No PEX superclass found.")
+			Quit
+		}
+		If '$Case($P(tSuperClass,".",*),"DuplexProcess":1,"DuplexService":1,"DuplexOperation":1,"InboundAdapter":1,"OutboundAdapter":1,"BusinessService":1,"BusinessProcess":1,"BusinessOperation":1,:0) {
+			Set tSC = $$$ERROR($$$EnsErrGeneral,"Invalid superclass")
+			Quit
+		}
+		Set tSuperClass = "Grongier.PEX."_$P(tSuperClass,".",*)
+		
+		Set tCOSClass.Super = tSuperClass
+		Set tCOSClass.GeneratedBy = $CLASSNAME()
+		Set tCOSClass.ClassVersion = $$$CLASSDEFINITIONVERSION
+		#dim tDescription As %String = pClassDetails."__getitem__"(1)
+		If (""'=tDescription) {
+			Set tCOSClass.Description = $Replace(tDescription,$C(10),$C(13,10))
+		}
+		
+		#; Do not display any of the connection settings
+		#dim tSETTINGSParamValue As %String = "%classname:Python $type,%module:Python $type,%settings:Python $type,%classpaths:Python $type"
+		
+		#dim tPropClassname As %Dictionary.PropertyDefinition = ##class(%Dictionary.PropertyDefinition).%New()
+		Set tPropClassname.Name = "%classname"
+		Set tPropClassname.Type = "%String"
+		Set tPropClassname.InitialExpression = $$$quote(pConnectionSettings("Classname"))
+		Set tPropClassname.Internal = 1
+		Set tSC = tCOSClass.Properties.Insert(tPropClassname)
+		Quit:$$$ISERR(tSC)
+		
+		
+		#dim tPropClasspaths As %Dictionary.PropertyDefinition = ##class(%Dictionary.PropertyDefinition).%New()
+		Set tPropClasspaths.Name = "%classpaths"
+		Set tPropClasspaths.Type = "%String"
+		Set tSC = tPropClasspaths.Parameters.SetAt("","MAXLEN")
+		Quit:$$$ISERR(tSC)
+		Set tPropClasspaths.InitialExpression = $$$quote(pConnectionSettings("Classpaths"))
+		Set tPropClasspaths.Description = "One or more Classpaths (separated by '|' character) needed in addition to the ones configured in the Remote Gateway"
+		Set tSC = tCOSClass.Properties.Insert(tPropClasspaths)
+		Quit:$$$ISERR(tSC)
+		
+		
+		#dim tPropLanguage As %Dictionary.PropertyDefinition = ##class(%Dictionary.PropertyDefinition).%New()
+		Set tPropLanguage.Name = "%module"
+		Set tPropLanguage.Type = "%String"
+		Set tPropLanguage.Internal = 1
+		Set tPropLanguage.InitialExpression = $$$quote(pConnectionSettings("Module"))
+		Set tSC = tCOSClass.Properties.Insert(tPropLanguage)
+		Quit:$$$ISERR(tSC)
+		
+		If $Case(tSuperClass,"Grongier.PEX.BusinessService":1,"Grongier.PEX.BusinessOperation":1,"Grongier.PEX.DuplexService":1,"Grongier.PEX.DuplexOperation":1,:0) {
+			set builtins = ##class(%SYS.Python).Import("builtins")
+			If (builtins.len(pClassDetails)>4) { //Adaptor
+
+				#dim tAdapterClass = pClassDetails."__getitem__"(4)
+				#; May want to issue a warning in the UI if the Adapter class does not exist
+				#; but we don't check here because it does compile and may just be that the user is registering the Service/Operation before the Adapter
+				#dim tADAPTERParam As %Dictionary.ParameterDefinition = ##class(%Dictionary.ParameterDefinition).%New()
+				Set tADAPTERParam.Name = "ADAPTER"
+				Set tADAPTERParam.Default = tAdapterClass
+				Set tSC = tCOSClass.Parameters.Insert(tADAPTERParam)
+				Quit:$$$ISERR(tSC)
+			}
+		}
+
+		set type = ""
+		set:($Case(tSuperClass,"Grongier.PEX.InboundAdapter":1,"Grongier.PEX.OutboundAdapter":1,:0)) type = "Adapter"
+		set tSETTINGSParamValue = $REPLACE(tSETTINGSParamValue,"$type",type)
+		
+		#dim tSETTINGSParam As %Dictionary.ParameterDefinition = ##class(%Dictionary.ParameterDefinition).%New()
+		Set tSETTINGSParam.Name = "SETTINGS"
+		Set tSETTINGSParam.Default = tSETTINGSParamValue
+		Set tSC = tCOSClass.Parameters.Insert(tSETTINGSParam)
+		Quit:$$$ISERR(tSC)
+		
+		Set tSC = tCOSClass.%Save()
+		Quit:$$$ISERR(tSC)
+		
+		Set tSC = $System.OBJ.Compile(pClassname,"-d")
+		
+	} Catch ex {
+		Set tSC = ex.AsStatus()
+	}
+	
+	Quit tSC
+}
+
+ClassMethod CreateProduction(
+	package As %String = "test",
+	name As %String = "AutoCreatedProduction",
+	xdata As %CharacterStream) As %Status
+{
+  #Dim produtionClassName As %String = package _ "." _ name
+  If ('$ZName(produtionClassName, 4))
+  {
+  Return $System.Status.Error(5001, "Invalid Production package or name.")
+  }
+  #Dim productionDefinition As %Dictionary.ClassDefinition
+  // Check if the production already exists
+  If (##class(%Dictionary.ClassDefinition).%ExistsId(produtionClassName))
+  {
+	// Open the production
+	set productionDefinition = ##class(%Dictionary.ClassDefinition).%OpenId(produtionClassName)
+  }
+  Else
+  {
+	// Create the production definition
+    set productionDefinition = ##Class(%Dictionary.ClassDefinition).%New()
+  }
+  //
+  Set productionDefinition.Name         = produtionClassName
+  Set productionDefinition.Super        = "Ens.Production"
+  Set productionDefinition.ClassVersion = 25
+  //
+  // Check if the XData Definition already exists
+  If (##Class(%Dictionary.XDataDefinition).%ExistsId(produtionClassName_"||ProductionDefinition"))
+  {
+	// delete the XData Definition
+	$$$ThrowOnError(##Class(%Dictionary.XDataDefinition).%DeleteId(produtionClassName_"||ProductionDefinition"))
+  }
+  #Dim xdataDefinition As %Dictionary.XDataDefinition = ##Class(%Dictionary.XDataDefinition).%New()
+  //
+  Set xdataDefinition.Name = "ProductionDefinition"
+  //
+  Do xdataDefinition.Data.CopyFrom(xdata)
+  //
+  // Insert XData Definition into Production Definition
+  Do productionDefinition.XDatas.Insert(xdataDefinition)
+  //
+  #Dim statusCode As %Status = productionDefinition.%Save()
+  //
+  If ($System.Status.IsError(statusCode))
+  {
+  Return statusCode
+  }
+  // Compile the production class
+  return $System.OBJ.Compile(produtionClassName,"k-d")
+}
+
+/// Export a production to an XML string
+ClassMethod ExportProduction(pProductionName As %String) As %String
+{
+	Set sc = $$$OK
+	set xdata = ""
+	// Check if the XData Definition exists
+	If (##Class(%Dictionary.XDataDefinition).%ExistsId(pProductionName_"||ProductionDefinition"))
+	{
+		// Open the XData Definition
+		Set xdataDefinition = ##Class(%Dictionary.XDataDefinition).%OpenId(pProductionName_"||ProductionDefinition")
+		Set xdata = xdataDefinition.Data
+	}
+	Else
+	{
+		$$$ThrowOnError($System.Status.Error(5001, "Production does not exist."))
+	}
+	Return xdata
+}
+
+}

grongier/pex/data/PEX/WSGI.cls

@@ -0,0 +1,99 @@
+Class Grongier.PEX.WSGI Extends (%RegisteredObject, %CSP.REST) [ ServerOnly = 1 ]
+{
+
+Parameter CLASSPATHS;
+
+Parameter MODULENAME;
+
+Parameter APPNAME;
+
+/// Instance of class
+Property app As %SYS.Python;
+
+/// Helper method to write data to the output stream
+ClassMethod write(data)
+{
+    w data
+}
+
+/// Helper to build the environ
+ClassMethod GetEnviron() As %SYS.Python
+{
+    //set builtins
+    set builtins = ##class(%SYS.Python).Import("builtins")
+
+    //import dict to create environ
+    set dict = builtins.dict()
+
+    #dim %request As %CSP.Request
+
+    //set environ 
+    do dict."__setitem__"("SERVER_NAME", $System.INetInfo.LocalHostName())
+    do dict."__setitem__"("SERVER_PORT", "")
+    do dict."__setitem__"("SERVER_PROTOCOL", "HTTP/1.1")
+    do dict."__setitem__"("SERVER_SOFTWARE", "IRIS")
+    do dict."__setitem__"("SCRIPT_NAME", ..#APPNAME)
+    do dict."__setitem__"("REQUEST_METHOD", %request.Method)
+    do dict."__setitem__"("CONTENT_TYPE", %request.ContentType)
+    do dict."__setitem__"("CHARSET", %request.CharSet)
+    Set app=$$getapp^%SYS.cspServer(%request.URL,.path,.match,.updatedurl)
+    do dict."__setitem__"("PATH_INFO", $extract(updatedurl,$length(path),*))
+
+    // to extract the query string
+
+    return dict
+}
+
+ClassMethod Page(skipheader As %Boolean = 1) As %Status [ Internal, ServerOnly = 1 ]
+{
+    Try {
+        //set classpass
+        if ..#CLASSPATHS '="" {
+            set sys = ##class(%SYS.Python).Import("sys")
+            set delimiter = $s($system.Version.GetOS()="Windows":";",1:":")
+            set extraClasspaths = $tr(..#CLASSPATHS,delimiter,"|")
+            for i=1:1:$l(extraClasspaths,"|") {
+                set onePath = $p(extraClasspaths,"|",i)
+                set onePath = ##class(%File).NormalizeDirectory(onePath)
+                if onePath?1"$$IRISHOME"1P.E set onePath = $e($system.Util.InstallDirectory(),1,*-1)_$e(onePath,11,*)
+                if onePath'="" do sys.path.append(onePath)
+            }
+        }
+
+        //set environ
+        set environ = ..GetEnviron()
+
+        //import sys
+        set sys = ##class(%SYS.Python).Import("sys")
+
+        //set stdin
+        set builtins = ##class(%SYS.Python).Import("builtins")
+        set ba = builtins.bytearray()
+        
+        while %request.Content.AtEnd = 0 {
+            do ba.extend(##class(%SYS.Python).Bytes(%request.Content.Read()))
+        }
+        //set handler
+        set handler = ##class(%SYS.Python).Import("grongier.pex.wsgi.handlers").IrisHandler(ba, sys.stdout, sys.stderr,environ)
+
+        //set module
+        set module = ##class(%SYS.Python).Import(..#MODULENAME)
+
+        //set builtins
+        set builtins = ##class(%SYS.Python).Import("builtins")
+
+        //set app
+        set application = builtins.getattr(module, ..#APPNAME)
+
+        //run app
+        do handler.run(application)
+
+    }
+    Catch ex {
+        return ex.AsStatus()
+    }
+
+    quit $$$OK
+}
+
+}

{iris_pex_embedded_python-2.3.3.dist-info → iris_pex_embedded_python-2.3.5.dist-info}/METADATA

@@ -1,6 +1,6 @@
 Metadata-Version: 2.1
 Name: iris-pex-embedded-python
-Version: 2.3.3
+Version: 2.3.5
 Summary: iris_pex_embedded_python
 Home-page: https://github.com/grongierisc/interoperability-embedded-python
 Author: grongier

iris_pex_embedded_python-2.3.5.dist-info/RECORD

@@ -0,0 +1,42 @@
+grongier/pex/__init__.py,sha256=nvcmRCxLy-lpL5GzlCKrmsSK8LF8Q0aKddx6ib8U50E,1166
+grongier/pex/__main__.py,sha256=ebEYPDOBKiXOlmdI4onpQLzfBKU4wyfijYyquA5dWV4,107
+grongier/pex/_business_host.py,sha256=01JsAKt4DMQ6X1IhNIUH5cgg38Hh9eKgPJUHY8qZi1c,20152
+grongier/pex/_business_operation.py,sha256=W_B9Ci1fei8SGcElkAd13gV9S4BNKeQciTMVqxxJVZc,3509
+grongier/pex/_business_process.py,sha256=qzt3FL3aqHhcOVR043zjYlHCET5ZRz_zNNdCbI7TXTE,12013
+grongier/pex/_business_service.py,sha256=8CgpjcdVmv5747CTa3Lw3B48RYXq2SQN9qfdxvqEI5g,3735
+grongier/pex/_cli.py,sha256=SJoEUQ8dTFDVZ0sQlmvGLSg0mzcOSW7hvOrS9G5g7f4,5647
+grongier/pex/_common.py,sha256=yiJ-sH4ml5u9qEnZFX_4F-Rn2X6shtMhceJA9RCMChI,15158
+grongier/pex/_director.py,sha256=0P1M6k2MaqViK-Mavfsu0RaI876HHPgarrUnA0a0ftA,8810
+grongier/pex/_inbound_adapter.py,sha256=aQqRfyw69Iz6AaYzeTAbC_ERDvKadY3tSSC1LJCUVQg,1661
+grongier/pex/_message.py,sha256=BmwBXriykU66bwAgRbdkMpjfJRVWoNRX2eDc9TXfXzA,325
+grongier/pex/_outbound_adapter.py,sha256=HOxTSGwgQVDXzYpSMArLEmipPNYLxOCFaiN51MelFNA,735
+grongier/pex/_pickle_message.py,sha256=noKfc2VkXufV3fqjKvNHN_oANQ1YN9ffCaSV0XSTAIE,331
+grongier/pex/_private_session_duplex.py,sha256=Qj_xzwwFnFVwi_Sl7Q7nKk4zmL6UC8iqBAuwnz7mVX8,5033
+grongier/pex/_private_session_process.py,sha256=_2r_csWcVRLmIUt4O0Y1Hg1FcX6A08lt9DvALQhwu8s,1722
+grongier/pex/_utils.py,sha256=bzd3nmBTso6HKMzyZZERY5Ai_8DsJrU54kHBe0HMy_8,15325
+grongier/pex/data/PEX/BusinessOperation.cls,sha256=qvLahHnQPAKMrGCekQNXPJgKPvlCWH5nJa0eYvceGvQ,932
+grongier/pex/data/PEX/BusinessProcess.cls,sha256=-7REU1ny8QhQGS0zpB1ByUtbspTzmtZ1nZ9TiLFf48A,2719
+grongier/pex/data/PEX/BusinessService.cls,sha256=2FXGkJ29zU3m-BcMVJTqD9skG9o7GvcHw60DAx4Fj3s,1039
+grongier/pex/data/PEX/Common.cls,sha256=N1tioRUfh7fZqw7OqZul7vlpaHC9lXIQtczogmwtXFM,3538
+grongier/pex/data/PEX/Director.cls,sha256=wImRl1P37_A-Om8ahl2hfl92hxicqKnKAqzHOE4L8wg,1894
+grongier/pex/data/PEX/InboundAdapter.cls,sha256=j-6tQPzo3tWTq7HJNxDR-4cK3VGVG0o3zgzD5LzIa74,628
+grongier/pex/data/PEX/Message.cls,sha256=tM5gkSdoCdssxAcX6mV4e3BoVgYBmNnNUsmAH_d-cHc,8227
+grongier/pex/data/PEX/OutboundAdapter.cls,sha256=75AquKo4iZ7Hzzo2nVrh1Z4CnS8x-qPO-Q1HpgUZRQw,976
+grongier/pex/data/PEX/PickleMessage.cls,sha256=M8Q5-BHddj6gnURYAGTlaNPB-o1JByycBrCKbpqfDLE,1691
+grongier/pex/data/PEX/Test.cls,sha256=97xsKrV0KuaE-2V_vUsDLdV0VNCGp2BXKWSkuAjp628,1622
+grongier/pex/data/PEX/Utils.cls,sha256=iZg3a7eHJ06579LTbeKtlM3qHJ2RSUskXTL8snSPbOc,13498
+grongier/pex/data/PEX/WSGI.cls,sha256=hso1O3VVFWxAAO4C6zuuhgyqDw26EP0N3eMCVuEYAzk,2908
+grongier/pex/data/PEX/Duplex/Operation.cls,sha256=bt6j7ZdhFyYfQAhNZEWoHtIYoOgOWqCb5s6VmlJjc4E,543
+grongier/pex/data/PEX/Duplex/Process.cls,sha256=sLoYjHJHYNBx2kpEijvkIH1ZgMmUD_Pr7aUiguloxEs,7103
+grongier/pex/data/PEX/Duplex/Service.cls,sha256=omgn16L2XfagAN8iZXXrlyNToRe5Af-kMBnjMzMigdo,179
+grongier/pex/data/PEX/PrivateSession/Duplex.cls,sha256=w5Lx9gXKrOs4QOBJ7_eet5vWdpHMegddL5j43EaZwEE,8065
+grongier/pex/data/PEX/PrivateSession/Message/Ack.cls,sha256=WbBn7pWj5mzruVfLpOAwzTW4JG44qDKHOSJq82_UgTc,986
+grongier/pex/data/PEX/PrivateSession/Message/Poll.cls,sha256=2lj-e20AH7RR8UgGJaldrk-1kd8WjQJNPiH-duds_4A,987
+grongier/pex/data/PEX/PrivateSession/Message/Start.cls,sha256=DAtq4DyRqFq2_4Isa0cZjjwuAzdHjsQu8wMppK4myzs,994
+grongier/pex/data/PEX/PrivateSession/Message/Stop.cls,sha256=ofVKjrN6UPFasalrjPFWYNwlJ5IBlAE62IH8_U07c0g,1435
+iris_pex_embedded_python-2.3.5.dist-info/LICENSE,sha256=rZSiBFId_sfbJ6RL0GjjPX-InNLkNS9ou7eQsikciI8,1089
+iris_pex_embedded_python-2.3.5.dist-info/METADATA,sha256=kYmIf8bh3L3MjdFQwkWmgSEVC3f-yc4JLIRxz_VfIuU,49500
+iris_pex_embedded_python-2.3.5.dist-info/WHEEL,sha256=pkctZYzUS4AYVn6dJ-7367OJZivF2e8RA9b_ZBjif18,92
+iris_pex_embedded_python-2.3.5.dist-info/entry_points.txt,sha256=atkAtHoIuwXcZ0jl5gwof0l__ru_lt8WhVYk6HxYf70,47
+iris_pex_embedded_python-2.3.5.dist-info/top_level.txt,sha256=IHTNyQ_h3DSfdFPl6yKfe3Flu-EfpykyfJi7jo-O6Vs,9
+iris_pex_embedded_python-2.3.5.dist-info/RECORD,,

iris_pex_embedded_python-2.3.3.dist-info/RECORD

@@ -1,23 +0,0 @@
-grongier/iris/__init__.py,sha256=47DEQpj8HBSa-_TImW-5JCeuQeRkm5NMpJWZG3hSuFU,0
-grongier/pex/__init__.py,sha256=nvcmRCxLy-lpL5GzlCKrmsSK8LF8Q0aKddx6ib8U50E,1166
-grongier/pex/__main__.py,sha256=ebEYPDOBKiXOlmdI4onpQLzfBKU4wyfijYyquA5dWV4,107
-grongier/pex/_business_host.py,sha256=01JsAKt4DMQ6X1IhNIUH5cgg38Hh9eKgPJUHY8qZi1c,20152
-grongier/pex/_business_operation.py,sha256=W_B9Ci1fei8SGcElkAd13gV9S4BNKeQciTMVqxxJVZc,3509
-grongier/pex/_business_process.py,sha256=WtO1RCZUKykaxUFocI1XmZmnSQzEOz_VFsVFytsOzFE,11838
-grongier/pex/_business_service.py,sha256=8CgpjcdVmv5747CTa3Lw3B48RYXq2SQN9qfdxvqEI5g,3735
-grongier/pex/_cli.py,sha256=94ZVqhdZWE80gV8BM0cEQ-eutioda2sfhWJn-lI46Xg,5320
-grongier/pex/_common.py,sha256=Mf3nX0Jf0YHPN72PeXIKd5kJbkz4N3xVqlGlEyL2DIM,15107
-grongier/pex/_director.py,sha256=0P1M6k2MaqViK-Mavfsu0RaI876HHPgarrUnA0a0ftA,8810
-grongier/pex/_inbound_adapter.py,sha256=aQqRfyw69Iz6AaYzeTAbC_ERDvKadY3tSSC1LJCUVQg,1661
-grongier/pex/_message.py,sha256=BmwBXriykU66bwAgRbdkMpjfJRVWoNRX2eDc9TXfXzA,325
-grongier/pex/_outbound_adapter.py,sha256=HOxTSGwgQVDXzYpSMArLEmipPNYLxOCFaiN51MelFNA,735
-grongier/pex/_pickle_message.py,sha256=noKfc2VkXufV3fqjKvNHN_oANQ1YN9ffCaSV0XSTAIE,331
-grongier/pex/_private_session_duplex.py,sha256=Qj_xzwwFnFVwi_Sl7Q7nKk4zmL6UC8iqBAuwnz7mVX8,5033
-grongier/pex/_private_session_process.py,sha256=_2r_csWcVRLmIUt4O0Y1Hg1FcX6A08lt9DvALQhwu8s,1722
-grongier/pex/_utils.py,sha256=7fqVgqM5fXCOnqw8CSayrHnl_VMejX9zXMm9SEKfvso,15120
-iris_pex_embedded_python-2.3.3.dist-info/LICENSE,sha256=rZSiBFId_sfbJ6RL0GjjPX-InNLkNS9ou7eQsikciI8,1089
-iris_pex_embedded_python-2.3.3.dist-info/METADATA,sha256=ODdhlwRr-rTxBPUsdlgmdGInzMQuo5eMo0p-eKamo_s,49500
-iris_pex_embedded_python-2.3.3.dist-info/WHEEL,sha256=pkctZYzUS4AYVn6dJ-7367OJZivF2e8RA9b_ZBjif18,92
-iris_pex_embedded_python-2.3.3.dist-info/entry_points.txt,sha256=atkAtHoIuwXcZ0jl5gwof0l__ru_lt8WhVYk6HxYf70,47
-iris_pex_embedded_python-2.3.3.dist-info/top_level.txt,sha256=IHTNyQ_h3DSfdFPl6yKfe3Flu-EfpykyfJi7jo-O6Vs,9
-iris_pex_embedded_python-2.3.3.dist-info/RECORD,,