aider-ce 0.88.20__py3-none-any.whl

aider/queries/tree-sitter-languages/dart-tags.scm

@@ -0,0 +1,91 @@
+(class_definition
+  name: (identifier) @name.definition.class) @definition.class
+
+(method_signature
+  (function_signature)) @definition.method
+
+(type_alias
+  (type_identifier) @name.definition.type) @definition.type
+
+(method_signature
+  (getter_signature
+    name: (identifier) @name.definition.method)) @definition.method
+
+(method_signature
+  (setter_signature
+    name: (identifier) @name.definition.method)) @definition.method
+
+(method_signature
+  (function_signature
+  name: (identifier) @name.definition.method)) @definition.method
+
+(method_signature
+  (factory_constructor_signature
+    (identifier) @name.definition.method)) @definition.method
+
+(method_signature
+  (constructor_signature
+  name: (identifier) @name.definition.method)) @definition.method
+
+(method_signature
+  (operator_signature)) @definition.method
+
+(method_signature) @definition.method
+
+(mixin_declaration
+  (mixin)
+  (identifier) @name.definition.mixin) @definition.mixin
+
+(extension_declaration
+  name: (identifier) @name.definition.extension) @definition.extension
+
+(enum_declaration
+  name: (identifier) @name.definition.enum) @definition.enum
+
+(function_signature
+  name: (identifier) @name.definition.function) @definition.function
+
+(new_expression
+  (type_identifier) @name.reference.class) @reference.class
+
+(initialized_variable_definition
+  name: (identifier)
+  value: (identifier) @name.reference.class
+  value: (selector
+	"!"?
+	(argument_part
+	  (arguments
+	    (argument)*))?)?) @reference.class
+
+(assignment_expression
+  left: (assignable_expression
+		  (identifier)
+		  (unconditional_assignable_selector
+			"."
+			(identifier) @name.reference.call))) @reference.call
+
+(assignment_expression
+  left: (assignable_expression
+		  (identifier)
+		  (conditional_assignable_selector
+			"?."
+			(identifier) @name.reference.call))) @reference.call
+
+((identifier) @name
+ (selector
+    "!"?
+    (conditional_assignable_selector
+      "?." (identifier) @name.reference.call)?
+    (unconditional_assignable_selector
+      "."? (identifier) @name.reference.call)?
+    (argument_part
+      (arguments
+        (argument)*))?)*
+	(cascade_section
+	  (cascade_selector
+		(identifier)) @name.reference.call
+	  (argument_part
+		(arguments
+		  (argument)*))?)?) @reference.call
+
+

aider/queries/tree-sitter-languages/elisp-tags.scm

@@ -0,0 +1,8 @@
+;; defun/defsubst
+(function_definition name: (symbol) @name.definition.function) @definition.function
+
+;; Treat macros as function definitions for the sake of TAGS.
+(macro_definition name: (symbol) @name.definition.function) @definition.function
+
+;; Match function calls
+(list (symbol) @name.reference.function) @reference.function

aider/queries/tree-sitter-languages/elixir-tags.scm

@@ -0,0 +1,54 @@
+; Definitions
+
+; * modules and protocols
+(call
+  target: (identifier) @ignore
+  (arguments (alias) @name.definition.module)
+  (#match? @ignore "^(defmodule|defprotocol)$")) @definition.module
+
+; * functions/macros
+(call
+  target: (identifier) @ignore
+  (arguments
+    [
+      ; zero-arity functions with no parentheses
+      (identifier) @name.definition.function
+      ; regular function clause
+      (call target: (identifier) @name.definition.function)
+      ; function clause with a guard clause
+      (binary_operator
+        left: (call target: (identifier) @name.definition.function)
+        operator: "when")
+    ])
+  (#match? @ignore "^(def|defp|defdelegate|defguard|defguardp|defmacro|defmacrop|defn|defnp)$")) @definition.function
+
+; References
+
+; ignore calls to kernel/special-forms keywords
+(call
+  target: (identifier) @ignore
+  (#match? @ignore "^(def|defp|defdelegate|defguard|defguardp|defmacro|defmacrop|defn|defnp|defmodule|defprotocol|defimpl|defstruct|defexception|defoverridable|alias|case|cond|else|for|if|import|quote|raise|receive|require|reraise|super|throw|try|unless|unquote|unquote_splicing|use|with)$"))
+
+; ignore module attributes
+(unary_operator
+  operator: "@"
+  operand: (call
+    target: (identifier) @ignore))
+
+; * function call
+(call
+  target: [
+   ; local
+   (identifier) @name.reference.call
+   ; remote
+   (dot
+     right: (identifier) @name.reference.call)
+  ]) @reference.call
+
+; * pipe into function call
+(binary_operator
+  operator: "|>"
+  right: (identifier) @name.reference.call) @reference.call
+
+; * modules
+(alias) @name.reference.module @reference.module

aider/queries/tree-sitter-languages/elm-tags.scm

@@ -0,0 +1,19 @@
+(value_declaration (function_declaration_left (lower_case_identifier) @name.definition.function)) @definition.function
+
+(function_call_expr (value_expr (value_qid) @name.reference.function)) @reference.function
+(exposed_value (lower_case_identifier) @name.reference.function) @reference.function
+(type_annotation ((lower_case_identifier) @name.reference.function) (colon)) @reference.function
+
+(type_declaration ((upper_case_identifier) @name.definition.type)) @definition.type
+
+(type_ref (upper_case_qid (upper_case_identifier) @name.reference.type)) @reference.type
+(exposed_type (upper_case_identifier) @name.reference.type) @reference.type
+
+(type_declaration (union_variant (upper_case_identifier) @name.definition.union)) @definition.union
+
+(value_expr (upper_case_qid (upper_case_identifier) @name.reference.union)) @reference.union
+
+
+(module_declaration
+    (upper_case_qid (upper_case_identifier)) @name.definition.module
+) @definition.module

aider/queries/tree-sitter-languages/fortran-tags.scm

@@ -0,0 +1,15 @@
+;; derived from: https://github.com/stadelmanma/tree-sitter-fortran
+;; License: MIT
+
+(module_statement
+  (name) @name.definition.class) @definition.class
+
+(function_statement
+  name: (name) @name.definition.function) @definition.function
+
+(subroutine_statement
+  name: (name) @name.definition.function) @definition.function
+
+(module_procedure_statement
+  name: (name) @name.definition.function) @definition.function
+   

aider/queries/tree-sitter-languages/go-tags.scm

@@ -0,0 +1,30 @@
+(
+  (comment)* @doc
+  .
+  (function_declaration
+    name: (identifier) @name.definition.function) @definition.function
+  (#strip! @doc "^//\\s*")
+  (#set-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (method_declaration
+    name: (field_identifier) @name.definition.method) @definition.method
+  (#strip! @doc "^//\\s*")
+  (#set-adjacent! @doc @definition.method)
+)
+
+(call_expression
+  function: [
+    (identifier) @name.reference.call
+    (parenthesized_expression (identifier) @name.reference.call)
+    (selector_expression field: (field_identifier) @name.reference.call)
+    (parenthesized_expression (selector_expression field: (field_identifier) @name.reference.call))
+  ]) @reference.call
+
+(type_spec
+  name: (type_identifier) @name.definition.type) @definition.type
+
+(type_identifier) @name.reference.type @reference.type

aider/queries/tree-sitter-languages/haskell-tags.scm

@@ -0,0 +1,3 @@
+(function  (variable) @name.definition.function)
+(bind      (variable) @name.definition.function)
+(signature (variable) @name.definition.type)

aider/queries/tree-sitter-languages/hcl-tags.scm

@@ -0,0 +1,77 @@
+;; Based on https://github.com/tree-sitter-grammars/tree-sitter-hcl/blob/main/make_grammar.js
+;; Which has Apache 2.0 License
+;; tags.scm for Terraform (tree-sitter-hcl)
+
+; === Definitions: Terraform Blocks ===
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @resource_type)
+  (string_lit (template_literal) @name.definition.resource)
+  (body) @definition.resource
+) (#eq? @block_type "resource")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.module)
+  (body) @definition.module
+) (#eq? @block_type "module")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.variable)
+  (body) @definition.variable
+) (#eq? @block_type "variable")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.output)
+  (body) @definition.output
+) (#eq? @block_type "output")
+
+(block 
+  (identifier) @block_type
+  (string_lit (template_literal) @name.definition.provider)
+  (body) @definition.provider
+) (#eq? @block_type "provider")
+
+(block 
+  (identifier) @block_type
+  (body 
+    (attribute 
+       (identifier) @name.definition.local 
+       (expression) @definition.local
+    )+
+  )
+) (#eq? @block_type "locals")
+
+; === References: Variables, Locals, Modules, Data, Resources ===
+((variable_expr) @ref_type
+  (get_attr (identifier) @name.reference.variable)
+) @reference.variable
+ (#eq? @ref_type "var")
+
+((variable_expr) @ref_type
+  (get_attr (identifier) @name.reference.local)
+) @reference.local
+ (#eq? @ref_type "local")
+
+((variable_expr) @ref_type
+  (get_attr (identifier) @name.reference.module)
+) @reference.module
+ (#eq? @ref_type "module")
+
+((variable_expr) @ref_type
+  (get_attr (identifier) @data_source_type)
+  (get_attr (identifier) @name.reference.data)
+) @reference.data
+ (#eq? @ref_type "data")
+
+((variable_expr) @resource_type
+  (get_attr (identifier) @name.reference.resource)
+) @reference.resource
+ (#not-eq? @resource_type "var")
+ (#not-eq? @resource_type "local")
+ (#not-eq? @resource_type "module")
+ (#not-eq? @resource_type "data")
+ (#not-eq? @resource_type "provider")
+ (#not-eq? @resource_type "output")

aider/queries/tree-sitter-languages/java-tags.scm

@@ -0,0 +1,20 @@
+(class_declaration
+  name: (identifier) @name.definition.class) @definition.class
+
+(method_declaration
+  name: (identifier) @name.definition.method) @definition.method
+
+(method_invocation
+  name: (identifier) @name.reference.call
+  arguments: (argument_list) @reference.call)
+
+(interface_declaration
+  name: (identifier) @name.definition.interface) @definition.interface
+
+(type_list
+  (type_identifier) @name.reference.implementation) @reference.implementation
+
+(object_creation_expression
+  type: (type_identifier) @name.reference.class) @reference.class
+
+(superclass (type_identifier) @name.reference.class) @reference.class

aider/queries/tree-sitter-languages/javascript-tags.scm

@@ -0,0 +1,88 @@
+(
+  (comment)* @doc
+  .
+  (method_definition
+    name: (property_identifier) @name.definition.method) @definition.method
+  (#not-eq? @name.definition.method "constructor")
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.method)
+)
+
+(
+  (comment)* @doc
+  .
+  [
+    (class
+      name: (_) @name.definition.class)
+    (class_declaration
+      name: (_) @name.definition.class)
+  ] @definition.class
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.class)
+)
+
+(
+  (comment)* @doc
+  .
+  [
+    (function
+      name: (identifier) @name.definition.function)
+    (function_declaration
+      name: (identifier) @name.definition.function)
+    (generator_function
+      name: (identifier) @name.definition.function)
+    (generator_function_declaration
+      name: (identifier) @name.definition.function)
+  ] @definition.function
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (lexical_declaration
+    (variable_declarator
+      name: (identifier) @name.definition.function
+      value: [(arrow_function) (function)]) @definition.function)
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (variable_declaration
+    (variable_declarator
+      name: (identifier) @name.definition.function
+      value: [(arrow_function) (function)]) @definition.function)
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(assignment_expression
+  left: [
+    (identifier) @name.definition.function
+    (member_expression
+      property: (property_identifier) @name.definition.function)
+  ]
+  right: [(arrow_function) (function)]
+) @definition.function
+
+(pair
+  key: (property_identifier) @name.definition.function
+  value: [(arrow_function) (function)]) @definition.function
+
+(
+  (call_expression
+    function: (identifier) @name.reference.call) @reference.call
+  (#not-match? @name.reference.call "^(require)$")
+)
+
+(call_expression
+  function: (member_expression
+    property: (property_identifier) @name.reference.call)
+  arguments: (_) @reference.call)
+
+(new_expression
+  constructor: (_) @name.reference.class) @reference.class

aider/queries/tree-sitter-languages/julia-tags.scm

@@ -0,0 +1,60 @@
+;; derived from: https://github.com/tree-sitter/tree-sitter-julia
+;; License: MIT
+
+(module
+  name: (identifier) @name.definition.module) @definition.module
+
+(module
+  name: (scoped_identifier) @name.definition.module) @definition.module
+
+(struct_definition
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(mutable_struct_definition
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(abstract_type_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(constant_assignment
+  left: (identifier) @name.definition.class) @definition.class
+
+(function_definition
+  name: (identifier) @name.definition.function) @definition.function
+
+(function_definition
+  name: (scoped_identifier) @name.definition.function) @definition.function
+
+(assignment
+  left: (call_expression
+          function: (identifier) @name.definition.function)) @definition.function
+
+(method_definition
+  name: (identifier) @name.definition.method) @definition.method
+
+(macro_definition
+  name: (identifier) @name.definition.macro) @definition.macro
+
+(macro_call
+  name: (identifier) @name.reference.call) @reference.call
+
+(call_expression
+  function: (identifier) @name.reference.call) @reference.call
+
+(call_expression
+  function: (scoped_identifier) @name.reference.call) @reference.call
+
+(type_expression
+  name: (type_identifier) @name.reference.type) @reference.type
+
+(constant_assignment
+  left: (identifier) @name.definition.constant) @definition.constant
+
+(export_statement
+  (identifier) @name.reference.export) @reference.export
+
+(using_statement
+  (identifier) @name.reference.module) @reference.module
+
+(import_statement
+  (identifier) @name.reference.module) @reference.module

aider/queries/tree-sitter-languages/kotlin-tags.scm

@@ -0,0 +1,27 @@
+; Definitions
+
+(class_declaration
+  (type_identifier) @name.definition.class) @definition.class
+
+(function_declaration
+  (simple_identifier) @name.definition.function) @definition.function
+
+(object_declaration
+  (type_identifier) @name.definition.object) @definition.object
+
+; References
+
+(call_expression
+  [
+    (simple_identifier) @name.reference.call
+    (navigation_expression
+      (navigation_suffix
+        (simple_identifier) @name.reference.call))
+  ]) @reference.call
+
+(delegation_specifier
+  [
+    (user_type) @name.reference.type
+    (constructor_invocation
+      (user_type) @name.reference.type)
+  ]) @reference.type

aider/queries/tree-sitter-languages/matlab-tags.scm

@@ -0,0 +1,10 @@
+(class_definition
+  name: (identifier) @name.definition.class) @definition.class
+
+(function_definition
+  name: (identifier) @name.definition.function) @definition.function
+
+(function_call
+  name: (identifier) @name.reference.call) @reference.call
+
+(command (command_name) @name.reference.call) @reference.call

aider/queries/tree-sitter-languages/ocaml-tags.scm

@@ -0,0 +1,115 @@
+; Modules
+;--------
+
+(
+  (comment)? @doc .
+  (module_definition (module_binding (module_name) @name.definition.module) @definition.module)
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(module_path (module_name) @name.reference.module) @reference.module
+
+; Module types
+;--------------
+
+(
+  (comment)? @doc .
+  (module_type_definition (module_type_name) @name.definition.interface) @definition.interface
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(module_type_path (module_type_name) @name.reference.implementation) @reference.implementation
+
+; Functions
+;----------
+
+(
+  (comment)? @doc .
+  (value_definition
+    [
+      (let_binding
+        pattern: (value_name) @name.definition.function
+        (parameter))
+      (let_binding
+        pattern: (value_name) @name.definition.function
+        body: [(fun_expression) (function_expression)])
+    ] @definition.function
+  )
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(
+  (comment)? @doc .
+  (external (value_name) @name.definition.function) @definition.function
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(application_expression
+  function: (value_path (value_name) @name.reference.call)) @reference.call
+
+(infix_expression
+  left: (value_path (value_name) @name.reference.call)
+  operator: (concat_operator) @reference.call
+  (#eq? @reference.call "@@"))
+
+(infix_expression
+  operator: (rel_operator) @reference.call
+  right: (value_path (value_name) @name.reference.call)
+  (#eq? @reference.call "|>"))
+
+; Operator
+;---------
+
+(
+  (comment)? @doc .
+  (value_definition
+    (let_binding
+      pattern: (parenthesized_operator (_) @name.definition.function)) @definition.function)
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+[
+  (prefix_operator)
+  (sign_operator)
+  (pow_operator)
+  (mult_operator)
+  (add_operator)
+  (concat_operator)
+  (rel_operator)
+  (and_operator)
+  (or_operator)
+  (assign_operator)
+  (hash_operator)
+  (indexing_operator)
+  (let_operator)
+  (let_and_operator)
+  (match_operator)
+] @name.reference.call @reference.call
+
+; Classes
+;--------
+
+(
+  (comment)? @doc .
+  [
+    (class_definition (class_binding (class_name) @name.definition.class) @definition.class)
+    (class_type_definition (class_type_binding (class_type_name) @name.definition.class) @definition.class)
+  ]
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+[
+  (class_path (class_name) @name.reference.class)
+  (class_type_path (class_type_name) @name.reference.class)
+] @reference.class
+
+; Methods
+;--------
+
+(
+  (comment)? @doc .
+  (method_definition (method_name) @name.definition.method) @definition.method
+  (#strip! @doc "^\\(\\*\\*?\\s*|\\s\\*\\)$")
+)
+
+(method_invocation (method_name) @name.reference.call) @reference.call