iris-pex-embedded-python 2.3.28b3__py3-none-any.whl → 3.0.0__py3-none-any.whl

iop/cls/IOP/Common.cls

@@ -0,0 +1,203 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Include Ensemble
+
+Class IOP.Common [ Abstract, ClassType = "", ProcedureBlock, System = 4 ]
+{
+
+/// One or more Classpaths (separated by '|' character) needed in addition to the ones configured in the Java Gateway Service
+Property %classpaths As %String(MAXLEN = "");
+
+Property %classname As %String(MAXLEN = "");
+
+Property %module As %String(MAXLEN = "");
+
+Property %settings As %String(MAXLEN = "");
+
+/// Instance of class
+Property %class As %SYS.Python;
+
+/// Get Class
+Method GetClass() As %SYS.Python
+{
+    Return ..%class
+}
+
+/// Get Classname
+Method GetClassname() As %String
+{
+    Return ..%classname
+}
+
+/// Get Classname
+Method GetModule() As %String
+{
+    Return ..%module
+}
+
+Method OnInit() As %Status
+{
+    set tSC = $$$OK
+    try {
+        $$$ThrowOnError(..Connect())
+        do ..%class."_dispatch_on_init"($this)
+    } catch ex {
+        set tSC = ex.AsStatus()
+    }
+    quit tSC
+}
+
+ClassMethod SetPythonPath(pClasspaths)
+{
+    set sys = ##class(%SYS.Python).Import("sys")
+
+    for i=0:1:(sys.path."__len__"()-1) {
+        Try {
+            if sys.path."__getitem__"(i) = pClasspaths {
+                do sys.path."__delitem__"(i)
+            }
+        }
+        Catch ex {
+            // do nothing
+        }
+
+    }
+    do sys.path.insert(0, pClasspaths)
+}
+
+Method Connect() As %Status
+{
+    set tSC = $$$OK
+    try {
+        
+        set container = $this
+        
+        //set classpass
+        if ..%classpaths '="" {
+            set delimiter = $s($system.Version.GetOS()="Windows":";",1:":")
+            set extraClasspaths = $tr(container.%classpaths,delimiter,"|")
+            for i=1:1:$l(extraClasspaths,"|") {
+                set onePath = $p(extraClasspaths,"|",i)
+                set onePath = ##class(%File).NormalizeDirectory(onePath)
+                do ..SetPythonPath(onePath)
+            }
+        }
+        if $isObject(..%class)=0 {
+            set importlib = ##class(%SYS.Python).Import("importlib")
+            set builtins = ##class(%SYS.Python).Import("builtins")
+            set module = importlib."import_module"(..%module)
+            set class = builtins.getattr(module, ..%classname)
+            set ..%class = class."__new__"(class)
+        }
+        ;
+        if ..%Extends("IOP.InboundAdapter") || ..%Extends("IOP.OutboundAdapter") {
+            do ..%class."_set_iris_handles"($this,..BusinessHost)
+        } elseif $this.%Extends("IOP.BusinessProcess") {
+            do ..%class."_set_iris_handles"($this,$$$NULLOREF)
+        } else {
+            do ..%class."_set_iris_handles"($this,..Adapter)
+        }
+        ;
+        do ..SetPropertyValues()
+        ;
+        try {
+            do ..%class."_dispatch_on_connected"($this)
+        } catch ex {
+            $$$LOGWARNING(ex.DisplayString())
+        }
+        ;
+    } catch ex {
+        set msg = $System.Status.GetOneStatusText(ex.AsStatus(),1)
+        set tSC = $$$ERROR($$$EnsErrGeneral,msg)
+    }
+    quit tSC
+}
+
+Method OnTearDown() As %Status
+{
+    set tSC = $$$OK
+    do ..%class."_dispatch_on_tear_down"()
+    quit tSC
+}
+
+Method SetPropertyValues()
+{
+    set remoteSettings = $tr(..%settings,$c(13))
+    for i=1:1:$l(remoteSettings,$c(10)) {
+        set oneLine = $p(remoteSettings,$c(10),i)
+        set property = $p(oneLine,"=",1) continue:property=""
+        set value = $p(oneLine,"=",2,*)
+        try {
+            set $property(..%class,property) = value
+        } catch ex {
+            $$$LOGWARNING(ex.DisplayString())
+        }
+    }
+    quit
+}
+
+Method dispatchSendRequestSync(
+	target,
+	request,
+	timeout,
+	description) As %String
+{
+    set tSC = ..SendRequestSync(target,request,.objResponse,timeout,description)
+    if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+    quit $g(objResponse)
+}
+
+Method dispatchSendRequestAsync(
+	target,
+	request,
+	description)
+{
+    set tSC = ..SendRequestAsync(target,request,description)
+    if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+    quit
+}
+
+ClassMethod OnGetConnections(
+	Output pArray As %String,
+	pItem As Ens.Config.Item)
+{
+    // finds any settings of type Ens.DataType.ConfigName
+    do ..GetPropertyConnections(.pArray,pItem)
+
+    // Get settings
+    do pItem.GetModifiedSetting("%classpaths", .tClasspaths)
+    do pItem.GetModifiedSetting("%classname", .tClassname)
+    do pItem.GetModifiedSetting("%module", .tModule)
+
+    // try to instantiate class
+    if tClasspaths '="" {
+            set sys = ##class(%SYS.Python).Import("sys")
+            set delimiter = $s($system.Version.GetOS()="Windows":";",1:":")
+            set extraClasspaths = $tr(tClasspaths,delimiter,"|")
+            for i=1:1:$l(extraClasspaths,"|") {
+                set onePath = $p(extraClasspaths,"|",i)
+                set onePath = ##class(%File).NormalizeDirectory(onePath)
+                if onePath?1"$$IRISHOME"1P.E set onePath = $e($system.Util.InstallDirectory(),1,*-1)_$e(onePath,11,*)
+                if onePath'="" do sys.path.append(onePath)
+            }
+    }
+    set importlib = ##class(%SYS.Python).Import("importlib")
+    set builtins = ##class(%SYS.Python).Import("builtins")
+    set module = importlib."import_module"(tModule)
+    set class = builtins.getattr(module, tClassname)
+    set tClass = class."__new__"(class)
+
+    set tPythonList = tClass."on_get_connections"()
+    set tPythonListLen = tPythonList."__len__"()
+    for i=0:1:(tPythonListLen-1) {
+        set tPythonItem = tPythonList."__getitem__"(i)
+        set pArray(tPythonItem) = ""
+		#; set ^AALog(pItem.Name,tPythonItem) = ""
+    }
+
+    quit
+}
+
+}

iop/cls/IOP/Director.cls

@@ -0,0 +1,57 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Include (%occInclude, Ensemble)
+
+Class IOP.Director [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+ClassMethod dispatchCreateBusinessService(pTargetDispatchName As %String) As Ens.BusinessService
+{
+	set tSC = ##class(Ens.Director).CreateBusinessService(pTargetDispatchName,.service)
+	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+	quit service
+}
+
+ClassMethod dispatchListProductions() As %String
+{
+	// Loop over the productions in this namespace
+	Set tRS = ##class(%ResultSet).%New("Ens.Config.Production:ProductionStatus")
+	If '$IsObject(tRS) Set tSC = %objlasterror Quit
+	
+	Set tSC = tRS.Execute()
+	Quit:$$$ISERR(tSC)
+	
+	set tDict = ##class(%SYS.Python).Import("builtins").dict()
+
+	While (tRS.Next()) {
+		Set tProduction = tRS.Data("Production")
+		Set tInfo = ##class(%SYS.Python).Import("builtins").dict()
+		do tInfo."__setitem__"("Status",tRS.Data("Status"))
+		do tInfo."__setitem__"("LastStartTime",tRS.Data("LastStartTime"))
+		do tInfo."__setitem__"("LastStopTime",tRS.Data("LastStopTime"))
+		do tInfo."__setitem__"("AutoStart",$G(^Ens.AutoStart)=tProduction)
+		do tDict."__setitem__"(tProduction,tInfo)
+	}
+
+	Kill tRS
+
+	return tDict
+}
+
+ClassMethod StatusProduction() As %String
+{
+	Set sc = $$$OK
+	Set tInfo = ##class(%SYS.Python).Import("builtins").dict()
+	$$$ThrowOnError(##class(Ens.Director).GetProductionStatus(.tProdName,.tStatus))
+	do tInfo."__setitem__"("Production",tProdName)
+	do tInfo."__setitem__"("Status",$CASE(tStatus,$$$eProductionStateRunning:"running",
+												$$$eProductionStateStopped:"stopped",
+												$$$eProductionStateSuspended:"suspended",
+												$$$eProductionStateTroubled:"toubled",
+												:"unknown"))
+	Return tInfo
+}
+
+}

iop/cls/IOP/Duplex/Operation.cls

@@ -0,0 +1,29 @@
+Class IOP.DuplexOperation Extends IOP.PrivateSessionDuplex
+{
+
+ClassMethod OnBusinessType(pItem As Ens.Config.Item) As %Integer
+{
+    Quit $$$eHostTypeOperation
+}
+
+XData MessageMap
+{
+<MapItems>
+<MapItem MessageType="Ens.Request"><Method>OnMessage</Method></MapItem>
+</MapItems>
+}
+
+Method OnMessage(
+	request As %Library.Persistent,
+	Output response As %Library.Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_message"(request)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+}

iop/cls/IOP/Duplex/Process.cls

@@ -0,0 +1,229 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.DuplexProcess Extends IOP.BusinessProcess [ ClassType = persistent, ProcedureBlock, System = 4 ]
+{
+
+/// Domain for Text localization
+Parameter DOMAIN = "PrivateSession";
+
+/// The Duplex Service name. This property is set at runtime after receiving the primary request
+Property ServiceDuplexName As %String;
+
+/// Indicates if a given ConfigItem is in private session or not
+Property %IsInPrivateSession As array Of %Boolean(STORAGEDEFAULT = "list");
+
+/// This method is always called asynchronously ONCE at the beginning of the process
+Method OnRequest(
+	pRequest As %Library.Persistent,
+	Output pResponse As Ens.Response) As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If $IsObject(pRequest)&&($classname(pRequest)="IOP.PrivateSession.Message.Start") {
+			Set tSC=..Reply(##class(IOP.PrivateSession.Message.Ack).%New()) Quit:$$$ISERR(tSC)
+			Set ..ServiceDuplexName = ..%PrimaryRequestHeader.SourceConfigName
+			Do ..IsInPrivateSessionSet(..ServiceDuplexName,1)
+			Set tSC=..SendRequestAsync(..ServiceDuplexName,##class(IOP.PrivateSession.Message.Poll).%New(),1) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStarted(..ServiceDuplexName,0) Quit:$$$ISERR(tSC)
+		} Else {
+			Set tSC=..OnDocument(..%PrimaryRequestHeader.SourceConfigName,pRequest)
+		}
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+/// Handle a 'Response'
+Method OnResponse(
+	request As %Library.Persistent,
+	ByRef response As %Library.Persistent,
+	callrequest As %Library.Persistent,
+	callresponse As %Library.Persistent,
+	pCompletionKey As %String) As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim tSourceConfigName, tOneConfigName As %String
+	try {
+		; get the SourceConfigName of this message
+		Set tSourceConfigName=..%CurrentResponseHeader.SourceConfigName
+		; handle SessionStop message
+		If $IsObject(callresponse)&&($classname(callresponse)="IOP.PrivateSession.Message.Ack") {
+			Do ..IsInPrivateSessionSet(tSourceConfigName,1)
+			Set tSC=..SendRequestAsync(tSourceConfigName,##class(IOP.PrivateSession.Message.Poll).%New(),1) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStarted(tSourceConfigName,1) Quit:$$$ISERR(tSC)
+			Quit
+		}
+		; handle SessionStop message
+		If $IsObject(callresponse)&&($classname(callresponse)="IOP.PrivateSession.Message.Stop") {
+			Set tSC=..UnRegisterPrivateSession(tSourceConfigName) Quit:$$$ISERR(tSC)
+			Set tSC=..OnPrivateSessionStopped(tSourceConfigName,0,callresponse.AttachedMessage) Quit:$$$ISERR(tSC)
+			Quit
+		}
+		; send poll request again back to the same ConfigItem if this this is in response to a poll request
+		If $IsObject(callrequest)&&($classname(callrequest)="IOP.PrivateSession.Message.Poll") {
+			If ..IsInPrivateSession(tSourceConfigName) {
+				Set tSC=..SendRequestAsync(tSourceConfigName,##class(IOP.PrivateSession.Message.Poll).%New(),1) If $$$ISERR(tSC)
+			}
+		}
+		; call OnDocument
+		Set tSC=..OnDocument(tSourceConfigName,callresponse) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StartPrivateSession(pDuplexConfigName As %String = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If pDuplexConfigName="" Set tSC=$$$EnsError($$$EnsErrGeneral,"Duplex configuration name is missing") Quit
+		If ..IsInPrivateSession(pDuplexConfigName) Quit
+		Set tSC=..SendRequestAsync(pDuplexConfigName,##class(IOP.PrivateSession.Message.Start).%New()) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StopPrivateSession(
+	pDuplexConfigName As %String = "",
+	pAttachedMessage As %Persistent = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		If pDuplexConfigName="" Set tSC=$$$EnsError($$$EnsErrGeneral,"Duplex configuration name is missing") Quit
+		If '..IsInPrivateSession(pDuplexConfigName) Quit
+		Set tSC=..SendRequestAsync(pDuplexConfigName,##class(IOP.PrivateSession.Message.Stop).%New(pAttachedMessage),0) Quit:$$$ISERR(tSC)
+		Set tSC=..UnRegisterPrivateSession(pDuplexConfigName)
+		Set tSC=..OnPrivateSessionStopped(pDuplexConfigName,1) Quit:$$$ISERR(tSC)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method StopAllPrivateSessions(pAttachedMessage As %Persistent = "") As %Status
+{
+	#dim tSC As %Status = $$$OK
+	#dim tItem As %String
+	try {
+		Set tItem="" For  {
+			Set tItem=..%IsInPrivateSession.Next(tItem) Quit:tItem=""
+			Set tSC=..StopPrivateSession(tItem,pAttachedMessage) Quit:$$$ISERR(tSC)
+		}
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method UnRegisterPrivateSession(pDuplexConfigName As %String) As %String
+{
+	#dim tSC As %Status = $$$OK
+	try {
+		For i=..%MasterPendingResponses.Count():-1:1 {
+			Set tRequestHeader=##class(Ens.MessageHeader).%OpenId($li(..%MasterPendingResponses.GetAt(i),1))
+			If $IsObject(tRequestHeader),tRequestHeader.TargetConfigName=pDuplexConfigName,tRequestHeader.MessageBodyClassName="IOP.PrivateSession.Message.Poll" {
+				Do ..%MasterPendingResponses.RemoveAt(i)
+			}
+		}
+		Do ..IsInPrivateSessionSet(pDuplexConfigName,0)
+	} catch {
+		Set tSC=$$$EnsSystemError
+	}
+	Quit tSC
+}
+
+Method IsInPrivateSessionSet(
+	pDuplexConfigName As %String,
+	pInPrivateSession As %Boolean)
+{
+	If pInPrivateSession {
+		Do ..%IsInPrivateSession.SetAt(1,pDuplexConfigName)
+	} Else {
+		Do ..%IsInPrivateSession.RemoveAt(pDuplexConfigName)
+	}
+	Quit
+}
+
+Method IsInPrivateSession(pDuplexConfigName As %String) As %Boolean
+{
+	If pDuplexConfigName="" Quit 0
+	Quit ..%IsInPrivateSession.IsDefined(pDuplexConfigName)
+}
+
+Method OnDocument(
+	pSourceConfigName As %String,
+	pInput As %Library.Persistent) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_document"($this,pSourceConfigName,pInput)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnPrivateSessionStarted(
+	pSourceConfigName As %String,
+	pSelfGenerated As %Boolean) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_started"($this,pSourceConfigName,pSelfGenerated)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnPrivateSessionStopped(
+	pSourceConfigName As %String,
+	pSelfGenerated As %Boolean,
+	pAttachedMessage As %Persistent = "") As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_stopped"($this,pSourceConfigName,pSelfGenerated,pAttachedMessage)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Storage Default
+{
+<Data name="ProcessDefaultData">
+<Subscript>"Process"</Subscript>
+<Value name="1">
+<Value>ServiceDuplexName</Value>
+</Value>
+<Value name="2">
+<Value>%IsInPrivateSession</Value>
+</Value>
+<Value name="3">
+<Value>%classpaths</Value>
+</Value>
+<Value name="4">
+<Value>%classname</Value>
+</Value>
+<Value name="5">
+<Value>%module</Value>
+</Value>
+<Value name="6">
+<Value>%settings</Value>
+</Value>
+<Value name="7">
+<Value>%class</Value>
+</Value>
+</Data>
+<DefaultData>ProcessDefaultData</DefaultData>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/Duplex/Service.cls

@@ -0,0 +1,9 @@
+Class IOP.DuplexService Extends IOP.PrivateSessionDuplex
+{
+
+ClassMethod OnBusinessType(pItem As Ens.Config.Item) As %Integer
+{
+    Quit $$$eHostTypeService
+}
+
+}

iop/cls/IOP/InboundAdapter.cls

@@ -0,0 +1,22 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.InboundAdapter Extends (Ens.InboundAdapter, IOP.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter SETTINGS = "%classname:Python InboundAdapter,%module:Python InboundAdapter,%settings:Python InboundAdapter,%classpaths:Python InboundAdapter";
+
+Method OnTask() As %Status
+{
+	set tSC = $$$OK
+	try {
+		$$$ThrowOnError(..Connect())
+		do ..%class."on_task"()
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+}

iop/cls/IOP/Message.cls

@@ -0,0 +1,128 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.Message Extends (Ens.MessageBody, %CSP.Page, %XML.Adaptor)
+{
+
+Parameter BUFFER = 64000;
+
+Property classname As %String(MAXLEN = "");
+
+Property jsonObject As %DynamicObject(XMLPROJECTION = "None");
+
+Property json As %String(MAXLEN = "");
+
+Property jstr As %Stream.GlobalCharacter [ Internal, Private ];
+
+Method %OnNew(classname) As %Status [ Private, ServerOnly = 1 ]
+{
+	set ..classname = $g(classname)
+	Quit $$$OK
+}
+
+Method jsonGet()
+{
+	QUIT ..GetObjectJson()
+}
+
+Method jsonSet(value) As %Status
+{
+	set ..jsonObject = {}.%FromJSON(value)
+	set ..jstr = ##class(%Stream.GlobalCharacter).%New()
+    do ..jstr.Write(value)
+	return $$$OK
+}
+
+Method %DispatchGetProperty(property As %String) As %ObjectHandle
+{
+	quit $property(..jsonObject,property)
+}
+
+Method %DispatchSetProperty(
+	property As %String,
+	value)
+{
+	set $property(..jsonObject,property) = value
+	quit
+}
+
+Method GetObjectJson(ByRef atEnd)
+{
+	set atEnd = 1
+	set json = ..jsonObject.%ToJSON()
+	if json = "{}" {
+		d ..jstr.Rewind()
+		set json = ..jstr.Read(..#BUFFER)
+        set atEnd = ..jstr.AtEnd
+	}
+    QUIT json
+}
+
+/// This method is called by the Management Portal to determine the content type that will be returned by the <method>%ShowContents</method> method.
+/// The return value is a string containing an HTTP content type.
+Method %GetContentType() As %String
+{
+	Quit "text/html"
+}
+
+/// This method is called by the Management Portal to display a portion of the HEAD section of a message-specific content viewer.<br>
+Method %ShowContentsHead(pZenOutput As %Boolean = 0)
+{
+    &html<<script src="https://code.jquery.com/jquery-2.1.1.min.js"></script>> 
+	&html<<script>var makeCompleteJSON=function(l,n){for(var r=["{","}","[","]",'"',"'"],t=function(l){for(var n=l.split(""),r=null,t=[],u=0;u<n.length;u++)char=n[u],"'"!=char&&'"'!=char||(null==r?r=char:r==char&&(r=null)),null==r&&":"==char&&t.push(u);return 1==t.length&&t[0]!=n.length-1},u=[],p=null,e=l.split(""),h="",o=-1,a=[],i=0;i<e.length;i++){if($.inArray(e[i],r)>-1){if(0==u.length&&("'"==e[i]||'"'==e[i]))return!1;'"'==p||"'"==p?p==e[i]&&(u.pop(),p=u[u.length-1]):"}"==e[i]&&"{"==p?(u.pop(),a.pop(),p=u[u.length-1],h="",o=-1):"]"==e[i]&&"["==p?(u.pop(),a.pop(),p=u[u.length-1]):(u.push(e[i]),"["==(p=e[i])&&a.push("array"),"{"==p&&(a.push("object"),o=i))}"object"==a[a.length-1]&&(h+=e[i])}if(!n&&o>-1){var s=function(l){for(var n=l.split(""),r=null,u=null,p=[],e=1;e<n.length;e++)"'"!=(r=n[e])&&'"'!=r||(null==u?u=r:u==r&&(u=null)),null==u&&","==r&&p.push(e);var h=[],o=1;for(e=0;e<p.length;e++)h.push($.trim(l.substring(o,p[e]))),o=p[e]+1;h.push($.trim(l.substring(o)));var a=h[h.length-1];return a.split(""),t(a)||h.pop(),"{"+h.join(",")}(h);return l=l.substring(0,o)+s,makeCompleteJSON(l,!0)}for(;u.length>0;)'"'==(p=u.pop())&&(l+='"'),"'"==p&&(l+="'"),"{"==p&&(l+="}"),"["==p&&(l+="]");return l};</script>>  
+	&html<<script>!function(e){"use strict";var n=function(n){var a=e("<span />",{"class":"collapser",on:{click:function(){var n=e(this);n.toggleClass("collapsed");var a=n.parent().children(".block"),p=a.children("ul");n.hasClass("collapsed")?(p.hide(),a.children(".dots, .comments").show()):(p.show(),a.children(".dots, .comments").hide())}}});return n&&a.addClass("collapsed"),a},a=function(a,p){var t=e.extend({},{nl2br:!0},p),r=function(e){return e.toString()?e.toString().replace(/&/g,"&amp;").replace(/"/g,"&quot;").replace(/</g,"&lt;").replace(/>/g,"&gt;"):""},s=function(n,a){return e("<span />",{"class":a,html:r(n)})},l=function(a,p){switch(e.type(a)){case"object":p||(p=0);var c=e("<span />",{"class":"block"}),d=Object.keys(a).length;if(!d)return c.append(s("{","b")).append(" ").append(s("}","b"));c.append(s("{","b"));var i=e("<ul />",{"class":"obj collapsible level"+p});return e.each(a,function(a,t){d--;var r=e("<li />").append(s('"',"q")).append(a).append(s('"',"q")).append(": ").append(l(t,p+1));-1===["object","array"].indexOf(e.type(t))||e.isEmptyObject(t)||r.prepend(n()),d>0&&r.append(","),i.append(r)}),c.append(i),c.append(s("...","dots")),c.append(s("}","b")),c.append(1===Object.keys(a).length?s("// 1 item","comments"):s("// "+Object.keys(a).length+" items","comments")),c;case"array":p||(p=0);var d=a.length,c=e("<span />",{"class":"block"});if(!d)return c.append(s("[","b")).append(" ").append(s("]","b"));c.append(s("[","b"));var i=e("<ul />",{"class":"obj collapsible level"+p});return e.each(a,function(a,t){d--;var r=e("<li />").append(l(t,p+1));-1===["object","array"].indexOf(e.type(t))||e.isEmptyObject(t)||r.prepend(n()),d>0&&r.append(","),i.append(r)}),c.append(i),c.append(s("...","dots")),c.append(s("]","b")),c.append(1===a.length?s("// 1 item","comments"):s("// "+a.length+" items","comments")),c;case"string":if(a=r(a),/^(http|https|file):\/\/[^\s]+$/i.test(a))return e("<span />").append(s('"',"q")).append(e("<a />",{href:a,text:a})).append(s('"',"q"));if(t.nl2br){var o=/\n/g;o.test(a)&&(a=(a+"").replace(o,"<br />"))}var u=e("<span />",{"class":"str"}).html(a);return e("<span />").append(s('"',"q")).append(u).append(s('"',"q"));case"number":return s(a.toString(),"num");case"undefined":return s("undefined","undef");case"null":return s("null","null");case"boolean":return s(a?"true":"false","bool")}};return l(a)};return e.fn.jsonView=function(n,p){var t=e(this);if(p=e.extend({},{nl2br:!0},p),"string"==typeof n)try{n=JSON.parse(n)}catch(r){}return t.append(e("<div />",{"class":"json-view"}).append(a(n,p))),t}}(jQuery);</script>>
+	&html<<style type="text/css">
+	.json-view{position:relative}
+	.json-view .collapser{width:20px;height:18px;display:block;position:absolute;left:-1.7em;top:-.2em;z-index:5;background-image:url(data:image/png;base64,iVBORw0KGgoAAAANSUhEUgAAAAgAAAAICAYAAADED76LAAAAGXRFWHRTb2Z0d2FyZQBBZG9iZSBJbWFnZVJlYWR5ccllPAAAAD1JREFUeNpiYGBgOADE%2F3Hgw0DM4IRHgSsDFOzFInmMAQnY49ONzZRjDFiADT7dMLALiE8y4AGW6LoBAgwAuIkf%2F%2FB7O9sAAAAASUVORK5CYII%3D);background-repeat:no-repeat;background-position:center center;opacity:.5;cursor:pointer}
+	.json-view .collapsed{-ms-transform:rotate(-90deg);-moz-transform:rotate(-90deg);-khtml-transform:rotate(-90deg);-webkit-transform:rotate(-90deg);-o-transform:rotate(-90deg);transform:rotate(-90deg)}
+	.json-view .bl{display:block;padding-left:20px;margin-left:-20px;position:relative}
+	.json-view {font-family:Verdana,sans-serif; font-size: 0.8em;}
+	.json-view ul{list-style-type:none;padding-left:2em;border-left:1px dotted;margin:.3em}
+	.json-view ul li{position:relative;color:#012E55}
+	.json-view .comments,.json-view .dots{display:none;-moz-user-select:none;-ms-user-select:none;-khtml-user-select:none;-webkit-user-select:none;-o-user-select:none;user-select:none}
+	.json-view .comments{padding-left:.8em;font-style:italic;color:#888}
+	.json-view .bool,.json-view .null,.json-view .num,.json-view .undef{font-weight:700;color:#1A01CC}
+	.json-view .str{color:#F79243}
+	</style>>
+}
+
+/// This method is called by the Management Portal to display a message-specific content viewer.<br>
+/// This method displays its content by writing out to the current device.
+/// The content should match the type returned by the <method>%GetContentType</method> method.<br>
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	set jsonObject = ..QuoteJS(..GetObjectJson(.atEnd))
+	set buffer = ..#BUFFER
+    if 'atEnd {
+        &html<<div>Warning JSON projection is not comptete, it's truncated, #(buffer)# charaters display</div>>
+    }
+	// https://github.com/bazh/jquery.json-view
+	&html<<div id="element">#(..classname)#</div>>
+	&html<<script>$(function() {$('#element').jsonView(makeCompleteJSON(#(jsonObject)#,false));});</script>>
+}
+
+Storage Default
+{
+<Data name="MessageDefaultData">
+<Subscript>"Message"</Subscript>
+<Value name="1">
+<Value>classname</Value>
+</Value>
+<Value name="2">
+<Value>json</Value>
+</Value>
+<Value name="3">
+<Value>jstr</Value>
+</Value>
+</Data>
+<Data name="jsonObject">
+<Attribute>jsonObject</Attribute>
+<Structure>node</Structure>
+<Subscript>"IOP.Message.jsonObject"</Subscript>
+</Data>
+<DefaultData>MessageDefaultData</DefaultData>
+<Type>%Storage.Persistent</Type>
+}
+
+}