QuickGraphLib 0.1.0a20__cp310-abi3-win_amd64.whl

QuickGraphLib/AntialiasingContainer.qml

@@ -0,0 +1,37 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+import QtQuick
+
+@Deprecated {
+    reason: "Due to the new Qt 6.7 Curve renderer, this is no longer needed for antialiasing"
+}
+
+/*!
+    \qmltype AntialiasingContainer
+    \inqmlmodule QuickGraphLib
+    \inherits Item
+    \brief Enables antialiasing for it's contents.
+
+    This item turns on \l {Multisample Antialiasing}. This helps with rendering in some cases.
+
+    \deprecated [0.1.0a10] Due to the new Qt 6.7 Curve renderer, this is no longer needed for antialiasing.
+        Replace with \l Item or remove completely
+*/
+
+Item {
+    id: root
+
+    /*!
+        Whether MSAA antialiasing is enabled. This can help with rendering when the target display has a
+        fractional scaling factor. It can also make rendering worse, especially with text.
+
+        \default false
+    */
+    property alias antialiasingEnabled: root.layer.enabled
+
+    implicitHeight: 100
+    implicitWidth: 100
+    layer.enabled: false
+    layer.samples: 2
+}

QuickGraphLib/Axis.qml

@@ -0,0 +1,264 @@
+// SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+// SPDX-License-Identifier: MIT
+
+pragma ComponentBehavior: Bound
+import QtQuick
+import QtQuick.Shapes as QQS
+import QuickGraphLib as QuickGraphLib
+
+/*!
+    \qmltype Axis
+    \inqmlmodule QuickGraphLib
+    \inherits Item
+    \brief Displays an Axis.
+
+    \sa {Basic sin graph (without prefabs)}, {Graph with all four axes}
+
+    \section2 Antialiasing
+
+    By default, the axis sets \l {preferredRendererType} to \c {Shape.CurveRenderer}.
+    This turns on high-quality antialiasing, which results in better looking axes on HiDPI systems.
+    However, if you know your application will only be viewed on LoDPI systems, the axes will look
+    slightly better without antialiasing. In addition, antialiasing may require more GPU performance,
+    so switching this back to \c {Shape.GeometryRenderer} may help on low-power systems. See
+    \l {Shape::rendererType} for more details.
+*/
+
+Item {
+    id: root
+
+    enum Direction {
+        Left,
+        Right,
+        Top,
+        Bottom
+    }
+
+    /*!
+        Must be assigned the data transform of the graph area this axis is paired to.
+
+        \sa GraphArea::dataTransform
+    */
+    property alias dataTransform: helper.dataTransform
+    /*!
+        Number of decimal points the ticks should show.
+
+        \sa TickLabel::decimalPoints
+
+        \default 2
+    */
+    property int decimalPoints: 2
+    /*!
+        The side of the graph the Axis is on. It can take one of the following values:
+
+        \value Axis.Direction.Left Axis to the left of the GraphArea
+        \value Axis.Direction.Right Axis to the right of the GraphArea
+        \value Axis.Direction.Top Axis above of the GraphArea
+        \value Axis.Direction.Bottom Axis below of the GraphArea
+
+        \default Axis.Direction.Left
+     */
+    property alias direction: helper.direction
+    /*!
+        The label text for this axis. Alias of \c labelItem.text.
+    */
+    property alias label: labelText.text
+    /*!
+        The color of the label. Alias of \c labelItem.color.
+    */
+    property alias labelColor: labelText.color
+    /*!
+        The font of the label. Alias of \c labelItem.font.
+    */
+    property alias labelFont: labelText.font
+    /*!
+        The axis label (a \l Text).
+    */
+    property alias labelItem: labelText
+    /*!
+        The preferred renderer type for rendering the spine and ticks.
+
+        \sa Shape::preferredRendererType
+
+        \default Shape.CurveRenderer
+    */
+    property alias preferredRendererType: shape.preferredRendererType
+    /*!
+        Whether to show a label for each tick.
+
+        \default true
+    */
+    property bool showTickLabels: true
+    /*!
+        Spacing between the axis label and the tick labels.
+
+        \default 4
+    */
+    property double spacing: 4
+    /*!
+        Color of the axis spine and ticks.
+
+        \default "black"
+    */
+    property alias strokeColor: myPath.strokeColor
+    /*!
+        Width of the axis spine and ticks.
+
+        \default 1
+    */
+    property alias strokeWidth: myPath.strokeWidth
+    /*!
+        The component used for rendering tick labels. If overridden,
+        the \c color, \c decimalPoints, \c direction, and \c font properties
+        of the component should be set explicitly. To get proper positioning,
+        it is recommended that \l TickLabel or a subclass is used.
+    */
+    property Component tickDelegate: TickLabel {
+        color: root.tickLabelColor
+        decimalPoints: root.decimalPoints
+        direction: root.direction
+        font: root.tickLabelFont
+    }
+    /*!
+        The color of the tick labels.
+
+        \default labelColor
+    */
+    property color tickLabelColor: labelColor
+    /*!
+        The font of the tick labels.
+
+        \default labelFont
+    */
+    property font tickLabelFont: labelFont
+    /*!
+        The length of each tick.
+
+        \default 10
+    */
+    property alias tickLength: helper.tickLength
+    /*!
+        The position of each tick. This should be a list of doubles in data coordinates.
+
+        \sa Helpers::range, Helpers::linspace, Grid::xTicks, Grid::yTicks
+    */
+    property alias ticks: helper.ticks
+
+    implicitHeight: {
+        switch (root.direction) {
+        case Axis.Direction.Left:
+        case Axis.Direction.Right:
+            return 100;
+        case Axis.Direction.Top:
+        case Axis.Direction.Bottom:
+            let height = 0;
+            if (ticks.length > 0) {
+                // Can't use childrenRect due to the binding loop it causes
+                height += root.tickLength + Math.max(0, ...tickLabelsContainer.children.map(x => x.height));
+            }
+            if (label !== "") {
+                height += labelText.height + root.spacing;
+            }
+            return height;
+        }
+    }
+    implicitWidth: {
+        switch (root.direction) {
+        case Axis.Direction.Left:
+        case Axis.Direction.Right:
+            let width = 0;
+            if (ticks.length > 0) {
+                // Can't use childrenRect due to the binding loop it causes
+                width += root.tickLength + Math.max(0, ...tickLabelsContainer.children.map(x => x.width));
+            }
+            if (label !== "") {
+                width += labelText.height + root.spacing;
+            }
+            return width;
+        case Axis.Direction.Top:
+        case Axis.Direction.Bottom:
+            return 100;
+        }
+    }
+    z: 1
+
+    QuickGraphLib.AxisHelper {
+        id: helper
+
+        height: root.height
+        tickLength: 10
+        width: root.width
+    }
+    QQS.Shape {
+        id: shape
+
+        anchors.fill: parent
+        preferredRendererType: QQS.Shape.CurveRenderer
+
+        QQS.ShapePath {
+            id: myPath
+
+            pathHints: QQS.ShapePath.PathLinear
+            strokeColor: "black"
+            strokeWidth: 1
+
+            PathPolyline {
+                path: helper.path
+            }
+        }
+    }
+    Item {
+        id: tickLabelsContainer
+
+        Repeater {
+            delegate: root.tickDelegate
+            model: root.showTickLabels ? helper.tickModel : null
+        }
+    }
+    Text {
+        id: labelText
+
+        x: {
+            switch (root.direction) {
+            case Axis.Direction.Left:
+                return height / 2;
+            case Axis.Direction.Right:
+                return root.width - height / 2;
+            case Axis.Direction.Top:
+            case Axis.Direction.Bottom:
+                return root.width / 2;
+            }
+        }
+        y: {
+            switch (root.direction) {
+            case Axis.Direction.Left:
+            case Axis.Direction.Right:
+                return root.height / 2;
+            case Axis.Direction.Top:
+                return height / 2;
+            case Axis.Direction.Bottom:
+                return root.height - height / 2;
+            }
+        }
+
+        transform: [
+            Translate {
+                x: -labelText.width / 2
+                y: -labelText.height / 2
+            },
+            Rotation {
+                angle: {
+                    switch (root.direction) {
+                    case Axis.Direction.Left:
+                        return -90;
+                    case Axis.Direction.Right:
+                        return 90;
+                    case Axis.Direction.Top:
+                    case Axis.Direction.Bottom:
+                        return 0;
+                    }
+                }
+            }
+        ]
+    }
+}

QuickGraphLib/CMakeLists.txt

@@ -0,0 +1,117 @@
+# SPDX-FileCopyrightText: Copyright (c) 2024 Refeyn Ltd and other QuickGraphLib contributors
+# SPDX-License-Identifier: MIT
+
+set(QGL_QML_FILES
+    AntialiasingContainer.qml
+    Axis.qml
+    GraphArea.qml
+    ScalingContainer.qml
+    ZoomPanHandler.qml
+    TickLabel.qml
+    ShapeRepeater.qml
+)
+
+set(QGL_SOURCES
+    helpers/Helpers.cpp
+    helpers/Helpers.hpp
+    helpers/AxisHelper.hpp
+    helpers/AxisHelper.cpp
+    helpers/Foreign.hpp
+    helpers/ShapeRepeaterHelper.hpp
+    helpers/ShapeRepeaterHelper.cpp
+    ImageView.hpp
+    ImageView.cpp
+    ColorMaps.hpp
+    ColorMaps.cpp
+    DataTypes.hpp
+    DataTypes.cpp
+    QuickGraphLib.hpp
+    Global.hpp
+)
+
+if(ENABLE_PYTHON)
+    list(APPEND QGL_SOURCES bindings/Bindings.hpp)
+endif()
+
+add_library(QuickGraphLibPlugin SHARED Plugin.cpp)
+target_link_libraries(QuickGraphLibPlugin PRIVATE Qt6::Gui)
+qt_add_qml_module(QuickGraphLib
+    URI QuickGraphLib
+    SHARED
+    VERSION 1.0
+    QML_FILES ${QGL_QML_FILES}
+    PLUGIN_TARGET QuickGraphLibPlugin
+    NO_GENERATE_PLUGIN_SOURCE
+    NO_PLUGIN_OPTIONAL
+    DEPENDENCIES QtQuick
+    SOURCES ${QGL_SOURCES}
+)
+set_property(
+    TARGET QuickGraphLib
+    PROPERTY LIBRARY_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+)
+set_property(
+    TARGET QuickGraphLib
+    PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+)
+target_compile_definitions(QuickGraphLib PRIVATE QGL_LIBRARY)
+
+target_compile_definitions(
+    QuickGraphLib
+    PRIVATE $<$<OR:$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>:QT_QML_DEBUG>
+)
+target_link_libraries(QuickGraphLib PRIVATE Qt6::Quick Qt6::Svg)
+target_include_directories(
+    QuickGraphLib
+    PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/helpers
+)
+
+install(
+    TARGETS QuickGraphLib
+    RUNTIME DESTINATION ${INSTALL_SUBPATH}/QuickGraphLib
+    LIBRARY DESTINATION ${INSTALL_SUBPATH}/QuickGraphLib
+)
+install(
+    TARGETS QuickGraphLibPlugin
+    RUNTIME DESTINATION ${INSTALL_SUBPATH}/QuickGraphLib
+    LIBRARY DESTINATION ${INSTALL_SUBPATH}/QuickGraphLib
+)
+install(FILES ${QGL_QML_FILES} DESTINATION ${INSTALL_SUBPATH}/QuickGraphLib)
+install(
+    FILES
+        ${CMAKE_CURRENT_BINARY_DIR}/qmldir
+        ${CMAKE_CURRENT_BINARY_DIR}/QuickGraphLib.qmltypes
+    DESTINATION ${INSTALL_SUBPATH}/QuickGraphLib
+)
+
+add_subdirectory(PreFabs)
+add_subdirectory(GraphItems)
+
+if(ENABLE_PYTHON)
+    set(QGL_PYTHON_FILES
+        __init__.py
+        consts.py
+        contours.py
+        py.typed
+        _version.py
+    )
+    foreach(PYTHON_FILE ${QGL_PYTHON_FILES})
+        add_custom_command(
+            OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${PYTHON_FILE}
+            COMMAND
+                ${CMAKE_COMMAND} -E copy
+                ${CMAKE_CURRENT_SOURCE_DIR}/${PYTHON_FILE}
+                ${CMAKE_CURRENT_BINARY_DIR}/${PYTHON_FILE}
+            DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${PYTHON_FILE}
+        )
+    endforeach()
+    list(TRANSFORM QGL_PYTHON_FILES PREPEND "${CMAKE_CURRENT_BINARY_DIR}/")
+    add_custom_target(QuickGraphLibPythonFiles ALL DEPENDS ${QGL_PYTHON_FILES})
+
+    install(
+        FILES ${QGL_PYTHON_FILES}
+        DESTINATION ${INSTALL_SUBPATH}/QuickGraphLib
+    )
+
+    add_subdirectory(bindings)
+endif()