iris-pex-embedded-python 2.3.27b2__py3-none-any.whl → 3.2.1b3__py3-none-any.whl

iop/cls/IOP/OutboundAdapter.cls

@@ -0,0 +1,36 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.OutboundAdapter Extends (Ens.OutboundAdapter, IOP.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Property KeepaliveInterval As %Numeric [ InitialExpression = 0 ];
+
+Parameter SETTINGS = "KeepaliveInterval:Python CallInterval,%classname:Python OutboundAdapter,%module:Python OutboundAdapter,%settings:Python OutboundAdapter,%classpaths:Python OutboundAdapter";
+
+Method %DispatchMethod(
+	method As %String,
+	args...) As %ObjectHandle
+{
+	if $quit {
+		quit $method($this.%class,method,args...)
+	} else {
+		do $method($this.%class,method,args...)
+		quit
+	}
+}
+
+Method OnKeepalive(pStatus As %Status = {$$$OK}) As %Status
+{
+	set tSC = $$$OK
+	try {
+		$$$ThrowOnError(##super(pStatus))
+		do ..%class."on_keepalive"()
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+}

iop/cls/IOP/PickleMessage.cls

@@ -0,0 +1,58 @@
+/* Copyright (c) 2021 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.PickleMessage Extends (Ens.MessageBody, %CSP.Page)
+{
+
+Property classname As %String(MAXLEN = "");
+
+Property jstr As %Stream.GlobalCharacter [ Internal, Private ];
+
+Method %OnNew(classname) As %Status [ Private, ServerOnly = 1 ]
+{
+	set ..classname = $g(classname)
+	Quit $$$OK
+}
+
+/// This method is called by the Management Portal to determine the content type that will be returned by the <method>%ShowContents</method> method.
+/// The return value is a string containing an HTTP content type.
+Method %GetContentType() As %String
+{
+	Quit "text/html"
+}
+
+/// This method is called by the Management Portal to display a message-specific content viewer.<br>
+/// This method displays its content by writing out to the current device.
+/// The content should match the type returned by the <method>%GetContentType</method> method.<br>
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	// https://github.com/bazh/jquery.json-view
+	&html<<div id="element">#(..classname)#</div>>
+	&html<<div>Pickle Pyhton Message can't be displayed</div>>
+}
+
+Storage Default
+{
+<Data name="MessageDefaultData">
+<Subscript>"Message"</Subscript>
+<Value name="1">
+<Value>classname</Value>
+</Value>
+<Value name="2">
+<Value>json</Value>
+</Value>
+<Value name="3">
+<Value>jstr</Value>
+</Value>
+</Data>
+<Data name="jsonObject">
+<Attribute>jsonObject</Attribute>
+<Structure>node</Structure>
+<Subscript>"IOP.Message.jsonObject"</Subscript>
+</Data>
+<DefaultData>MessageDefaultData</DefaultData>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/PrivateSession/Duplex.cls

@@ -0,0 +1,260 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+Class IOP.PrivateSessionDuplex Extends (IOP.Common, Ens.BusinessDuplex) [ Abstract, System = 4 ]
+{
+
+/// Domain for error messages   
+Parameter DOMAIN = "PrivateSession";
+
+Parameter SETTINGS = "DuplexTargetConfigName,%classname:Python BusinessProcess,%module:Python BusinessProcess,%settings:Python BusinessProcess,%classpaths:Python BusinessProcess";
+
+/// Configuration item(s) to which to send messages
+Property DuplexTargetConfigName As %String(MAXLEN = 1000);
+
+/// This holds the deferred response token
+Property DeferredResponseToken As %String;
+
+/// This holds data that is not yet ready for processing
+Property ReceivedDataQueue As list Of %Library.Persistent;
+
+/// This method is called by the TCP Adapter when a message is received.
+Method OnProcessInput(
+	pInput As %Persistent,
+	Output pOutput As %Persistent,
+	ByRef pHint As %String) As %Status
+{
+	set tSC = $$$OK
+	try {
+		try {
+			set ..%class."_wait_for_next_call_interval" = ..%WaitForNextCallInterval
+		}catch {}
+            set pOutput = ..%class."_dispatch_on_process_input"(pInput)
+		try {
+			set ..%WaitForNextCallInterval = ..%class."_wait_for_next_call_interval"
+		}catch {}
+} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method dispatchSendDocumentToProcess(pDocument) As %String
+{
+	set tSC = ..SendDocumentToProcess(pDocument)
+	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
+	quit
+}
+
+Method SendDocumentToProcess(pDocument As %Library.Persistent) As %Status
+{
+    #dim tSC As %Status = $$$OK
+    try {
+        If '..%InPrivateSession Set tSC=..StartPrivateSession() Quit:$$$ISERR(tSC)
+        If ..DeferredResponseToken'="" {
+            Set tSC=..SendDeferredResponse(..DeferredResponseToken,pDocument) If $$$ISERR(tSC) Quit
+            Set ..DeferredResponseToken=""
+        } else {
+            Do ..ReceivedDataQueue.Insert(pDocument)
+        }
+    } catch {
+        Set tSC=$$$EnsSystemError
+    }
+    Quit tSC
+}
+
+Method StartPrivateSession() As %Status
+{
+    #dim tSC As %Status = $$$OK
+    try {
+        If ..%InPrivateSession Quit
+        Set tSC = ..RegisterPrivateSession() Quit:$$$ISERR(tSC)
+        Set tSC=..SendRequestAsync(..DuplexTargetConfigName,##class(IOP.PrivateSession.Message.Start).%New()) Quit:$$$ISERR(tSC)
+        Set tSC = ..OnPrivateSessionStarted(1) Quit:$$$ISERR(tSC)
+    } catch {
+        Set tSC=$$$EnsSystemError
+    }
+    Quit tSC
+}
+
+Method StopPrivateSession(pAttachedMessage As %Persistent = "") As %Status
+{
+    #dim tSC As %Status = $$$OK
+    #dim tMessageHeaderId As %String
+    #dim tRequestHeader As Ens.MessageHeader
+    try {
+	    If ..%InPrivateSession {
+	        #; Target might receive stop message before this job unregisters and therefore need to remove queue pointer 
+	        If ..DeferredResponseToken'="" {
+		        try {
+					Set tMessageHeaderId=$p(..DeferredResponseToken,"|",1)
+					Set tRequestHeader=##Class(Ens.MessageHeader).%OpenId(tMessageHeaderId,,.tSC) Quit:$$$ISERR(tSC)
+					If $$$ConfigSessionQueueName(..%ConfigName,..%PrivateSessionId)'=tRequestHeader.ReturnQueueName {
+			        	Kill $$$ConfigSessionQueueName(..%ConfigName,..%PrivateSessionId)
+					}
+					Set tRequestHeader=""
+		        } catch {}
+	        }
+			Set tSC=..SendDocumentToProcess(##class(IOP.PrivateSession.Message.Stop).%New(pAttachedMessage)) Quit:$$$ISERR(tSC)
+            Set tSC=..UnRegisterPrivateSession()
+            set ..DeferredResponseToken=""
+            
+            #; Ensure all messages are delivered including STOP message (JN1098)
+            #; Do ..ReceivedDataQueue.Clear()
+            Set tSC=..OnPrivateSessionStopped(1) Quit:$$$ISERR(tSC)
+        }
+    } catch {
+        Set tSC=$$$EnsSystemError
+    }
+    Quit tSC
+}
+
+Method RegisterPrivateSession() As %Status
+{
+	If ..%InPrivateSession Quit $$$OK
+	If ..%SessionId="" Set tSC=..ForceSessionId() Quit:$$$ISERR(tSC) tSC
+	Set ..%PrivateSessionId=..%SessionId
+	Set tSC = ##class(Ens.Queue).Create(..QueueName()) Quit:$$$ISERR(tSC) tSC
+
+    try {
+        Set tSC=..Adapter.OpenEventDevice() 
+    }
+    catch {
+
+    }
+	
+	Set $$$ConfigSessionQueueName(..%ConfigName,..%SessionId)=..QueueName()
+	$$$sysTRACE("Registered Private Session '"_..%PrivateSessionId_"'")
+	Quit $$$OK
+}
+
+Method UnRegisterPrivateSession() As %Status
+{
+	If '..%InPrivateSession Quit $$$OK
+	Kill $$$ConfigSessionQueueName(..%ConfigName,..%PrivateSessionId)
+    try {
+        Set tSC=..Adapter.CloseEventDevice()
+    }
+    catch {
+
+    }
+	 
+	Set tSC=##class(Ens.Queue).Delete(..QueueName(),"*") Quit:$$$ISERR(tSC) tSC
+	$$$sysTRACE("Unregistered Private Session '"_..%PrivateSessionId_"'")
+	Set ..%PrivateSessionId=""
+	Set ..%SessionId=""
+	Kill $$$JobSessionId
+	Quit $$$OK
+}
+
+XData MessageMap
+{
+<MapItems>
+<MapItem MessageType="IOP.PrivateSession.Message.Start"><Method>OnMsgPrivateSessionStart</Method></MapItem>
+<MapItem MessageType="IOP.PrivateSession.Message.Stop"><Method>OnMsgPrivateSessionStop</Method></MapItem>
+<MapItem MessageType="IOP.PrivateSession.Message.Poll"><Method>OnMsgPrivateSessionPoll</Method></MapItem>
+</MapItems>
+}
+
+Method OnMsgPrivateSessionStart(
+	pRequest As IOP.PrivateSession.Message.Start,
+	Output pResponse As %Library.Persistent) As %Status
+{
+    #dim tSC As %Status = $$$OK
+    try {
+        Set tSC=..RegisterPrivateSession() Quit:$$$ISERR(tSC)
+        Set tSC=..OnPrivateSessionStarted(0) Quit:$$$ISERR(tSC)
+        Kill %objlasterror Set pResponse=##class(IOP.PrivateSession.Message.Ack).%New()
+        If '$IsObject(pResponse) Set tSC=$$$ERROR($$$FailedToNewClass,"IOP.PrivateSession.Message.Ack") Quit
+    } catch {
+        Set tSC=$$$EnsSystemError
+    }
+    Quit tSC
+}
+
+Method OnMsgPrivateSessionStop(
+	pRequest As IOP.PrivateSession.Message.Stop,
+	Output pResponse As %Library.Persistent) As %Status
+{
+    #dim tSC As %Status = $$$OK
+    try {
+        Set tSC=..UnRegisterPrivateSession() Quit:$$$ISERR(tSC)
+        set ..DeferredResponseToken=""
+        do ..ReceivedDataQueue.Clear()
+        Set tSC=..OnPrivateSessionStopped(0,pRequest.AttachedMessage) Quit:$$$ISERR(tSC)
+    } catch {
+        Set tSC=$$$EnsSystemError
+    }
+    Quit tSC
+}
+
+Method OnMsgPrivateSessionPoll(
+	pPollIn As IOP.PrivateSession.Message.Poll,
+	Output pResponse As %Library.Persistent) As %Status
+{
+    #dim tSC As %Status = $$$OK
+    #dim tToken As %String
+    try  {
+        If ..ReceivedDataQueue.Count() {
+            Set pResponse=..ReceivedDataQueue.GetAt(1)
+            do ..ReceivedDataQueue.RemoveAt(1)
+        } Else {
+            Set tSC=..DeferResponse(.tToken) If $$$ISERR(tSC) Quit
+            Set ..DeferredResponseToken=tToken
+        }
+    } catch {
+        Set tSC=$$$EnsSystemError
+    }
+    Quit tSC
+}
+
+/// Return an array of connections for drawing lines on the config diagram
+ClassMethod OnGetConnections(
+	Output pArray As %String,
+	pItem As Ens.Config.Item)
+{
+    Do ##super(.pArray,pItem)
+    If pItem.GetModifiedSetting("DuplexTargetConfigName",.tValue) {
+        Set tOne=$ZStrip(tValue,"<>W")
+        Set:""'=tOne pArray(tOne)=""
+    }
+}
+
+Method OnPrivateSessionStarted(pSelfGenerated As %Boolean) As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_started"($this,pSelfGenerated)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnPrivateSessionStopped(
+	pSelfGenerated As %Boolean,
+	pAttachedMessage As %Persistent = "") As %Status
+{
+	set tSC = $$$OK
+	try {
+		set response = ..%class."_dispatch_on_private_session_stopped"($this,pSelfGenerated,pAttachedMessage)
+	} catch ex {
+		set tSC = ex.AsStatus()
+	}
+	quit tSC
+}
+
+Method OnTearDown() As %Status
+{
+    #dim tSC As %Status = $$$OK
+    try {
+        If ..%InPrivateSession Set tSC=..StopPrivateSession() Quit:$$$ISERR(tSC)
+        do ..%class."_dispatch_on_tear_down"()
+    } catch {
+        Set tSC=$$$EnsSystemError
+    }
+    Quit tSC
+}
+
+}

iop/cls/IOP/PrivateSession/Message/Ack.cls

@@ -0,0 +1,32 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+/// This class is a DICOM framework class
+Class IOP.PrivateSession.Message.Ack Extends (%Persistent, Ens.Util.MessageBodyMethods) [ ClassType = persistent, Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter DOMAIN = "PrivateSession";
+
+/// From 'Ens.Util.MessageBodyMethods'
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	Write $$$Text("(session-ack)")
+}
+
+Storage Default
+{
+<Data name="AckDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.PrivateSe9756.AckD</DataLocation>
+<DefaultData>AckDefaultData</DefaultData>
+<IdLocation>^IOP.PrivateSe9756.AckD</IdLocation>
+<IndexLocation>^IOP.PrivateSe9756.AckI</IndexLocation>
+<StreamLocation>^IOP.PrivateSe9756.AckS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/PrivateSession/Message/Poll.cls

@@ -0,0 +1,32 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+/// This class is a DICOM framework class
+Class IOP.PrivateSession.Message.Poll Extends (%Persistent, Ens.Util.MessageBodyMethods) [ ClassType = persistent, Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter DOMAIN = "PrivateSession";
+
+/// From 'Ens.Util.MessageBodyMethods'
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	Write $$$Text("(poll-data)")
+}
+
+Storage Default
+{
+<Data name="PollDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.PrivateS9756.PollD</DataLocation>
+<DefaultData>PollDefaultData</DefaultData>
+<IdLocation>^IOP.PrivateS9756.PollD</IdLocation>
+<IndexLocation>^IOP.PrivateS9756.PollI</IndexLocation>
+<StreamLocation>^IOP.PrivateS9756.PollS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/PrivateSession/Message/Start.cls

@@ -0,0 +1,32 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+/// This class is a DICOM framework class
+Class IOP.PrivateSession.Message.Start Extends (%Persistent, Ens.Util.MessageBodyMethods) [ ClassType = persistent, Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter DOMAIN = "PrivateSession";
+
+/// From 'Ens.Util.MessageBodyMethods'
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	Write $$$Text("(session-start)")
+}
+
+Storage Default
+{
+<Data name="StartDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.Private9756.StartD</DataLocation>
+<DefaultData>StartDefaultData</DefaultData>
+<IdLocation>^IOP.Private9756.StartD</IdLocation>
+<IndexLocation>^IOP.Private9756.StartI</IndexLocation>
+<StreamLocation>^IOP.Private9756.StartS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}

iop/cls/IOP/PrivateSession/Message/Stop.cls

@@ -0,0 +1,48 @@
+/* Copyright (c) 2022 by InterSystems Corporation.
+   Cambridge, Massachusetts, U.S.A.  All rights reserved.
+   Confidential property of InterSystems Corporation. */
+
+/// This class is a DICOM framework class
+Class IOP.PrivateSession.Message.Stop Extends (%Persistent, Ens.Util.MessageBodyMethods) [ ClassType = persistent, Inheritance = right, ProcedureBlock, System = 4 ]
+{
+
+Parameter DOMAIN = "PrivateSession";
+
+/// The message body
+Property AttachedMessage As %Persistent(CLASSNAME = 1);
+
+/// From 'Ens.Util.MessageBodyMethods'
+Method %ShowContents(pZenOutput As %Boolean = 0)
+{
+	If $IsObject(..AttachedMessage) {
+		Write $$$FormatText($$$Text("(session-stop) with AttachedMessage [%1] "),$classname(..AttachedMessage))
+	} Else {
+		Write $$$Text("(session-stop)")
+	}
+}
+
+Method %OnNew(initvalue As %RegisteredObject) As %Status [ Private, ProcedureBlock = 1, ServerOnly = 1 ]
+{
+	Set ..AttachedMessage=initvalue
+	Quit $$$OK
+}
+
+Storage Default
+{
+<Data name="StopDefaultData">
+<Value name="1">
+<Value>%%CLASSNAME</Value>
+</Value>
+<Value name="2">
+<Value>AttachedMessage</Value>
+</Value>
+</Data>
+<DataLocation>^IOP.PrivateS9756.StopD</DataLocation>
+<DefaultData>StopDefaultData</DefaultData>
+<IdLocation>^IOP.PrivateS9756.StopD</IdLocation>
+<IndexLocation>^IOP.PrivateS9756.StopI</IndexLocation>
+<StreamLocation>^IOP.PrivateS9756.StopS</StreamLocation>
+<Type>%Storage.Persistent</Type>
+}
+
+}