ManimPango 0.6.0__cp39-cp39-macosx_11_0_arm64.whl

manimpango/cmanimpango.pyx

@@ -0,0 +1,321 @@
+import typing
+import warnings
+from xml.sax.saxutils import escape
+
+from . import registered_fonts
+from .enums import Alignment
+from .utils import *
+
+include "utils.pxi"
+
+class TextSetting:
+    """Formatting for slices of a :class:`manim.mobject.svg.text_mobject.Text` object."""
+    def __init__(
+        self,
+        start: int,
+        end: int,
+        font: str,
+        slant: str,
+        weight: str,
+        line_num = -1,
+        color: str = None,
+    ):
+        self.start = start
+        self.end = end
+        self.font = font
+        self.slant = slant
+        self.weight = weight
+        self.line_num = line_num
+        self.color = color
+
+
+def text2svg(
+    settings: list,
+    size: float,
+    line_spacing: float,
+    disable_liga: bool,
+    file_name: str,
+    START_X: int,
+    START_Y: int,
+    width: int,
+    height: int,
+    orig_text: str,
+    pango_width: typing.Union[int, None] = None,
+) -> str:
+    """Render an SVG file from a :class:`manim.mobject.svg.text_mobject.Text` object."""
+    cdef cairo_surface_t* surface
+    cdef cairo_t* cr
+    cdef PangoFontDescription* font_desc
+    cdef PangoLayout* layout
+    cdef double font_size_c = size
+    cdef cairo_status_t status
+    cdef int temp_width
+    cdef PangoFontMap* fontmap
+
+    file_name_bytes = file_name.encode("utf-8")
+    surface = cairo_svg_surface_create(file_name_bytes,width,height)
+
+    if surface == NULL:
+        raise MemoryError("Cairo.SVGSurface can't be created.")
+
+    cr = cairo_create(surface)
+    status = cairo_status(cr)
+
+    if cr == NULL or status == CAIRO_STATUS_NO_MEMORY:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        raise MemoryError("Cairo.Context can't be created.")
+    elif status != CAIRO_STATUS_SUCCESS:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        raise Exception(cairo_status_to_string(status))
+
+    cairo_move_to(cr,START_X,START_Y)
+    offset_x = 0
+    last_line_num = 0
+
+    layout = pango_cairo_create_layout(cr)
+    fontmap = pango_context_get_font_map (pango_layout_get_context (layout));
+
+    for font_item in registered_fonts:
+        if font_item.type == 'win32':
+            add_to_fontmap(fontmap, font_item.path)
+
+    if layout == NULL:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        raise MemoryError("Pango.Layout can't be created from Cairo Context.")
+
+    if pango_width is None:
+        pango_layout_set_width(layout, pango_units_from_double(width))
+    else:
+        pango_layout_set_width(layout, pango_units_from_double(pango_width))
+
+    for setting in settings:
+        family = setting.font.encode('utf-8')
+        style = PangoUtils.str2style(setting.slant)
+        weight = PangoUtils.str2weight(setting.weight)
+        color = setting.color
+        text_str = orig_text[setting.start : setting.end].replace("\n", " ")
+        font_desc = pango_font_description_new()
+        if font_desc==NULL:
+            cairo_destroy(cr)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise MemoryError("Pango.FontDesc can't be created.")
+        pango_font_description_set_size(font_desc, pango_units_from_double(font_size_c))
+        if family:
+            pango_font_description_set_family(font_desc, family)
+        pango_font_description_set_style(font_desc, style.value)
+        pango_font_description_set_weight(font_desc, weight.value)
+        pango_layout_set_font_description(layout, font_desc)
+        pango_font_description_free(font_desc)
+        if setting.line_num != last_line_num:
+            offset_x = 0
+            last_line_num = setting.line_num
+        cairo_move_to(cr,START_X + offset_x,START_Y + line_spacing * setting.line_num)
+
+        pango_cairo_update_layout(cr,layout)
+        markup = escape(text_str)
+        if color:
+            markup = (f"<span color='{color}'>{markup}</span>")
+            if MarkupUtils.validate(markup):
+                cairo_destroy(cr)
+                cairo_surface_destroy(surface)
+                g_object_unref(layout)
+                raise ValueError(f"Pango cannot recognize your color '{color}' for text '{text_str}'.")
+        if disable_liga:
+            markup = f"<span font_features='liga=0,dlig=0,clig=0,hlig=0'>{markup}</span>"
+        pango_layout_set_markup(layout, markup.encode('utf-8'), -1)
+        pango_cairo_show_layout(cr, layout)
+        pango_layout_get_size(layout,&temp_width,NULL)
+        offset_x += pango_units_to_double(temp_width)
+
+    status = cairo_status(cr)
+
+    if cr == NULL or status == CAIRO_STATUS_NO_MEMORY:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        g_object_unref(layout)
+        raise MemoryError("Cairo.Context can't be created.")
+    elif status != CAIRO_STATUS_SUCCESS:
+        cairo_destroy(cr)
+        cairo_surface_destroy(surface)
+        g_object_unref(layout)
+        raise Exception(cairo_status_to_string(status).decode())
+
+    cairo_destroy(cr)
+    cairo_surface_destroy(surface)
+    g_object_unref(layout)
+    return file_name
+
+class MarkupUtils:
+    @staticmethod
+    def validate(markup: str) -> str:
+        """Validates whether markup is a valid Markup
+        and return the error's if any.
+
+        Parameters
+        ==========
+        markup : :class:`str`
+            The markup which should be checked.
+
+        Returns
+        =======
+        :class:`str`
+            Returns empty string if markup is valid. If markup
+            contains error it return the error message.
+
+        """
+        cdef GError *err = NULL
+        text_bytes = markup.encode("utf-8")
+        res = pango_parse_markup(
+            text_bytes,
+            -1,
+            0,
+            NULL,
+            NULL,
+            NULL,
+            &err
+        )
+        if res:
+            return ""
+        else:
+            message = <bytes>err.message
+            g_error_free(err)
+            return message.decode('utf-8')
+
+    @staticmethod
+    def text2svg(
+        text: str,
+        font: str | None,
+        slant: str,
+        weight: str,
+        size: float,
+        _, # for some there was a keyword here.
+        disable_liga: bool,
+        file_name: str,
+        START_X: int,
+        START_Y: int,
+        width: int,
+        height: int,
+        *, # keyword only arguments below
+        justify: bool | None = None,
+        indent: float | int | None = None,
+        line_spacing: float | None = None,
+        alignment: Alignment | None = None,
+        pango_width: int | None = None,
+    ) -> str:
+        """Render an SVG file from a :class:`manim.mobject.svg.text_mobject.MarkupText` object."""
+        cdef cairo_surface_t* surface
+        cdef cairo_t* context
+        cdef PangoFontDescription* font_desc
+        cdef PangoLayout* layout
+        cdef cairo_status_t status
+        cdef double font_size = size
+        cdef int temp_int # a temporary C integer for conversion
+        cdef PangoFontMap* fontmap
+
+        file_name_bytes = file_name.encode("utf-8")
+
+        if disable_liga:
+            text_bytes = f"<span font_features='liga=0,dlig=0,clig=0,hlig=0'>{text}</span>".encode("utf-8")
+        else:
+            text_bytes = text.encode("utf-8")
+
+        surface = cairo_svg_surface_create(file_name_bytes,width,height)
+        if surface == NULL:
+            raise MemoryError("Cairo.SVGSurface can't be created.")
+        context = cairo_create(surface)
+        status = cairo_status(context)
+        if context == NULL or status == CAIRO_STATUS_NO_MEMORY:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            raise MemoryError("Cairo.Context can't be created.")
+        elif status != CAIRO_STATUS_SUCCESS:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            raise Exception(cairo_status_to_string(status))
+
+        cairo_move_to(context,START_X,START_Y)
+        layout = pango_cairo_create_layout(context)
+        if layout == NULL:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            raise MemoryError("Pango.Layout can't be created from Cairo Context.")
+
+        fontmap = pango_context_get_font_map (pango_layout_get_context (layout));
+
+        for font_item in registered_fonts:
+            if font_item.type == 'win32':
+                add_to_fontmap(fontmap, font_item.path)
+
+        if pango_width is None:
+            pango_layout_set_width(layout, pango_units_from_double(width))
+        else:
+            pango_layout_set_width(layout, pango_units_from_double(pango_width))
+
+        if justify:
+            pango_layout_set_justify(layout, justify)
+
+        if indent:
+            temp_int = pango_units_from_double(indent)
+            pango_layout_set_indent(layout, temp_int)
+
+        if line_spacing:
+            # Typical values are: 0, 1, 1.5, 2.
+            ret = set_line_width(layout, line_spacing)
+            if not ret:
+                # warn that line spacing don't work
+                # because of old Pango version they
+                # have
+                warnings.warn(
+                    "Pango Version<1.44 found."
+                    "Impossible to set line_spacing."
+                    "Expect Ugly Output."
+                )
+
+        if alignment:
+            pango_layout_set_alignment(layout, alignment.value)
+
+        font_desc = pango_font_description_new()
+        if font_desc == NULL:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise MemoryError("Pango.FontDesc can't be created.")
+        pango_font_description_set_size(font_desc, pango_units_from_double(font_size))
+        if font is not None and len(font) != 0:
+            pango_font_description_set_family(font_desc, font.encode("utf-8"))
+        pango_font_description_set_style(font_desc, PangoUtils.str2style(slant).value)
+        pango_font_description_set_weight(font_desc, PangoUtils.str2weight(weight).value)
+        pango_layout_set_font_description(layout, font_desc)
+        pango_font_description_free(font_desc)
+
+        cairo_move_to(context,START_X,START_Y)
+        pango_cairo_update_layout(context,layout)
+        pango_layout_set_markup(layout,text_bytes,-1)
+        pango_cairo_show_layout(context, layout)
+
+        status = cairo_status(context)
+        if context == NULL or status == CAIRO_STATUS_NO_MEMORY:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise MemoryError("Cairo.Context can't be created.")
+        elif status != CAIRO_STATUS_SUCCESS:
+            cairo_destroy(context)
+            cairo_surface_destroy(surface)
+            g_object_unref(layout)
+            raise Exception(cairo_status_to_string(status).decode())
+
+        cairo_destroy(context)
+        cairo_surface_destroy(surface)
+        g_object_unref(layout)
+        return file_name
+
+cpdef str pango_version():
+    return pango_version_string().decode('utf-8')
+
+cpdef str cairo_version():
+    return cairo_version_string().decode('utf-8')

manimpango/enums.pyx

@@ -0,0 +1,113 @@
+from enum import Enum
+
+from pango cimport *
+
+
+class Style(Enum):
+    """
+    An enumeration specifying the various slant styles possible for a font.
+
+    Attributes
+    ----------
+
+    NORMAL :
+        the font is upright.
+
+    ITALIC :
+        the font is slanted, but in a roman style.
+
+    OBLIQUE:
+        the font is slanted in an italic style.
+    """
+    NORMAL = PANGO_STYLE_NORMAL
+    ITALIC = PANGO_STYLE_ITALIC
+    OBLIQUE = PANGO_STYLE_OBLIQUE
+
+class Weight(Enum):
+    """
+    An enumeration specifying the weight (boldness) of a font.
+    This is a numerical value ranging from 100 to 1000, but there are some predefined values
+    Using numerical value other then that defined here is not supported.
+
+    Attributes
+    ----------
+
+    NORMAL :
+        the default weight (= 400)
+
+    BOLD :
+        the bold weight( = 700)
+
+    THIN :
+        the thin weight( = 100; Since: 1.24)
+
+    ULTRALIGHT :
+        the ultralight weight( = 200)
+
+    LIGHT :
+        the light weight( = 300)
+
+    BOOK :
+        the book weight( = 380; Since: 1.24)
+
+    MEDIUM :
+        the normal weight( = 500; Since: 1.24)
+
+    SEMIBOLD :
+        the semibold weight( = 600)
+
+    ULTRABOLD :
+        the ultrabold weight( = 800)
+
+    HEAVY :
+        the heavy weight( = 900)
+
+    ULTRAHEAVY :
+        the ultraheavy weight( = 1000; Since: 1.24)
+    """
+    NORMAL = PANGO_WEIGHT_NORMAL
+    BOLD = PANGO_WEIGHT_BOLD
+    THIN = PANGO_WEIGHT_THIN
+    ULTRALIGHT = PANGO_WEIGHT_ULTRALIGHT
+    LIGHT = PANGO_WEIGHT_LIGHT
+    BOOK = PANGO_WEIGHT_BOOK
+    MEDIUM = PANGO_WEIGHT_MEDIUM
+    SEMIBOLD = PANGO_WEIGHT_SEMIBOLD
+    ULTRABOLD = PANGO_WEIGHT_ULTRABOLD
+    HEAVY = PANGO_WEIGHT_HEAVY
+    ULTRAHEAVY = PANGO_WEIGHT_ULTRAHEAVY
+
+class Variant(Enum):
+    """
+    An enumeration specifying capitalization variant of the font.
+
+    Attributes
+    ----------
+
+    NORMAL :
+        A normal font.
+
+    SMALL_CAPS :
+        A font with the lower case characters replaced by smaller variants
+        of the capital characters.
+    """
+    NORMAL = PANGO_VARIANT_NORMAL
+    SMALL_CAPS = PANGO_VARIANT_SMALL_CAPS
+
+class Alignment(Enum):
+    """
+    An enumeration specifying alignment.
+
+    Attributes
+    ----------
+
+    NORMAL :
+        A normal font.
+
+    SMALL_CAPS :
+        A font with the lower case characters replaced by smaller variants
+        of the capital characters.
+    """
+    LEFT = PANGO_ALIGN_LEFT
+    CENTER = PANGO_ALIGN_CENTER
+    RIGHT = PANGO_ALIGN_RIGHT

manimpango/glib.pxd

@@ -0,0 +1,13 @@
+cdef extern from "glib.h":
+    ctypedef void* gpointer
+    ctypedef int gint
+    ctypedef unsigned int guint
+    ctypedef gint gboolean
+    ctypedef unsigned short guint16
+    ctypedef char gchar
+    ctypedef struct GError:
+        gint code
+        gchar *message
+    void g_error_free (GError *error)
+    void g_object_unref(gpointer object)
+    void g_free(gpointer mem)

manimpango/pango.pxd

@@ -0,0 +1,193 @@
+from cairo cimport *
+from glib cimport *
+
+
+cdef extern from "pango/pangocairo.h":
+    int PANGO_SCALE
+    int pango_units_from_double(double d)
+    double pango_units_to_double (int i)
+    ctypedef struct PangoLayout:
+        pass
+    ctypedef struct PangoContext:
+        pass
+    ctypedef struct PangoFontMap:
+        pass
+    ctypedef struct PangoFontDescription:
+        pass
+    ctypedef struct PangoFontFamily:
+        pass
+    ctypedef enum PangoStyle:
+        PANGO_STYLE_NORMAL
+        PANGO_STYLE_OBLIQUE
+        PANGO_STYLE_ITALIC
+    ctypedef enum PangoWeight:
+        PANGO_WEIGHT_THIN
+        PANGO_WEIGHT_ULTRALIGHT
+        PANGO_WEIGHT_LIGHT
+        PANGO_WEIGHT_BOOK
+        PANGO_WEIGHT_NORMAL
+        PANGO_WEIGHT_MEDIUM
+        PANGO_WEIGHT_SEMIBOLD
+        PANGO_WEIGHT_BOLD
+        PANGO_WEIGHT_ULTRABOLD
+        PANGO_WEIGHT_HEAVY
+        PANGO_WEIGHT_ULTRAHEAVY
+    ctypedef enum PangoVariant:
+        PANGO_VARIANT_NORMAL
+        PANGO_VARIANT_SMALL_CAPS
+    ctypedef enum PangoWrapMode:
+        PANGO_WRAP_WORD
+        PANGO_WRAP_CHAR
+        PANGO_WRAP_WORD_CHAR
+    ctypedef enum PangoAlignment:
+        PANGO_ALIGN_LEFT
+        PANGO_ALIGN_CENTER
+        PANGO_ALIGN_RIGHT
+    PangoLayout* pango_cairo_create_layout(cairo_t* cr)
+    void pango_cairo_show_layout(
+        cairo_t* cr,
+        PangoLayout* layout
+    )
+    void pango_cairo_update_layout(
+        cairo_t* cr,
+        PangoLayout* layout
+    )
+    PangoFontDescription* pango_font_description_new()
+    void pango_font_description_set_size(
+        PangoFontDescription* desc,
+        gint size
+    )
+    void pango_font_description_set_family(
+        PangoFontDescription* desc,
+        const char* family
+    )
+    void pango_font_description_set_style(
+        PangoFontDescription* desc,
+        PangoStyle style
+    )
+    void pango_font_description_set_weight(
+        PangoFontDescription* desc,
+        PangoWeight weight
+    )
+    void pango_font_description_set_variant(
+        PangoFontDescription* desc,
+        PangoVariant variant
+    )
+
+    void pango_layout_set_width(
+        PangoLayout* layout,
+        int width
+    )
+    void pango_layout_set_font_description(
+        PangoLayout* layout,
+        const PangoFontDescription* desc
+    )
+    void pango_layout_set_text(
+        PangoLayout* layout,
+        const char* text,
+        int length
+    )
+    void pango_layout_set_wrap(
+        PangoLayout *layout,
+        PangoWrapMode wrap
+    )
+    void pango_layout_set_markup(
+        PangoLayout *layout,
+        const char *markup,
+        int length
+    )
+    void pango_layout_get_size(
+        PangoLayout* layout,
+        int* width,
+        int* height
+    )
+    const char* pango_version_string()
+    void pango_font_description_free(
+        PangoFontDescription *desc
+    )
+    gboolean pango_parse_markup(
+       const char *markup_text,
+       int length,
+       unsigned int accel_marker,
+       void* attr_list,
+       void* text,
+       void* accel_char,
+       void* error
+    )
+    PangoFontMap* pango_cairo_font_map_new()
+    void pango_font_map_list_families(
+        PangoFontMap *fontmap,
+        PangoFontFamily ***families,
+        int *n_families
+    )
+    PangoFontFamily* pango_font_map_get_family(
+        PangoFontMap *fontmap,
+        const char *name
+    )
+    const char* pango_font_family_get_name(
+        PangoFontFamily *family
+    )
+    void pango_layout_set_justify(
+        PangoLayout *layout,
+        gboolean justify
+    )
+    void pango_layout_set_indent(
+        PangoLayout *layout,
+        int indent
+    )
+    void pango_layout_set_alignment(
+        PangoLayout *layout,
+        PangoAlignment alignment
+    )
+    PangoFontMap* pango_context_get_font_map(
+        PangoContext* context
+    )
+    PangoContext* pango_layout_get_context(
+        PangoLayout* layout
+    )
+
+
+
+cdef extern from *:
+    """
+    #if _WIN32
+        #include <pango/pangowin32.h>
+    #endif
+    #if PANGO_VERSION_CHECK(1,44,0)
+        int set_line_width(PangoLayout *layout,float spacing)
+        {
+          pango_layout_set_line_spacing(layout, spacing);
+          return 1;
+        }
+    #else
+        int set_line_width(PangoLayout *layout,float spacing){return 0;}
+    #endif
+
+    #if _WIN32 && PANGO_VERSION_CHECK(1,52,0)
+        gboolean font_map_add_font_file(PangoFontMap *font_map,
+                                    const char   *font_file_path,
+                                    GError      **error)
+        {
+          return pango_win32_font_map_add_font_file(font_map, font_file_path, error);
+        }
+    #else
+        gboolean font_map_add_font_file(PangoFontMap *font_map,
+                                    const char   *font_file_path,
+                                    GError      **error)
+        {
+            return 1;
+        }
+    #endif
+
+    """
+    # The above docs string is C which is used to
+    # check for the Pango Version there at run time.
+    # pango_layout_set_line_spacing is only avaiable only for
+    # pango>=1.44.0 but we support pango>=1.30.0 that why this
+    # conditionals.
+    bint set_line_width(PangoLayout *layout,float spacing)
+
+    # only for windows and 1.52.0+
+    gboolean font_map_add_font_file(PangoFontMap *font_map,
+                                    const char   *font_file_path,
+                                    GError      **error)