evo8-linux 0.1.0__py3-none-any.whl

This diff represents the content of publicly available package versions that have been released to one of the supported registries. The information contained in this diff is provided for informational purposes only and reflects changes between package versions as they appear in their respective public registries.
Files changed (49) hide show
  1. evo8/__init__.py +3 -0
  2. evo8/about.py +131 -0
  3. evo8/alsa.py +77 -0
  4. evo8/apps.py +76 -0
  5. evo8/calibrate.py +159 -0
  6. evo8/cli.py +214 -0
  7. evo8/data/__init__.py +0 -0
  8. evo8/data/applications/evo8-mixer.desktop +8 -0
  9. evo8/data/evo8-mixer.svg +38 -0
  10. evo8/data/pipewire/pipewire-pulse.conf.d/20-bloquear-volumen-micro.conf +16 -0
  11. evo8/data/pipewire/pipewire.conf.d/20-mezcla.conf +158 -0
  12. evo8/data/systemd/evo8-restore.service +8 -0
  13. evo8/data/udev/70-audient-evo8.rules +7 -0
  14. evo8/gui/__init__.py +1 -0
  15. evo8/gui/app.py +92 -0
  16. evo8/gui/backend.py +485 -0
  17. evo8/gui/meters.py +86 -0
  18. evo8/gui/qml/AboutPage.qml +257 -0
  19. evo8/gui/qml/CardProfiles.qml +118 -0
  20. evo8/gui/qml/ConsolePage.qml +255 -0
  21. evo8/gui/qml/Divider.qml +8 -0
  22. evo8/gui/qml/GlyphButton.qml +30 -0
  23. evo8/gui/qml/HardwarePage.qml +603 -0
  24. evo8/gui/qml/HwMixStrip.qml +178 -0
  25. evo8/gui/qml/Main.qml +139 -0
  26. evo8/gui/qml/PixelSlider.qml +80 -0
  27. evo8/gui/qml/Strip.qml +396 -0
  28. evo8/gui/qml/StripGroup.qml +23 -0
  29. evo8/gui/qml/Theme.qml +22 -0
  30. evo8/gui/qml/Tip.qml +20 -0
  31. evo8/gui/qml/Toggle.qml +41 -0
  32. evo8/gui/qml/VMeter.qml +28 -0
  33. evo8/gui/qml/format.js +88 -0
  34. evo8/gui/qml/qmldir +14 -0
  35. evo8/gui/snapshot.py +98 -0
  36. evo8/hw.py +147 -0
  37. evo8/mix.py +109 -0
  38. evo8/monitor.py +229 -0
  39. evo8/profiles.py +112 -0
  40. evo8/pw.py +164 -0
  41. evo8/state.py +45 -0
  42. evo8/usb.py +122 -0
  43. evo8/user_setup.py +224 -0
  44. evo8_linux-0.1.0.dist-info/METADATA +198 -0
  45. evo8_linux-0.1.0.dist-info/RECORD +49 -0
  46. evo8_linux-0.1.0.dist-info/WHEEL +5 -0
  47. evo8_linux-0.1.0.dist-info/entry_points.txt +5 -0
  48. evo8_linux-0.1.0.dist-info/licenses/LICENSE +21 -0
  49. evo8_linux-0.1.0.dist-info/top_level.txt +1 -0
@@ -0,0 +1,178 @@
1
+ import QtQuick
2
+ import "."
3
+ import "format.js" as F
4
+
5
+ // One source in the EVO's internal mix, like a channel of EVO Control's mixer:
6
+ // pan (balance for a stereo pair), mute, and an upright fader in dB whose
7
+ // bottom cell is "off".
8
+ Item {
9
+ id: strip
10
+ property string title: ""
11
+ property string subtitle: ""
12
+ property var state: null // {level, pan, muted} or null when unknown
13
+ property bool pending: false
14
+ property real floor: -61
15
+ property real faderHeight: Theme.faderHeight * 0.8
16
+ // Everything but the fader, so a parent can size the fader to fill a
17
+ // height. Summed from the other children (never from the column's own
18
+ // height, which includes the fader and would make a binding loop).
19
+ readonly property real chromeHeight: {
20
+ var h = 16, n = 0
21
+ for (var i = 0; i < col.children.length; i++) {
22
+ var c = col.children[i]
23
+ if (c === faderBox || !c.visible) continue
24
+ h += c.height
25
+ n++
26
+ }
27
+ return h + col.spacing * n
28
+ }
29
+ signal levelMoved(real level)
30
+ signal panMoved(real pan)
31
+ signal muteToggled()
32
+
33
+ readonly property bool known: state !== null
34
+ readonly property real level: known ? Math.max(floor, state.level) : floor
35
+ readonly property real pan: known ? state.pan : 0
36
+ readonly property bool muted: known && state.muted
37
+
38
+ width: Theme.stripWidth
39
+ height: col.implicitHeight + 16
40
+ opacity: known ? 1 : 0.5
41
+
42
+ Rectangle {
43
+ anchors.fill: parent
44
+ radius: Theme.radius
45
+ color: Theme.alpha(Theme.foreground, 0.03)
46
+ border.width: strip.pending ? 1 : 0
47
+ border.color: Theme.accent
48
+ }
49
+
50
+ Column {
51
+ id: col
52
+ anchors.left: parent.left
53
+ anchors.right: parent.right
54
+ anchors.top: parent.top
55
+ anchors.margins: 8
56
+ spacing: 8
57
+
58
+ Column {
59
+ width: parent.width
60
+ spacing: 1
61
+ Text {
62
+ width: parent.width
63
+ horizontalAlignment: Text.AlignHCenter
64
+ text: strip.title
65
+ color: Theme.foreground
66
+ font.family: Theme.font
67
+ font.pixelSize: Theme.body
68
+ font.bold: true
69
+ }
70
+ Text {
71
+ width: parent.width
72
+ horizontalAlignment: Text.AlignHCenter
73
+ elide: Text.ElideRight
74
+ text: strip.subtitle === "" ? " " : strip.subtitle
75
+ color: Theme.dim
76
+ font.family: Theme.font
77
+ font.pixelSize: Theme.caption
78
+ }
79
+ }
80
+
81
+ // Pan / balance with its reset to centre.
82
+ Column {
83
+ width: parent.width
84
+ spacing: 3
85
+ Item {
86
+ width: parent.width
87
+ height: panLabel.implicitHeight
88
+ Text {
89
+ id: panLabel
90
+ text: "PAN"
91
+ color: Theme.dim
92
+ font.family: Theme.font
93
+ font.pixelSize: Theme.caption
94
+ font.letterSpacing: 1.2
95
+ font.bold: true
96
+ }
97
+ GlyphButton {
98
+ anchors.right: parent.right
99
+ anchors.verticalCenter: panLabel.verticalCenter
100
+ text: "󰑐"
101
+ font.pixelSize: Theme.caption
102
+ active: strip.known && !strip.muted && Math.abs(strip.pan) > 0.005
103
+ tip: "Al centro"
104
+ onClicked: strip.panMoved(0)
105
+ }
106
+ }
107
+ PixelSlider {
108
+ width: parent.width
109
+ minimum: -1
110
+ maximum: 1
111
+ step: 0.05
112
+ value: strip.pan
113
+ enabled: strip.known && !strip.muted
114
+ onMoved: function(v) { strip.panMoved(v) }
115
+ }
116
+ Text {
117
+ width: parent.width
118
+ horizontalAlignment: Text.AlignHCenter
119
+ text: F.panText(strip.pan)
120
+ color: Theme.foreground
121
+ font.family: Theme.font
122
+ font.pixelSize: Theme.caption
123
+ font.bold: true
124
+ }
125
+ }
126
+
127
+ GlyphButton {
128
+ anchors.horizontalCenter: parent.horizontalCenter
129
+ text: strip.muted ? "󰝟" : "󰕾"
130
+ font.pixelSize: Theme.title
131
+ color: strip.muted ? Theme.urgent : Theme.foreground
132
+ active: strip.known
133
+ tip: strip.muted ? "Volver a oír" : "Dejar de oír"
134
+ onClicked: strip.muteToggled()
135
+ }
136
+
137
+ Item {
138
+ id: faderBox
139
+ width: parent.width
140
+ height: strip.faderHeight
141
+ Item {
142
+ anchors.centerIn: parent
143
+ width: 30
144
+ height: parent.height
145
+ opacity: strip.muted ? 0.5 : 1
146
+ // 0 dB mark (the factory level).
147
+ Rectangle {
148
+ width: parent.width
149
+ height: 1
150
+ color: Theme.alpha(Theme.foreground, 0.35)
151
+ y: 0
152
+ }
153
+ PixelSlider {
154
+ anchors.centerIn: parent
155
+ width: parent.height
156
+ rotation: -90
157
+ minimum: strip.floor
158
+ maximum: 0
159
+ step: 1
160
+ value: strip.muted ? strip.floor : strip.level
161
+ enabled: strip.known
162
+ onMoved: function(v) { strip.levelMoved(v) }
163
+ onRightClicked: strip.muteToggled()
164
+ }
165
+ }
166
+ }
167
+
168
+ Text {
169
+ width: parent.width
170
+ horizontalAlignment: Text.AlignHCenter
171
+ text: !strip.known ? "?" : strip.muted ? "apagado" : Math.round(strip.level) + " dB"
172
+ color: strip.muted ? Theme.urgent : (strip.pending ? Theme.accent : Theme.foreground)
173
+ font.family: Theme.font
174
+ font.pixelSize: Theme.caption
175
+ font.bold: true
176
+ }
177
+ }
178
+ }
evo8/gui/qml/Main.qml ADDED
@@ -0,0 +1,139 @@
1
+ import QtQuick
2
+ import QtQuick.Controls
3
+ import QtQuick.Layouts
4
+ import "."
5
+
6
+ ApplicationWindow {
7
+ id: window
8
+ title: "Mezclador"
9
+ width: 1640
10
+ height: 640
11
+ minimumWidth: 720
12
+ minimumHeight: 520
13
+ visible: true
14
+ color: Theme.background
15
+
16
+ readonly property var m: mixer.model
17
+ property int page: 0
18
+
19
+ Shortcut { sequence: "Escape"; onActivated: window.close() }
20
+
21
+ component Tab: Text {
22
+ id: tab
23
+ property int index: 0
24
+ text: ""
25
+ color: window.page === index ? Theme.foreground : Theme.dim
26
+ font.family: Theme.font
27
+ font.pixelSize: Theme.body
28
+ font.bold: window.page === index
29
+ font.letterSpacing: 1.2
30
+ Rectangle {
31
+ anchors.top: parent.bottom
32
+ anchors.topMargin: 4
33
+ width: parent.width
34
+ height: 2
35
+ color: Theme.accent
36
+ visible: window.page === tab.index
37
+ }
38
+ MouseArea {
39
+ anchors.fill: parent
40
+ anchors.margins: -6
41
+ cursorShape: Qt.PointingHandCursor
42
+ onClicked: window.page = tab.index
43
+ }
44
+ }
45
+
46
+ ColumnLayout {
47
+ anchors.fill: parent
48
+ anchors.margins: 18
49
+ spacing: 14
50
+
51
+ RowLayout {
52
+ Layout.fillWidth: true
53
+ spacing: 28
54
+ Image {
55
+ source: "../../data/evo8-mixer.svg"
56
+ Layout.preferredWidth: 22
57
+ Layout.preferredHeight: 22
58
+ sourceSize: Qt.size(44, 44)
59
+ smooth: true
60
+ }
61
+ Text {
62
+ Layout.leftMargin: -18
63
+ text: "Mezclador"
64
+ color: Theme.foreground
65
+ font.family: Theme.font
66
+ font.pixelSize: Theme.title
67
+ font.bold: true
68
+ }
69
+ Tab { index: 0; text: "CONSOLA" }
70
+ Tab { index: 1; text: "EVO 8" }
71
+ Tab { index: 2; text: "ACERCA DE" }
72
+ Item { Layout.fillWidth: true }
73
+ Text {
74
+ text: window.m.notice || ""
75
+ visible: text !== "" && !(window.m.message)
76
+ color: Theme.accent
77
+ font.family: Theme.font
78
+ font.pixelSize: Theme.caption
79
+ font.bold: true
80
+ elide: Text.ElideLeft
81
+ Layout.maximumWidth: 900
82
+ }
83
+ Text {
84
+ text: window.m.message || ""
85
+ color: Theme.urgent
86
+ font.family: Theme.font
87
+ font.pixelSize: Theme.caption
88
+ elide: Text.ElideLeft
89
+ Layout.maximumWidth: 600
90
+ }
91
+ }
92
+
93
+ // Hidden on the other tabs but keeps its line: if it collapsed, the
94
+ // content area would change height and every console strip would lay
95
+ // itself out again on each tab switch (~0.5 s).
96
+ Text {
97
+ Layout.fillWidth: true
98
+ opacity: window.page === 0 ? 1 : 0
99
+ text: window.m.gains !== null
100
+ ? "PRE preamp de la EVO · FADER cuánto entra a la Mezcla · SINC alinea lo que tocas sobre Compartido · PERFILES cómo usa el sistema cada tarjeta · 󰑐 volver al estándar"
101
+ : "No se encontró la Mezcla: corre «evoctl setup» y reinicia PipeWire"
102
+ color: window.m.gains !== null ? Theme.dim : Theme.urgent
103
+ font.family: Theme.font
104
+ font.pixelSize: Theme.caption
105
+ elide: Text.ElideRight
106
+ }
107
+
108
+ // Give the scroll views the available space directly. Their content
109
+ // sizes depend on that space and must stay out of layout negotiation.
110
+ //
111
+ // Pages are switched with opacity + enabled, not visible: toggling
112
+ // visible tells every one of a page's ~2000 items, and each Row or
113
+ // Column of fader/meter cells lays itself out again per child
114
+ // (~0.4 s on the console). A page at opacity 0 is skipped by the
115
+ // renderer, and a disabled one gets no input.
116
+ Item {
117
+ Layout.fillWidth: true
118
+ Layout.fillHeight: true
119
+
120
+ ConsolePage {
121
+ anchors.fill: parent
122
+ opacity: window.page === 0 ? 1 : 0
123
+ enabled: window.page === 0
124
+ }
125
+
126
+ HardwarePage {
127
+ anchors.fill: parent
128
+ opacity: window.page === 1 ? 1 : 0
129
+ enabled: window.page === 1
130
+ }
131
+
132
+ AboutPage {
133
+ anchors.fill: parent
134
+ opacity: window.page === 2 ? 1 : 0
135
+ enabled: window.page === 2
136
+ }
137
+ }
138
+ }
139
+ }
@@ -0,0 +1,80 @@
1
+ import QtQuick
2
+ import "."
3
+
4
+ // Segmented horizontal slider: a row of square cells lit up to the value, with
5
+ // a square handle. Turned -90° it is the strips' fader. Drag, click or scroll;
6
+ // right click asks for mute (`rightClicked`).
7
+ Item {
8
+ id: root
9
+ property real value: 0
10
+ property real minimum: 0
11
+ property real maximum: 1
12
+ property real step: 0.01
13
+ property bool live: true
14
+ signal moved(real value)
15
+ signal rightClicked()
16
+
17
+ implicitWidth: 120
18
+ implicitHeight: 18
19
+ opacity: enabled ? 1 : 0.4
20
+
21
+ readonly property real cell: 6
22
+ readonly property int cells: Math.max(4, Math.floor((width - cell) / (cell + 2)))
23
+ readonly property real ratio: maximum > minimum
24
+ ? Math.max(0, Math.min(1, (value - minimum) / (maximum - minimum))) : 0
25
+
26
+ function valueAt(x) {
27
+ var r = Math.max(0, Math.min(1, (x - cell / 2) / Math.max(1, width - cell)))
28
+ var v = minimum + r * (maximum - minimum)
29
+ if (step > 0) v = Math.round(v / step) * step
30
+ return Math.max(minimum, Math.min(maximum, v))
31
+ }
32
+
33
+ Row {
34
+ anchors.verticalCenter: parent.verticalCenter
35
+ x: root.cell / 2
36
+ spacing: 2
37
+ Repeater {
38
+ model: root.cells
39
+ Rectangle {
40
+ required property int index
41
+ width: root.cell
42
+ height: root.cell
43
+ color: (index + 0.5) / root.cells <= root.ratio
44
+ ? Theme.foreground : Theme.alpha(Theme.accent, 0.22)
45
+ }
46
+ }
47
+ }
48
+
49
+ Rectangle {
50
+ width: root.cell + 6
51
+ height: root.cell + 6
52
+ radius: width / 2
53
+ anchors.verticalCenter: parent.verticalCenter
54
+ x: root.ratio * (root.width - width)
55
+ color: Theme.foreground
56
+ border.color: Theme.background
57
+ border.width: 1
58
+ }
59
+
60
+ MouseArea {
61
+ anchors.fill: parent
62
+ anchors.margins: -4
63
+ enabled: root.enabled
64
+ acceptedButtons: Qt.LeftButton | Qt.RightButton
65
+ cursorShape: Qt.PointingHandCursor
66
+ preventStealing: true
67
+ onPressed: function(m) {
68
+ if (m.button === Qt.RightButton) { root.rightClicked(); return }
69
+ root.moved(root.valueAt(m.x - 4))
70
+ }
71
+ onPositionChanged: function(m) {
72
+ if (pressed && (m.buttons & Qt.LeftButton)) root.moved(root.valueAt(m.x - 4))
73
+ }
74
+ onWheel: function(w) {
75
+ var s = root.step > 0 ? root.step : (root.maximum - root.minimum) / 100
76
+ var v = root.value + (w.angleDelta.y > 0 ? s : -s)
77
+ root.moved(Math.max(root.minimum, Math.min(root.maximum, v)))
78
+ }
79
+ }
80
+ }