ViennaPS 3.0.1__pp39-pypy39_pp73-macosx_11_0_arm64.whl

viennaps.libs/cmake/vtk-9.3/FindCGNS.cmake

@@ -0,0 +1,48 @@
+#
+# Find the native CGNS includes and library
+#
+# CGNS_INCLUDE_DIR - where to find cgns.h, etc.
+# CGNS_LIBRARIES   - List of fully qualified libraries to link against when using CGNS.
+# CGNS_FOUND       - Do not attempt to use CGNS if "no" or undefined.
+
+find_path(CGNS_INCLUDE_DIR
+  NAMES
+    cgnslib.h
+  PATHS
+    /usr/local/include
+    /usr/include
+  DOC "CGNS include directory")
+mark_as_advanced(CGNS_INCLUDE_DIR)
+
+find_library(CGNS_LIBRARY
+  NAMES
+    cgns
+  DOC "CGNS library")
+mark_as_advanced(CGNS_LIBRARY)
+
+if (CGNS_INCLUDE_DIR)
+  file(STRINGS "${CGNS_INCLUDE_DIR}/cgnslib.h" version
+    REGEX "CGNS_DOTVERS")
+  string(REGEX REPLACE ".*CGNS_DOTVERS *\([0-9.]*\).*" "\\1" CGNS_VERSION "${version}")
+  unset(version)
+else ()
+  set(CGNS_VERSION CGNS_VERSION-NOTFOUND)
+endif ()
+
+# handle the QUIETLY and REQUIRED arguments and set CGNS_FOUND to TRUE if
+# all listed variables are TRUE
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(CGNS
+  REQUIRED_VARS CGNS_INCLUDE_DIR CGNS_LIBRARY
+  VERSION_VAR CGNS_VERSION)
+
+if (CGNS_FOUND)
+  set(CGNS_LIBRARIES "${CGNS_LIBRARY}")
+  set(CGNS_INCLUDE_DIRS "${CGNS_INCLUDE_DIR}")
+  if (NOT TARGET CGNS::CGNS)
+    add_library(CGNS::CGNS UNKNOWN IMPORTED)
+    set_target_properties(CGNS::CGNS PROPERTIES
+      IMPORTED_LOCATION "${CGNS_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${CGNS_INCLUDE_DIR}")
+  endif ()
+endif ()

viennaps.libs/cmake/vtk-9.3/FindDirectX.cmake

@@ -0,0 +1,18 @@
+if (WIN32)
+  # Create imported target DirectX::d3d11
+  if (NOT TARGET DirectX::d3d11)
+    add_library(DirectX::d3d11 INTERFACE IMPORTED)
+    set_target_properties(DirectX::d3d11 PROPERTIES IMPORTED_LIBNAME "d3d11.lib")
+  endif()
+
+  # Create imported target DirectX::dxgi
+  if (NOT TARGET DirectX::dxgi)
+    add_library(DirectX::dxgi INTERFACE IMPORTED)
+    set_target_properties(DirectX::dxgi PROPERTIES IMPORTED_LIBNAME "dxgi.lib")
+  endif()
+
+  set(DirectX_FOUND TRUE)
+else()
+  set(DirectX_FOUND FALSE)
+  set(DirectX_NOT_FOUND_MESSAGE "Unsupported platform")
+endif()

viennaps.libs/cmake/vtk-9.3/FindEXPAT.cmake

@@ -0,0 +1,85 @@
+# XXX: Copied from CMake, but includes vtkDetectLibraryType.
+# See https://gitlab.kitware.com/cmake/cmake/-/issues/18564
+
+#[=======================================================================[.rst:
+FindEXPAT
+---------
+
+Find the native Expat headers and library.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+This module defines the following :prop_tgt:`IMPORTED` targets:
+
+``EXPAT::EXPAT``
+  The Expat ``expat`` library, if found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module will set the following variables in your project:
+
+``EXPAT_INCLUDE_DIRS``
+  where to find expat.h, etc.
+``EXPAT_LIBRARIES``
+  the libraries to link against to use Expat.
+``EXPAT_FOUND``
+  true if the Expat headers and libraries were found.
+
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+
+pkg_check_modules(PC_EXPAT QUIET expat)
+
+# Look for the header file.
+find_path(EXPAT_INCLUDE_DIR NAMES expat.h HINTS ${PC_EXPAT_INCLUDE_DIRS})
+
+# Look for the library.
+find_library(EXPAT_LIBRARY NAMES expat libexpat HINTS ${PC_EXPAT_LIBRARY_DIRS})
+
+if (EXPAT_INCLUDE_DIR AND EXISTS "${EXPAT_INCLUDE_DIR}/expat.h")
+    file(STRINGS "${EXPAT_INCLUDE_DIR}/expat.h" expat_version_str
+         REGEX "^#[\t ]*define[\t ]+XML_(MAJOR|MINOR|MICRO)_VERSION[\t ]+[0-9]+$")
+
+    unset(EXPAT_VERSION_STRING)
+    foreach(VPART MAJOR MINOR MICRO)
+        foreach(VLINE ${expat_version_str})
+            if(VLINE MATCHES "^#[\t ]*define[\t ]+XML_${VPART}_VERSION[\t ]+([0-9]+)$")
+                set(EXPAT_VERSION_PART "${CMAKE_MATCH_1}")
+                if(EXPAT_VERSION_STRING)
+                    string(APPEND EXPAT_VERSION_STRING ".${EXPAT_VERSION_PART}")
+                else()
+                    set(EXPAT_VERSION_STRING "${EXPAT_VERSION_PART}")
+                endif()
+            endif()
+        endforeach()
+    endforeach()
+endif ()
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(EXPAT
+                                  REQUIRED_VARS EXPAT_LIBRARY EXPAT_INCLUDE_DIR
+                                  VERSION_VAR EXPAT_VERSION_STRING)
+
+# Copy the results to the output variables and target.
+if(EXPAT_FOUND)
+  set(EXPAT_LIBRARIES ${EXPAT_LIBRARY})
+  set(EXPAT_INCLUDE_DIRS ${EXPAT_INCLUDE_DIR})
+
+  if(NOT TARGET EXPAT::EXPAT)
+    include(vtkDetectLibraryType)
+    vtk_detect_library_type(expat_library_type
+      PATH "${EXPAT_LIBRARY}")
+    add_library(EXPAT::EXPAT "${expat_library_type}" IMPORTED)
+    unset(expat_library_type)
+    set_target_properties(EXPAT::EXPAT PROPERTIES
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+      IMPORTED_LOCATION "${EXPAT_LIBRARY}"
+      IMPORTED_IMPLIB "${EXPAT_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${EXPAT_INCLUDE_DIRS}")
+  endif()
+endif()
+
+mark_as_advanced(EXPAT_INCLUDE_DIR EXPAT_LIBRARY)

viennaps.libs/cmake/vtk-9.3/FindEigen3.cmake

@@ -0,0 +1,33 @@
+find_path(Eigen3_INCLUDE_DIR
+  NAMES signature_of_eigen3_matrix_library
+  PATH_SUFFIXES eigen3 eigen
+  DOC "Eigen include directory")
+mark_as_advanced(Eigen3_INCLUDE_DIR)
+
+if (Eigen3_INCLUDE_DIR)
+  file(STRINGS "${Eigen3_INCLUDE_DIR}/Eigen/src/Core/util/Macros.h" _Eigen3_version_lines
+    REGEX "#define[ \t]+EIGEN_(WORLD|MAJOR|MINOR)_VERSION")
+  string(REGEX REPLACE ".*EIGEN_WORLD_VERSION *\([0-9]*\).*" "\\1" _Eigen3_version_world "${_Eigen3_version_lines}")
+  string(REGEX REPLACE ".*EIGEN_MAJOR_VERSION *\([0-9]*\).*" "\\1" _Eigen3_version_major "${_Eigen3_version_lines}")
+  string(REGEX REPLACE ".*EIGEN_MINOR_VERSION *\([0-9]*\).*" "\\1" _Eigen3_version_minor "${_Eigen3_version_lines}")
+  set(Eigen3_VERSION "${_Eigen3_version_world}.${_Eigen3_version_major}.${_Eigen3_version_minor}")
+  unset(_Eigen3_version_world)
+  unset(_Eigen3_version_major)
+  unset(_Eigen3_version_minor)
+  unset(_Eigen3_version_lines)
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Eigen3
+  REQUIRED_VARS Eigen3_INCLUDE_DIR
+  VERSION_VAR Eigen3_VERSION)
+
+if (Eigen3_FOUND)
+  set(Eigen3_INCLUDE_DIRS "${Eigen3_INCLUDE_DIR}")
+
+  if (NOT TARGET Eigen3::Eigen3)
+    add_library(Eigen3::Eigen3 INTERFACE IMPORTED)
+    set_target_properties(Eigen3::Eigen3 PROPERTIES
+      INTERFACE_INCLUDE_DIRECTORIES "${Eigen3_INCLUDE_DIR}")
+  endif ()
+endif ()

viennaps.libs/cmake/vtk-9.3/FindExprTk.cmake

@@ -0,0 +1,58 @@
+# - Try to find ExprTk lib
+#
+# This module supports requiring a minimum version, e.g. you can do
+#   find_package(ExprTk 2.7)
+# to require version 2.7 or newer of ExprTk.
+#
+# Once done this will define
+#
+#  ExprTk_FOUND - system has exprtk with correct version
+#  ExprTk_INCLUDE_DIRS - the exprtk include directory
+#  ExprTk_VERSION - exprtk version
+#
+# And the following imported target:
+#
+#  ExprTk::ExprTk
+
+find_path(ExprTk_INCLUDE_DIR
+  NAMES exprtk.hpp
+  DOC "Path to ExprTk header")
+mark_as_advanced(ExprTk_INCLUDE_DIR)
+
+if (ExprTk_INCLUDE_DIR)
+  file(STRINGS "${ExprTk_INCLUDE_DIR}/exprtk.hpp" _exprtk_version_header REGEX "\"[0-9.]+\"")
+  set(ExprTk_VERSION)
+  foreach (_exprtk_version_line IN LISTS _exprtk_version_header)
+    if ("${ExprTk_VERSION}" STREQUAL "")
+      string(REGEX MATCH "version = \"(2\.7[0-9.]+)\".*$" _exprtk_version_match "${_exprtk_version_line}")
+      set(ExprTk_VERSION "${CMAKE_MATCH_1}")
+    else ()
+      string(REGEX MATCH "\"([0-9.]+)\".*$" _exprtk_version_match "${_exprtk_version_line}")
+      set(ExprTk_VERSION "${ExprTk_VERSION}${CMAKE_MATCH_1}")
+    endif ()
+    if (_exprtk_version_match MATCHES "\;")
+      break()
+    endif ()
+  endforeach ()
+  if (NOT ExprTk_VERSION)
+    # fallback: version in exprtk.hpp has always started with 2.7
+    set(ExprTk_VERSION "2.7")
+  endif ()
+  unset(_exprtk_version_header)
+  unset(_exprtk_version_line)
+  unset(_exprtk_version_match)
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(ExprTk
+  REQUIRED_VARS ExprTk_INCLUDE_DIR
+  VERSION_VAR ExprTk_VERSION)
+
+if (ExprTk_FOUND)
+  set(ExprTk_INCLUDE_DIRS "${ExprTk_INCLUDE_DIR}")
+  if (NOT TARGET ExprTk::ExprTk)
+    add_library(ExprTk::ExprTk INTERFACE IMPORTED)
+    set_target_properties(ExprTk::ExprTk PROPERTIES
+      INTERFACE_INCLUDE_DIRECTORIES "${ExprTk_INCLUDE_DIR}")
+  endif ()
+endif ()

viennaps.libs/cmake/vtk-9.3/FindFFMPEG.cmake

@@ -0,0 +1,195 @@
+#[==[
+Provides the following variables:
+
+  * `FFMPEG_INCLUDE_DIRS`: Include directories necessary to use FFMPEG.
+  * `FFMPEG_LIBRARIES`: Libraries necessary to use FFMPEG. Note that this only
+    includes libraries for the components requested.
+  * `FFMPEG_VERSION`: The version of FFMPEG found.
+
+The following components are supported:
+
+  * `avcodec`
+  * `avdevice`
+  * `avfilter`
+  * `avformat`
+  * `avresample`
+  * `avutil`
+  * `swresample`
+  * `swscale`
+
+For each component, the following are provided:
+
+  * `FFMPEG_<component>_FOUND`: Libraries for the component.
+  * `FFMPEG_<component>_INCLUDE_DIRS`: Include directories for
+    the component.
+  * `FFMPEG_<component>_LIBRARIES`: Libraries for the component.
+  * `FFMPEG::<component>`: A target to use with `target_link_libraries`.
+
+Note that only components requested with `COMPONENTS` or `OPTIONAL_COMPONENTS`
+are guaranteed to set these variables or provide targets.
+#]==]
+
+function (_ffmpeg_find component headername)
+  find_path("FFMPEG_${component}_INCLUDE_DIR"
+    NAMES
+      "lib${component}/${headername}"
+    PATHS
+      "${FFMPEG_ROOT}/include"
+      ~/Library/Frameworks
+      /Library/Frameworks
+      /usr/local/include
+      /usr/include
+      /sw/include # Fink
+      /opt/local/include # DarwinPorts
+      /opt/csw/include # Blastwave
+      /opt/include
+      /usr/freeware/include
+    PATH_SUFFIXES
+      ffmpeg
+    DOC "FFMPEG's ${component} include directory")
+  mark_as_advanced("FFMPEG_${component}_INCLUDE_DIR")
+
+  # On Windows, static FFMPEG is sometimes built as `lib<name>.a`.
+  if (WIN32)
+    list(APPEND CMAKE_FIND_LIBRARY_SUFFIXES ".a" ".lib")
+    list(APPEND CMAKE_FIND_LIBRARY_PREFIXES "" "lib")
+  endif ()
+
+  find_library("FFMPEG_${component}_LIBRARY"
+    NAMES
+      "${component}"
+    PATHS
+      "${FFMPEG_ROOT}/lib"
+      ~/Library/Frameworks
+      /Library/Frameworks
+      /usr/local/lib
+      /usr/local/lib64
+      /usr/lib
+      /usr/lib64
+      /sw/lib
+      /opt/local/lib
+      /opt/csw/lib
+      /opt/lib
+      /usr/freeware/lib64
+      "${FFMPEG_ROOT}/bin"
+    DOC "FFMPEG's ${component} library")
+  mark_as_advanced("FFMPEG_${component}_LIBRARY")
+
+  if (FFMPEG_${component}_LIBRARY AND FFMPEG_${component}_INCLUDE_DIR)
+    set(_deps_found TRUE)
+    set(_deps_link)
+    foreach (_ffmpeg_dep IN LISTS ARGN)
+      if (TARGET "FFMPEG::${_ffmpeg_dep}")
+        list(APPEND _deps_link "FFMPEG::${_ffmpeg_dep}")
+      else ()
+        set(_deps_found FALSE)
+      endif ()
+    endforeach ()
+    if (_deps_found)
+      if (NOT TARGET "FFMPEG::${component}")
+        add_library("FFMPEG::${component}" UNKNOWN IMPORTED)
+        set_target_properties("FFMPEG::${component}" PROPERTIES
+          IMPORTED_LOCATION "${FFMPEG_${component}_LIBRARY}"
+          INTERFACE_INCLUDE_DIRECTORIES "${FFMPEG_${component}_INCLUDE_DIR}"
+          IMPORTED_LINK_INTERFACE_LIBRARIES "${_deps_link}")
+      endif ()
+      set("FFMPEG_${component}_FOUND" 1
+        PARENT_SCOPE)
+
+      set(version_header_path "${FFMPEG_${component}_INCLUDE_DIR}/lib${component}/version.h")
+      if (EXISTS "${version_header_path}")
+        string(TOUPPER "${component}" component_upper)
+        file(STRINGS "${version_header_path}" version
+          REGEX "#define  *LIB${component_upper}_VERSION_(MAJOR|MINOR|MICRO) ")
+        string(REGEX REPLACE ".*_MAJOR *\([0-9]*\).*" "\\1" major "${version}")
+        string(REGEX REPLACE ".*_MINOR *\([0-9]*\).*" "\\1" minor "${version}")
+        string(REGEX REPLACE ".*_MICRO *\([0-9]*\).*" "\\1" micro "${version}")
+        if (NOT major STREQUAL "" AND
+            NOT minor STREQUAL "" AND
+            NOT micro STREQUAL "")
+          set("FFMPEG_${component}_VERSION" "${major}.${minor}.${micro}"
+            PARENT_SCOPE)
+        endif ()
+      endif ()
+    else ()
+      set("FFMPEG_${component}_FOUND" 0
+        PARENT_SCOPE)
+      set(what)
+      if (NOT FFMPEG_${component}_LIBRARY)
+        set(what "library")
+      endif ()
+      if (NOT FFMPEG_${component}_INCLUDE_DIR)
+        if (what)
+          string(APPEND what " or headers")
+        else ()
+          set(what "headers")
+        endif ()
+      endif ()
+      set("FFMPEG_${component}_NOT_FOUND_MESSAGE"
+        "Could not find the ${what} for ${component}."
+        PARENT_SCOPE)
+    endif ()
+  endif ()
+endfunction ()
+
+_ffmpeg_find(avutil     avutil.h)
+_ffmpeg_find(avresample avresample.h
+  avutil)
+_ffmpeg_find(swresample swresample.h
+  avutil)
+_ffmpeg_find(swscale    swscale.h
+  avutil)
+_ffmpeg_find(avcodec    avcodec.h
+  avutil)
+_ffmpeg_find(avformat   avformat.h
+  avcodec avutil)
+_ffmpeg_find(avfilter   avfilter.h
+  avutil)
+_ffmpeg_find(avdevice   avdevice.h
+  avformat avutil)
+
+if (TARGET FFMPEG::avutil)
+  set(_ffmpeg_version_header_path "${FFMPEG_avutil_INCLUDE_DIR}/libavutil/ffversion.h")
+  if (EXISTS "${_ffmpeg_version_header_path}")
+    file(STRINGS "${_ffmpeg_version_header_path}" _ffmpeg_version
+      REGEX "FFMPEG_VERSION")
+    string(REGEX REPLACE ".*\"n?\(.*\)\"" "\\1" FFMPEG_VERSION "${_ffmpeg_version}")
+    unset(_ffmpeg_version)
+  else ()
+    set(FFMPEG_VERSION FFMPEG_VERSION-NOTFOUND)
+  endif ()
+  unset(_ffmpeg_version_header_path)
+endif ()
+
+set(FFMPEG_INCLUDE_DIRS)
+set(FFMPEG_LIBRARIES)
+set(_ffmpeg_required_vars)
+foreach (_ffmpeg_component IN LISTS FFMPEG_FIND_COMPONENTS)
+  if (TARGET "FFMPEG::${_ffmpeg_component}")
+    set(FFMPEG_${_ffmpeg_component}_INCLUDE_DIRS
+      "${FFMPEG_${_ffmpeg_component}_INCLUDE_DIR}")
+    set(FFMPEG_${_ffmpeg_component}_LIBRARIES
+      "${FFMPEG_${_ffmpeg_component}_LIBRARY}")
+    list(APPEND FFMPEG_INCLUDE_DIRS
+      "${FFMPEG_${_ffmpeg_component}_INCLUDE_DIRS}")
+    list(APPEND FFMPEG_LIBRARIES
+      "${FFMPEG_${_ffmpeg_component}_LIBRARIES}")
+    if (FFMEG_FIND_REQUIRED_${_ffmpeg_component})
+      list(APPEND _ffmpeg_required_vars
+        "FFMPEG_${_ffmpeg_required_vars}_INCLUDE_DIRS"
+        "FFMPEG_${_ffmpeg_required_vars}_LIBRARIES")
+    endif ()
+  endif ()
+endforeach ()
+unset(_ffmpeg_component)
+
+if (FFMPEG_INCLUDE_DIRS)
+  list(REMOVE_DUPLICATES FFMPEG_INCLUDE_DIRS)
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(FFMPEG
+  REQUIRED_VARS FFMPEG_INCLUDE_DIRS FFMPEG_LIBRARIES ${_ffmpeg_required_vars}
+  VERSION_VAR FFMPEG_VERSION
+  HANDLE_COMPONENTS)
+unset(_ffmpeg_required_vars)

viennaps.libs/cmake/vtk-9.3/FindFontConfig.cmake

@@ -0,0 +1,30 @@
+# SPDX-FileCopyrightText: Copyright (c) Ken Martin, Will Schroeder, Bill Lorensen
+# SPDX-FileCopyrightText: Copyright 2012 Kitware, Inc.
+# SPDX-License-Identifier: BSD-3-Clause 
+# - Find FontConfig library
+# Find the FontConfig includes and library
+# This module defines
+#  FONTCONFIG_INCLUDE_DIR, where to find fontconfig.h
+#  FONTCONFIG_LIBRARIES, libraries to link against to use the FontConfig API.
+#  FONTCONFIG_FOUND, If false, do not try to use FontConfig.
+find_path(FONTCONFIG_INCLUDE_DIR fontconfig/fontconfig.h)
+
+find_library(FONTCONFIG_LIBRARY NAMES fontconfig)
+
+# handle the QUIETLY and REQUIRED arguments and set FONTCONFIG_FOUND to TRUE if
+# all listed variables are TRUE
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(FontConfig DEFAULT_MSG
+  FONTCONFIG_LIBRARY  FONTCONFIG_INCLUDE_DIR)
+
+if(FONTCONFIG_FOUND)
+  if (NOT TARGET FontConfig::FontConfig)
+    add_library(FontConfig::FontConfig UNKNOWN IMPORTED)
+    set_target_properties(FontConfig::FontConfig PROPERTIES
+      IMPORTED_LOCATION "${FONTCONFIG_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${FONTCONFIG_INCLUDE_DIR}")
+  endif ()
+  set( FONTCONFIG_LIBRARIES ${FONTCONFIG_LIBRARY} )
+endif()
+
+mark_as_advanced(FONTCONFIG_INCLUDE_DIR FONTCONFIG_LIBRARY FONTCONFIG_LIBRARIES)