ViennaPS 3.0.1__cp310-cp310-macosx_11_0_arm64.whl

viennaps.libs/cmake/vtk-9.3/FindLibXml2.cmake

@@ -0,0 +1,116 @@
+# XXX: Copied from CMake, but includes vtkDetectLibraryType and the ICU dependency.
+# See https://gitlab.kitware.com/cmake/cmake/-/issues/18564
+
+#[=======================================================================[.rst:
+FindLibXml2
+-----------
+
+Find the XML processing library (libxml2).
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``LibXml2::LibXml2``, if
+libxml2 has been found.
+
+Result variables
+^^^^^^^^^^^^^^^^
+
+This module will set the following variables in your project:
+
+``LIBXML2_FOUND``
+  true if libxml2 headers and libraries were found
+``LIBXML2_INCLUDE_DIR``
+  the directory containing LibXml2 headers
+``LIBXML2_INCLUDE_DIRS``
+  list of the include directories needed to use LibXml2
+``LIBXML2_LIBRARIES``
+  LibXml2 libraries to be linked
+``LIBXML2_DEFINITIONS``
+  the compiler switches required for using LibXml2
+``LIBXML2_XMLLINT_EXECUTABLE``
+  path to the XML checking tool xmllint coming with LibXml2
+``LIBXML2_VERSION_STRING``
+  the version of LibXml2 found (since CMake 2.8.8)
+
+Cache variables
+^^^^^^^^^^^^^^^
+
+The following cache variables may also be set:
+
+``LIBXML2_INCLUDE_DIR``
+  the directory containing LibXml2 headers
+``LIBXML2_LIBRARY``
+  path to the LibXml2 library
+#]=======================================================================]
+
+# use pkg-config to get the directories and then use these values
+# in the find_path() and find_library() calls
+find_package(PkgConfig QUIET)
+PKG_CHECK_MODULES(PC_LIBXML QUIET libxml-2.0)
+set(LIBXML2_DEFINITIONS ${PC_LIBXML_CFLAGS_OTHER})
+
+find_path(LIBXML2_INCLUDE_DIR NAMES libxml/xpath.h
+   HINTS
+   ${PC_LIBXML_INCLUDEDIR}
+   ${PC_LIBXML_INCLUDE_DIRS}
+   PATH_SUFFIXES libxml2
+   )
+
+# CMake 3.9 and below used 'LIBXML2_LIBRARIES' as the name of
+# the cache entry storing the find_library result.  Use the
+# value if it was set by the project or user.
+if(DEFINED LIBXML2_LIBRARIES AND NOT DEFINED LIBXML2_LIBRARY)
+  set(LIBXML2_LIBRARY ${LIBXML2_LIBRARIES})
+endif()
+
+find_library(LIBXML2_LIBRARY NAMES xml2 libxml2
+   HINTS
+   ${PC_LIBXML_LIBDIR}
+   ${PC_LIBXML_LIBRARY_DIRS}
+   )
+
+find_program(LIBXML2_XMLLINT_EXECUTABLE xmllint)
+# for backwards compat. with KDE 4.0.x:
+set(XMLLINT_EXECUTABLE "${LIBXML2_XMLLINT_EXECUTABLE}")
+
+if(PC_LIBXML_VERSION)
+    set(LIBXML2_VERSION_STRING ${PC_LIBXML_VERSION})
+elseif(LIBXML2_INCLUDE_DIR AND EXISTS "${LIBXML2_INCLUDE_DIR}/libxml/xmlversion.h")
+    file(STRINGS "${LIBXML2_INCLUDE_DIR}/libxml/xmlversion.h" libxml2_version_str
+         REGEX "^#define[\t ]+LIBXML_DOTTED_VERSION[\t ]+\".*\"")
+
+    string(REGEX REPLACE "^#define[\t ]+LIBXML_DOTTED_VERSION[\t ]+\"([^\"]*)\".*" "\\1"
+           LIBXML2_VERSION_STRING "${libxml2_version_str}")
+    unset(libxml2_version_str)
+endif()
+
+set(LIBXML2_INCLUDE_DIRS ${LIBXML2_INCLUDE_DIR} ${PC_LIBXML_INCLUDE_DIRS})
+set(LIBXML2_LIBRARIES ${LIBXML2_LIBRARY})
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LibXml2
+                                  REQUIRED_VARS LIBXML2_LIBRARY LIBXML2_INCLUDE_DIR
+                                  VERSION_VAR LIBXML2_VERSION_STRING)
+
+mark_as_advanced(LIBXML2_INCLUDE_DIR LIBXML2_LIBRARY LIBXML2_XMLLINT_EXECUTABLE)
+
+if(LibXml2_FOUND AND NOT TARGET LibXml2::LibXml2)
+   include(vtkDetectLibraryType)
+   vtk_detect_library_type(libxml2_library_type
+     PATH "${LIBXML2_LIBRARY}")
+   add_library(LibXml2::LibXml2 "${libxml2_library_type}" IMPORTED)
+   unset(libxml2_library_type)
+   set_target_properties(LibXml2::LibXml2
+     PROPERTIES
+      IMPORTED_LOCATION "${LIBXML2_LIBRARY}"
+      IMPORTED_IMPLIB "${LIBXML2_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${LIBXML2_INCLUDE_DIRS}")
+
+   find_package(ICU QUIET COMPONENTS uc)
+   if (ICU_FOUND)
+    set_target_properties(LibXml2::LibXml2
+      PROPERTIES
+        IMPORTED_LINK_INTERFACE_LIBRARIES "ICU::uc")
+   endif ()
+endif()

viennaps.libs/cmake/vtk-9.3/FindMEMKIND.cmake

@@ -0,0 +1,58 @@
+#[=======================================================================[.rst:
+FindMEMKIND
+---------
+
+Find memkind's headers and library.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+This module defines the following :prop_tgt:`IMPORTED` targets:
+
+``MEMKIND::MEMKIND``
+  The memkind library, if found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module will set the following variables in your project:
+
+``MEMKIND_INCLUDE_DIRS``
+  where to find memkind.h, etc.
+``MEMKIND_LIBRARIES``
+  the libraries to link against to use memkind.
+``MEMKIND_FOUND``
+  true if the memkind headers and libraries were found.
+
+#]=======================================================================]
+include(CMakeFindDependencyMacro)
+
+# Look for the header file.
+find_path(MEMKIND_INCLUDE_DIR
+  NAMES memkind.h
+  DOC "memkind include directory")
+mark_as_advanced(MEMKIND_INCLUDE_DIR)
+
+# Look for the library.
+find_library(MEMKIND_LIBRARY
+  NAMES memkind libmemkind
+  DOC "memkind library")
+mark_as_advanced(MEMKIND_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(MEMKIND
+  REQUIRED_VARS MEMKIND_LIBRARY MEMKIND_INCLUDE_DIR)
+
+# Copy the results to the output variables and target.
+if(MEMKIND_FOUND)
+  set(MEMKIND_LIBRARIES "${MEMKIND_LIBRARY}")
+  set(MEMKIND_INCLUDE_DIRS "${MEMKIND_INCLUDE_DIR}")
+
+  if(NOT TARGET MEMKIND::MEMKIND)
+    add_library(MEMKIND::MEMKIND UNKNOWN IMPORTED)
+    set_target_properties(MEMKIND::MEMKIND PROPERTIES
+      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+      IMPORTED_LOCATION "${MEMKIND_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${MEMKIND_INCLUDE_DIRS}")
+  endif()
+endif()

viennaps.libs/cmake/vtk-9.3/FindMySQL.cmake

@@ -0,0 +1,112 @@
+#[==[
+Provides the following variables:
+
+  * `MySQL_INCLUDE_DIRS`: Include directories necessary to use MySQL.
+  * `MySQL_LIBRARIES`: Libraries necessary to use MySQL.
+  * A `MySQL::MySQL` imported target.
+#]==]
+
+# No .pc files are shipped with MySQL on Windows.
+set(_MySQL_use_pkgconfig 0)
+if (NOT WIN32)
+  find_package(PkgConfig)
+  if (PkgConfig_FOUND)
+    set(_MySQL_use_pkgconfig 1)
+  endif ()
+endif ()
+
+if (_MySQL_use_pkgconfig)
+  pkg_check_modules(_libmariadb "libmariadb" QUIET IMPORTED_TARGET)
+  unset(_mysql_target)
+  if (_libmariadb_FOUND)
+    set(_mysql_target "_libmariadb")
+  else ()
+    pkg_check_modules(_mariadb "mariadb" QUIET IMPORTED_TARGET)
+    if (NOT _mariadb_FOUND)
+      pkg_check_modules(_mysql "mysql" QUIET IMPORTED_TARGET)
+      if (_mysql_FOUND)
+        set(_mysql_target "_mysql")
+      endif ()
+    else ()
+      set(_mysql_target "_mariadb")
+      if (_mariadb_VERSION VERSION_LESS 10.4)
+        get_property(_include_dirs
+          TARGET    "PkgConfig::_mariadb"
+          PROPERTY  "INTERFACE_INCLUDE_DIRECTORIES")
+        # Remove "${prefix}/mariadb/.." from the interface since it breaks other
+        # projects.
+        list(FILTER _include_dirs EXCLUDE REGEX "\\.\\.")
+        set_property(TARGET "PkgConfig::_mariadb"
+          PROPERTY
+            "INTERFACE_INCLUDE_DIRECTORIES" "${_include_dirs}")
+        unset(_include_dirs)
+      endif ()
+    endif ()
+  endif ()
+
+  set(MySQL_FOUND 0)
+  if (_mysql_target)
+    set(MySQL_FOUND 1)
+    set(MySQL_INCLUDE_DIRS ${${_mysql_target}_INCLUDE_DIRS})
+    set(MySQL_LIBRARIES ${${_mysql_target}_LINK_LIBRARIES})
+    if (NOT TARGET MySQL::MySQL)
+      add_library(MySQL::MySQL INTERFACE IMPORTED)
+      target_link_libraries(MySQL::MySQL
+        INTERFACE "PkgConfig::${_mysql_target}")
+    endif ()
+  endif ()
+  unset(_mysql_target)
+else ()
+  set(_MySQL_mariadb_versions 10.2 10.3)
+  set(_MySQL_versions 5.0)
+  set(_MySQL_paths)
+  foreach (_MySQL_version IN LISTS _MySQL_mariadb_versions)
+    list(APPEND _MySQL_paths
+      "[HKEY_LOCAL_MACHINE\\SOFTWARE\\MariaDB ${_MySQL_version};INSTALLDIR]"
+      "[HKEY_LOCAL_MACHINE\\SOFTWARE\\MariaDB ${_MySQL_version} (x64);INSTALLDIR]")
+  endforeach ()
+  foreach (_MySQL_version IN LISTS _MySQL_versions)
+    list(APPEND _MySQL_paths
+      "C:/Program Files/MySQL/MySQL Server ${_MySQL_version}/lib/opt"
+      "[HKEY_LOCAL_MACHINE\\SOFTWARE\\MySQL AB\\MySQL Server ${_MySQL_version};Location]"
+      "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Wow6432Node\\MySQL AB\\MySQL Server ${_MySQL_version};Location]")
+  endforeach ()
+  unset(_MySQL_version)
+  unset(_MySQL_versions)
+  unset(_MySQL_mariadb_versions)
+
+  find_path(MySQL_INCLUDE_DIR
+    NAMES mysql.h
+    PATHS
+      "C:/Program Files/MySQL/include"
+      "C:/MySQL/include"
+      ${_MySQL_paths}
+    PATH_SUFFIXES include include/mysql
+    DOC "Location of mysql.h")
+  mark_as_advanced(MySQL_INCLUDE_DIR)
+  find_library(MySQL_LIBRARY
+    NAMES libmariadb mysql libmysql mysqlclient
+    PATHS
+      "C:/Program Files/MySQL/lib"
+      "C:/MySQL/lib/debug"
+      ${_MySQL_paths}
+    PATH_SUFFIXES lib lib/opt
+    DOC "Location of the mysql library")
+  mark_as_advanced(MySQL_LIBRARY)
+
+  include(FindPackageHandleStandardArgs)
+  find_package_handle_standard_args(MySQL
+    REQUIRED_VARS MySQL_INCLUDE_DIR MySQL_LIBRARY)
+
+  if (MySQL_FOUND)
+    set(MySQL_INCLUDE_DIRS "${MySQL_INCLUDE_DIR}")
+    set(MySQL_LIBRARIES "${MySQL_LIBRARY}")
+    if (NOT TARGET MySQL::MySQL)
+      add_library(MySQL::MySQL UNKNOWN IMPORTED)
+      set_target_properties(MySQL::MySQL PROPERTIES
+      IMPORTED_LOCATION "${MySQL_LIBRARY}"
+        INTERFACE_INCLUDE_DIRECTORIES "${MySQL_INCLUDE_DIR}")
+    endif ()
+  endif ()
+endif ()
+unset(_MySQL_use_pkgconfig)

viennaps.libs/cmake/vtk-9.3/FindNetCDF.cmake

@@ -0,0 +1,131 @@
+#[==[
+Provides the following variables:
+
+  * `NetCDF_FOUND`: Whether NetCDF was found or not.
+  * `NetCDF_INCLUDE_DIRS`: Include directories necessary to use NetCDF.
+  * `NetCDF_LIBRARIES`: Libraries necessary to use NetCDF.
+  * `NetCDF_VERSION`: The version of NetCDF found.
+  * `NetCDF::NetCDF`: A target to use with `target_link_libraries`.
+  * `NetCDF_HAS_PARALLEL`: Whether or not NetCDF was found with parallel IO support.
+#]==]
+
+function(FindNetCDF_get_is_parallel_aware include_dir)
+  file(STRINGS "${include_dir}/netcdf_meta.h" _netcdf_lines
+    REGEX "#define[ \t]+NC_HAS_PARALLEL[ \t]")
+  string(REGEX REPLACE ".*NC_HAS_PARALLEL[ \t]*([0-1]+).*" "\\1" _netcdf_has_parallel "${_netcdf_lines}")
+  if (_netcdf_has_parallel)
+    set(NetCDF_HAS_PARALLEL TRUE PARENT_SCOPE)
+  else()
+    set(NetCDF_HAS_PARALLEL FALSE PARENT_SCOPE)
+  endif()
+endfunction()
+
+# Try to find a CMake-built NetCDF.
+find_package(netCDF CONFIG QUIET)
+if (netCDF_FOUND)
+  # Forward the variables in a consistent way.
+  set(NetCDF_FOUND "${netCDF_FOUND}")
+  set(NetCDF_INCLUDE_DIRS "${netCDF_INCLUDE_DIR}")
+  set(NetCDF_LIBRARIES "${netCDF_LIBRARIES}")
+  set(NetCDF_VERSION "${NetCDFVersion}")
+
+  include(FindPackageHandleStandardArgs)
+  find_package_handle_standard_args(NetCDF
+    REQUIRED_VARS NetCDF_INCLUDE_DIRS NetCDF_LIBRARIES
+    VERSION_VAR NetCDF_VERSION)
+
+  if (NOT TARGET NetCDF::NetCDF)
+    add_library(NetCDF::NetCDF INTERFACE IMPORTED)
+    if (TARGET "netCDF::netcdf")
+      # 4.7.3
+      set_target_properties(NetCDF::NetCDF PROPERTIES
+        INTERFACE_LINK_LIBRARIES "netCDF::netcdf")
+    elseif (TARGET "netcdf")
+      set_target_properties(NetCDF::NetCDF PROPERTIES
+        INTERFACE_LINK_LIBRARIES "netcdf")
+    else ()
+      set_target_properties(NetCDF::NetCDF PROPERTIES
+        INTERFACE_LINK_LIBRARIES "${netCDF_LIBRARIES}")
+    endif ()
+  endif ()
+
+  FindNetCDF_get_is_parallel_aware("${NetCDF_INCLUDE_DIRS}")
+  # Skip the rest of the logic in this file.
+  return ()
+endif ()
+
+find_package(PkgConfig QUIET)
+if (PkgConfig_FOUND)
+  pkg_check_modules(_NetCDF QUIET netcdf IMPORTED_TARGET)
+  if (_NetCDF_FOUND)
+    # Forward the variables in a consistent way.
+    set(NetCDF_FOUND "${_NetCDF_FOUND}")
+    set(NetCDF_INCLUDE_DIRS "${_NetCDF_INCLUDE_DIRS}")
+    set(NetCDF_LIBRARIES "${_NetCDF_LIBRARIES}")
+    set(NetCDF_VERSION "${_NetCDF_VERSION}")
+
+    include(FindPackageHandleStandardArgs)
+    find_package_handle_standard_args(NetCDF
+      REQUIRED_VARS NetCDF_LIBRARIES
+      # This is not required because system-default include paths are not
+      # reported by `FindPkgConfig`, so this might be empty. Assume that if we
+      # have a library, the include directories are fine (if any) since
+      # PkgConfig reported that the package was found.
+      # NetCDF_INCLUDE_DIRS
+      VERSION_VAR NetCDF_VERSION)
+
+    if (NOT TARGET NetCDF::NetCDF)
+      add_library(NetCDF::NetCDF INTERFACE IMPORTED)
+      set_target_properties(NetCDF::NetCDF PROPERTIES
+        INTERFACE_LINK_LIBRARIES "PkgConfig::_NetCDF")
+    endif ()
+
+    FindNetCDF_get_is_parallel_aware("${_NetCDF_INCLUDEDIR}")
+    # Skip the rest of the logic in this file.
+    return ()
+  endif ()
+endif ()
+
+find_path(NetCDF_INCLUDE_DIR
+  NAMES netcdf.h
+  DOC "netcdf include directories")
+mark_as_advanced(NetCDF_INCLUDE_DIR)
+
+find_library(NetCDF_LIBRARY
+  NAMES netcdf
+  DOC "netcdf library")
+mark_as_advanced(NetCDF_LIBRARY)
+
+if (NetCDF_INCLUDE_DIR)
+  file(STRINGS "${NetCDF_INCLUDE_DIR}/netcdf_meta.h" _netcdf_version_lines
+    REGEX "#define[ \t]+NC_VERSION_(MAJOR|MINOR|PATCH|NOTE)")
+  string(REGEX REPLACE ".*NC_VERSION_MAJOR *\([0-9]*\).*" "\\1" _netcdf_version_major "${_netcdf_version_lines}")
+  string(REGEX REPLACE ".*NC_VERSION_MINOR *\([0-9]*\).*" "\\1" _netcdf_version_minor "${_netcdf_version_lines}")
+  string(REGEX REPLACE ".*NC_VERSION_PATCH *\([0-9]*\).*" "\\1" _netcdf_version_patch "${_netcdf_version_lines}")
+  string(REGEX REPLACE ".*NC_VERSION_NOTE *\"\([^\"]*\)\".*" "\\1" _netcdf_version_note "${_netcdf_version_lines}")
+  set(NetCDF_VERSION "${_netcdf_version_major}.${_netcdf_version_minor}.${_netcdf_version_patch}${_netcdf_version_note}")
+  unset(_netcdf_version_major)
+  unset(_netcdf_version_minor)
+  unset(_netcdf_version_patch)
+  unset(_netcdf_version_note)
+  unset(_netcdf_version_lines)
+
+  FindNetCDF_get_is_parallel_aware("${NetCDF_INCLUDE_DIR}")
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(NetCDF
+  REQUIRED_VARS NetCDF_LIBRARY NetCDF_INCLUDE_DIR
+  VERSION_VAR NetCDF_VERSION)
+
+if (NetCDF_FOUND)
+  set(NetCDF_INCLUDE_DIRS "${NetCDF_INCLUDE_DIR}")
+  set(NetCDF_LIBRARIES "${NetCDF_LIBRARY}")
+
+  if (NOT TARGET NetCDF::NetCDF)
+    add_library(NetCDF::NetCDF UNKNOWN IMPORTED)
+    set_target_properties(NetCDF::NetCDF PROPERTIES
+      IMPORTED_LOCATION "${NetCDF_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${NetCDF_INCLUDE_DIR}")
+  endif ()
+endif ()

viennaps.libs/cmake/vtk-9.3/FindODBC.cmake

@@ -0,0 +1,79 @@
+#[==[
+Provides the following variables:
+
+  * `ODBC_INCLUDE_DIRS`: Include directories necessary to use ODBC.
+  * `ODBC_LIBRARIES`: Libraries necessary to use ODBC.
+  * A `ODBC::ODBC` imported target.
+#]==]
+
+# No .pc files are shipped with ODBC on Windows.
+set(_ODBC_use_pkgconfig 0)
+if (NOT MSVC)
+  find_package(PkgConfig QUIET)
+  if (PkgConfig_FOUND)
+    set(_ODBC_use_pkgconfig 1)
+  endif ()
+endif ()
+
+if (_ODBC_use_pkgconfig)
+  pkg_check_modules(_iodbc "libiodbc" QUIET IMPORTED_TARGET)
+  unset(_odbc_target)
+  if (NOT _iodbc_FOUND)
+    pkg_check_modules(_unixodbc "odbc" QUIET IMPORTED_TARGET)
+    if (_unixodbc_FOUND)
+      set(_odbc_target "_unixodbc")
+    endif ()
+  else ()
+    set(_odbc_target "_iodbc")
+  endif ()
+
+  set(ODBC_FOUND 0)
+  if (_odbc_target)
+    set(ODBC_FOUND 1)
+    set(ODBC_INCLUDE_DIRS ${${_odbc_target}_INCLUDE_DIRS})
+    set(ODBC_LIBRARIES ${${_odbc_target}_LINK_LIBRARIES})
+    if (NOT TARGET ODBC::ODBC)
+      add_library(ODBC::ODBC INTERFACE IMPORTED)
+      target_link_libraries(ODBC::ODBC
+        INTERFACE "PkgConfig::${_odbc_target}")
+      if (MINGW AND _odbc_target STREQUAL "_unixodbc")
+        set_target_properties(ODBC::ODBC PROPERTIES
+          INTERFACE_COMPILE_DEFINITIONS SQL_WCHART_CONVERT)
+      endif ()
+    endif ()
+  endif ()
+  unset(_odbc_target)
+else ()
+  find_path(ODBC_INCLUDE_DIR
+    NAMES sql.h
+    PATHS
+      "C:/Program Files/ODBC"
+      "C:/ODBC"
+    PATH_SUFFIXES include include/odbc libiodbc
+    DOC "Location of sql.h")
+  mark_as_advanced(ODBC_INCLUDE_DIR)
+  find_library(ODBC_LIBRARY
+    NAMES odbc iodbc unixodbc odbc32
+    PATHS
+      "C:/Program Files/ODBC"
+      "C:/ODBC"
+    PATH_SUFFIXES lib lib/debug
+    DOC "Location of the ODBC library")
+  mark_as_advanced(ODBC_LIBRARY)
+
+  include(FindPackageHandleStandardArgs)
+  find_package_handle_standard_args(ODBC
+    REQUIRED_VARS ODBC_INCLUDE_DIR ODBC_LIBRARY)
+
+  if (ODBC_FOUND)
+    set(ODBC_INCLUDE_DIRS "${ODBC_INCLUDE_DIR}")
+    set(ODBC_LIBRARIES "${ODBC_LIBRARY}")
+    if (NOT TARGET ODBC::ODBC)
+      add_library(ODBC::ODBC UNKNOWN IMPORTED)
+      set_target_properties(ODBC::ODBC PROPERTIES
+        IMPORTED_LOCATION "${ODBC_LIBRARY}"
+        INTERFACE_INCLUDE_DIRECTORIES "${ODBC_INCLUDE_DIR}")
+    endif ()
+  endif ()
+endif ()
+unset(_ODBC_use_pkgconfig)

viennaps.libs/cmake/vtk-9.3/FindOGG.cmake

@@ -0,0 +1,26 @@
+find_path(OGG_INCLUDE_DIR
+  NAMES
+    ogg/ogg.h
+  DOC "ogg include directory")
+mark_as_advanced(OGG_INCLUDE_DIR)
+
+find_library(OGG_LIBRARY
+  NAMES
+    ogg
+  DOC "ogg library")
+mark_as_advanced(OGG_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(OGG REQUIRED_VARS OGG_LIBRARY OGG_INCLUDE_DIR)
+
+if (OGG_FOUND)
+  set(OGG_LIBRARIES "${OGG_LIBRARY}")
+  set(OGG_INCLUDE_DIRS "${OGG_INCLUDE_DIR}")
+
+  if (NOT TARGET OGG::OGG)
+    add_library(OGG::OGG UNKNOWN IMPORTED)
+    set_target_properties(OGG::OGG PROPERTIES
+      IMPORTED_LOCATION "${OGG_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${OGG_INCLUDE_DIR}")
+  endif ()
+endif ()

viennaps.libs/cmake/vtk-9.3/FindOSMesa.cmake

@@ -0,0 +1,56 @@
+# Try to find Mesa off-screen library and include dir.
+# Once done this will define
+#
+# OSMesa_FOUND        - true if OSMesa has been found
+# OSMesa_INCLUDE_DIRS - where the GL/osmesa.h can be found
+# OSMesa_LIBRARIES    - Link this to use OSMesa
+# OSMesa_VERSION      - Version of OSMesa found
+# OSMesa::OSMesa      - Imported target
+
+find_path(OSMESA_INCLUDE_DIR
+  NAMES GL/osmesa.h
+  PATHS "${OSMESA_ROOT}/include"
+        "$ENV{OSMESA_ROOT}/include"
+        /usr/openwin/share/include
+        /opt/graphics/OpenGL/include
+  DOC   "OSMesa include directory")
+mark_as_advanced(OSMESA_INCLUDE_DIR)
+
+find_library(OSMESA_LIBRARY
+  NAMES OSMesa OSMesa16 OSMesa32
+  PATHS "${OSMESA_ROOT}/lib"
+        "$ENV{OSMESA_ROOT}/lib"
+        /opt/graphics/OpenGL/lib
+        /usr/openwin/lib
+  DOC   "OSMesa library")
+mark_as_advanced(OSMESA_LIBRARY)
+
+if (OSMESA_INCLUDE_DIR AND EXISTS "${OSMESA_INCLUDE_DIR}/GL/osmesa.h")
+  file(STRINGS "${OSMESA_INCLUDE_DIR}/GL/osmesa.h" _OSMesa_version_lines
+    REGEX "OSMESA_[A-Z]+_VERSION")
+  string(REGEX REPLACE ".*# *define +OSMESA_MAJOR_VERSION +([0-9]+).*" "\\1" _OSMesa_version_major "${_OSMesa_version_lines}")
+  string(REGEX REPLACE ".*# *define +OSMESA_MINOR_VERSION +([0-9]+).*" "\\1" _OSMesa_version_minor "${_OSMesa_version_lines}")
+  string(REGEX REPLACE ".*# *define +OSMESA_PATCH_VERSION +([0-9]+).*" "\\1" _OSMesa_version_patch "${_OSMesa_version_lines}")
+  set(OSMesa_VERSION "${_OSMesa_version_major}.${_OSMesa_version_minor}.${_OSMesa_version_patch}")
+  unset(_OSMesa_version_major)
+  unset(_OSMesa_version_minor)
+  unset(_OSMesa_version_patch)
+  unset(_OSMesa_version_lines)
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(OSMesa
+  REQUIRED_VARS OSMESA_INCLUDE_DIR OSMESA_LIBRARY
+  VERSION_VAR OSMesa_VERSION)
+
+if (OSMesa_FOUND)
+  set(OSMesa_INCLUDE_DIRS "${OSMESA_INCLUDE_DIR}")
+  set(OSMesa_LIBRARIES "${OSMESA_LIBRARY}")
+
+  if (NOT TARGET OSMesa::OSMesa)
+    add_library(OSMesa::OSMesa UNKNOWN IMPORTED)
+    set_target_properties(OSMesa::OSMesa PROPERTIES
+      IMPORTED_LOCATION "${OSMESA_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${OSMESA_INCLUDE_DIR}")
+  endif ()
+endif ()

viennaps.libs/cmake/vtk-9.3/FindOpenSlide.cmake

@@ -0,0 +1,40 @@
+# A CMake find module for the OpenSlide microscopy file reader library.
+#
+# http://openslide.org
+#
+# Once done, this module will define
+#   OPENSLIDE_FOUND         - system has OpenSlide
+#   OPENSLIDE_INCLUDE_DIRS  - the OpenSlide include directory
+#   OPENSLIDE_LIBRARIES     - link to these to use OpenSlide
+#   OpenSlide::OpenSlide    - imported target
+
+# Look for the header.
+find_path(OPENSLIDE_INCLUDE_DIR
+  NAMES
+    openslide/openslide.h
+  PATHS
+    /usr/local/include
+    /usr/include
+  DOC "OpenSlide include directory")
+mark_as_advanced(OPENSLIDE_INCLUDE_DIR)
+
+# Look for the library.
+find_library(OPENSLIDE_LIBRARY
+  NAMES openslide
+  DOC "OpenSlide library")
+mark_as_advanced(OPENSLIDE_LIBRARY)
+
+find_package(PackageHandleStandardArgs)
+find_package_handle_standard_args(OpenSlide
+  REQUIRED_VARS OPENSLIDE_LIBRARY OPENSLIDE_INCLUDE_DIR)
+
+if (OPENSLIDE_FOUND)
+  set(OPENSLIDE_LIBRARIES "${OPENSLIDE_LIBRARY}")
+  set(OPENSLIDE_INCLUDE_DIRS "${OPENSLIDE_INCLUDE_DIR}")
+  if (NOT TARGET OpenSlide::OpenSlide)
+    add_library(OpenSlide::OpenSlide UNKNOWN IMPORTED)
+    set_target_properties(OpenSlide::OpenSlide PROPERTIES
+      IMPORTED_LOCATION "${OPENSLIDE_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${OPENSLIDE_INCLUDE_DIR}")
+  endif ()
+endif ()

viennaps.libs/cmake/vtk-9.3/FindOpenVR.cmake

@@ -0,0 +1,61 @@
+# Note that OpenVR lacks a useful install tree. This should work if
+# `OpenVR_ROOT` is set to the source directory of OpenVR.
+
+# TODO: fails for universal builds
+if (CMAKE_SIZEOF_VOID_P EQUAL 8)
+  set(_openvr_bitness 64)
+else ()
+  set(_openvr_bitness 32)
+endif ()
+
+set(_openvr_platform_base)
+if (CMAKE_SYSTEM_NAME MATCHES "Darwin")
+  set(_openvr_platform_base osx)
+  # SteamVR only supports 32-bit on OS X
+  set(OpenVR_PLATFORM osx32)
+else ()
+  if (CMAKE_SYSTEM_NAME MATCHES "Linux")
+    set(_openvr_platform_base linux)
+  elseif (WIN32)
+    set(_openvr_platform_base win)
+  endif ()
+  set(OpenVR_PLATFORM ${_openvr_platform_base}${_openvr_bitness})
+endif ()
+
+find_path(OpenVR_INCLUDE_DIR
+  NAMES
+    openvr.h
+  PATH_SUFFIXES
+    openvr
+    headers
+    public/headers
+    steam
+    public/steam
+  DOC "OpenVR include directory")
+mark_as_advanced(OpenVR_INCLUDE_DIR)
+
+find_library(OpenVR_LIBRARY
+  NAMES openvr_api64 openvr_api
+  PATH_SUFFIXES
+    "${OpenVR_PLATFORM}"
+    "bin/${OpenVR_PLATFORM}"
+  DOC "OpenVR API library")
+mark_as_advanced(OpenVR_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(OpenVR
+  REQUIRED_VARS OpenVR_LIBRARY OpenVR_INCLUDE_DIR)
+
+if (OpenVR_FOUND)
+  set(OpenVR_INCLUDE_DIRS "${OpenVR_INCLUDE_DIR}")
+  set(OpenVR_LIBRARIES "${OpenVR_LIBRARY}")
+  if (NOT TARGET OpenVR::OpenVR)
+    add_library(OpenVR::OpenVR UNKNOWN IMPORTED)
+    set_target_properties(OpenVR::OpenVR PROPERTIES
+      IMPORTED_LOCATION "${OpenVR_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${OpenVR_INCLUDE_DIR}")
+  endif ()
+endif ()
+
+unset(_openvr_bitness)
+unset(_openvr_platform_base)