iris-pex-embedded-python 2.3.19__py3-none-any.whl → 2.3.21b1__py3-none-any.whl

grongier/iris/Grongier/PEX/Utils.cls

@@ -1,312 +0,0 @@
-/* Copyright (c) 2021 by InterSystems Corporation.
-   Cambridge, Massachusetts, U.S.A.  All rights reserved.
-   Confidential property of InterSystems Corporation. */
-
-Include Ensemble
-
-Class Grongier.PEX.Utils [ Abstract ]
-{
-
-ClassMethod dispatchRegisterComponent(pModule As %String, pRemoteClassname As %String, pCLASSPATHS As %String = "", pOverwrite As %Boolean = 0, pProxyClassname As %String = "") As %Status
-{
-	set tSc = $$$OK
-	$$$ThrowOnError(##class(Grongier.PEX.Utils).RegisterComponent(pModule, pRemoteClassname, pCLASSPATHS, pOverwrite , pProxyClassname))
-	return tSc
-}
-
-/// "bo","Duplex","/irisdev/app/src/python/demo/duplex/",1,"Duplex.Duplex"
-ClassMethod RegisterComponent(pModule As %String, pRemoteClassname As %String, pCLASSPATHS As %String = "", pOverwrite As %Boolean = 0, pProxyClassname As %String = "") As %Status
-{
-	#dim tSC As %Status = $$$OK
-	#dim ex As %Exception.AbstractException
-	#dim tLanguage,tExtraClasspaths,tDelimiter,tOnePath As %String = ""
-	#dim tClassDetails,tRemoteSettings As %String = ""
-	#dim tClasspaths As %ListOfDataTypes
-	
-	Quit:(""=pRemoteClassname) $$$ERROR($$$EnsErrGeneral,"Remote Classname must be specified in order to register a Production EXtensions component")
-	Quit:(""=pModule) $$$ERROR($$$EnsErrGeneral,"Must specify the module of the remote code.")
-		
-	Try {
-
-		$$$ThrowOnError(..GetRemoteClassInfo(pRemoteClassname,pModule,pCLASSPATHS,.tClassDetails,.tRemoteSettings))
-
-		Set tConnectionSettings("Classpaths") = pCLASSPATHS
-		Set tConnectionSettings("Module") = pModule
-		Set tConnectionSettings("Classname") = pRemoteClassname
-		Set:(""=pProxyClassname) pProxyClassname = "User."_pRemoteClassname
-		
-		$$$ThrowOnError(..GenerateProxyClass(pProxyClassname,.tConnectionSettings,tClassDetails,tRemoteSettings,pOverwrite))
-
-	} Catch ex {
-		set msg = $System.Status.GetOneStatusText(ex.AsStatus(),1)
-		set tSC = $$$ERROR($$$EnsErrGeneral,msg)
-	}
-
-	Quit tSC
-}
-
-ClassMethod DeleteComponentProxy(pClassname As %String = "") As %Status
-{
-	#dim tSC As %Status = $$$OK
-	#dim ex As %Exception.AbstractException
-	#dim tIsPEX As %Boolean = 0
-	#dim tClass As %Dictionary.CompiledClass
-	
-	Quit:(""=pClassname) $$$ERROR($$$EnsErrGeneral,"Remote class name must be specified.")
-	
-	Try {
-		
-		If '##class(%Dictionary.ClassDefinition).%ExistsId(pClassname) {
-			Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("No proxy class defined for remote class '%1'.",pClassname))
-			Quit
-		}
-		If $classmethod(pClassname,"%Extends","Grongier.PEX.Common") {
-			Set tClass = ##class(%Dictionary.CompiledClass).%OpenId(pClassname,,.tSC)
-			Quit:$$$ISERR(tSC)
-			If '$IsObject(tClass) {
-				Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Proxy class for remote class '%1' could not be opened.",pClassname))
-				Quit
-			}
-			Set tIsPEX = ("Grongier.PEX.Utils" = tClass.GeneratedBy)
-		}
-		If tIsPEX {
-			Set tSC = ##class(%Dictionary.ClassDefinition).%DeleteId(pClassname)
-			If $$$ISERR(tSC) {
-				Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Unable to delete proxy class for remote class '%1' : '%2'.",pClassname,$System.Status.GetErrorText(tSC)))
-				Quit
-			}
-		} Else {
-			Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Cannot delete class '%1' because it is not a PEX proxy class.",pClassname))
-			Quit
-		}
-		
-	} Catch ex {
-		Set tSC = ex.AsStatus()
-	}
-	
-	Quit tSC
-}
-
-// ..GetRemoteClassInfo(pRemoteClassname,pModule,pCLASSPATHS,.tClassDetails,.tRemoteSettings)
-
-ClassMethod GetRemoteClassInfo(pRemoteClassname As %String, pModule As %String, pClasspaths As %String, ByRef pClassDetails, ByRef pRemoteSettings) As %Status [ Internal, Private ]
-{
-	#dim tSC As %Status = $$$OK
-	#dim ex As %Exception.AbstractException
-	#dim tGateway As %External.Gateway
-	#dim tGatewayProxy As %Net.Remote.Object
-	
-	Try {
-		if pClasspaths '="" {
-			set delimiter = $s($system.Version.GetOS()="Windows":";",1:":")
-			set extraClasspaths = $tr(pClasspaths,delimiter,"|")
-			for i=1:1:$l(extraClasspaths,"|") {
-				set onePath = $p(extraClasspaths,"|",i)
-				set onePath = ##class(%File).NormalizeDirectory(onePath)
-				if onePath?1"$$IRISHOME"1P.E set onePath = $e($system.Util.InstallDirectory(),1,*-1)_$e(onePath,11,*)
-				if onePath'="" do ##class(Grongier.PEX.Python).SetClassPath(onePath)
-			}
-		}
-		;
-
-		set tClass = ##class(Grongier.PEX.Python).GetInstanceFromModuleClassName(pModule,pRemoteClassname)
-
-		If $IsObject(tClass) {
-			#; List of information about the class as a whole - $lb(SuperClass, Description, InfoURL, IconURL, Adapter)
-			Set pClassDetails = tClass."_get_info"()
-			#; List of information about the various properties of the class
-			#; List of lists of form $lb(propName,dataType,defaultVal,required,category,description)
-			Set pRemoteSettings = tClass."_get_properties"()
-		} Else {
-			Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Error opening gateway proxy for class '%1'"),pRemoteClassname)
-		}
-	} Catch ex {
-		set msg = $System.Status.GetOneStatusText(ex.AsStatus(),1)
-		set tSC = $$$ERROR($$$EnsErrGeneral,msg)
-	}
-	
-	Quit tSC
-}
-
-/// Set tConnectionSettings("Classpaths") = pCLASSPATHS
-/// Set tConnectionSettings("Module") = pModule
-/// Set tConnectionSettings("Classname") = pRemoteClassname
-/// Set:(""=pProxyClassname) pProxyClassname = pRemoteClassname
-/// 
-/// Set tSC = ..GenerateProxyClass(pProxyClassname,.tConnectionSettings,tClassDetails,tRemoteSettings,pOverwrite)
-/// "bo","Duplex","/irisdev/app/src/python/demo/duplex/",1,"Duplex.Duplex"
-ClassMethod GenerateProxyClass(pClassname As %String, ByRef pConnectionSettings, pClassDetails As %String = "", pRemoteSettings As %String = "", pOverwrite As %Boolean = 0) As %Status [ Internal, Private ]
-{
-	#dim tSC As %Status = $$$OK
-	#dim ex As %Exception.AbstractException
-	
-	Quit:(""=pClassname) $$$ERROR($$$EnsErrGeneral,"Class name must be specified in order to generate a proxy class for this Production EXtensions component")
-	
-	Try {
-
-		If ##class(%Dictionary.ClassDefinition).%ExistsId(pClassname) {
-			If 'pOverwrite {
-				Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Proxy class '%1' already exists.",pClassname))
-				Quit
-			} Else {
-				#dim tIsPEX As %Boolean = 0
-				If $classmethod(pClassname,"%Extends","Grongier.PEX.Common") {
-					#dim tClass As %Dictionary.CompiledClass = ##class(%Dictionary.CompiledClass).%OpenId(pClassname)
-					If '$IsObject(tClass) {
-						Set tSC = $$$ERROR($$$EnsErrGeneral,"Class not found")
-						Quit
-					}
-					Set tIsPEX = ("Grongier.PEX.Utils" = tClass.GeneratedBy)
-				}
-				If tIsPEX {
-					Set tSC = ##class(%Dictionary.ClassDefinition).%DeleteId(pClassname)
-					If $$$ISERR(tSC) {
-						Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Unable to delete existing proxy class '%1' : '%2'.",pClassname,$System.Status.GetErrorText(tSC)))
-						Quit
-					}
-				} Else {
-					Set tSC = $$$ERROR($$$EnsErrGeneral,$$$FormatText("Cannot overwrite class '%1' because it is not a PEX proxy class.",pClassname))
-					Quit
-				}
-			}
-		}
-		
-		#; create subclass of the ObjectScript Business Host
-		#dim tCOSClass As %Dictionary.ClassDefinition
-		Set tCOSClass = ##class(%Dictionary.ClassDefinition).%New()
-		Set tCOSClass.Name = pClassname
-
-		#dim tSuperClass As %String = pClassDetails."__getitem__"(0)
-		If (""=tSuperClass) {
-			Set tSC = $$$ERROR($$$EnsErrGeneral,"No PEX superclass found.")
-			Quit
-		}
-		If '$Case($P(tSuperClass,".",*),"DuplexProcess":1,"DuplexService":1,"DuplexOperation":1,"InboundAdapter":1,"OutboundAdapter":1,"BusinessService":1,"BusinessProcess":1,"BusinessOperation":1,:0) {
-			Set tSC = $$$ERROR($$$EnsErrGeneral,"Invalid superclass")
-			Quit
-		}
-		Set tSuperClass = "Grongier.PEX."_$P(tSuperClass,".",*)
-		
-		Set tCOSClass.Super = tSuperClass
-		Set tCOSClass.GeneratedBy = $CLASSNAME()
-		Set tCOSClass.ClassVersion = $$$CLASSDEFINITIONVERSION
-		#dim tDescription As %String = pClassDetails."__getitem__"(1)
-		If (""'=tDescription) {
-			Set tCOSClass.Description = $Replace(tDescription,$C(10),$C(13,10))
-		}
-		
-		#; Do not display any of the connection settings
-		#dim tSETTINGSParamValue As %String = "%classname:Python $type,%module:Python $type,%settings:Python $type,%classpaths:Python $type"
-		
-		#dim tPropClassname As %Dictionary.PropertyDefinition = ##class(%Dictionary.PropertyDefinition).%New()
-		Set tPropClassname.Name = "%classname"
-		Set tPropClassname.Type = "%String"
-		Set tPropClassname.InitialExpression = $$$quote(pConnectionSettings("Classname"))
-		Set tPropClassname.Internal = 1
-		Set tSC = tCOSClass.Properties.Insert(tPropClassname)
-		Quit:$$$ISERR(tSC)
-		
-		
-		#dim tPropClasspaths As %Dictionary.PropertyDefinition = ##class(%Dictionary.PropertyDefinition).%New()
-		Set tPropClasspaths.Name = "%classpaths"
-		Set tPropClasspaths.Type = "%String"
-		Set tSC = tPropClasspaths.Parameters.SetAt("","MAXLEN")
-		Quit:$$$ISERR(tSC)
-		Set tPropClasspaths.InitialExpression = $$$quote(pConnectionSettings("Classpaths"))
-		Set tPropClasspaths.Description = "One or more Classpaths (separated by '|' character) needed in addition to the ones configured in the Remote Gateway"
-		Set tSC = tCOSClass.Properties.Insert(tPropClasspaths)
-		Quit:$$$ISERR(tSC)
-		
-		
-		#dim tPropLanguage As %Dictionary.PropertyDefinition = ##class(%Dictionary.PropertyDefinition).%New()
-		Set tPropLanguage.Name = "%module"
-		Set tPropLanguage.Type = "%String"
-		Set tPropLanguage.Internal = 1
-		Set tPropLanguage.InitialExpression = $$$quote(pConnectionSettings("Module"))
-		Set tSC = tCOSClass.Properties.Insert(tPropLanguage)
-		Quit:$$$ISERR(tSC)
-		
-		If $Case(tSuperClass,"Grongier.PEX.BusinessService":1,"Grongier.PEX.BusinessOperation":1,"Grongier.PEX.DuplexService":1,"Grongier.PEX.DuplexOperation":1,:0) {
-			
-			If (##class(Grongier.PEX.Python).Len(pClassDetails)>4) { //Adaptor
-
-				#dim tAdapterClass = pClassDetails."__getitem__"(4)
-				#; May want to issue a warning in the UI if the Adapter class does not exist
-				#; but we don't check here because it does compile and may just be that the user is registering the Service/Operation before the Adapter
-				#dim tADAPTERParam As %Dictionary.ParameterDefinition = ##class(%Dictionary.ParameterDefinition).%New()
-				Set tADAPTERParam.Name = "ADAPTER"
-				Set tADAPTERParam.Default = tAdapterClass
-				Set tSC = tCOSClass.Parameters.Insert(tADAPTERParam)
-				Quit:$$$ISERR(tSC)
-			}
-		}
-
-		set type = ""
-		set:($Case(tSuperClass,"Grongier.PEX.InboundAdapter":1,"Grongier.PEX.OutboundAdapter":1,:0)) type = "Adapter"
-		set tSETTINGSParamValue = $REPLACE(tSETTINGSParamValue,"$type",type)
-		
-		#dim tSETTINGSParam As %Dictionary.ParameterDefinition = ##class(%Dictionary.ParameterDefinition).%New()
-		Set tSETTINGSParam.Name = "SETTINGS"
-		Set tSETTINGSParam.Default = tSETTINGSParamValue
-		Set tSC = tCOSClass.Parameters.Insert(tSETTINGSParam)
-		Quit:$$$ISERR(tSC)
-		
-		Set tSC = tCOSClass.%Save()
-		Quit:$$$ISERR(tSC)
-		
-		Set tSC = $System.OBJ.Compile(pClassname,"-d")
-		
-	} Catch ex {
-		Set tSC = ex.AsStatus()
-	}
-	
-	Quit tSC
-}
-
-// Thanks to Alex Woodhead for this serializer
-ClassMethod ListFrompyList(ByRef pyList As %SYS.Python = {$$$NULLOREF}, ByRef impBi As %SYS.Python = {##class(%SYS.Python).Import("builtins")}, msgkeys = "") As %SYS.Python [ ProcedureBlock = 1 ]
-{
-	set ret=$LB()
-	// How to get length of list
-	set listlen=impBi.len(pyList)
-	for i=1:1:listlen {
-		set data=..pyListGet(i,pyList)
-		// if data is also a list // TODO
-		if $IsObject(data) {
-			if ..pyListIs(data) {
-			  set data=..ListFrompyList(data,impBi,,msgkeys_"["_i_"]")
-			} else {
-				set $ZE="Class "_..%ClassName(1)_" Method ListFrompyList. Unsupported value type """_..pyTypeName(data)_""" at position "_msgkeys_"["_i_"]"
-				do BACK^%ETN	
-			}
-		}
-		// add string / numeric / IRIS LIST to ret
-		set ret=$LU(ret,i,data)
-	}
-	quit ret
-}
-
-ClassMethod pyListIs(ByRef pyList As %SYS.Python) As %SYS.Python [ Language = python ]
-{
-	return (type(pyList)==list)
-}
-
-/// Returns empty string on error
-/// position starts at one to keep same as IRIS List
-ClassMethod pyListGet(position As %Integer, ByRef pyList As %SYS.Python) As %SYS.Python [ Language = python ]
-{
-	ret=""
-	try:
-	  ret=(pyList[position-1])
-	except:
-	  print("Error in pyListGet")
-	  
-	return ret
-}
-
-ClassMethod pyTypeName(obj As %SYS.Python) As %String [ Language = python ]
-{
-	return type(obj).__name__
-}
-
-}

grongier/pex/data/PEX/BusinessOperation.cls

@@ -1,35 +0,0 @@
-/* Copyright (c) 2021 by InterSystems Corporation.
-   Cambridge, Massachusetts, U.S.A.  All rights reserved.
-   Confidential property of InterSystems Corporation. */
-
-Class Grongier.PEX.BusinessOperation Extends (Ens.BusinessOperation, Grongier.PEX.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
-{
-
-Parameter SETTINGS = "%classname:Python BusinessOperation,%module:Python BusinessOperation,%settings:Python BusinessOperation,%classpaths:Python BusinessOperation";
-
-Method OnMessage(
-	request As %Library.Persistent,
-	Output response As %Library.Persistent) As %Status
-{
-	set tSC = $$$OK
-	try {
-		set response = ..%class."_dispatch_on_message"(request)
-	} catch ex {
-		set tSC = ex.AsStatus()
-	}
-	quit tSC
-}
-
-Method OnKeepalive(pStatus As %Status = {$$$OK}) As %Status
-{
-	set tSC = $$$OK
-	try {
-		$$$ThrowOnError(##super(pStatus))
-		do ..%class."on_keepalive"()
-	} catch ex {
-		set tSC = ex.AsStatus()
-	}
-	quit tSC
-}
-
-}

grongier/pex/data/PEX/BusinessProcess.cls

@@ -1,113 +0,0 @@
-/* Copyright (c) 2021 by InterSystems Corporation.
-   Cambridge, Massachusetts, U.S.A.  All rights reserved.
-   Confidential property of InterSystems Corporation. */
-
-Class Grongier.PEX.BusinessProcess Extends (Ens.BusinessProcess, Grongier.PEX.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
-{
-
-Parameter SETTINGS = "%classname:Python BusinessProcess,%module:Python BusinessProcess,%settings:Python BusinessProcess,%classpaths:Python BusinessProcess";
-
-Property persistentProperties As array Of %String(MAXLEN = "");
-
-Method dispatchReply(response)
-{
-	set tSC = ..Reply(response)
-	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
-	quit
-}
-
-Method dispatchSetTimer(
-	timeout,
-	completionKey)
-{
-	set tSC = ..SetTimer(timeout,$g(completionKey))
-	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
-	quit
-}
-
-Method OnRequest(
-	request As %Persistent,
-	Output response As %Persistent) As %Status
-{
-	set tSC = $$$OK
-	try {
-		set response = ..%class."_dispatch_on_request"($this,request)
-	} catch ex {
-		set tSC = ex.AsStatus()
-	}
-	quit tSC
-}
-
-/// Handle a 'Response'
-Method OnResponse(
-	request As %Persistent,
-	Output response As %Persistent,
-	callRequest As %Persistent,
-	callResponse As %Persistent,
-	pCompletionKey As %String) As %Status
-{
-	set tSC = $$$OK
-	try {
-		set response = ..%class."_dispatch_on_response"($this,request,response,callRequest,callResponse,pCompletionKey)
-	} catch ex {
-		set tSC = ex.AsStatus()
-	}
-	quit tSC
-}
-
-Method OnComplete(
-	request As %Library.Persistent,
-	ByRef response As %Library.Persistent) As %Status
-{
-	set tSC = $$$OK
-	try {
-		set tSC = ..Connect() quit:$$$ISERR(tSC)
-		set response = ..%class."_dispatch_on_complete"($this,request,response)
-	} catch ex {
-		set tSC = ex.AsStatus()
-	}
-	quit tSC
-}
-
-Method getPersistentProperty(name)
-{
-	quit ..persistentProperties.GetAt(name)
-}
-
-Method setPersistentProperty(
-	name,
-	value)
-{
-	quit ..persistentProperties.SetAt(value,name)
-}
-
-Storage Default
-{
-<Data name="BusinessProcessDefaultData1">
-<Subscript>"BusinessProcess"</Subscript>
-<Value name="1">
-<Value>%classpaths</Value>
-</Value>
-<Value name="2">
-<Value>%classname</Value>
-</Value>
-<Value name="3">
-<Value>%module</Value>
-</Value>
-<Value name="4">
-<Value>%settings</Value>
-</Value>
-<Value name="5">
-<Value>%class</Value>
-</Value>
-</Data>
-<Data name="persistentProperties">
-<Attribute>persistentProperties</Attribute>
-<Structure>subnode</Structure>
-<Subscript>"Grongier.PEX.BusinessProcess.persistentProperties"</Subscript>
-</Data>
-<DefaultData>BusinessProcessDefaultData1</DefaultData>
-<Type>%Storage.Persistent</Type>
-}
-
-}

grongier/pex/data/PEX/BusinessService.cls

@@ -1,35 +0,0 @@
-/* Copyright (c) 2021 by InterSystems Corporation.
-   Cambridge, Massachusetts, U.S.A.  All rights reserved.
-   Confidential property of InterSystems Corporation. */
-
-Class Grongier.PEX.BusinessService Extends (Ens.BusinessService, Grongier.PEX.Common) [ Inheritance = right, ProcedureBlock, System = 4 ]
-{
-
-Parameter SETTINGS = "%classname:Python BusinessService,%module:Python BusinessService,%settings:Python BusinessService,%classpaths:Python BusinessService";
-
-Method dispatchProcessInput(pInput As %RegisteredObject) As %RegisteredObject
-{
-	
-	quit ..%class."on_process_input"(pInput)
-}
-
-Method OnProcessInput(
-	request As %RegisteredObject,
-	Output response As %RegisteredObject) As %Status
-{
-	set tSC = $$$OK
-	try {
-		try {
-			set ..%class."_wait_for_next_call_interval" = ..%WaitForNextCallInterval
-		} catch {}
-		set response = ..%class."_dispatch_on_process_input"(request)
-		try {
-			set ..%WaitForNextCallInterval = ..%class."_wait_for_next_call_interval"
-		} catch {}
-	} catch ex {
-		set tSC = ex.AsStatus()
-	}
-	quit tSC
-}
-
-}

grongier/pex/data/PEX/Common.cls

@@ -1,146 +0,0 @@
-/* Copyright (c) 2021 by InterSystems Corporation.
-   Cambridge, Massachusetts, U.S.A.  All rights reserved.
-   Confidential property of InterSystems Corporation. */
-
-Include Ensemble
-
-Class Grongier.PEX.Common [ Abstract, ClassType = "", ProcedureBlock, System = 4 ]
-{
-
-/// One or more Classpaths (separated by '|' character) needed in addition to the ones configured in the Java Gateway Service
-Property %classpaths As %String(MAXLEN = "");
-
-Property %classname As %String(MAXLEN = "");
-
-Property %module As %String(MAXLEN = "");
-
-Property %settings As %String(MAXLEN = "");
-
-/// Instance of class
-Property %class As %SYS.Python;
-
-/// Get Class
-Method GetClass() As %SYS.Python
-{
-	Return ..%class
-}
-
-/// Get Classname
-Method GetClassname() As %String
-{
-	Return ..%classname
-}
-
-/// Get Classname
-Method GetModule() As %String
-{
-	Return ..%module
-}
-
-Method OnInit() As %Status
-{
-	set tSC = $$$OK
-	try {
-        $$$ThrowOnError(..Connect())
-		do ..%class."_dispatch_on_init"($this)
-	} catch ex {
-		set tSC = ex.AsStatus()
-	}
-	quit tSC
-}
-
-Method Connect() As %Status
-{
-	set tSC = $$$OK
-	try {
-		
-		set container = $this
-		
-		//set classpass
-		if ..%classpaths '="" {
-			set sys = ##class(%SYS.Python).Import("sys")
-			set delimiter = $s($system.Version.GetOS()="Windows":";",1:":")
-			set extraClasspaths = $tr(container.%classpaths,delimiter,"|")
-			for i=1:1:$l(extraClasspaths,"|") {
-				set onePath = $p(extraClasspaths,"|",i)
-				set onePath = ##class(%File).NormalizeDirectory(onePath)
-				if onePath?1"$$IRISHOME"1P.E set onePath = $e($system.Util.InstallDirectory(),1,*-1)_$e(onePath,11,*)
-				if onePath'="" do sys.path.append(onePath)
-			}
-		}
-		if $isObject(..%class)=0 {
-			set importlib = ##class(%SYS.Python).Import("importlib")
-			set builtins = ##class(%SYS.Python).Import("builtins")
-			set module = importlib."import_module"(..%module)
-			set class = builtins.getattr(module, ..%classname)
-			set ..%class = class."__new__"(class)
-		}
-		;
-		if ..%Extends("Grongier.PEX.InboundAdapter") || ..%Extends("Grongier.PEX.OutboundAdapter") {
-			do ..%class."_set_iris_handles"($this,..BusinessHost)
-		} elseif $this.%Extends("Grongier.PEX.BusinessProcess") {
-			do ..%class."_set_iris_handles"($this,$$$NULLOREF)
-		} else {
-			do ..%class."_set_iris_handles"($this,..Adapter)
-		}
-		;
-		do ..SetPropertyValues()
-		;
-		try {
-			do ..%class."_dispatch_on_connected"($this)
-		} catch ex {
-			$$$LOGWARNING(ex.DisplayString())
-		}
-		;
-	} catch ex {
-		set msg = $System.Status.GetOneStatusText(ex.AsStatus(),1)
-		set tSC = $$$ERROR($$$EnsErrGeneral,msg)
-	}
-	quit tSC
-}
-
-Method OnTearDown() As %Status
-{
-	set tSC = $$$OK
-    do ..%class."_dispatch_on_tear_down"()
-	quit tSC
-}
-
-Method SetPropertyValues()
-{
-	set remoteSettings = $tr(..%settings,$c(13))
-	for i=1:1:$l(remoteSettings,$c(10)) {
-		set oneLine = $p(remoteSettings,$c(10),i)
-		set property = $p(oneLine,"=",1) continue:property=""
-		set value = $p(oneLine,"=",2,*)
-		try {
-			set $property(..%class,property) = value
-		} catch ex {
-			$$$LOGWARNING(ex.DisplayString())
-		}
-	}
-	quit
-}
-
-Method dispatchSendRequestSync(
-	target,
-	request,
-	timeout,
-	description) As %String
-{
-	set tSC = ..SendRequestSync(target,request,.objResponse,timeout,description)
-	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
-	quit $g(objResponse)
-}
-
-Method dispatchSendRequestAsync(
-	target,
-	request,
-	description)
-{
-	set tSC = ..SendRequestAsync(target,request,description)
-	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
-	quit
-}
-
-}

grongier/pex/data/PEX/Director.cls

@@ -1,57 +0,0 @@
-/* Copyright (c) 2021 by InterSystems Corporation.
-   Cambridge, Massachusetts, U.S.A.  All rights reserved.
-   Confidential property of InterSystems Corporation. */
-
-Include (%occInclude, Ensemble)
-
-Class Grongier.PEX.Director [ Inheritance = right, ProcedureBlock, System = 4 ]
-{
-
-ClassMethod dispatchCreateBusinessService(pTargetDispatchName As %String) As Ens.BusinessService
-{
-	set tSC = ##class(Ens.Director).CreateBusinessService(pTargetDispatchName,.service)
-	if $$$ISERR(tSC) throw ##class(%Exception.StatusException).CreateFromStatus(tSC)
-	quit service
-}
-
-ClassMethod dispatchListProductions() As %String
-{
-	// Loop over the productions in this namespace
-	Set tRS = ##class(%ResultSet).%New("Ens.Config.Production:ProductionStatus")
-	If '$IsObject(tRS) Set tSC = %objlasterror Quit
-	
-	Set tSC = tRS.Execute()
-	Quit:$$$ISERR(tSC)
-	
-	set tDict = ##class(%SYS.Python).Import("builtins").dict()
-
-	While (tRS.Next()) {
-		Set tProduction = tRS.Data("Production")
-		Set tInfo = ##class(%SYS.Python).Import("builtins").dict()
-		do tInfo."__setitem__"("Status",tRS.Data("Status"))
-		do tInfo."__setitem__"("LastStartTime",tRS.Data("LastStartTime"))
-		do tInfo."__setitem__"("LastStopTime",tRS.Data("LastStopTime"))
-		do tInfo."__setitem__"("AutoStart",$G(^Ens.AutoStart)=tProduction)
-		do tDict."__setitem__"(tProduction,tInfo)
-	}
-
-	Kill tRS
-
-	return tDict
-}
-
-ClassMethod StatusProduction() As %String
-{
-	Set sc = $$$OK
-	Set tInfo = ##class(%SYS.Python).Import("builtins").dict()
-	$$$ThrowOnError(##class(Ens.Director).GetProductionStatus(.tProdName,.tStatus))
-	do tInfo."__setitem__"("Production",tProdName)
-	do tInfo."__setitem__"("Status",$CASE(tStatus,$$$eProductionStateRunning:"running",
-												$$$eProductionStateStopped:"stopped",
-												$$$eProductionStateSuspended:"suspended",
-												$$$eProductionStateTroubled:"toubled",
-												:"unknown"))
-	Return tInfo
-}
-
-}