wiki-server 0.25.9 → 0.26.0-rc.0

package/lib/sitemap.coffee

@@ -1,246 +0,0 @@
-###
- * Federated Wiki : Node Server
- *
- * Copyright Ward Cunningham and other contributors
- * Licensed under the MIT license.
- * https://github.com/fedwiki/wiki-server/blob/master/LICENSE.txt
-###
-
-# **sitemap.coffee**
-
-fs = require 'fs'
-path = require 'path'
-events = require 'events'
-writeFileAtomic = require 'write-file-atomic'
-xml2js = require 'xml2js'
-
-synopsis = require 'wiki-client/lib/synopsis'
-
-asSlug = (name) ->
-  name.replace(/\s/g, '-').replace(/[^A-Za-z0-9-]/g, '').toLowerCase()
-
-
-module.exports = exports = (argv) ->
-
-  wikiName = new URL(argv.url).hostname
-
-  sitemap = []
-
-  queue = []
-
-  sitemapPageHandler = null
-
-  # ms since last update we will remove sitemap from memory
-  sitemapTimeoutMs = 120000
-  sitemapTimeoutHandler = null
-
-  sitemapLoc = path.join(argv.status, 'sitemap.json')
-  xmlSitemapLoc = path.join(argv.status, 'sitemap.xml')
-
-  working = false
-
-  lastEdit = (journal) ->
-    for action in (journal || []) by -1
-      return action.date if action.date and action.type != 'fork'
-    undefined
-
-  sitemapUpdate = (file, page, cb) ->
-
-    extractPageLinks = (collaborativeLinks, currentItem, currentIndex, array) ->
-      # extract collaborative links 
-      # - this will need extending if we also extract the id of the item containing the link
-      try
-        linkRe = /\[\[([^\]]+)\]\]/g
-        match = undefined
-        while (match = linkRe.exec(currentItem.text)) != null
-          if not collaborativeLinks.has(asSlug(match[1]))
-            collaborativeLinks.set(asSlug(match[1]), currentItem.id)
-        if 'reference' == currentItem.type
-          if not collaborativeLinks.has(currentItem.slug)
-            collaborativeLinks.set(currentItem.slug, currentItem.id)
-      catch err
-        console.log "METADATA *** #{wikiName} Error extracting links from #{currentIndex} of #{JSON.stringify(array)}", err.message
-      collaborativeLinks
-
-    try
-      pageLinksMap = page.story.reduce( extractPageLinks, new Map())
-    catch err
-      console.log "METADATA *** #{wikiName} reduce to extract links on #{file} failed", err.message
-      pageLinksMap = []
-    #
-    if pageLinksMap.size > 0
-      pageLinks = Object.fromEntries(pageLinksMap)
-    else
-      pageLinks = undefined
-
-    entry = {
-      'slug': file
-      'title': page.title
-      'date': lastEdit(page.journal)
-      'synopsis': synopsis(page)
-      'links': pageLinks
-    }
-
-    slugs = sitemap.map (page) -> page.slug
-
-    idx = slugs.indexOf(file)
-
-    if ~idx
-      sitemap[idx] = entry
-    else
-      sitemap.push entry
-
-    cb()
-
-  sitemapRemovePage = (file, cb) ->
-    slugs = sitemap.map (page) -> page.slug
-    idx = slugs.indexOf(file)
-
-    if ~idx
-      sitemap.splice(idx,1)
-
-    cb()
-
-  sitemapSave = (sitemap, cb) ->
-    fs.exists argv.status, (exists) ->
-      if exists
-        writeFileAtomic sitemapLoc, JSON.stringify(sitemap), (e) ->
-          return cb(e) if e
-          cb()
-      else
-        fs.mkdir argv.status, { recursive: true }, ->
-          writeFileAtomic sitemapLoc, JSON.stringify(sitemap), (e) ->
-            return cb(e) if e
-            cb()
-
-  sitemapRestore = (cb) ->
-    fs.exists sitemapLoc, (exists) ->
-      if exists
-        fs.readFile(sitemapLoc, (err, data) ->
-          return cb(err) if err
-          try
-            sitemap = JSON.parse(data)
-          catch e
-            return cb(e)
-          process.nextTick( ->
-            serial(queue.shift()))
-        )
-      else
-        # sitemap file does not exist, so needs creating
-        itself.createSitemap(sitemapPageHandler)
-
-  xmlSitemapSave = (sitemap, cb) ->
-    xmlmap = []
-    sitemap.forEach (page) ->
-      result = {}
-      result["loc"] = argv.url + "/" + page.slug + ".html"
-      if page.date?
-        date = new Date(page.date)
-        if !(isNaN(date.valueOf()))
-          result["lastmod"] = date.toISOString().substring(0,10)
-      xmlmap.push result
-    xmlmap = {'urlset': {"$": {"xmlns": "http://www.sitemaps.org/schemas/sitemap/0.9"},'url': xmlmap}}
-    builder = new xml2js.Builder()
-    xml = builder.buildObject(xmlmap)
-    fs.exists argv.status, (exists) ->
-      if exists
-        writeFileAtomic xmlSitemapLoc, xml, (e) ->
-          return cb(e) if e
-          cb()
-      else
-        fs.mkdir argv.status, { recursive: true }, ->
-          writeFileAtomic xmlSitemapLoc, xml, (e) ->
-            return cb(e) if e
-            cb()
-
-  serial = (item) ->
-    if item
-      switch item.action
-        when "update"
-          itself.start()
-          sitemapUpdate(item.file, item.page, (e) ->
-            process.nextTick( ->
-              serial(queue.shift())
-            )
-          )
-        when "remove"
-          itself.start()
-          sitemapRemovePage(item.file, (e) ->
-            process.nextTick( ->
-              serial(queue.shift())
-            )
-          )
-        else
-          console.log "Sitemap unexpected action #{item.action} for #{item.page} in #{wikiName}"
-          process.nextTick( ->
-            serial(queue.shift))
-    else
-      sitemapSave sitemap, (e) ->
-        console.log "Problems saving sitemap #{wikiName}: "+ e if e
-        itself.stop()
-      xmlSitemapSave sitemap, (e) ->
-        console.log "Problems saving sitemap(xml) #{wikiName}"+ e if e
-
-
-  #### Public stuff ####
-
-  itself = new events.EventEmitter
-  itself.start = ->
-    clearTimeout(sitemapTimeoutHandler)
-    working = true
-    @emit 'working'
-  itself.stop = ->
-    clearsitemap = ->
-      console.log "removing sitemap #{wikiName} from memory"
-      sitemap = []
-      clearTimeout(sitemapTimeoutHandler)
-    sitemapTimeoutHandler = setTimeout clearsitemap, sitemapTimeoutMs
-    working = false
-    @emit 'finished'
-
-  itself.isWorking = ->
-    working
-
-  itself.createSitemap = (pagehandler) ->
-
-    itself.start()
-
-    # we save the pagehandler, so we can recreate the sitemap if it is removed
-    sitemapPageHandler = pagehandler if !sitemapPageHandler?
-
-    pagehandler.pages (e, newsitemap) ->
-      if e
-        console.log "createSitemap #{wikiName} : error " + e
-        itself.stop()
-        return e
-      sitemap = newsitemap
-
-      process.nextTick ( ->
-        serial(queue.shift()))
-
-  itself.removePage = (file) ->
-    action = "remove"
-    queue.push({action, file, ""})
-    if sitemap.length is 0 and !working
-      itself.start()
-      sitemapRestore (e) ->
-        console.log "Problems restoring sitemap #{wikiName} : " + e if e
-        itself.createSitemap(sitemapPageHandler)
-    else
-      serial(queue.shift()) unless working
-
-
-  itself.update = (file, page) ->
-    action = "update"
-    queue.push({action, file, page})
-    if sitemap.length is 0 and !working
-      itself.start()
-      sitemapRestore (e) ->
-        console.log "Problems restoring sitemap #{wikiName} : " + e if e
-        itself.createSitemap(sitemapPageHandler)
-    else
-      serial(queue.shift()) unless working
-
-
-
-  itself

package/test/asdf-test-page

@@ -1,8 +0,0 @@
-{ "title": "Asdf Test Page", "story": [
-        {"id": "a1", "type": "paragraph", "text": "this is the first paragraph"},
-        {"id": "a2", "type": "paragraph", "text": "this is the second paragraph"},
-        {"id": "a3", "type": "paragraph", "text": "this is the third paragraph"},
-        {"id": "a4", "type": "paragraph", "text": "this is the fourth paragraph"}
-      ],
-      journal: []
-    }

package/test/defaultargs.coffee

@@ -1,10 +0,0 @@
-defaultargs = require '../lib/defaultargs'
-
-describe 'defaultargs', ->
-  describe '#defaultargs()', ->
-    it 'should not write over give args', ->
-      defaultargs({port: 1234}).port.should.equal(1234)
-    it 'should write non give args', ->
-      defaultargs().port.should.equal(3000)
-    it 'should modify dependant args', ->
-      defaultargs({data: '/tmp/asdf/'}).db.should.equal('/tmp/asdf/pages')	

package/test/mocha.opts

@@ -1,2 +0,0 @@
---require should
---compilers coffee:coffeescript/register

package/test/page.coffee

@@ -1,61 +0,0 @@
-path = require('path')
-random = require('../lib/random_id')
-testid = random()
-argv = require('../lib/defaultargs.coffee')({data: path.join('/tmp', 'sfwtests', testid), root: path.join(__dirname, '..'), packageDir: path.join(__dirname, '..', 'node_modules'), security_legacy: true})
-page = require('../lib/page.coffee')(argv)
-fs = require('fs')
-
-testpage = {title: 'Asdf'}
-
-describe 'page', ->
-  describe '#page.put()', ->
-    it 'should save a page', (done) ->
-      page.put('asdf', testpage, (e) ->
-        done(e)
-      )
-  describe '#page.get()', ->
-    it 'should get a page if it exists', (done) ->
-      page.get('asdf', (e, got) ->
-        if e then throw e
-        got.title.should.equal 'Asdf'
-        done()
-      )
-    it 'should copy a page from default if nonexistant in db', (done) ->
-      page.get('welcome-visitors', (e, got) ->
-        if e then throw e
-        got.title.should.equal 'Welcome Visitors'
-        done()
-      )
-    # note: here we assume the wiki-plugin-activity repo has been cloned into an adjacent directory
-    it 'should copy a page from plugins if nonexistant in db', (done) ->
-      page.get('recent-changes', (e, got) ->
-        if e then throw e
-        got.title.should.equal 'Recent Changes'
-        done()
-      )
-    # note: here we assume the wiki-plugin-activity repo has been cloned into an adjacent directory
-    it 'should mark a page from plugins with the plugin name', (done) ->
-      page.get('recent-changes', (e, got) ->
-        if e then throw e
-        got.plugin.should.equal 'activity'
-        done()
-      )
-    it 'should create a page if it exists nowhere', (done) ->
-      page.get(random(), (e, got) ->
-        if e then throw e
-        got.should.equal('Page not found')
-        done()
-      )
-    it 'should eventually write the page to disk', (done) ->
-      test = ->
-        fs.readFile(path.join(argv.db, 'asdf'), (err, data) ->
-          if err then throw err
-          readPage = JSON.parse(data)
-          page.get('asdf', (e, got) ->
-            readPage.title.should.equal got.title
-            done()
-          )
-        )
-      if page.isWorking()
-        page.on('finished', -> test())
-      else test()

package/test/random.coffee

@@ -1,8 +0,0 @@
-random = require '../lib/random_id'
-
-describe 'random', ->
-  describe '#random_id', ->
-    it 'should not be the same twice', ->
-      random().should.not.equal random()
-    it 'should be 16 digits', ->
-      random().length.should.equal 16

package/test/server.coffee

@@ -1,228 +0,0 @@
-request = require 'supertest'
-fs = require 'fs'
-server = require '..'
-path = require 'path'
-random = require '../lib/random_id'
-testid = random()
-argv = require('../lib/defaultargs.coffee')({data: path.join('/tmp', 'sfwtests', testid), packageDir: path.join(__dirname, '..', 'node_modules'), port: 55557, security_legacy: true})
-
-describe 'server', ->
-  app = {}
-  before((done) ->
-    # as starting the server this was does not create a sitemap file, create an empty one
-    sitemapLoc = path.join('/tmp', 'sfwtests', testid, 'status', 'sitemap.json')
-    fs.mkdirSync path.join('/tmp', 'sfwtests', testid)
-    fs.mkdirSync path.join('/tmp', 'sfwtests', testid, 'status')
-    fs.writeFileSync sitemapLoc, JSON.stringify([])
-
-    app = server(argv)
-    app.once("owner-set", ->
-      app.listen app.startOpts.port, app.startOpts.host, done
-    ))
-
-
-  request = request('http://localhost:55557')
-
-  # location of the test page
-  loc = path.join('/tmp', 'sfwtests', testid, 'pages', 'adsf-test-page')
-
-  it 'factories should return a list of plugin', () ->
-    await request
-      .get('/system/factories.json')
-      .expect(200)
-      .expect('Content-Type', /json/)
-      .then (res) ->
-        res.body[1].name.should.equal('Video')
-        res.body[1].category.should.equal('format')
-
-  it 'new site should have an empty list of pages', () ->
-    await request
-      .get('/system/slugs.json')
-      .expect(200)
-      .expect('Content-Type', /json/)
-      .then (res) ->
-        res.body.should.be.empty
-      , (error) ->
-        throw error
-      .catch (error) ->
-        throw error
-
-  it 'should create a page', () ->
-    body = JSON.stringify({
-      type: 'create'
-      item: {
-        title: "Asdf Test Page"
-        story: [
-          {id: "a1", type: "paragraph", text: "this is the first paragraph"}
-          {id: "a2", type: "paragraph", text: "this is the second paragraph"}
-          {id: "a3", type: "paragraph", text: "this is the third paragraph"}
-          {id: "a4", type: "paragraph", text: "this is the fourth paragraph"}
-          ]
-      }
-      date: 1234567890123
-      })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(200)
-      .catch (err) ->
-        throw err
-
-  it 'should move the paragraphs to the order given ', () ->
-    body = '{ "type": "move", "order": [ "a1", "a3", "a2", "a4"] }'
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(200)
-      .then (res) ->
-        if err
-          throw err
-        try
-          page = JSON.parse(fs.readFileSync(loc))
-        catch err
-          throw err
-        page.story[1].id.should.equal('a3')
-        page.story[2].id.should.equal('a2')
-        page.journal[1].type.should.equal('move')
-      , (err) ->
-        throw err
-      .catch (err) ->
-        throw err
-
-  it 'should add a paragraph', () ->
-    body = JSON.stringify({
-      type: 'add'
-      after: 'a2'
-      item: {id: 'a5', type: 'paragraph', text: 'this is the NEW paragrpah'}
-    })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(200)
-      .then (res) ->
-        try
-          page = JSON.parse(fs.readFileSync(loc))
-        catch err
-          throw err
-        page.story.length.should.equal(5)
-        page.story[3].id.should.equal('a5')
-        page.journal[2].type.should.equal('add')
-      , (err) ->
-        throw err
-      .catch (err) ->
-        throw err
-
-  it 'should remove a paragraph with given id', () ->
-    body = JSON.stringify({
-      type: 'remove'
-      id: 'a2'
-    })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(200)
-      .then (res) ->
-        try
-          page = JSON.parse(fs.readFileSync(loc))
-        catch err
-          throw err
-        page.story.length.should.equal(4)
-        page.story[1].id.should.equal('a3')
-        page.story[2].id.should.not.equal('a2')
-        page.story[2].id.should.equal('a5')
-        page.journal[3].type.should.equal('remove')
-      , (err) ->
-        throw err
-      .catch (err) ->
-        throw err
-
-  it 'should edit a paragraph in place', () ->
-    body = JSON.stringify({
-      type: 'edit'
-      item: {id: 'a3', type: 'paragraph', text: 'edited'}
-      id: 'a3'
-    })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(200)
-      .then (res) ->
-        try
-          page = JSON.parse(fs.readFileSync(loc))
-        catch err
-          throw err
-        page.story[1].text.should.equal('edited')
-        page.journal[4].type.should.equal('edit')
-      , (err) ->
-        throw err
-      .catch (err) ->
-        throw err
-
-  it 'should default to no change', () ->
-    body = JSON.stringify({
-      type: 'asdf'
-      })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(500)
-      .then (res) ->
-        try
-          page = JSON.parse(fs.readFileSync(loc))
-        catch err
-          throw err
-        page.story.length.should.equal(4)
-        page.journal.length.should.equal(5)
-        page.story[0].id.should.equal('a1')
-        page.story[3].text.should.equal('this is the fourth paragraph')
-        page.journal[4].type.should.equal('edit')
-      , (err) ->
-        throw err
-      .catch (err) ->
-        throw err
-
-  it 'should refuse to create over a page', () ->
-    body = JSON.stringify({
-      type: 'create'
-      item: { title: 'Doh'}
-      id: 'c1'
-    })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(409)
-      .then (res) ->
-        try
-          page = JSON.parse(fs.readFileSync(loc))
-        catch err
-          throw err
-        page.title.should.not.equal('Doh')
-      , (err) ->
-        throw err
-      .catch (err) ->
-        throw err
-
-  it 'site should now have one page', () ->
-    request
-      .get('/system/slugs.json')
-      .expect(200)
-      .expect('Content-Type', /json/)
-      .then (res) ->
-        res.body.length.should.equal[1]
-        res.body[0].should.equal['adsf-test-page']
-      , (err) ->
-        throw err
-      .catch (err) ->
-        throw err
-
-
-
-  after( ->
-    app.close() if app.close)

package/test/sitemap.coffee

@@ -1,110 +0,0 @@
-request = require 'supertest'
-fs = require 'fs'
-server = require '..'
-path = require 'path'
-random = require '../lib/random_id'
-testid = random()
-argv = require('../lib/defaultargs.coffee')({data: path.join('/tmp', 'sfwtests', testid), port: 55556, security_legacy: true})
-
-describe 'sitemap', ->
-  app = {}
-  runningServer = null
-  beforeEach((done) ->
-    app = server(argv)
-    app.once("owner-set", ->
-      runningServer = app.listen app.startOpts.port, app.startOpts.host, done
-    ))
-  afterEach () ->
-    runningServer.close()
-
-
-  request = request('http://localhost:55556')
-  fs.mkdirSync path.join('/tmp', 'sfwtests', testid, 'pages'), {recursive: true}
-
-  # location of the sitemap
-  sitemapLoc = path.join('/tmp', 'sfwtests', testid, 'status', 'sitemap.json')
-
-  it 'new site should have an empty sitemap', () ->
-    request
-    .get('/system/sitemap.json')
-    .expect(200)
-    .expect('Content-Type', /json/)
-    .then (res) ->
-      res.body.should.be.empty
-    , (err) ->
-      throw err
-
-
-  it 'creating a page should add it to the sitemap', () ->
-    body = JSON.stringify({
-      type: 'create'
-      item: {
-        title: "Asdf Test Page"
-        story: [
-          {id: "a1", type: "paragraph", text: "this is the first paragraph"}
-          {id: "a2", type: "paragraph", text: "this is the second paragraph"}
-          {id: "a3", type: "paragraph", text: "this is the third paragraph"}
-          {id: "a4", type: "paragraph", text: "this is the fourth paragraph"}
-          ]
-      }
-      date: 1234567890123
-      })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(200)
-      .then (res) ->
-        # sitemap update does not happen until after the put has returned, so wait for it to finish
-        app.sitemaphandler.once 'finished', ->
-          try
-            sitemap = JSON.parse(fs.readFileSync(sitemapLoc))
-          catch err
-            throw err
-          sitemap[0].slug.should.equal['adsf-test-page']
-          sitemap[0].synopsis.should.equal['this is the first paragraph']
-      , (err) ->
-        throw err
-
-  it 'synopsis should reflect edit to first paragraph', () ->
-    body = JSON.stringify({
-      type: 'edit'
-      item: {id: 'a1', type: 'paragraph', text: 'edited'}
-      id: 'a1'
-    })
-
-    request
-      .put('/page/adsf-test-page/action')
-      .send("action=" + body)
-      .expect(200)
-      .then (res) ->
-        app.sitemaphandler.once 'finished', ->
-          try
-            sitemap = JSON.parse(fs.readFileSync(sitemapLoc))
-          catch err
-            throw err
-          sitemap[0].slug.should.equal['adsf-test-page']
-          sitemap[0].synopsis.should.equal['edited']
-      , (err) ->
-        throw err
-
-  it 'deleting a page should remove it from the sitemap', () ->
-
-    request
-      .delete('/adsf-test-page.json')
-      .send()
-      .expect(200)
-      .then (res) ->
-        app.sitemaphandler.once 'finished', ->
-          try
-            sitemap = JSON.parse(fs.readFileSync(sitemapLoc))
-          catch error
-            throw err
-          sitemap.should.be.empty
-      , (err) ->
-        throw err
-
-
-
-  after( ->
-    app.close() if app.close)