ManimPango 0.6.1__cp39-cp39-macosx_10_13_x86_64.whl

manimpango/__init__.py

@@ -0,0 +1,35 @@
+# -*- coding: utf-8 -*-
+import os
+import sys
+
+from ._version import __version__  # noqa: F403,F401
+
+if os.name == "nt":  # pragma: no cover
+    os.environ["PATH"] = (
+        f"{os.path.abspath(os.path.dirname(__file__))}"
+        f"{os.pathsep}"
+        f"{os.environ['PATH']}"
+    )
+try:
+    from .register_font import *  # isort:skip # noqa: F403,F401
+    from .cmanimpango import *  # noqa: F403,F401
+    from .enums import *  # noqa: F403,F401
+except ImportError as ie:  # pragma: no cover
+    py_ver = ".".join(map(str, sys.version_info[:3]))
+    msg = f"""
+
+ManimPango could not import and load the necessary shared libraries.
+This error may occur when ManimPango and its dependencies are improperly set up.
+Please make sure the following versions are what you expect:
+
+    * ManimPango v{__version__}, Python v{py_ver}
+
+If you believe there is a greater problem,
+feel free to contact us or create an issue on GitHub:
+
+    * Discord: https://www.manim.community/discord/
+    * GitHub: https://github.com/ManimCommunity/ManimPango/issues
+
+Original error: {ie}
+"""
+    raise ImportError(msg)

manimpango/_register_font.pxd

@@ -0,0 +1,71 @@
+from libc.stddef cimport wchar_t
+from pango cimport *
+
+
+cdef extern from "Python.h":
+    wchar_t* PyUnicode_AsWideCharString(
+        object unicode,
+        Py_ssize_t* size
+    )
+
+cdef extern from "fontconfig/fontconfig.h":
+    ctypedef int FcBool
+    ctypedef struct FcConfig:
+        pass
+    FcBool FcConfigAppFontAddFile(
+        FcConfig* config,
+        const unsigned char* file_name
+    )
+    FcConfig* FcConfigGetCurrent()
+    void FcConfigAppFontClear(void *)
+
+# Windows and macOS specific API's
+IF UNAME_SYSNAME == "Windows":
+    cdef extern from "windows.h":
+        ctypedef const wchar_t* LPCWSTR
+        ctypedef enum DWORD:
+            FR_PRIVATE
+        int AddFontResourceExW(
+            LPCWSTR name,
+            DWORD fl,
+            unsigned int res
+        )
+        bint RemoveFontResourceExW(
+            LPCWSTR name,
+            DWORD  fl,
+            unsigned int pdv
+        )
+
+        ctypedef void* HANDLE
+        HANDLE CreateMutexA(void* lpMutexAttributes, int bInitialOwner, const char* lpName)
+        int ReleaseMutex(HANDLE hMutex)
+        int WaitForSingleObject(HANDLE hHandle, unsigned long dwMilliseconds)
+        int CloseHandle(HANDLE hObject)
+
+ELIF UNAME_SYSNAME == "Darwin":
+    cdef extern from "Carbon/Carbon.h":
+        ctypedef struct CFURLRef:
+            pass
+        ctypedef enum CTFontManagerScope:
+            kCTFontManagerScopeProcess
+        ctypedef unsigned int UInt8
+        ctypedef long CFIndex
+        ctypedef unsigned int UInt32
+        ctypedef UInt32 CFStringEncoding
+        CFURLRef CFURLCreateWithBytes(
+            void*,
+            unsigned char *URLBytes,
+            CFIndex length,
+            CFStringEncoding encoding,
+            void*
+        )
+        bint CTFontManagerRegisterFontsForURL(
+            CFURLRef fontURL,
+            CTFontManagerScope scope,
+            void* error
+        )
+        bint CTFontManagerUnregisterFontsForURL(
+            CFURLRef fontURL,
+            CTFontManagerScope scope,
+            void* error
+        )

manimpango/_register_font.pyx

@@ -0,0 +1,160 @@
+from pathlib import Path
+from pango cimport *
+
+import os
+from dataclasses import dataclass
+
+include "utils.pxi"
+
+@dataclass(frozen=True)
+class RegisteredFont:
+    """A class to represent a font file.
+
+    Attributes
+    ----------
+    path : :class:`str`
+        The path to the font file.
+    """
+
+    path: str
+    type: "fontconfig" | "win32" | "macos"
+
+cpdef bint _fc_register_font(set registered_fonts, str font_path):
+    a = Path(font_path)
+    assert a.exists(), f"font doesn't exist at {a.absolute()}"
+    font_path = os.fspath(a.absolute())
+    font_path_bytes = font_path.encode('utf-8')
+    cdef const unsigned char* fontPath = font_path_bytes
+    fontAddStatus = FcConfigAppFontAddFile(FcConfigGetCurrent(), fontPath)
+    if fontAddStatus:
+        registered_fonts.add(RegisteredFont(font_path, "fontconfig"))
+        return True
+    else:
+        return False
+
+
+cpdef bint _fc_unregister_font(set registered_fonts, str font_path):
+    FcConfigAppFontClear(NULL)
+    # remove all type "fontconfig" files
+    copy = registered_fonts.copy()
+    for font in copy:
+        if font.type == 'fontconfig':
+            registered_fonts.remove(font)
+
+    return True
+
+
+IF UNAME_SYSNAME == "Linux":
+    _register_font = _fc_register_font
+    _unregister_font = _fc_unregister_font
+
+
+ELIF UNAME_SYSNAME == "Windows":
+    cpdef bint _register_font(set registered_fonts, str font_path):
+        a = Path(font_path)
+        assert a.exists(), f"font doesn't exist at {a.absolute()}"
+        font_path = os.fspath(a.absolute())
+        cdef LPCWSTR wchar_path = PyUnicode_AsWideCharString(font_path, NULL)
+        fontAddStatus = AddFontResourceExW(
+            wchar_path,
+            FR_PRIVATE,
+            0
+        )
+
+        if fontAddStatus > 0:
+            registered_fonts.add(RegisteredFont(font_path, "win32"))
+            return True
+        else:
+            return False
+
+
+    cpdef bint _unregister_font(set registered_fonts, str font_path):
+        a = Path(font_path)
+        assert a.exists(), f"font doesn't exist at {a.absolute()}"
+        font_path = os.fspath(a.absolute())
+
+        font = RegisteredFont(font_path, "win32")
+        if font in registered_fonts:
+            registered_fonts.remove(font)
+
+        cdef LPCWSTR wchar_path = PyUnicode_AsWideCharString(font_path, NULL)
+        return RemoveFontResourceExW(
+            wchar_path,
+            FR_PRIVATE,
+            0
+        )
+
+
+ELIF UNAME_SYSNAME == "Darwin":
+    cpdef bint _register_font(set registered_fonts, str font_path):
+        a = Path(font_path)
+        assert a.exists(), f"font doesn't exist at {a.absolute()}"
+        font_path_bytes_py = str(a.absolute().as_uri()).encode('utf-8')
+        cdef unsigned char* font_path_bytes = <bytes>font_path_bytes_py
+        b = len(a.absolute().as_uri())
+        cdef CFURLRef cf_url = CFURLCreateWithBytes(NULL, font_path_bytes, b, 0x08000100, NULL)
+        res = CTFontManagerRegisterFontsForURL(
+            cf_url,
+            kCTFontManagerScopeProcess,
+            NULL
+        )
+        if res:
+            registered_fonts.add(RegisteredFont(os.fspath(a.absolute()), "macos"))
+            return True
+        else:
+            return False
+
+
+    cpdef bint _unregister_font(set registered_fonts, str font_path):
+        a = Path(font_path)
+        assert a.exists(), f"font doesn't exist at {a.absolute()}"
+        font_path_bytes_py = str(a.absolute().as_uri()).encode('utf-8')
+        cdef unsigned char* font_path_bytes = <bytes>font_path_bytes_py
+        b = len(a.absolute().as_uri())
+        cdef CFURLRef cf_url = CFURLCreateWithBytes(NULL, font_path_bytes, b, 0x08000100, NULL)
+        res = CTFontManagerUnregisterFontsForURL(
+            cf_url,
+            kCTFontManagerScopeProcess,
+            NULL
+        )
+        if res:
+            font = RegisteredFont(os.fspath(a.absolute()), "macos")
+            if font in registered_fonts:
+                registered_fonts.remove(font)
+            return True
+        else:
+            return False
+
+
+cpdef list _list_fonts(tuple registered_fonts):
+    cdef PangoFontMap* fontmap = pango_cairo_font_map_new()
+    if fontmap == NULL:
+        raise MemoryError("Pango.FontMap can't be created.")
+
+    for font in registered_fonts:
+        if font.type == 'win32':
+            add_to_fontmap(fontmap, font.path)
+
+    cdef int n_families=0
+    cdef PangoFontFamily** families=NULL
+    pango_font_map_list_families(
+        fontmap,
+        &families,
+        &n_families
+    )
+    if families is NULL or n_families == 0:
+        raise MemoryError("Pango returned unexpected length on families.")
+
+    family_list = []
+    for i in range(n_families):
+        name = pango_font_family_get_name(families[i])
+        # according to pango's docs, the `char *` returned from
+        # `pango_font_family_get_name`is owned by pango, and python
+        # shouldn't interfere with it. I hope Cython handles it.
+        # https://cython.readthedocs.io/en/stable/src/tutorial/strings.html#dealing-with-const
+        family_list.append(name.decode())
+
+    g_free(families)
+    g_object_unref(fontmap)
+    family_list.sort()
+    return family_list

manimpango/_version.py

@@ -0,0 +1,2 @@
+# -*- coding: utf-8 -*-
+__version__ = "0.6.1"

manimpango/cairo.pxd

@@ -0,0 +1,27 @@
+cdef extern from "cairo.h":
+    ctypedef struct cairo_surface_t:
+        pass
+    ctypedef struct cairo_t:
+        pass
+    ctypedef enum cairo_status_t:
+        CAIRO_STATUS_SUCCESS
+        CAIRO_STATUS_NO_MEMORY
+    cairo_t* cairo_create(cairo_surface_t* target)
+    void cairo_move_to(
+        cairo_t* cr,
+        double x,
+        double y
+    )
+    void cairo_destroy(cairo_t* cr)
+    void cairo_surface_destroy(cairo_surface_t* surface)
+
+    cairo_status_t cairo_status(cairo_t *cr)
+    const char* cairo_status_to_string(cairo_status_t status)
+    const char* cairo_version_string()
+
+cdef extern from "cairo-svg.h":
+    cairo_surface_t* cairo_svg_surface_create(
+        const char* filename,
+        double width_in_points,
+        double height_in_points
+    )

manimpango/cmanimpango.pxd

@@ -0,0 +1,3 @@
+from cairo cimport *
+from glib cimport *
+from pango cimport *

manimpango/cmanimpango.pyx

@@ -0,0 +1,321 @@
+import typing
+import warnings
+from xml.sax.saxutils import escape
+
+from . import registered_fonts
+from .enums import Alignment
+from .utils import *
+
+include "utils.pxi"
+
+class TextSetting:
+    """Formatting for slices of a :class:`manim.mobject.svg.text_mobject.Text` object."""
+    def __init__(
+        self,
+        start: int,
+        end: int,
+        font: str,
+        slant: str,
+        weight: str,
+        line_num = -1,
+        color: str = None,
+    ):
+        self.start = start
+        self.end = end
+        self.font = font
+        self.slant = slant
+        self.weight = weight
+        self.line_num = line_num
+        self.color = color
+
+
+def text2svg(
+    settings: list,
+    size: float,
+    line_spacing: float,
+    disable_liga: bool,
+    file_name: str,
+    START_X: int,
+    START_Y: int,
+    width: int,
+    height: int,
+    orig_text: str,
+    pango_width: typing.Union[int, None] = None,
+) -> str:
+    """Render an SVG file from a :class:`manim.mobject.svg.text_mobject.Text` object."""
+    cdef cairo_surface_t* surface
+    cdef cairo_t* cr
+    cdef PangoFontDescription* font_desc
+    cdef PangoLayout* layout
+    cdef double font_size_c = size
+    cdef cairo_status_t status
+    cdef int temp_width
+    cdef PangoFontMap* fontmap
+
+    file_name_bytes = file_name.encode("utf-8")
+    surface = cairo_svg_surface_create(file_name_bytes,width,height)
+
+    if surface == NULL:
+        raise MemoryError("Cairo.SVGSurface can't be created.")
+
+    cr = cairo_create(surface)
+    status = cairo_status(cr)
+
+    if cr == NULL or status == CAIRO_STATUS_NO_MEMORY:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        raise MemoryError("Cairo.Context can't be created.")
+    elif status != CAIRO_STATUS_SUCCESS:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        raise Exception(cairo_status_to_string(status))
+
+    cairo_move_to(cr,START_X,START_Y)
+    offset_x = 0
+    last_line_num = 0
+
+    layout = pango_cairo_create_layout(cr)
+    fontmap = pango_context_get_font_map (pango_layout_get_context (layout));
+
+    for font_item in registered_fonts:
+        if font_item.type == 'win32':
+            add_to_fontmap(fontmap, font_item.path)
+
+    if layout == NULL:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        raise MemoryError("Pango.Layout can't be created from Cairo Context.")
+
+    if pango_width is None:
+        pango_layout_set_width(layout, pango_units_from_double(width))
+    else:
+        pango_layout_set_width(layout, pango_units_from_double(pango_width))
+
+    for setting in settings:
+        family = setting.font.encode('utf-8')
+        style = PangoUtils.str2style(setting.slant)
+        weight = PangoUtils.str2weight(setting.weight)
+        color = setting.color
+        text_str = orig_text[setting.start : setting.end].replace("\n", " ")
+        font_desc = pango_font_description_new()
+        if font_desc==NULL:
+            cairo_destroy(cr)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise MemoryError("Pango.FontDesc can't be created.")
+        pango_font_description_set_size(font_desc, pango_units_from_double(font_size_c))
+        if family:
+            pango_font_description_set_family(font_desc, family)
+        pango_font_description_set_style(font_desc, style.value)
+        pango_font_description_set_weight(font_desc, weight.value)
+        pango_layout_set_font_description(layout, font_desc)
+        pango_font_description_free(font_desc)
+        if setting.line_num != last_line_num:
+            offset_x = 0
+            last_line_num = setting.line_num
+        cairo_move_to(cr,START_X + offset_x,START_Y + line_spacing * setting.line_num)
+
+        pango_cairo_update_layout(cr,layout)
+        markup = escape(text_str)
+        if color:
+            markup = (f"<span color='{color}'>{markup}</span>")
+            if MarkupUtils.validate(markup):
+                cairo_destroy(cr)
+                cairo_surface_destroy(surface)
+                g_object_unref(layout)
+                raise ValueError(f"Pango cannot recognize your color '{color}' for text '{text_str}'.")
+        if disable_liga:
+            markup = f"<span font_features='liga=0,dlig=0,clig=0,hlig=0'>{markup}</span>"
+        pango_layout_set_markup(layout, markup.encode('utf-8'), -1)
+        pango_cairo_show_layout(cr, layout)
+        pango_layout_get_size(layout,&temp_width,NULL)
+        offset_x += pango_units_to_double(temp_width)
+
+    status = cairo_status(cr)
+
+    if cr == NULL or status == CAIRO_STATUS_NO_MEMORY:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        g_object_unref(layout)
+        raise MemoryError("Cairo.Context can't be created.")
+    elif status != CAIRO_STATUS_SUCCESS:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        g_object_unref(layout)
+        raise Exception(cairo_status_to_string(status).decode())
+
+    cairo_destroy(cr)
+    cairo_surface_destroy(surface)
+    g_object_unref(layout)
+    return file_name
+
+class MarkupUtils:
+    @staticmethod
+    def validate(markup: str) -> str:
+        """Validates whether markup is a valid Markup
+        and return the error's if any.
+
+        Parameters
+        ==========
+        markup : :class:`str`
+            The markup which should be checked.
+
+        Returns
+        =======
+        :class:`str`
+            Returns empty string if markup is valid. If markup
+            contains error it return the error message.
+
+        """
+        cdef GError *err = NULL
+        text_bytes = markup.encode("utf-8")
+        res = pango_parse_markup(
+            text_bytes,
+            -1,
+            0,
+            NULL,
+            NULL,
+            NULL,
+            &err
+        )
+        if res:
+            return ""
+        else:
+            message = <bytes>err.message
+            g_error_free(err)
+            return message.decode('utf-8')
+
+    @staticmethod
+    def text2svg(
+        text: str,
+        font: str | None,
+        slant: str,
+        weight: str,
+        size: float,
+        _, # for some there was a keyword here.
+        disable_liga: bool,
+        file_name: str,
+        START_X: int,
+        START_Y: int,
+        width: int,
+        height: int,
+        *, # keyword only arguments below
+        justify: bool | None = None,
+        indent: float | int | None = None,
+        line_spacing: float | None = None,
+        alignment: Alignment | None = None,
+        pango_width: int | None = None,
+    ) -> str:
+        """Render an SVG file from a :class:`manim.mobject.svg.text_mobject.MarkupText` object."""
+        cdef cairo_surface_t* surface
+        cdef cairo_t* context
+        cdef PangoFontDescription* font_desc
+        cdef PangoLayout* layout
+        cdef cairo_status_t status
+        cdef double font_size = size
+        cdef int temp_int # a temporary C integer for conversion
+        cdef PangoFontMap* fontmap
+
+        file_name_bytes = file_name.encode("utf-8")
+
+        if disable_liga:
+            text_bytes = f"<span font_features='liga=0,dlig=0,clig=0,hlig=0'>{text}</span>".encode("utf-8")
+        else:
+            text_bytes = text.encode("utf-8")
+
+        surface = cairo_svg_surface_create(file_name_bytes,width,height)
+        if surface == NULL:
+            raise MemoryError("Cairo.SVGSurface can't be created.")
+        context = cairo_create(surface)
+        status = cairo_status(context)
+        if context == NULL or status == CAIRO_STATUS_NO_MEMORY:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            raise MemoryError("Cairo.Context can't be created.")
+        elif status != CAIRO_STATUS_SUCCESS:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            raise Exception(cairo_status_to_string(status))
+
+        cairo_move_to(context,START_X,START_Y)
+        layout = pango_cairo_create_layout(context)
+        if layout == NULL:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            raise MemoryError("Pango.Layout can't be created from Cairo Context.")
+
+        fontmap = pango_context_get_font_map (pango_layout_get_context (layout));
+
+        for font_item in registered_fonts:
+            if font_item.type == 'win32':
+                add_to_fontmap(fontmap, font_item.path)
+
+        if pango_width is None:
+            pango_layout_set_width(layout, pango_units_from_double(width))
+        else:
+            pango_layout_set_width(layout, pango_units_from_double(pango_width))
+
+        if justify:
+            pango_layout_set_justify(layout, justify)
+
+        if indent:
+            temp_int = pango_units_from_double(indent)
+            pango_layout_set_indent(layout, temp_int)
+
+        if line_spacing:
+            # Typical values are: 0, 1, 1.5, 2.
+            ret = set_line_width(layout, line_spacing)
+            if not ret:
+                # warn that line spacing don't work
+                # because of old Pango version they
+                # have
+                warnings.warn(
+                    "Pango Version<1.44 found."
+                    "Impossible to set line_spacing."
+                    "Expect Ugly Output."
+                )
+
+        if alignment:
+            pango_layout_set_alignment(layout, alignment.value)
+
+        font_desc = pango_font_description_new()
+        if font_desc == NULL:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise MemoryError("Pango.FontDesc can't be created.")
+        pango_font_description_set_size(font_desc, pango_units_from_double(font_size))
+        if font is not None and len(font) != 0:
+            pango_font_description_set_family(font_desc, font.encode("utf-8"))
+        pango_font_description_set_style(font_desc, PangoUtils.str2style(slant).value)
+        pango_font_description_set_weight(font_desc, PangoUtils.str2weight(weight).value)
+        pango_layout_set_font_description(layout, font_desc)
+        pango_font_description_free(font_desc)
+
+        cairo_move_to(context,START_X,START_Y)
+        pango_cairo_update_layout(context,layout)
+        pango_layout_set_markup(layout,text_bytes,-1)
+        pango_cairo_show_layout(context, layout)
+
+        status = cairo_status(context)
+        if context == NULL or status == CAIRO_STATUS_NO_MEMORY:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise MemoryError("Cairo.Context can't be created.")
+        elif status != CAIRO_STATUS_SUCCESS:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise Exception(cairo_status_to_string(status).decode())
+
+        cairo_destroy(context)
+        cairo_surface_destroy(surface)
+        g_object_unref(layout)
+        return file_name
+
+cpdef str pango_version():
+    return pango_version_string().decode('utf-8')
+
+cpdef str cairo_version():
+    return cairo_version_string().decode('utf-8')