QuickGraphLib 0.1.0a2__cp37-abi3-win_amd64.whl

QuickGraphLib/AntialiasingContainer.qml

@@ -0,0 +1,18 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+
+/*!
+    \qmltype AntialiasingContainer
+    \inqmlmodule QuickGraphLib
+    \inherits QtQuick::Item
+    \brief Enables antialiasing for it's contents.
+*/
+
+Item {
+    implicitHeight: 100
+    implicitWidth: 100
+    layer.enabled: true // Improves rendering of fractional DPIs
+    layer.samples: 2
+}

QuickGraphLib/Axis.qml

@@ -0,0 +1,183 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+pragma ComponentBehavior: Bound
+import QtQuick
+import QtQuick.Shapes as QQS
+import QuickGraphLib as QuickGraphLib
+
+/*!
+    \qmltype Axis
+    \inqmlmodule QuickGraphLib
+    \inherits QtQuick::Item
+    \brief Displays an Axis.
+*/
+
+Item {
+    id: root
+
+    enum Direction {
+        Left,
+        Right,
+        Top,
+        Bottom
+    }
+
+    /*!
+        TODO
+        \sa {GraphArea::dataTransform}
+    */
+    property alias dataTransform: helper.dataTransform
+    /*! TODO */
+    property int decimalPoints: 2
+    /*! TODO
+
+
+        \value Axis.Direction.Left Axis to the left of the GraphArea
+        \value Axis.Direction.Right Axis to the right of the GraphArea
+        \value Axis.Direction.Top Axis above of the GraphArea
+        \value Axis.Direction.Bottom Axis below of the GraphArea
+     */
+    property alias direction: helper.direction
+    /*! TODO */
+    property alias label: labelText.text
+    /*! TODO */
+    property alias labelColor: labelText.color
+    /*! TODO */
+    property alias labelFont: labelText.font
+    /*! TODO */
+    property bool showTickLabels: true
+    /*! TODO */
+    property double spacing: 4
+    /*! TODO */
+    property alias strokeColor: myPath.strokeColor
+    /*! TODO */
+    property alias strokeWidth: myPath.strokeWidth
+    /*! TODO */
+    property Component tickDelegate: TickLabel {
+        color: root.labelColor
+        decimalPoints: root.decimalPoints
+        direction: root.direction
+        font: root.labelFont
+    }
+    /*! TODO */
+    property color tickLabelColor: labelColor
+    /*! TODO */
+    property font tickLabelFont: labelFont
+    /*! TODO */
+    property alias tickLength: helper.tickLength
+    /*! TODO */
+    property alias ticks: helper.ticks
+
+    implicitHeight: {
+        switch (root.direction) {
+        case Axis.Direction.Left:
+        case Axis.Direction.Right:
+            return 100;
+        case Axis.Direction.Top:
+        case Axis.Direction.Bottom:
+            let height = 0;
+            if (ticks.length > 0) {
+                height += root.tickLength + Math.max(0, ...[...Array(tickLabels.count).keys()].map(i => tickLabels.itemAt(i)?.height));
+            }
+            if (label !== "") {
+                height += labelText.height + root.spacing;
+            }
+            return height;
+        }
+    }
+    implicitWidth: {
+        switch (root.direction) {
+        case Axis.Direction.Left:
+        case Axis.Direction.Right:
+            let width = 0;
+            if (ticks.length > 0) {
+                width += root.tickLength + Math.max(0, ...[...Array(tickLabels.count).keys()].map(i => tickLabels.itemAt(i)?.width));
+            }
+            if (label !== "") {
+                width += labelText.height + root.spacing;
+            }
+            return width;
+        case Axis.Direction.Top:
+        case Axis.Direction.Bottom:
+            return 100;
+        }
+    }
+    z: 1
+
+    QuickGraphLib.AxisHelper {
+        id: helper
+
+        height: root.height
+        tickLength: 10
+        width: root.width
+    }
+    QQS.Shape {
+        id: shape
+
+        anchors.fill: parent
+
+        QQS.ShapePath {
+            id: myPath
+
+            strokeColor: "black"
+            strokeWidth: 1
+
+            PathPolyline {
+                path: helper.path
+            }
+        }
+    }
+    Repeater {
+        id: tickLabels
+
+        delegate: root.tickDelegate
+        model: root.showTickLabels ? helper.tickModel : null
+    }
+    Text {
+        id: labelText
+
+        x: {
+            switch (root.direction) {
+            case Axis.Direction.Left:
+                return height / 2;
+            case Axis.Direction.Right:
+                return root.width - height / 2;
+            case Axis.Direction.Top:
+            case Axis.Direction.Bottom:
+                return root.width / 2;
+            }
+        }
+        y: {
+            switch (root.direction) {
+            case Axis.Direction.Left:
+            case Axis.Direction.Right:
+                return root.height / 2;
+            case Axis.Direction.Top:
+                return height / 2;
+            case Axis.Direction.Bottom:
+                return root.height - height / 2;
+            }
+        }
+
+        transform: [
+            Translate {
+                x: -labelText.width / 2
+                y: -labelText.height / 2
+            },
+            Rotation {
+                angle: {
+                    switch (root.direction) {
+                    case Axis.Direction.Left:
+                        return -90;
+                    case Axis.Direction.Right:
+                        return 90;
+                    case Axis.Direction.Top:
+                    case Axis.Direction.Bottom:
+                        return 0;
+                    }
+                }
+            }
+        ]
+    }
+}

QuickGraphLib/GraphArea.qml

@@ -0,0 +1,57 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+
+/*!
+    \qmltype Histogram
+    \inqmlmodule QuickGraphLib
+    \inherits QtQuick::Shapes::Shape
+    \brief An area that graphs can be added to.
+*/
+
+QQS.Shape {
+    id: root
+
+    /*!
+        Transform from data coordinates to pixel coordinates inside the GraphArea with the viewTransform applied
+    */
+    readonly property matrix4x4 dataTransform: viewTransform.times(rawDataTransform)
+    /*!
+        The view rect the view is actually showing based on viewTransform
+    */
+    readonly property rect effectiveViewRect: {
+        let mat = rawDataTransform.inverted().times(viewTransform.inverted().times(rawDataTransform));
+        // Map corners instead of the whole rect to preserve the invertedness of each axis
+        let blCorner = mat.map(Qt.point(viewRect.x, viewRect.y));
+        let trCorner = mat.map(Qt.point(viewRect.right, viewRect.bottom));
+        return Qt.rect(blCorner.x, blCorner.y, trCorner.x - blCorner.x, trCorner.y - blCorner.y);
+    }
+    /*!
+        Transform from data coordinates to pixel coordinates inside the GraphArea
+    */
+    readonly property matrix4x4 rawDataTransform: {
+        let mat = Qt.matrix4x4();
+        // Flip coordinate system so that Y points upwards
+        mat.translate(Qt.vector3d(0, root.height, 0));
+        mat.scale(root.width / viewRect.width, -root.height / viewRect.height, 1);
+        mat.translate(Qt.vector3d(-viewRect.x, -viewRect.y, 0));
+        return mat;
+    }
+    /*! TODO */
+    required property rect viewRect
+    /*! TODO */
+    property matrix4x4 viewTransform
+
+    function baseTransformFromRect(r: rect): matrix4x4 {
+        let mat = Qt.matrix4x4();
+        mat.scale(viewRect.width / r.width, viewRect.height / r.height, 1);
+        mat.translate(Qt.vector3d((viewRect.x - r.x) / viewRect.width, (r.y + r.height - viewRect.y - viewRect.height) / viewRect.height, 0));
+        return mat;
+    }
+
+    clip: true
+    implicitHeight: 100
+    implicitWidth: 100
+}

QuickGraphLib/GraphItems/AxHLine.qml

@@ -0,0 +1,34 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+
+/*!
+    \qmltype AxHLine
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Shapes::ShapePath
+    \brief Displays a horizontal line.
+*/
+
+QQS.ShapePath {
+    id: root
+
+    readonly property point bottomRightPoint: dataTransform.map(Qt.point(viewRect.right, position))
+
+    /*! TODO */
+    required property matrix4x4 dataTransform
+    /*! TODO */
+    required property double position
+    readonly property point topLeftPoint: dataTransform.map(Qt.point(viewRect.left, position))
+    /*! TODO */
+    required property rect viewRect
+
+    startX: topLeftPoint.x
+    startY: topLeftPoint.y
+
+    PathLine {
+        x: root.bottomRightPoint.x
+        y: root.topLeftPoint.y
+    }
+}

QuickGraphLib/GraphItems/AxHSpan.qml

@@ -0,0 +1,46 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+
+/*!
+    \qmltype AxHSpan
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Shapes::ShapePath
+    \brief Displays a horizontal span.
+*/
+
+QQS.ShapePath {
+    id: root
+
+    readonly property point bottomRightPoint: dataTransform.map(Qt.point(viewRect.right, yMin))
+
+    /*! TODO */
+    required property matrix4x4 dataTransform
+    readonly property point topLeftPoint: dataTransform.map(Qt.point(viewRect.left, yMax))
+    /*! TODO */
+    required property rect viewRect
+    /*! TODO */
+    required property double yMax
+    /*! TODO */
+    required property double yMin
+
+    startX: topLeftPoint.x
+    startY: topLeftPoint.y
+    strokeColor: "transparent"
+
+    PathLine {
+        x: root.bottomRightPoint.x + root.strokeWidth
+        y: root.topLeftPoint.y
+    }
+    // Would be much nicer to use PathMove, but then the whole rect is not filled
+    PathLine {
+        x: root.bottomRightPoint.x + root.strokeWidth
+        y: root.bottomRightPoint.y
+    }
+    PathLine {
+        x: root.topLeftPoint.x
+        y: root.bottomRightPoint.y
+    }
+}

QuickGraphLib/GraphItems/AxVLine.qml

@@ -0,0 +1,34 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+
+/*!
+    \qmltype AxVLine
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Rectangle
+    \brief Displays an vertical line.
+*/
+
+QQS.ShapePath {
+    id: root
+
+    readonly property point bottomRightPoint: dataTransform.map(Qt.point(position, viewRect.top))
+
+    /*! TODO */
+    required property matrix4x4 dataTransform
+    /*! TODO */
+    required property double position
+    readonly property point topLeftPoint: dataTransform.map(Qt.point(position, viewRect.bottom))
+    /*! TODO */
+    required property rect viewRect
+
+    startX: topLeftPoint.x
+    startY: topLeftPoint.y
+
+    PathLine {
+        x: root.topLeftPoint.x
+        y: root.bottomRightPoint.y + root.strokeWidth
+    }
+}

QuickGraphLib/GraphItems/AxVSpan.qml

@@ -0,0 +1,46 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+
+/*!
+    \qmltype AxVSpan
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Shapes::ShapePath
+    \brief Displays an vertical span.
+*/
+
+QQS.ShapePath {
+    id: root
+
+    readonly property point bottomRightPoint: dataTransform.map(Qt.point(xMax, viewRect.top))
+
+    /*! TODO */
+    required property matrix4x4 dataTransform
+    readonly property point topLeftPoint: dataTransform.map(Qt.point(xMin, viewRect.bottom))
+    /*! TODO */
+    required property rect viewRect
+    /*! TODO */
+    required property double xMax
+    /*! TODO */
+    required property double xMin
+
+    startX: topLeftPoint.x
+    startY: topLeftPoint.y
+    strokeColor: "transparent"
+
+    PathLine {
+        x: root.topLeftPoint.x
+        y: root.bottomRightPoint.y + root.strokeWidth
+    }
+    // Would be much nicer to use PathMove, but then the whole rect is not filled
+    PathLine {
+        x: root.bottomRightPoint.x
+        y: root.bottomRightPoint.y + root.strokeWidth
+    }
+    PathLine {
+        x: root.bottomRightPoint.x
+        y: root.topLeftPoint.y
+    }
+}

QuickGraphLib/GraphItems/BasicLegend.qml

@@ -0,0 +1,31 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+
+/*!
+    \qmltype BasicLegend
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Rectangle
+    \brief Displays a simple legend.
+
+    \note This graph item does not inherit from ShapePath, unlike other graph items.
+*/
+
+Rectangle {
+    /*! TODO */
+    default property alias contentChildren: legend.children
+    /*! TODO */
+    property alias verticalSpacing: legend.spacing
+
+    border.color: "black"
+    color: "#aaffffff"
+    height: legend.height + 10
+    width: legend.width + 10
+
+    Column {
+        id: legend
+
+        anchors.centerIn: parent
+    }
+}

QuickGraphLib/GraphItems/BasicLegendItem.qml

@@ -0,0 +1,57 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+
+/*!
+    \qmltype BasicLegendItem
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Row
+    \brief An single entry in a simple legend.
+*/
+
+Row {
+    id: root
+
+    /*! TODO */
+    property color fillColor: "transparent"
+    /*! TODO */
+    property Gradient fillGradient: null
+    /*! TODO */
+    property color strokeColor: "black"
+    /*! TODO */
+    property real strokeWidth: 1
+    /*! TODO */
+    property alias text: label.text
+    /*! TODO */
+    property alias textColor: label.color
+    /*! TODO */
+    property alias textFont: label.font
+
+    spacing: 2
+
+    Item {
+        id: clipper
+
+        anchors.verticalCenter: parent.verticalCenter
+        clip: true
+        height: root.height - 2
+        width: root.height - 2
+
+        Rectangle {
+            border.color: root.strokeColor
+            border.width: root.strokeWidth
+            color: root.fillColor
+            gradient: root.fillGradient
+            height: clipper.height / 2 + root.strokeWidth * 2
+            width: clipper.width + root.strokeWidth * 4
+            x: -root.strokeWidth * 2
+            y: clipper.height / 2
+        }
+    }
+    Text {
+        id: label
+
+        anchors.verticalCenter: parent.verticalCenter
+    }
+}

QuickGraphLib/GraphItems/Contour.qml

@@ -0,0 +1,34 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+import QuickGraphLib as QuickGraphLib
+
+/*!
+    \qmltype Contours
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Shapes::ShapePath
+    \brief Draw a contour line or fill.
+*/
+
+QQS.ShapePath {
+    id: root
+
+    /*!
+        TODO
+    */
+    required property matrix4x4 dataTransform
+    /*!
+        TODO
+    */
+    required property var paths
+
+    capStyle: QQS.ShapePath.RoundCap
+    fillColor: "transparent"
+    joinStyle: QQS.ShapePath.RoundJoin
+
+    PathMultiline {
+        paths: root.paths.map(ps => QuickGraphLib.Helpers.mapPoints(ps, root.dataTransform))
+    }
+}

QuickGraphLib/GraphItems/GraphItemDragHandler.qml

@@ -0,0 +1,39 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+
+/*!
+    \qmltype GraphItemDragHandler
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::MouseArea
+    \brief Assists converting mouse drags into data positions.
+*/
+
+MouseArea {
+    id: root
+
+    property rect _startDragPos
+
+    /*! TODO */
+    required property matrix4x4 dataTransform
+    /*! TODO */
+    property bool dragging
+
+    signal moved(rect position)
+
+    hoverEnabled: true
+
+    onPositionChanged: event => {
+        if (dragging) {
+            moved(dataTransform.inverted().mapRect(Qt.rect(root.x + event.x - _startDragPos.x, parent.y + root.y - _startDragPos.y, _startDragPos.width, _startDragPos.height)));
+        }
+    }
+    onPressed: event => {
+        _startDragPos = Qt.rect(mouseX, mouseY, width, height);
+        dragging = true;
+    }
+    onReleased: event => {
+        dragging = false;
+    }
+}

QuickGraphLib/GraphItems/Grid.qml

@@ -0,0 +1,39 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+import QuickGraphLib.GraphItems as QGLGraphItems
+
+/*!
+    \qmltype Grid
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Shapes::ShapePath
+    \brief Displays a grid in the background of a graph.
+*/
+
+QQS.ShapePath {
+    id: root
+
+    property QGLGraphItems.GridHelper _helper: QGLGraphItems.GridHelper {
+        id: helper
+
+    }
+
+    /*! TODO */
+    property alias dataTransform: helper.dataTransform
+    /*! TODO */
+    property alias viewRect: helper.viewRect
+    /*! TODO */
+    property alias xTicks: helper.xTicks
+    /*! TODO */
+    property alias yTicks: helper.yTicks
+
+    capStyle: QQS.ShapePath.RoundCap
+    fillColor: "transparent"
+    joinStyle: QQS.ShapePath.RoundJoin
+
+    PathMultiline {
+        paths: helper.paths
+    }
+}

QuickGraphLib/GraphItems/Histogram.qml

@@ -0,0 +1,39 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+import QtQuick.Shapes as QQS
+import QuickGraphLib.GraphItems as QGLGraphItems
+
+/*!
+    \qmltype Histogram
+    \inqmlmodule QuickGraphLib.GraphItems
+    \inherits QtQuick::Shapes::ShapePath
+    \brief Displays a histogram.
+*/
+
+QQS.ShapePath {
+    id: root
+
+    property QGLGraphItems.HistogramHelper _helper: QGLGraphItems.HistogramHelper {
+        id: helper
+
+        vertical: false
+    }
+
+    /*! TODO */
+    property alias bins: helper.bins
+    /*! TODO */
+    property alias dataTransform: helper.dataTransform
+    /*! TODO */
+    property alias heights: helper.heights
+    /*! TODO */
+    property alias vertical: helper.vertical
+
+    capStyle: QQS.ShapePath.RoundCap
+    joinStyle: QQS.ShapePath.RoundJoin
+
+    PathPolyline {
+        path: root._helper.path
+    }
+}