beswarm 0.1.2__py3-none-any.whl → 0.1.4__py3-none-any.whl

beswarm/queries/tree-sitter-languages/hcl-tags.scm

@@ -0,0 +1,77 @@
+;; Based on https://github.com/tree-sitter-grammars/tree-sitter-hcl/blob/main/make_grammar.js
+;; Which has Apache 2.0 License
+;; tags.scm for Terraform (tree-sitter-hcl)
+
+; === Definitions: Terraform Blocks ===
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @resource_type)
+  (string_lit (template_literal) @name.definition.resource)
+  (body) @definition.resource
+) (#eq? @block_type "resource")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.module)
+  (body) @definition.module
+) (#eq? @block_type "module")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.variable)
+  (body) @definition.variable
+) (#eq? @block_type "variable")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.output)
+  (body) @definition.output
+) (#eq? @block_type "output")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.provider)
+  (body) @definition.provider
+) (#eq? @block_type "provider")
+
+(block 
+  (identifier) @block_type
+  (body 
+    (attribute 
+       (identifier) @name.definition.local 
+       (expression) @definition.local
+    )+
+  )
+) (#eq? @block_type "locals")
+
+; === References: Variables, Locals, Modules, Data, Resources ===
+((variable_expr) @ref_type
+  (get_attr (identifier) @name.reference.variable)
+) @reference.variable
+ (#eq? @ref_type "var")
+
+((variable_expr) @ref_type
+  (get_attr (identifier) @name.reference.local)
+) @reference.local
+ (#eq? @ref_type "local")
+
+((variable_expr) @ref_type
+  (get_attr (identifier) @name.reference.module)
+) @reference.module
+ (#eq? @ref_type "module")
+
+((variable_expr) @ref_type
+  (get_attr (identifier) @data_source_type)
+  (get_attr (identifier) @name.reference.data)
+) @reference.data
+ (#eq? @ref_type "data")
+
+((variable_expr) @resource_type
+  (get_attr (identifier) @name.reference.resource)
+) @reference.resource
+ (#not-eq? @resource_type "var")
+ (#not-eq? @resource_type "local")
+ (#not-eq? @resource_type "module")
+ (#not-eq? @resource_type "data")
+ (#not-eq? @resource_type "provider")
+ (#not-eq? @resource_type "output")

beswarm/queries/tree-sitter-languages/java-tags.scm

@@ -0,0 +1,20 @@
+(class_declaration
+  name: (identifier) @name.definition.class) @definition.class
+
+(method_declaration
+  name: (identifier) @name.definition.method) @definition.method
+
+(method_invocation
+  name: (identifier) @name.reference.call
+  arguments: (argument_list) @reference.call)
+
+(interface_declaration
+  name: (identifier) @name.definition.interface) @definition.interface
+
+(type_list
+  (type_identifier) @name.reference.implementation) @reference.implementation
+
+(object_creation_expression
+  type: (type_identifier) @name.reference.class) @reference.class
+
+(superclass (type_identifier) @name.reference.class) @reference.class

beswarm/queries/tree-sitter-languages/javascript-tags.scm

@@ -0,0 +1,88 @@
+(
+  (comment)* @doc
+  .
+  (method_definition
+    name: (property_identifier) @name.definition.method) @definition.method
+  (#not-eq? @name.definition.method "constructor")
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.method)
+)
+
+(
+  (comment)* @doc
+  .
+  [
+    (class
+      name: (_) @name.definition.class)
+    (class_declaration
+      name: (_) @name.definition.class)
+  ] @definition.class
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.class)
+)
+
+(
+  (comment)* @doc
+  .
+  [
+    (function
+      name: (identifier) @name.definition.function)
+    (function_declaration
+      name: (identifier) @name.definition.function)
+    (generator_function
+      name: (identifier) @name.definition.function)
+    (generator_function_declaration
+      name: (identifier) @name.definition.function)
+  ] @definition.function
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (lexical_declaration
+    (variable_declarator
+      name: (identifier) @name.definition.function
+      value: [(arrow_function) (function)]) @definition.function)
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (variable_declaration
+    (variable_declarator
+      name: (identifier) @name.definition.function
+      value: [(arrow_function) (function)]) @definition.function)
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(assignment_expression
+  left: [
+    (identifier) @name.definition.function
+    (member_expression
+      property: (property_identifier) @name.definition.function)
+  ]
+  right: [(arrow_function) (function)]
+) @definition.function
+
+(pair
+  key: (property_identifier) @name.definition.function
+  value: [(arrow_function) (function)]) @definition.function
+
+(
+  (call_expression
+    function: (identifier) @name.reference.call) @reference.call
+  (#not-match? @name.reference.call "^(require)$")
+)
+
+(call_expression
+  function: (member_expression
+    property: (property_identifier) @name.reference.call)
+  arguments: (_) @reference.call)
+
+(new_expression
+  constructor: (_) @name.reference.class) @reference.class

beswarm/queries/tree-sitter-languages/kotlin-tags.scm

@@ -0,0 +1,27 @@
+; Definitions
+
+(class_declaration
+  (type_identifier) @name.definition.class) @definition.class
+
+(function_declaration
+  (simple_identifier) @name.definition.function) @definition.function
+
+(object_declaration
+  (type_identifier) @name.definition.object) @definition.object
+
+; References
+
+(call_expression
+  [
+    (simple_identifier) @name.reference.call
+    (navigation_expression
+      (navigation_suffix
+        (simple_identifier) @name.reference.call))
+  ]) @reference.call
+
+(delegation_specifier
+  [
+    (user_type) @name.reference.type
+    (constructor_invocation
+      (user_type) @name.reference.type)
+  ]) @reference.type

beswarm/queries/tree-sitter-languages/ocaml-tags.scm

@@ -0,0 +1,115 @@
+; Modules
+;--------
+
+(
+  (comment)? @doc .
+  (module_definition (module_binding (module_name) @name.definition.module) @definition.module)
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(module_path (module_name) @name.reference.module) @reference.module
+
+; Module types
+;--------------
+
+(
+  (comment)? @doc .
+  (module_type_definition (module_type_name) @name.definition.interface) @definition.interface
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(module_type_path (module_type_name) @name.reference.implementation) @reference.implementation
+
+; Functions
+;----------
+
+(
+  (comment)? @doc .
+  (value_definition
+    [
+      (let_binding
+        pattern: (value_name) @name.definition.function
+        (parameter))
+      (let_binding
+        pattern: (value_name) @name.definition.function
+        body: [(fun_expression) (function_expression)])
+    ] @definition.function
+  )
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(
+  (comment)? @doc .
+  (external (value_name) @name.definition.function) @definition.function
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(application_expression
+  function: (value_path (value_name) @name.reference.call)) @reference.call
+
+(infix_expression
+  left: (value_path (value_name) @name.reference.call)
+  operator: (concat_operator) @reference.call
+  (#eq? @reference.call "@@"))
+
+(infix_expression
+  operator: (rel_operator) @reference.call
+  right: (value_path (value_name) @name.reference.call)
+  (#eq? @reference.call "|>"))
+
+; Operator
+;---------
+
+(
+  (comment)? @doc .
+  (value_definition
+    (let_binding
+      pattern: (parenthesized_operator (_) @name.definition.function)) @definition.function)
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+[
+  (prefix_operator)
+  (sign_operator)
+  (pow_operator)
+  (mult_operator)
+  (add_operator)
+  (concat_operator)
+  (rel_operator)
+  (and_operator)
+  (or_operator)
+  (assign_operator)
+  (hash_operator)
+  (indexing_operator)
+  (let_operator)
+  (let_and_operator)
+  (match_operator)
+] @name.reference.call @reference.call
+
+; Classes
+;--------
+
+(
+  (comment)? @doc .
+  [
+    (class_definition (class_binding (class_name) @name.definition.class) @definition.class)
+    (class_type_definition (class_type_binding (class_type_name) @name.definition.class) @definition.class)
+  ]
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+[
+  (class_path (class_name) @name.reference.class)
+  (class_type_path (class_type_name) @name.reference.class)
+] @reference.class
+
+; Methods
+;--------
+
+(
+  (comment)? @doc .
+  (method_definition (method_name) @name.definition.method) @definition.method
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(method_invocation (method_name) @name.reference.call) @reference.call

beswarm/queries/tree-sitter-languages/php-tags.scm

@@ -0,0 +1,26 @@
+(class_declaration
+  name: (name) @name.definition.class) @definition.class
+
+(function_definition
+  name: (name) @name.definition.function) @definition.function
+
+(method_declaration
+  name: (name) @name.definition.function) @definition.function
+
+(object_creation_expression
+  [
+    (qualified_name (name) @name.reference.class)
+    (variable_name (name) @name.reference.class)
+  ]) @reference.class
+
+(function_call_expression
+  function: [
+    (qualified_name (name) @name.reference.call)
+    (variable_name (name)) @name.reference.call
+  ]) @reference.call
+
+(scoped_call_expression
+  name: (name) @name.reference.call) @reference.call
+
+(member_call_expression
+  name: (name) @name.reference.call) @reference.call

beswarm/queries/tree-sitter-languages/python-tags.scm

@@ -0,0 +1,12 @@
+(class_definition
+  name: (identifier) @name.definition.class) @definition.class
+
+(function_definition
+  name: (identifier) @name.definition.function) @definition.function
+
+(call
+  function: [
+      (identifier) @name.reference.call
+      (attribute
+        attribute: (identifier) @name.reference.call)
+  ]) @reference.call

beswarm/queries/tree-sitter-languages/ql-tags.scm

@@ -0,0 +1,26 @@
+(classlessPredicate
+  name: (predicateName) @name.definition.function) @definition.function
+
+(memberPredicate
+  name: (predicateName) @name.definition.method) @definition.method
+
+(aritylessPredicateExpr
+  name: (literalId) @name.reference.call) @reference.call
+
+(module
+  name: (moduleName) @name.definition.module) @definition.module
+
+(dataclass
+  name: (className) @name.definition.class) @definition.class
+
+(datatype
+  name: (className) @name.definition.class) @definition.class
+
+(datatypeBranch
+  name: (className) @name.definition.class) @definition.class
+
+(qualifiedRhs
+  name: (predicateName) @name.reference.call) @reference.call
+
+(typeExpr
+  name: (className) @name.reference.type) @reference.type

beswarm/queries/tree-sitter-languages/ruby-tags.scm

@@ -0,0 +1,64 @@
+; Method definitions
+
+(
+  (comment)* @doc
+  .
+  [
+    (method
+      name: (_) @name.definition.method) @definition.method
+    (singleton_method
+      name: (_) @name.definition.method) @definition.method
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.method)
+)
+
+(alias
+  name: (_) @name.definition.method) @definition.method
+
+(setter
+  (identifier) @ignore)
+
+; Class definitions
+
+(
+  (comment)* @doc
+  .
+  [
+    (class
+      name: [
+        (constant) @name.definition.class
+        (scope_resolution
+          name: (_) @name.definition.class)
+      ]) @definition.class
+    (singleton_class
+      value: [
+        (constant) @name.definition.class
+        (scope_resolution
+          name: (_) @name.definition.class)
+      ]) @definition.class
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.class)
+)
+
+; Module definitions
+
+(
+  (module
+    name: [
+      (constant) @name.definition.module
+      (scope_resolution
+        name: (_) @name.definition.module)
+    ]) @definition.module
+)
+
+; Calls
+
+(call method: (identifier) @name.reference.call) @reference.call
+
+(
+  [(identifier) (constant)] @name.reference.call @reference.call
+  (#is-not? local)
+  (#not-match? @name.reference.call "^(lambda|load|require|require_relative|__FILE__|__LINE__)$")
+)

beswarm/queries/tree-sitter-languages/rust-tags.scm

@@ -0,0 +1,60 @@
+; ADT definitions
+
+(struct_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+(enum_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+(union_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+; type aliases
+
+(type_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+; method definitions
+
+(declaration_list
+    (function_item
+        name: (identifier) @name.definition.method)) @definition.method
+
+; function definitions
+
+(function_item
+    name: (identifier) @name.definition.function) @definition.function
+
+; trait definitions
+(trait_item
+    name: (type_identifier) @name.definition.interface) @definition.interface
+
+; module definitions
+(mod_item
+    name: (identifier) @name.definition.module) @definition.module
+
+; macro definitions
+
+(macro_definition
+    name: (identifier) @name.definition.macro) @definition.macro
+
+; references
+
+(call_expression
+    function: (identifier) @name.reference.call) @reference.call
+
+(call_expression
+    function: (field_expression
+        field: (field_identifier) @name.reference.call)) @reference.call
+
+(macro_invocation
+    macro: (identifier) @name.reference.call) @reference.call
+
+; implementations
+
+(impl_item
+    trait: (type_identifier) @name.reference.implementation) @reference.implementation
+
+(impl_item
+    type: (type_identifier) @name.reference.implementation
+    !trait) @reference.implementation

beswarm/queries/tree-sitter-languages/scala-tags.scm

@@ -0,0 +1,65 @@
+; Definitions
+
+(package_clause
+  name: (package_identifier) @name.definition.module) @definition.module
+
+(trait_definition
+  name: (identifier) @name.definition.interface) @definition.interface
+
+(enum_definition
+  name: (identifier) @name.definition.enum) @definition.enum
+
+(simple_enum_case
+  name: (identifier) @name.definition.class) @definition.class
+
+(full_enum_case
+  name: (identifier) @name.definition.class) @definition.class
+
+(class_definition
+  name: (identifier) @name.definition.class) @definition.class
+
+(object_definition
+  name: (identifier) @name.definition.object) @definition.object
+
+(function_definition
+  name: (identifier) @name.definition.function) @definition.function
+
+(val_definition
+  pattern: (identifier) @name.definition.variable) @definition.variable
+
+(given_definition
+  name: (identifier) @name.definition.variable) @definition.variable
+
+(var_definition
+  pattern: (identifier) @name.definition.variable) @definition.variable
+
+(val_declaration
+  name: (identifier) @name.definition.variable) @definition.variable
+
+(var_declaration
+  name: (identifier) @name.definition.variable) @definition.variable
+
+(type_definition
+  name: (type_identifier) @name.definition.type) @definition.type
+
+(class_parameter
+  name: (identifier) @name.definition.property) @definition.property
+
+; References
+
+(call_expression
+  (identifier) @name.reference.call) @reference.call
+
+(instance_expression
+  (type_identifier) @name.reference.interface) @reference.interface
+
+(instance_expression
+  (generic_type
+    (type_identifier) @name.reference.interface)) @reference.interface
+
+(extends_clause
+  (type_identifier) @name.reference.class) @reference.class
+
+(extends_clause
+  (generic_type
+    (type_identifier) @name.reference.class)) @reference.class

beswarm/queries/tree-sitter-languages/typescript-tags.scm

@@ -0,0 +1,41 @@
+(function_signature
+  name: (identifier) @name.definition.function) @definition.function
+
+(method_signature
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(abstract_method_signature
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(abstract_class_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(module
+  name: (identifier) @name.definition.module) @definition.module
+
+(interface_declaration
+  name: (type_identifier) @name.definition.interface) @definition.interface
+
+(type_annotation
+  (type_identifier) @name.reference.type) @reference.type
+
+(new_expression
+  constructor: (identifier) @name.reference.class) @reference.class
+
+(function_declaration
+  name: (identifier) @name.definition.function) @definition.function
+
+(method_definition
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(class_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(interface_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(type_alias_declaration
+  name: (type_identifier) @name.definition.type) @definition.type
+
+(enum_declaration
+  name: (identifier) @name.definition.enum) @definition.enum

beswarm/tools/__init__.py

@@ -0,0 +1,13 @@
+from .think import think
+from .edit_file import edit_file
+from .worker import worker
+from .search_arxiv import search_arxiv
+from .repomap import get_code_repo_map
+
+__all__ = [
+    "think",
+    "edit_file",
+    "worker",
+    "search_arxiv",
+    "get_code_repo_map",
+]