ts-wasms 1.0.3 → 1.0.4

package/out/nix/highlights.scm

@@ -0,0 +1,99 @@
+(comment) @comment
+
+[
+  "if"
+  "then"
+  "else"
+  "let"
+  "inherit"
+  "in"
+  "rec"
+  "with"
+  "assert"
+  "or"
+] @keyword
+
+((identifier) @variable.builtin
+ (#match? @variable.builtin "^(__currentSystem|__currentTime|__langVersion|__nixPath|__nixVersion|__storeDir|builtins|false|null|true)$")
+ (#is-not? local))
+
+((identifier) @function.builtin
+ (#match? @function.builtin "^(__add|__addErrorContext|__all|__any|__appendContext|__attrNames|__attrValues|__bitAnd|__bitOr|__bitXor|__catAttrs|__ceil|__compareVersions|__concatLists|__concatMap|__concatStringsSep|__deepSeq|__div|__elem|__elemAt|__fetchurl|__filter|__filterSource|__findFile|__flakeRefToString|__floor|__foldl'|__fromJSON|__functionArgs|__genList|__genericClosure|__getAttr|__getContext|__getEnv|__getFlake|__groupBy|__hasAttr|__hasContext|__hashFile|__hashString|__head|__intersectAttrs|__isAttrs|__isBool|__isFloat|__isFunction|__isInt|__isList|__isPath|__isString|__length|__lessThan|__listToAttrs|__mapAttrs|__match|__mul|__parseDrvName|__parseFlakeRef|__partition|__path|__pathExists|__readDir|__readFile|__readFileType|__replaceStrings|__seq|__sort|__split|__splitVersion|__storePath|__stringLength|__sub|__substring|__tail|__toFile|__toJSON|__toPath|__toXML|__trace|__traceVerbose|__tryEval|__typeOf|__unsafeDiscardOutputDependency|__unsafeDiscardStringContext|__unsafeGetAttrPos|__zipAttrsWith|abort|baseNameOf|break|derivation|derivationStrict|dirOf|fetchGit|fetchMercurial|fetchTarball|fetchTree|fromTOML|import|isNull|map|placeholder|removeAttrs|scopedImport|throw|toString)$")
+ (#is-not? local))
+
+[
+  (integer_expression)
+  (float_expression)
+] @number
+
+(escape_sequence) @escape
+(dollar_escape) @escape
+
+(function_expression
+  universal: (identifier) @variable.parameter
+)
+
+(formal
+  name: (identifier) @variable.parameter
+  "?"? @punctuation.delimiter)
+
+(select_expression
+  attrpath: (attrpath (identifier)) @property)
+
+(apply_expression
+  function: [
+    (variable_expression (identifier)) @function
+    (select_expression
+      attrpath: (attrpath
+        attr: (identifier) @function .))])
+
+(unary_expression
+  operator: _ @operator)
+
+(binary_expression
+  operator: _ @operator)
+
+(variable_expression (identifier) @variable)
+
+(binding
+  attrpath: (attrpath (identifier)) @property)
+
+(identifier) @property
+
+(inherit_from attrs: (inherited_attrs attr: (identifier) @property) )
+
+[
+  ";"
+  "."
+  ","
+  "="
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+(identifier) @variable
+
+[
+  (string_expression)
+  (indented_string_expression)
+] @string
+
+[
+  (path_expression)
+  (hpath_expression)
+  (spath_expression)
+] @string.special.path
+
+(uri_expression) @string.special.uri
+
+(interpolation
+  "${" @punctuation.special
+  (_) @embedded
+  "}" @punctuation.special)

package/out/nix/injections.scm

@@ -0,0 +1,39 @@
+; mark arbitary languages with a comment
+((((comment) @injection.language) .
+  (indented_string_expression (string_fragment) @injection.content))
+  (#set! injection.combined))
+
+((binding
+   attrpath: (attrpath (identifier) @_path)
+   expression: (indented_string_expression
+     (string_fragment) @injection.content))
+ (#match? @_path "(^\\w*Phase|(pre|post)\\w*|(.*\\.)?\\w*([sS]cript|[hH]ook)|(.*\\.)?startup)$")
+ (#set! injection.language "bash")
+ (#set! injection.combined))
+
+((apply_expression
+   function: (apply_expression function: (_) @_func)
+   argument: (indented_string_expression (string_fragment) @injection.content))
+ (#match? @_func "(^|\\.)writeShellScript(Bin)?$")
+ (#set! injection.language "bash")
+ (#set! injection.combined))
+
+(apply_expression
+  (apply_expression
+    function: (apply_expression
+      function: ((_) @_func)))
+    argument: (indented_string_expression (string_fragment) @injection.content)
+  (#match? @_func "(^|\\.)runCommand(((No)?(CC))?(Local)?)?$")
+  (#set! injection.language "bash")
+  (#set! injection.combined))
+
+(apply_expression
+  function: ((_) @_func)
+  argument: (_ (_)* (_ (_)* (binding
+    attrpath: (attrpath (identifier) @_path)
+     expression: (indented_string_expression
+       (string_fragment) @injection.content))))
+  (#match? @_func "(^|\\.)writeShellApplication$")
+  (#match? @_path "^text$")
+  (#set! injection.language "bash")
+  (#set! injection.combined))

package/out/nix/locals.scm

@@ -0,0 +1,33 @@
+;; when using @local.reference, tree-sitter seems to 
+;; apply the scope from the identifier it has looked up,
+;; which makes sense for most languages.
+;; however, we want to highlight things as function based on their call-site,
+;; not their definition; therefore using TS's support for tracking locals
+;; impedes our ability to get the highlighting we want.
+;;
+;; also, TS doesn't seem to support scoping as implemented in languages
+;; with lazy let bindings, which results in syntax highlighting/goto-reference
+;; results that depend on the order of definitions, which is counter to the
+;; semantics of Nix.
+;;
+;; so for now we'll opt for not having any locals queries.
+;;
+;; see: https://github.com/tree-sitter/tree-sitter/issues/918
+
+;(function_expression
+;  universal: (identifier)? @local.definition
+;  formals: (formals (formal name: (identifier) @local.definition)*)
+;  universal: (identifier)? @local.definition
+;  ) @local.scope
+;
+;(rec_attrset_expression
+;  bind: (binding
+;    attrpath: (attrpath . (attr_identifier) @local.definition)) 
+;) @local.scope
+;
+;(let_expression
+;  bind: (binding
+;    attrpath: (attrpath . (attr_identifier) @local.definition)) 
+;) @local.scope
+;
+;(identifier) @local.reference 

package/out/nix/tags.scm

@@ -0,0 +1,16 @@
+;; https://tree-sitter.github.io/tree-sitter/4-code-navigation.html
+
+;;Function definitions
+(binding
+  attrpath: (attrpath attr: (identifier)) @name
+  expression: (function_expression) @definition.function)
+;;Function/method calls
+(apply_expression function: (apply_expression function: (variable_expression name: (identifier) @name)) @reference.call)
+
+;; TODO: (if even applicable?)
+;;Interface definitions       @definition.interface
+;;Interface implementation    @reference.implementation
+;;Class definitions           @definition.class
+;;Class reference             @reference.class
+;;Method definitions          @definition.method
+;;Module definitions          @definition.module

package/out/ocaml/highlights.scm

@@ -0,0 +1,148 @@
+; Punctuation
+;------------
+
+[
+  "," "." ";" ":" "=" "|" "~" "?" "+" "-" "!" ">" "&"
+  "->" ";;" ":>" "+=" ":=" ".."
+] @punctuation.delimiter
+
+["(" ")" "[" "]" "{" "}" "[|" "|]" "[<" "[>"] @punctuation.bracket
+
+(object_type ["<" ">"] @punctuation.bracket)
+
+"%" @punctuation.special
+
+(attribute ["[@" "]"] @punctuation.special)
+(item_attribute ["[@@" "]"] @punctuation.special)
+(floating_attribute ["[@@@" "]"] @punctuation.special)
+(extension ["[%" "]"] @punctuation.special)
+(item_extension ["[%%" "]"] @punctuation.special)
+(quoted_extension ["{%" "}"] @punctuation.special)
+(quoted_item_extension ["{%%" "}"] @punctuation.special)
+
+; Keywords
+;---------
+
+[
+  "and" "as" "assert" "begin" "class" "constraint" "do" "done" "downto" "effect"
+  "else" "end" "exception" "external" "for" "fun" "function" "functor" "if" "in"
+  "include" "inherit" "initializer" "lazy" "let" "match" "method" "module"
+  "mutable" "new" "nonrec" "object" "of" "open" "private" "rec" "sig" "struct"
+  "then" "to" "try" "type" "val" "virtual" "when" "while" "with"
+] @keyword
+
+; Operators
+;----------
+
+[
+  (prefix_operator)
+  (sign_operator)
+  (pow_operator)
+  (mult_operator)
+  (add_operator)
+  (concat_operator)
+  (rel_operator)
+  (and_operator)
+  (or_operator)
+  (assign_operator)
+  (hash_operator)
+  (indexing_operator)
+  (let_operator)
+  (let_and_operator)
+  (match_operator)
+] @operator
+
+(match_expression (match_operator) @keyword)
+
+(value_definition [(let_operator) (let_and_operator)] @keyword)
+
+["*" "#" "::" "<-"] @operator
+
+; Constants
+;----------
+
+(boolean) @constant
+
+[(number) (signed_number)] @number
+
+[(string) (character)] @string
+
+(quoted_string "{" @string "}" @string) @string
+
+(escape_sequence) @escape
+
+(conversion_specification) @string.special
+
+; Variables
+;----------
+
+[(value_name) (type_variable)] @variable
+
+(value_pattern) @variable.parameter
+
+; Properties
+;-----------
+
+[(label_name) (field_name) (instance_variable_name)] @property
+
+; Functions
+;----------
+
+(let_binding
+  pattern: (value_name) @function
+  (parameter))
+
+(let_binding
+  pattern: (value_name) @function
+  body: [(fun_expression) (function_expression)])
+
+(value_specification (value_name) @function)
+
+(external (value_name) @function)
+
+(method_name) @function.method
+
+(application_expression
+  function: (value_path (value_name) @function))
+
+(infix_expression
+  left: (value_path (value_name) @function)
+  operator: (concat_operator) @operator
+  (#eq? @operator "@@"))
+
+(infix_expression
+  operator: (rel_operator) @operator
+  right: (value_path (value_name) @function)
+  (#eq? @operator "|>"))
+
+(
+  (value_name) @function.builtin
+  (#match? @function.builtin "^(raise(_notrace)?|failwith|invalid_arg)$")
+)
+
+; Types
+;------
+
+[(class_name) (class_type_name) (type_constructor)] @type
+
+(
+  (type_constructor) @type.builtin
+  (#match? @type.builtin "^(int|char|bytes|string|float|bool|unit|exn|array|list|option|int32|int64|nativeint|format6|lazy_t)$")
+)
+
+[(constructor_name) (tag)] @constructor
+
+; Modules
+;--------
+
+[(module_name) (module_type_name)] @module
+
+; Attributes
+;-----------
+
+(attribute_id) @tag
+
+; Comments
+;---------
+
+[(comment) (line_number_directive) (directive) (shebang)] @comment

package/out/ocaml/locals.scm

@@ -0,0 +1,24 @@
+; Scopes
+;-------
+
+[
+  (let_binding)
+  (class_binding)
+  (class_function)
+  (method_definition)
+  (fun_expression)
+  (object_expression)
+  (for_expression)
+  (match_case)
+  (attribute_payload)
+] @local.scope
+
+; Definitions
+;------------
+
+(value_pattern) @local.definition
+
+; References
+;-----------
+
+(value_path . (value_name) @local.reference)

package/out/ocaml/tags.scm

@@ -0,0 +1,170 @@
+; Modules
+;--------
+
+(
+  (comment)? @doc .
+  (module_definition
+    (module_binding (module_name) @name) @definition.module
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(module_path (module_name) @name) @reference.module
+(extended_module_path (module_name) @name) @reference.module
+
+(
+  (comment)? @doc .
+  (module_type_definition (module_type_name) @name) @definition.interface
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(module_type_path (module_type_name) @name) @reference.implementation
+
+
+; Classes
+;--------
+
+(
+  (comment)? @doc .
+  [
+    (class_definition
+      (class_binding (class_name) @name) @definition.class
+    )
+    (class_type_definition
+      (class_type_binding (class_type_name) @name) @definition.class
+    )
+  ]
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+[
+  (class_path (class_name) @name)
+  (class_type_path (class_type_name) @name)
+] @reference.class
+
+(
+  (comment)? @doc .
+  (method_definition (method_name) @name) @definition.method
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(method_invocation (method_name) @name) @reference.call
+
+
+; Types
+;------
+
+(
+  (comment)? @doc .
+  (type_definition
+    (type_binding
+      name: [
+        (type_constructor) @name
+        (type_constructor_path (type_constructor) @name)
+      ]
+    ) @definition.type
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(type_constructor_path (type_constructor) @name) @reference.type
+
+[
+  (constructor_declaration (constructor_name) @name)
+  (tag_specification (tag) @name)
+] @definition.enum_variant
+
+[
+  (constructor_path (constructor_name) @name)
+  (tag) @name
+] @reference.enum_variant
+
+(field_declaration (field_name) @name) @definition.field
+
+(field_path (field_name) @name) @reference.field
+
+
+; Functions
+;----------
+
+(
+  (comment)? @doc .
+  (value_definition
+    [
+      (let_binding pattern: (value_name) @name (parameter))
+      (let_binding
+        pattern: (value_name) @name
+        body: [(fun_expression) (function_expression)]
+      )
+    ] @definition.function
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(
+  (comment)? @doc .
+  (external (value_name) @name) @definition.function
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(application_expression
+  function: (value_path (value_name) @name)
+) @reference.call
+
+(infix_expression
+  left: (value_path (value_name) @name)
+  operator: (concat_operator) @reference.call
+  (#eq? @reference.call "@@")
+)
+
+(infix_expression
+  operator: (rel_operator) @reference.call
+  right: (value_path (value_name) @name)
+  (#eq? @reference.call "|>")
+)
+
+
+; Operators
+;----------
+
+(
+  (comment)? @doc .
+  (value_definition
+    [
+      (let_binding pattern: (parenthesized_operator (_) @name) (parameter))
+      (let_binding
+        pattern: (parenthesized_operator (_) @name)
+        body: [(fun_expression) (function_expression)]
+      )
+    ] @definition.operator
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(application_expression
+  function: (value_path (parenthesized_operator (_) @name))
+) @reference.call
+
+(infix_expression
+  left: (value_path (parenthesized_operator (_) @name))
+  operator: (concat_operator) @reference.call
+  (#eq? @reference.call "@@")
+)
+
+(infix_expression
+  operator: (rel_operator) @reference.call
+  right: (value_path (parenthesized_operator (_) @name))
+  (#eq? @reference.call "|>")
+)
+
+(prefix_expression operator: (prefix_operator) @name) @reference.call
+
+(hash_expression operator: (hash_operator) @name) @reference.call
+
+(infix_expression operator: (_) @name) @reference.call
+
+(indexing_operator_path (indexing_operator) @name) @reference.call
+
+(value_definition [(let_operator) (let_and_operator)] @name) @reference.call
+
+(match_expression (match_operator) @name) @reference.call