ts-wasms 1.0.6 → 2.0.0

package/out/c/indents.scm

@@ -0,0 +1,99 @@
+[
+  (compound_statement)
+  (field_declaration_list)
+  (case_statement)
+  (enumerator_list)
+  (compound_literal_expression)
+  (initializer_list)
+  (init_declarator)
+] @indent.begin
+
+; With current indent logic, if we capture expression_statement with @indent.begin
+; It will be affected by _parent_ node with error subnodes deep down the tree
+; So narrow indent capture to check for error inside expression statement only,
+(expression_statement
+  (_) @indent.begin
+  ";" @indent.end)
+
+(ERROR
+  "for"
+  "(" @indent.begin
+  ";"
+  ";"
+  ")" @indent.end)
+
+((for_statement
+  body: (_) @_body) @indent.begin
+  (#not-kind-eq? @_body "compound_statement"))
+
+(while_statement
+  condition: (_) @indent.begin)
+
+((while_statement
+  body: (_) @_body) @indent.begin
+  (#not-kind-eq? @_body "compound_statement"))
+
+((if_statement)
+  .
+  (ERROR
+    "else" @indent.begin))
+
+(if_statement
+  condition: (_) @indent.begin)
+
+; Supports if without braces (but not both if-else without braces)
+(if_statement
+  consequence: (_
+    ";" @indent.end) @_consequence
+  (#not-kind-eq? @_consequence "compound_statement")
+  alternative: (else_clause
+    "else" @indent.branch
+    [
+      (if_statement
+        (compound_statement) @indent.dedent)? @indent.dedent
+      (compound_statement)? @indent.dedent
+      (_)? @indent.dedent
+    ])?) @indent.begin
+
+(else_clause
+  (_
+    .
+    "{" @indent.branch))
+
+(compound_statement
+  "}" @indent.end)
+
+[
+  ")"
+  "}"
+  (statement_identifier)
+] @indent.branch
+
+[
+  "#define"
+  "#ifdef"
+  "#ifndef"
+  "#elif"
+  "#if"
+  "#else"
+  "#endif"
+] @indent.zero
+
+[
+  (preproc_arg)
+  (string_literal)
+] @indent.ignore
+
+((ERROR
+  (parameter_declaration)) @indent.align
+  (#set! indent.open_delimiter "(")
+  (#set! indent.close_delimiter ")"))
+
+([
+  (argument_list)
+  (parameter_list)
+] @indent.align
+  (#set! indent.open_delimiter "(")
+  (#set! indent.close_delimiter ")"))
+
+(comment) @indent.auto

package/out/c/injections.scm

@@ -0,0 +1,128 @@
+((preproc_arg) @injection.content
+  (#set! injection.self))
+
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((comment) @injection.content
+  (#match? @injection.content "/\\*!([a-zA-Z]+:)?re2c")
+  (#set! injection.language "re2c"))
+
+((comment) @injection.content
+  (#lua-match? @injection.content "/[*/][!*/]<?[^a-zA-Z]")
+  (#set! injection.language "doxygen"))
+
+((call_expression
+  function: (identifier) @_function
+  arguments: (argument_list
+    .
+    [
+      (string_literal
+        (string_content) @injection.content)
+      (concatenated_string
+        (string_literal
+          (string_content) @injection.content))
+    ]))
+  ; format-ignore
+  (#any-of? @_function 
+    "printf" "printf_s"
+    "vprintf" "vprintf_s"
+    "scanf" "scanf_s"
+    "vscanf" "vscanf_s"
+    "wprintf" "wprintf_s"
+    "vwprintf" "vwprintf_s"
+    "wscanf" "wscanf_s"
+    "vwscanf" "vwscanf_s"
+    "cscanf" "_cscanf"
+    "printw"
+    "scanw")
+  (#set! injection.language "printf"))
+
+((call_expression
+  function: (identifier) @_function
+  arguments: (argument_list
+    (_)
+    .
+    [
+      (string_literal
+        (string_content) @injection.content)
+      (concatenated_string
+        (string_literal
+          (string_content) @injection.content))
+    ]))
+  ; format-ignore
+  (#any-of? @_function 
+    "fprintf" "fprintf_s"
+    "sprintf"
+    "dprintf"
+    "fscanf" "fscanf_s"
+    "sscanf" "sscanf_s"
+    "vsscanf" "vsscanf_s"
+    "vfprintf" "vfprintf_s"
+    "vsprintf"
+    "vdprintf"
+    "fwprintf" "fwprintf_s"
+    "vfwprintf" "vfwprintf_s"
+    "fwscanf" "fwscanf_s"
+    "swscanf" "swscanf_s"
+    "vswscanf" "vswscanf_s"
+    "vfscanf" "vfscanf_s"
+    "vfwscanf" "vfwscanf_s"
+    "wprintw"
+    "vw_printw" "vwprintw"
+    "wscanw"
+    "vw_scanw" "vwscanw")
+  (#set! injection.language "printf"))
+
+((call_expression
+  function: (identifier) @_function
+  arguments: (argument_list
+    (_)
+    .
+    (_)
+    .
+    [
+      (string_literal
+        (string_content) @injection.content)
+      (concatenated_string
+        (string_literal
+          (string_content) @injection.content))
+    ]))
+  ; format-ignore
+  (#any-of? @_function 
+    "sprintf_s"
+    "snprintf" "snprintf_s"
+    "vsprintf_s"
+    "vsnprintf" "vsnprintf_s"
+    "swprintf" "swprintf_s"
+    "snwprintf_s"
+    "vswprintf" "vswprintf_s"
+    "vsnwprintf_s"
+    "mvprintw"
+    "mvscanw")
+  (#set! injection.language "printf"))
+
+((call_expression
+  function: (identifier) @_function
+  arguments: (argument_list
+    (_)
+    .
+    (_)
+    .
+    (_)
+    .
+    [
+      (string_literal
+        (string_content) @injection.content)
+      (concatenated_string
+        (string_literal
+          (string_content) @injection.content))
+    ]))
+  (#any-of? @_function "mvwprintw" "mvwscanw")
+  (#set! injection.language "printf"))
+
+; TODO: add when asm is added
+; (gnu_asm_expression assembly_code: (string_literal) @injection.content
+; (#set! injection.language "asm"))
+; (gnu_asm_expression assembly_code: (concatenated_string (string_literal) @injection.content)
+; (#set! injection.language "asm"))

package/out/c/locals.scm

@@ -0,0 +1,67 @@
+; Functions definitions
+(function_declarator
+  declarator: (identifier) @local.definition.function)
+
+(preproc_function_def
+  name: (identifier) @local.definition.macro) @local.scope
+
+(preproc_def
+  name: (identifier) @local.definition.macro)
+
+(pointer_declarator
+  declarator: (identifier) @local.definition.var)
+
+(parameter_declaration
+  declarator: (identifier) @local.definition.parameter)
+
+(init_declarator
+  declarator: (identifier) @local.definition.var)
+
+(array_declarator
+  declarator: (identifier) @local.definition.var)
+
+(declaration
+  declarator: (identifier) @local.definition.var)
+
+(enum_specifier
+  name: (_) @local.definition.type
+  (enumerator_list
+    (enumerator
+      name: (identifier) @local.definition.var)))
+
+; Type / Struct / Enum
+(field_declaration
+  declarator: (field_identifier) @local.definition.field)
+
+(type_definition
+  declarator: (type_identifier) @local.definition.type)
+
+(struct_specifier
+  name: (type_identifier) @local.definition.type)
+
+; goto
+(labeled_statement
+  (statement_identifier) @local.definition)
+
+; References
+(identifier) @local.reference
+
+((field_identifier) @local.reference
+  (#set! reference.kind "field"))
+
+((type_identifier) @local.reference
+  (#set! reference.kind "type"))
+
+(goto_statement
+  (statement_identifier) @local.reference)
+
+; Scope
+[
+  (for_statement)
+  (if_statement)
+  (while_statement)
+  (translation_unit)
+  (function_definition)
+  (compound_statement) ; a block in curly braces
+  (struct_specifier)
+] @local.scope

package/out/clojure/folds.scm

@@ -0,0 +1,2 @@
+(source
+  (list_lit) @fold)

package/out/clojure/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/clojure/locals.scm

@@ -0,0 +1 @@
+; placeholder file to get incremental selection to work

package/out/cmake/folds.scm

@@ -0,0 +1,8 @@
+[
+  (if_condition)
+  (foreach_loop)
+  (while_loop)
+  (function_def)
+  (macro_def)
+  (block_def)
+] @fold

package/out/cmake/highlights.scm

@@ -0,0 +1,221 @@
+(normal_command
+  (identifier)
+  (argument_list
+    (argument
+      (unquoted_argument)) @constant)
+  (#lua-match? @constant "^[%u@][%u%d_]+$"))
+
+[
+  (quoted_argument)
+  (bracket_argument)
+] @string
+
+(variable_ref) @none
+
+(variable) @variable
+
+[
+  (bracket_comment)
+  (line_comment)
+] @comment @spell
+
+(normal_command
+  (identifier) @function)
+
+[
+  "ENV"
+  "CACHE"
+] @module
+
+[
+  "$"
+  "{"
+  "}"
+] @punctuation.special
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+[
+  (function)
+  (endfunction)
+  (macro)
+  (endmacro)
+] @keyword.function
+
+[
+  (if)
+  (elseif)
+  (else)
+  (endif)
+] @keyword.conditional
+
+[
+  (foreach)
+  (endforeach)
+  (while)
+  (endwhile)
+] @keyword.repeat
+
+(normal_command
+  (identifier) @keyword.repeat
+  (#match? @keyword.repeat "^([cC][oO][nN][tT][iI][nN][uU][eE]|[bB][rR][eE][aA][kK])$"))
+
+(normal_command
+  (identifier) @keyword.return
+  (#match? @keyword.return "^[rR][eE][tT][uU][rR][nN]$"))
+
+(function_command
+  (function)
+  (argument_list
+    .
+    (argument) @function
+    (argument)* @variable.parameter))
+
+(macro_command
+  (macro)
+  (argument_list
+    .
+    (argument) @function.macro
+    (argument)* @variable.parameter))
+
+(block_def
+  (block_command
+    (block) @function.builtin
+    (argument_list
+      (argument
+        (unquoted_argument) @constant
+        (#any-of? @constant "SCOPE_FOR" "POLICIES" "VARIABLES" "PROPAGATE")
+      )*
+    )?
+  )
+  (endblock_command (endblock) @function.builtin))
+
+((argument) @boolean
+  (#match? @boolean "^(1|[oO][nN]|[yY][eE][sS]|[tT][rR][uU][eE]|[yY]|0|[oO][fF][fF]|[nN][oO]|[fF][aA][lL][sS][eE]|[nN]|[iI][gG][nN][oO][rR][eE]|[nN][oO][tT][fF][oO][uU][nN][dD]|.*-[nN][oO][tT][fF][oO][uU][nN][dD])$"))
+
+(if_command
+  (if)
+  (argument_list
+    (argument) @keyword.operator)
+  (#any-of? @keyword.operator
+    "NOT" "AND" "OR" "COMMAND" "POLICY" "TARGET" "TEST" "DEFINED" "IN_LIST" "EXISTS" "IS_NEWER_THAN"
+    "IS_DIRECTORY" "IS_SYMLINK" "IS_ABSOLUTE" "MATCHES" "LESS" "GREATER" "EQUAL" "LESS_EQUAL"
+    "GREATER_EQUAL" "STRLESS" "STRGREATER" "STREQUAL" "STRLESS_EQUAL" "STRGREATER_EQUAL"
+    "VERSION_LESS" "VERSION_GREATER" "VERSION_EQUAL" "VERSION_LESS_EQUAL" "VERSION_GREATER_EQUAL"))
+
+(elseif_command
+  (elseif)
+  (argument_list
+    (argument) @keyword.operator)
+  (#any-of? @keyword.operator
+    "NOT" "AND" "OR" "COMMAND" "POLICY" "TARGET" "TEST" "DEFINED" "IN_LIST" "EXISTS" "IS_NEWER_THAN"
+    "IS_DIRECTORY" "IS_SYMLINK" "IS_ABSOLUTE" "MATCHES" "LESS" "GREATER" "EQUAL" "LESS_EQUAL"
+    "GREATER_EQUAL" "STRLESS" "STRGREATER" "STREQUAL" "STRLESS_EQUAL" "STRGREATER_EQUAL"
+    "VERSION_LESS" "VERSION_GREATER" "VERSION_EQUAL" "VERSION_LESS_EQUAL" "VERSION_GREATER_EQUAL"))
+
+(normal_command
+  (identifier) @function.builtin
+  (#match? @function.builtin
+    "^([cC][mM][aA][kK][eE]_[hH][oO][sS][tT]_[sS][yY][sS][tT][eE][mM]_[iI][nN][fF][oO][rR][mM][aA][tT][iI][oO][nN]|[cC][mM][aA][kK][eE]_[lL][aA][nN][gG][uU][aA][gG][eE]|[cC][mM][aA][kK][eE]_[mM][iI][nN][iI][mM][uU][mM]_[rR][eE][qQ][uU][iI][rR][eE][dD]|[cC][mM][aA][kK][eE]_[pP][aA][rR][sS][eE]_[aA][rR][gG][uU][mM][eE][nN][tT][sS]|[cC][mM][aA][kK][eE]_[pP][aA][tT][hH]|[cC][mM][aA][kK][eE]_[pP][oO][lL][iI][cC][yY]|[cC][oO][nN][fF][iI][gG][uU][rR][eE]_[fF][iI][lL][eE]|[eE][xX][eE][cC][uU][tT][eE]_[pP][rR][oO][cC][eE][sS][sS]|[fF][iI][lL][eE]|[fF][iI][nN][dD]_[fF][iI][lL][eE]|[fF][iI][nN][dD]_[lL][iI][bB][rR][aA][rR][yY]|[fF][iI][nN][dD]_[pP][aA][cC][kK][aA][gG][eE]|[fF][iI][nN][dD]_[pP][aA][tT][hH]|[fF][iI][nN][dD]_[pP][rR][oO][gG][rR][aA][mM]|[fF][oO][rR][eE][aA][cC][hH]|[gG][eE][tT]_[cC][mM][aA][kK][eE]_[pP][rR][oO][pP][eE][rR][tT][yY]|[gG][eE][tT]_[dD][iI][rR][eE][cC][tT][oO][rR][yY]_[pP][rR][oO][pP][eE][rR][tT][yY]|[gG][eE][tT]_[fF][iI][lL][eE][nN][aA][mM][eE]_[cC][oO][mM][pP][oO][nN][eE][nN][tT]|[gG][eE][tT]_[pP][rR][oO][pP][eE][rR][tT][yY]|[iI][nN][cC][lL][uU][dD][eE]|[iI][nN][cC][lL][uU][dD][eE]_[gG][uU][aA][rR][dD]|[lL][iI][sS][tT]|[mM][aA][cC][rR][oO]|[mM][aA][rR][kK]_[aA][sS]_[aA][dD][vV][aA][nN][cC][eE][dD]|[mM][aA][tT][hH]|[mM][eE][sS][sS][aA][gG][eE]|[oO][pP][tT][iI][oO][nN]|[sS][eE][pP][aA][rR][aA][tT][eE]_[aA][rR][gG][uU][mM][eE][nN][tT][sS]|[sS][eE][tT]|[sS][eE][tT]_[dD][iI][rR][eE][cC][tT][oO][rR][yY]_[pP][rR][oO][pP][eE][rR][tT][iI][eE][sS]|[sS][eE][tT]_[pP][rR][oO][pP][eE][rR][tT][yY]|[sS][iI][tT][eE]_[nN][aA][mM][eE]|[sS][tT][rR][iI][nN][gG]|[uU][nN][sS][eE][tT]|[vV][aA][rR][iI][aA][bB][lL][eE]_[wW][aA][tT][cC][hH]|[aA][dD][dD]_[cC][oO][mM][pP][iI][lL][eE]_[dD][eE][fF][iI][nN][iI][tT][iI][oO][nN][sS]|[aA][dD][dD]_[cC][oO][mM][pP][iI][lL][eE]_[oO][pP][tT][iI][oO][nN][sS]|[aA][dD][dD]_[cC][uU][sS][tT][oO][mM]_[cC][oO][mM][mM][aA][nN][dD]|[aA][dD][dD]_[cC][uU][sS][tT][oO][mM]_[tT][aA][rR][gG][eE][tT]|[aA][dD][dD]_[dD][eE][fF][iI][nN][iI][tT][iI][oO][nN][sS]|[aA][dD][dD]_[dD][eE][pP][eE][nN][dD][eE][nN][cC][iI][eE][sS]|[aA][dD][dD]_[eE][xX][eE][cC][uU][tT][aA][bB][lL][eE]|[aA][dD][dD]_[lL][iI][bB][rR][aA][rR][yY]|[aA][dD][dD]_[lL][iI][nN][kK]_[oO][pP][tT][iI][oO][nN][sS]|[aA][dD][dD]_[sS][uU][bB][dD][iI][rR][eE][cC][tT][oO][rR][yY]|[aA][dD][dD]_[tT][eE][sS][tT]|[aA][uU][xX]_[sS][oO][uU][rR][cC][eE]_[dD][iI][rR][eE][cC][tT][oO][rR][yY]|[bB][uU][iI][lL][dD]_[cC][oO][mM][mM][aA][nN][dD]|[cC][rR][eE][aA][tT][eE]_[tT][eE][sS][tT]_[sS][oO][uU][rR][cC][eE][lL][iI][sS][tT]|[dD][eE][fF][iI][nN][eE]_[pP][rR][oO][pP][eE][rR][tT][yY]|[eE][nN][aA][bB][lL][eE]_[lL][aA][nN][gG][uU][aA][gG][eE]|[eE][nN][aA][bB][lL][eE]_[tT][eE][sS][tT][iI][nN][gG]|[eE][xX][pP][oO][rR][tT]|[fF][lL][tT][kK]_[wW][rR][aA][pP]_[uU][iI]|[gG][eE][tT]_[sS][oO][uU][rR][cC][eE]_[fF][iI][lL][eE]_[pP][rR][oO][pP][eE][rR][tT][yY]|[gG][eE][tT]_[tT][aA][rR][gG][eE][tT]_[pP][rR][oO][pP][eE][rR][tT][yY]|[gG][eE][tT]_[tT][eE][sS][tT]_[pP][rR][oO][pP][eE][rR][tT][yY]|[iI][nN][cC][lL][uU][dD][eE]_[dD][iI][rR][eE][cC][tT][oO][rR][iI][eE][sS]|[iI][nN][cC][lL][uU][dD][eE]_[eE][xX][tT][eE][rR][nN][aA][lL]_[mM][sS][pP][rR][oO][jJ][eE][cC][tT]|[iI][nN][cC][lL][uU][dD][eE]_[rR][eE][gG][uU][lL][aA][rR]_[eE][xX][pP][rR][eE][sS][sS][iI][oO][nN]|[iI][nN][sS][tT][aA][lL][lL]|[lL][iI][nN][kK]_[dD][iI][rR][eE][cC][tT][oO][rR][iI][eE][sS]|[lL][iI][nN][kK]_[lL][iI][bB][rR][aA][rR][iI][eE][sS]|[lL][oO][aA][dD]_[cC][aA][cC][hH][eE]|[pP][rR][oO][jJ][eE][cC][tT]|[rR][eE][mM][oO][vV][eE]_[dD][eE][fF][iI][nN][iI][tT][iI][oO][nN][sS]|[sS][eE][tT]_[sS][oO][uU][rR][cC][eE]_[fF][iI][lL][eE][sS]_[pP][rR][oO][pP][eE][rR][tT][iI][eE][sS]|[sS][eE][tT]_[tT][aA][rR][gG][eE][tT]_[pP][rR][oO][pP][eE][rR][tT][iI][eE][sS]|[sS][eE][tT]_[tT][eE][sS][tT][sS]_[pP][rR][oO][pP][eE][rR][tT][iI][eE][sS]|[sS][oO][uU][rR][cC][eE]_[gG][rR][oO][uU][pP]|[tT][aA][rR][gG][eE][tT]_[cC][oO][mM][pP][iI][lL][eE]_[dD][eE][fF][iI][nN][iI][tT][iI][oO][nN][sS]|[tT][aA][rR][gG][eE][tT]_[cC][oO][mM][pP][iI][lL][eE]_[fF][eE][aA][tT][uU][rR][eE][sS]|[tT][aA][rR][gG][eE][tT]_[cC][oO][mM][pP][iI][lL][eE]_[oO][pP][tT][iI][oO][nN][sS]|[tT][aA][rR][gG][eE][tT]_[iI][nN][cC][lL][uU][dD][eE]_[dD][iI][rR][eE][cC][tT][oO][rR][iI][eE][sS]|[tT][aA][rR][gG][eE][tT]_[lL][iI][nN][kK]_[dD][iI][rR][eE][cC][tT][oO][rR][iI][eE][sS]|[tT][aA][rR][gG][eE][tT]_[lL][iI][nN][kK]_[lL][iI][bB][rR][aA][rR][iI][eE][sS]|[tT][aA][rR][gG][eE][tT]_[lL][iI][nN][kK]_[oO][pP][tT][iI][oO][nN][sS]|[tT][aA][rR][gG][eE][tT]_[pP][rR][eE][cC][oO][mM][pP][iI][lL][eE]_[hH][eE][aA][dD][eE][rR][sS]|[tT][aA][rR][gG][eE][tT]_[sS][oO][uU][rR][cC][eE][sS]|[tT][rR][yY]_[cC][oO][mM][pP][iI][lL][eE]|[tT][rR][yY]_[rR][uU][nN]|[cC][tT][eE][sS][tT]_[bB][uU][iI][lL][dD]|[cC][tT][eE][sS][tT]_[cC][oO][nN][fF][iI][gG][uU][rR][eE]|[cC][tT][eE][sS][tT]_[cC][oO][vV][eE][rR][aA][gG][eE]|[cC][tT][eE][sS][tT]_[eE][mM][pP][tT][yY]_[bB][iI][nN][aA][rR][yY]_[dD][iI][rR][eE][cC][tT][oO][rR][yY]|[cC][tT][eE][sS][tT]_[mM][eE][mM][cC][hH][eE][cC][kK]|[cC][tT][eE][sS][tT]_[rR][eE][aA][dD]_[cC][uU][sS][tT][oO][mM]_[fF][iI][lL][eE][sS]|[cC][tT][eE][sS][tT]_[rR][uU][nN]_[sS][cC][rR][iI][pP][tT]|[cC][tT][eE][sS][tT]_[sS][lL][eE][eE][pP]|[cC][tT][eE][sS][tT]_[sS][tT][aA][rR][tT]|[cC][tT][eE][sS][tT]_[sS][uU][bB][mM][iI][tT]|[cC][tT][eE][sS][tT]_[tT][eE][sS][tT]|[cC][tT][eE][sS][tT]_[uU][pP][dD][aA][tT][eE]|[cC][tT][eE][sS][tT]_[uU][pP][lL][oO][aA][dD])$"))
+
+(normal_command
+  (identifier) @_function
+  (argument_list
+    .
+    (argument) @variable)
+  (#match? @_function "^[sS][eE][tT]$"))
+
+(normal_command
+  (identifier) @_function
+  (#match? @_function "^[sS][eE][tT]$")
+  (argument_list
+    .
+    (argument)
+    ((argument) @_cache @keyword.modifier
+      .
+      (argument) @_type @type
+      (#any-of? @_cache "CACHE")
+      (#any-of? @_type "BOOL" "FILEPATH" "PATH" "STRING" "INTERNAL"))))
+
+(normal_command
+  (identifier) @_function
+  (#match? @_function "^[uU][nN][sS][eE][tT]$")
+  (argument_list
+    .
+    (argument)
+    (argument) @keyword.modifier
+    (#any-of? @keyword.modifier "CACHE" "PARENT_SCOPE")))
+
+(normal_command
+  (identifier) @_function
+  (#match? @_function "^[lL][iI][sS][tT]$")
+  (argument_list
+    .
+    (argument) @constant
+    (#any-of? @constant "LENGTH" "GET" "JOIN" "SUBLIST" "FIND")
+    .
+    (argument) @variable
+    (argument) @variable .))
+
+(normal_command
+  (identifier) @_function
+  (#match? @_function "^[lL][iI][sS][tT]$")
+  (argument_list
+    .
+    (argument) @constant
+    .
+    (argument) @variable
+    (#any-of? @constant
+      "APPEND" "FILTER" "INSERT" "POP_BACK" "POP_FRONT" "PREPEND" "REMOVE_ITEM" "REMOVE_AT"
+      "REMOVE_DUPLICATES" "REVERSE" "SORT")))
+
+(normal_command
+  (identifier) @_function
+  (#match? @_function "^[lL][iI][sS][tT]$")
+  (argument_list
+    .
+    (argument) @_transform @constant
+    .
+    (argument) @variable
+    .
+    (argument) @_action @constant
+    (#eq? @_transform "TRANSFORM")
+    (#any-of? @_action "APPEND" "PREPEND" "TOUPPER" "TOLOWER" "STRIP" "GENEX_STRIP" "REPLACE")))
+
+(normal_command
+  (identifier) @_function
+  (#match? @_function "^[lL][iI][sS][tT]$")
+  (argument_list
+    .
+    (argument) @_transform @constant
+    .
+    (argument) @variable
+    .
+    (argument) @_action @constant
+    .
+    (argument)? @_selector @constant
+    (#eq? @_transform "TRANSFORM")
+    (#any-of? @_action "APPEND" "PREPEND" "TOUPPER" "TOLOWER" "STRIP" "GENEX_STRIP" "REPLACE")
+    (#any-of? @_selector "AT" "FOR" "REGEX")))
+
+(normal_command
+  (identifier) @_function
+  (#match? @_function "^[lL][iI][sS][tT]$")
+  (argument_list
+    .
+    (argument) @_transform @constant
+    (argument) @constant
+    .
+    (argument) @variable
+    (#eq? @_transform "TRANSFORM")
+    (#eq? @constant "OUTPUT_VARIABLE")))
+
+(escape_sequence) @string.escape
+
+((source_file
+  .
+  (line_comment) @keyword.directive @nospell)
+  (#lua-match? @keyword.directive "^#!/"))

package/out/cmake/indents.scm

@@ -0,0 +1,26 @@
+[
+  (normal_command)
+  (if_condition)
+  (foreach_loop)
+  (while_loop)
+  (function_def)
+  (macro_def)
+  (block_def)
+] @indent.begin
+
+[
+  (elseif_command)
+  (else_command)
+  (endif_command)
+  (endforeach_command)
+  (endwhile_command)
+  (endfunction_command)
+  (endmacro_command)
+  (endblock_command)
+] @indent.branch
+
+")" @indent.branch
+
+")" @indent.end
+
+(argument_list) @indent.auto

package/out/cmake/injections.scm

@@ -0,0 +1,5 @@
+([
+  (bracket_comment)
+  (line_comment)
+] @injection.content
+  (#set! injection.language "comment"))

package/out/comment/highlights.scm

@@ -0,0 +1,49 @@
+((tag
+  (name) @comment.todo @nospell
+  ("(" @punctuation.bracket
+    (user) @constant
+    ")" @punctuation.bracket)?
+  ":" @punctuation.delimiter)
+  (#any-of? @comment.todo "TODO" "WIP"))
+
+("text" @comment.todo @nospell
+  (#any-of? @comment.todo "TODO" "WIP"))
+
+((tag
+  (name) @comment.note @nospell
+  ("(" @punctuation.bracket
+    (user) @constant
+    ")" @punctuation.bracket)?
+  ":" @punctuation.delimiter)
+  (#any-of? @comment.note "NOTE" "XXX" "INFO" "DOCS" "PERF" "TEST"))
+
+("text" @comment.note @nospell
+  (#any-of? @comment.note "NOTE" "XXX" "INFO" "DOCS" "PERF" "TEST"))
+
+((tag
+  (name) @comment.warning @nospell
+  ("(" @punctuation.bracket
+    (user) @constant
+    ")" @punctuation.bracket)?
+  ":" @punctuation.delimiter)
+  (#any-of? @comment.warning "HACK" "WARNING" "WARN" "FIX"))
+
+("text" @comment.warning @nospell
+  (#any-of? @comment.warning "HACK" "WARNING" "WARN" "FIX"))
+
+((tag
+  (name) @comment.error @nospell
+  ("(" @punctuation.bracket
+    (user) @constant
+    ")" @punctuation.bracket)?
+  ":" @punctuation.delimiter)
+  (#any-of? @comment.error "FIXME" "BUG" "ERROR"))
+
+("text" @comment.error @nospell
+  (#any-of? @comment.error "FIXME" "BUG" "ERROR"))
+
+; Issue number (#123)
+("text" @number
+  (#lua-match? @number "^#[0-9]+$"))
+
+(uri) @string.special.url @nospell

package/out/commonlisp/folds.scm

@@ -0,0 +1,2 @@
+(source
+  (list_lit) @fold)