tree-sitter-wasm 1.0.3 → 1.0.4

package/index.d.ts

@@ -33,6 +33,7 @@ export type QueryMap = {
     "embedded_template": "highlights" | "injections" | "injections-ejs" | "injections-erb" | "injections-etlua";
     "erlang": "folds" | "highlights" | "injections";
     "fish": "folds" | "highlights" | "indents" | "injections" | "locals";
+    "fortran": "folds" | "highlights" | "indents" | "injections" | "locals" | "tags";
     "gdscript": "folds" | "highlights" | "indents" | "injections" | "locals";
     "gdshader": "highlights" | "injections" | "locals" | "tags";
     "git_config": "folds" | "highlights" | "injections";
@@ -93,13 +94,16 @@ export type QueryMap = {
     "solidity": "folds" | "highlights" | "highlights-nvim" | "injections" | "locals" | "tags";
     "sql": "folds" | "highlights" | "indents" | "injections";
     "ssh_config": "folds" | "highlights" | "indents" | "injections" | "locals";
+    "svelte": "folds" | "highlights" | "indents" | "injections" | "locals" | "tags";
     "swift": "folds" | "highlights" | "indents" | "injections" | "locals" | "outline" | "tags" | "textobjects";
+    "systemverilog": "folds" | "highlights" | "injections";
     "templ": "folds" | "highlights" | "injections";
     "terraform": "folds" | "highlights" | "indents" | "injections";
     "toml": "folds" | "highlights" | "indents" | "injections" | "locals";
     "tsv": "highlights";
     "tsx": "folds" | "highlights" | "indents" | "injections" | "locals" | "tags";
     "typescript": "folds" | "highlights" | "indents" | "injections" | "locals" | "tags";
+    "typst": "folds" | "highlights" | "indents" | "injections";
     "vim": "folds" | "highlights" | "injections" | "locals";
     "vimdoc": "highlights" | "injections";
     "vue": "folds" | "highlights" | "indents" | "injections";

package/manifest.json

@@ -213,6 +213,14 @@
         "injections",
         "locals"
     ],
+    "fortran": [
+        "folds",
+        "highlights",
+        "indents",
+        "injections",
+        "locals",
+        "tags"
+    ],
     "gdscript": [
         "folds",
         "highlights",
@@ -595,6 +603,14 @@
         "injections",
         "locals"
     ],
+    "svelte": [
+        "folds",
+        "highlights",
+        "indents",
+        "injections",
+        "locals",
+        "tags"
+    ],
     "swift": [
         "folds",
         "highlights",
@@ -605,6 +621,11 @@
         "tags",
         "textobjects"
     ],
+    "systemverilog": [
+        "folds",
+        "highlights",
+        "injections"
+    ],
     "templ": [
         "folds",
         "highlights",
@@ -642,6 +663,12 @@
         "locals",
         "tags"
     ],
+    "typst": [
+        "folds",
+        "highlights",
+        "indents",
+        "injections"
+    ],
     "vim": [
         "folds",
         "highlights",

package/out/d/tags.scm

@@ -26,3 +26,4 @@
 (variable_declaration (type (identifier) @name) @reference.class (declarator))
 
 ((alias_declaration (alias_initializer . (identifier) @name))) @definition.class
+(mixin_template_declaration (mixin) (template_declaration (template) (identifier) @name)) @definition.type

package/out/fortran/folds.scm

@@ -0,0 +1,12 @@
+;; by @oponkork
+[
+ (if_statement)
+ (where_statement)
+ (enum_statement)
+ (do_loop)
+ (derived_type_definition)
+ (function)
+ (subroutine)
+ (module_procedure)
+ (interface)
+] @fold

package/out/fortran/highlights.scm

@@ -0,0 +1,204 @@
+[
+ (identifier)
+ (module_name)
+] @variable
+
+(string_literal) @string
+(number_literal) @number
+(statement_label) @number
+(statement_label_reference) @number
+(boolean_literal) @boolean
+(comment) @comment
+(custom_directive) @custom_directive
+
+[
+ (derived_type)
+ (derived_type_statement)
+ (import_statement)
+ (intrinsic_type)
+ (type_name)
+] @type
+
+(intrinsic_type) @type.builtin
+
+(base_type_specifier
+  (identifier) @type)
+
+[
+ (module_statement)
+ (submodule_statement)
+] @module
+
+[
+ (abstract_specifier)
+ (access_specifier)
+ (block_label)
+ (block_label_start_expression)
+ (none)
+ (procedure_attributes)
+ (procedure_qualifier)
+ (type_qualifier)
+] @attribute
+
+[
+ "#define"
+ "#elif"
+ "#endif"
+ "#if"
+ "#ifdef"
+ (base_type_specifier)
+ (block_construct)
+ (contains_statement)
+ (default)
+ (end_associate_statement)
+ (end_block_construct_statement)
+ (end_block_data_statement)
+ (end_coarray_critical_statement)
+ (end_coarray_team_statement)
+ (end_do_loop_statement)
+ (end_enum_statement)
+ (end_enumeration_type_statement)
+ (end_forall_statement)
+ (end_function_statement)
+ (end_if_statement)
+ (end_interface_statement)
+ (end_module_procedure_statement)
+ (end_module_statement)
+ (end_program_statement)
+ (end_select_statement)
+ (end_submodule_statement)
+ (end_subroutine_statement)
+ (end_type_statement)
+ (end_where_statement)
+ (enum_statement)
+ (enumeration_type_statement)
+ (enumerator_statement)
+ (equivalence_statement)
+ (function_statement)
+ (implicit_statement)
+ (interface_statement)
+ (keyword_statement)
+ (language_binding)
+ (namelist_statement)
+ (print_statement)
+ (procedure_statement)
+ (program_statement)
+ (subroutine_statement)
+] @keyword
+
+(use_statement "use" @keyword)
+(use_statement "intrinsic" @keyword)
+(included_items "only" @keyword)
+(allocate_statement "allocate" @keyword)
+(deallocate_statement "deallocate" @keyword)
+(subroutine_call "call" @keyword)
+(do_statement "do" @keyword)
+(while_statement "while" @keyword)
+(if_statement ["if" "then"] @keyword)
+(elseif_clause ["else" "if" "elseif"] @keyword)
+(else_clause "else" @keyword)
+(open_statement "open" @keyword)
+(write_statement "write" @keyword)
+(private_statement "private" @keyword)
+(public_statement "public" @keyword)
+
+
+(select_case_statement "select" @keyword "case" @keyword)
+(select_type_statement "select" @keyword "type" @keyword)
+(select_rank_statement "select" @keyword "rank" @keyword)
+(case_statement "case" @keyword)
+(type_statement "type" @keyword)
+(rank_statement "rank" @keyword)
+
+
+[
+ "*"
+ "+"
+ "-"
+ "/"
+ "="
+ "<"
+ ">"
+ "<="
+ ">="
+ "=="
+ "/="
+ ".and."
+ ".or."
+ ".lt."
+ ".gt."
+ ".ge."
+ ".le."
+ ".eq."
+ ".eqv."
+ ".neqv."
+ ".ne."
+] @operator
+
+;; Brackets
+[
+ "("
+ ")"
+ "["
+ "]"
+ "<<<"
+ ">>>"
+] @punctuation.bracket
+
+;; Delimiter
+[
+ "::"
+ ","
+ "%"
+ ":"
+] @punctuation.delimiter
+
+"&" @punctuation.special
+
+(parameters
+  (identifier) @variable.parameter)
+
+(program_statement
+  (name) @variable)
+
+(module_statement
+  (name) @variable)
+
+(submodule_statement
+  (module_name) (name) @variable)
+
+(function_statement
+  (name) @function)
+
+(subroutine_statement
+  (name) @function)
+
+(module_procedure_statement
+  (name) @function)
+
+(end_program_statement
+  (name) @variable)
+
+(end_module_statement
+  (name) @variable)
+
+(end_submodule_statement
+  (name) @variable)
+
+(end_function_statement
+  (name) @function)
+
+(end_subroutine_statement
+  (name) @function)
+
+(end_module_procedure_statement
+  (name) @function)
+
+(subroutine_call
+  (identifier) @function)
+
+(keyword_argument
+  name: (identifier) @keyword)
+
+(derived_type_member_expression
+  (type_member) @property)

package/out/fortran/indents.scm

@@ -0,0 +1,31 @@
+[
+  (module)
+  (submodule)
+  (program)
+  (subroutine)
+  (module_procedure)
+  (function)
+  ; (interface)
+  (if_statement)
+  (do_loop)
+  (where_statement)
+  (derived_type_definition)
+  (enum)
+] @indent
+
+[
+  (end_module_statement)
+  (end_submodule_statement)
+  (end_program_statement)
+  (end_subroutine_statement)
+  (end_module_procedure_statement)
+  (end_function_statement)
+  ; (end_interface_statement)
+  (end_if_statement)
+  (end_do_loop_statement)
+  (else_clause)
+  (elseif_clause)
+  (end_type_statement)
+  (end_enum_statement)
+  (end_where_statement)
+] @branch

package/out/fortran/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/fortran/locals.scm

@@ -0,0 +1,10 @@
+(derived_type_definition) @local.scope
+(program) @local.scope
+(module) @local.scope
+(submodule) @local.scope
+(interface) @local.scope
+(function) @local.scope
+(subroutine) @local.scope
+(block_construct) @local.scope
+
+(variable_declaration declarator: (identifier) @local.definition)

package/out/fortran/tags.scm

@@ -0,0 +1,42 @@
+(derived_type_statement
+  (type_name) @name) @definition.class
+
+(base_type_specifier
+  (identifier) @name) @reference.class
+
+(program_statement
+  (name) @name) @definition.module
+
+(module_statement
+  (name) @name) @definition.module
+
+(submodule_statement
+  (module_name) (name) @name) @definition.module
+
+(interface
+ (function
+   (function_statement
+    (name) @name) @definition.interface))
+
+(interface
+ (subroutine
+   (subroutine_statement
+    (name) @name) @definition.interface))
+
+(function_statement
+  (name) @name) @definition.function
+
+(subroutine_statement
+  (name) @name) @definition.function
+
+(module_procedure_statement
+  (name) @name) @reference.implementation
+
+(call_expression
+  (identifier) @name) @reference.call
+
+(subroutine_call
+  (identifier) @name) @reference.call
+
+(derived_type
+   (type_name) @name) @reference.class

package/out/svelte/folds.scm

@@ -0,0 +1,9 @@
+[
+ (style_element)
+ (script_element)
+ (element)
+ (if_statement)
+ (else_statement)
+ (each_statement)
+ (await_statement)
+] @fold

package/out/svelte/highlights.scm

@@ -0,0 +1,68 @@
+; Special identifiers
+;--------------------
+
+; TODO:
+((element (start_tag (tag_name) @_tag) (text) @text.title)
+ (#match? @_tag "^(h[0-9]|title)$"))
+
+((element (start_tag (tag_name) @_tag) (text) @text.strong)
+ (#match? @_tag "^(strong|b)$"))
+
+((element (start_tag (tag_name) @_tag) (text) @text.emphasis)
+ (#match? @_tag "^(em|i)$"))
+
+((element (start_tag (tag_name) @_tag) (text) @text.strike)
+ (#match? @_tag "^(s|del)$"))
+
+((element (start_tag (tag_name) @_tag) (text) @text.underline)
+ (#eq? @_tag "u"))
+
+((element (start_tag (tag_name) @_tag) (text) @text.literal)
+ (#match? @_tag "^(code|kbd)$"))
+
+((element (start_tag (tag_name) @_tag) (text) @text.uri)
+ (#eq? @_tag "a"))
+
+((attribute
+   (attribute_name) @_attr
+   (quoted_attribute_value (attribute_value) @text.uri))
+ (#match? @_attr "^(href|src)$"))
+
+(tag_name) @tag
+(attribute_name) @property
+(erroneous_end_tag_name) @error
+(comment) @comment
+
+[
+  (attribute_value)
+  (quoted_attribute_value)
+] @string
+
+[
+  (text)
+  (raw_text_expr)
+] @none
+
+[
+  (special_block_keyword)
+  (then)
+  (as)
+] @keyword
+
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+"=" @operator
+
+[
+  "<"
+  ">"
+  "</"
+  "/>"
+  "#"
+  ":"
+  "/"
+  "@"
+] @tag.delimiter

package/out/svelte/indents.scm

@@ -0,0 +1,20 @@
+[
+  (element)
+  (if_statement)
+  (each_statement)
+  (await_statement)
+  (script_element)
+  (style_element)
+] @indent
+
+[
+  (end_tag)
+  (else_statement)
+  (if_end_expr)
+  (each_end_expr)
+  (await_end_expr)
+  ">"
+  "/>"
+] @branch
+
+(comment) @ignore

package/out/svelte/injections.scm

@@ -0,0 +1,33 @@
+; injections.scm
+; --------------
+((style_element
+  (raw_text) @css))
+
+(
+  (style_element
+    (start_tag
+      (attribute
+        (quoted_attribute_value (attribute_value))))
+    (raw_text) @css)
+)
+
+((attribute
+   (attribute_name) @_attr
+   (quoted_attribute_value (attribute_value) @css))
+ (#eq? @_attr "style"))
+
+((script_element
+  (raw_text) @javascript))
+
+((raw_text_expr) @javascript)
+
+(
+  (script_element
+    (start_tag
+      (attribute
+        (quoted_attribute_value (attribute_value) @_lang)))
+    (raw_text) @typescript)
+  (#match? @_lang "(ts|typescript)")
+)
+
+(comment) @comment

package/out/svelte/locals.scm

@@ -0,0 +1 @@
+;; locals

package/out/svelte/tags.scm

@@ -0,0 +1 @@
+;; tags

package/out/systemverilog/folds.scm

@@ -0,0 +1,23 @@
+[
+  (seq_block)
+  (function_body_declaration)
+  (task_body_declaration)
+  (generate_block)
+  (always_construct)
+  (property_declaration)
+  (checker_declaration)
+  (class_declaration)
+  (config_declaration)
+  (covergroup_declaration)
+  (clocking_declaration)
+  (interface_declaration)
+  (module_declaration)
+  (package_declaration)
+  (module_instantiation)
+  (program_declaration)
+  (specify_block)
+  (generate_region)
+  (package_import_declaration)
+  (text_macro_definition)
+  (include_compiler_directive)+
+] @fold

package/out/systemverilog/highlights.scm

@@ -0,0 +1,325 @@
+;; Comments
+(one_line_comment) @comment
+(block_comment) @comment
+
+
+;; Strings
+(string_literal) @string
+(quoted_string) @string ; `include strings
+(system_lib_string) @string
+
+
+;; Keywords
+(["begin" "end" "this"]) @keyword
+(["input" "output" "inout" "ref"]) @keyword
+(["alias" "and" "assert" "assign" "assume" "before" "bind" "binsof" "break"
+  "case" "checker" "class" "class" "clocking" "config" "const" "constraint"
+  "cover" "covergroup" "coverpoint" "cross" "default" "defparam" "disable"
+  "do" "else" "endcase" "endchecker" "endclass" "endclocking" "endconfig"
+  "endfunction" "endgenerate" "endgroup" "endinterface" "endmodule"
+  "endpackage" "endprogram" "endproperty" "endsequence" "endtask" "enum"
+  "extends" "extern" "final" "first_match" "for" "force" "foreach" "forever"
+  "fork" "forkjoin" "function" "generate" "genvar" "if" "iff" "illegal_bins"
+  "implements" "import" "initial" "inside" "interconnect" "interface"
+  "intersect" "join" "join_any" "join_none" "local" "localparam" "matches"
+  "modport" "new" "null" "option" "or" "package" "packed" "parameter"
+  "program" "property" "pure" "randcase" "randomize" "release" "repeat"
+  "return" "sequence" "showcancelled" "soft" "solve" "struct" "super" "tagged"
+  "task" "timeprecision" "timeunit" "type" "typedef" "union" "unique"
+  "virtual" "wait" "while" "with"
+  (always_keyword)             ; always, always_comb, always_latch, always_ff
+  (bins_keyword)               ; bins, illegal_bins, ignore_bins
+  (case_keyword)               ; case, casez, casex
+  (class_item_qualifier)       ; static, protected, local
+  (edge_identifier)            ; posedge, negedge, edge
+  (lifetime)                   ; static, automatic
+  (module_keyword)             ; module, macromodule
+  (random_qualifier)           ; rand, randc
+  (unique_priority)]) @keyword ; unique, unique0, priority
+
+
+;; Preprocessor directives and macro usage
+(["`include" "`define" "`ifdef" "`ifndef" "`timescale" "`default_nettype"
+  "`elsif" "`undef" (resetall_compiler_directive) (undefineall_compiler_directive)
+  "`endif" "`else" "`unconnected_drive" (celldefine_compiler_directive)
+  (endcelldefine_compiler_directive) (endkeywords_directive) "`line"
+  "`begin_keywords" "`pragma" "`__FILE__" "`__LINE__"]) @string.special
+(text_macro_usage
+ (simple_identifier) @string.special)
+
+
+;; Delimiters, operators
+([";" ":" "," "::"
+  "=" "?" "|=" "&=" "^="
+  "|->" "|=>" "->"
+  ":=" ":/" "-:" "+:"]) @punctuation.delimiter
+(["(" ")"]) @punctuation.bracket
+(["[" "]"]) @punctuation.bracket
+(["{" "}" "'{"]) @punctuation.bracket
+
+(["."] @operator)
+(["+" "-" "*" "/" "%" "**"]) @operator
+(["<" "<=" ">" ">="]) @operator
+(["===" "!==" "==" "!="]) @operator
+(["&&" "||" "!"]) @operator
+(["~" "&" "~&" "|" "~|" "^" "~^"]) @operator
+(["<<" ">>" "<<<" ">>>"]) @operator
+
+(["@" "#" "##"]) @operator
+(assignment_operator) @operator
+(unary_operator) @operator
+(inc_or_dec_operator) @operator
+(stream_operator) @operator
+(event_trigger) @operator
+(["->" "->>"]) @operator
+
+
+;; Declarations
+;; Module/interface/program/package/class/checker
+(module_nonansi_header
+ name: (simple_identifier) @function)
+(module_ansi_header
+ name: (simple_identifier) @function)
+(interface_nonansi_header
+ name: (simple_identifier) @function)
+(interface_ansi_header
+ name: (simple_identifier) @function)
+(program_nonansi_header
+ name: (simple_identifier) @function)
+(program_ansi_header
+ name: (simple_identifier) @function)
+(package_declaration
+ name: (simple_identifier) @function)
+(class_declaration
+ name: (simple_identifier) @function)
+(interface_class_declaration
+ name: (simple_identifier) @function)
+(checker_declaration
+ name: (simple_identifier) @function)
+(class_declaration
+ (class_type
+  (simple_identifier) @type)) ; Parent class
+;; Function/task/methods
+(function_body_declaration
+ name: (simple_identifier) @function)
+(task_body_declaration
+ name: (simple_identifier) @function)
+(function_prototype
+ (data_type_or_void)
+ name: (simple_identifier) @function)
+(task_prototype
+ name: (simple_identifier) @function)
+(class_scope ; Definition of extern defined methods
+ (class_type
+  (simple_identifier)) @function)
+
+
+;; Types
+[(integer_vector_type) ; bit, logic, reg
+  (integer_atom_type)   ; byte, shortint, int, longint, integer, time
+  (non_integer_type)    ; shortreal, real, realtime
+  (net_type)            ; supply0, supply1, tri, triand, trior, trireg, tri0, tri1, uwire, wire, wand, wor
+  ["string" "event" "signed" "unsigned" "chandle"]] @type
+(data_type_or_implicit
+ (data_type
+  (simple_identifier)) @type)
+(data_type
+ (class_type
+  (simple_identifier) @type
+  (parameter_value_assignment)))
+(data_type
+ (class_type
+  (simple_identifier) @operator
+  (simple_identifier) @type))
+(net_port_header
+ (net_port_type
+  (simple_identifier) @type))
+(variable_port_header
+ (variable_port_type
+  (data_type
+   (simple_identifier) @type)))
+(["void'" (data_type_or_void)]) @type ; void cast of task called as a function
+(interface_port_header ; Interfaces with modports
+ interface_name: (simple_identifier) @type
+ modport_name: (simple_identifier) @type)
+(type_assignment
+ name: (simple_identifier) @type)
+(net_declaration ; User type variable declaration
+ (simple_identifier) @type)
+(enum_base_type ; Enum base type with user type
+ (simple_identifier) @type)
+
+
+;; Instances
+;; Module names
+(module_instantiation
+ instance_type: (simple_identifier) @module)
+(interface_instantiation
+ instance_type: (simple_identifier) @module)
+(program_instantiation
+ instance_type: (simple_identifier) @module)
+(checker_instantiation
+ instance_type: (simple_identifier) @module)
+(udp_instantiation
+ instance_type: (simple_identifier) @module)
+(gate_instantiation
+ [(cmos_switchtype)
+  (mos_switchtype)
+  (enable_gatetype)
+  (n_input_gatetype)
+  (n_output_gatetype)
+  (pass_en_switchtype)
+  (pass_switchtype)
+  "pulldown" "pullup"]
+ @module)
+;; Instance names
+(name_of_instance
+ instance_name: (simple_identifier) @constant)
+;; Instance parameters
+(module_instantiation
+ (parameter_value_assignment
+  (list_of_parameter_value_assignments
+   (named_parameter_assignment
+    (simple_identifier) @constant))))
+(module_instantiation
+ (parameter_value_assignment
+  (list_of_parameter_value_assignments
+   (ordered_parameter_assignment
+    (param_expression
+     (data_type
+      (simple_identifier) @constant))))))
+;; Port names
+(named_port_connection
+ port_name: (simple_identifier) @constant)
+(named_parameter_assignment
+ (simple_identifier) @constant)
+(named_checker_port_connection
+ port_name: (simple_identifier) @constant)
+;; Bind statements
+(bind_directive
+ (bind_target_scope
+  (simple_identifier) @constant))
+
+
+;; Numbers
+(hex_number
+ size: (unsigned_number) @number
+ base: (hex_base) @punctuation.delimiter)
+(decimal_number
+ size: (unsigned_number) @number
+ base: (decimal_base) @punctuation.delimiter)
+(octal_number
+ size: (unsigned_number) @number
+ base: (octal_base) @punctuation.delimiter)
+(binary_number
+ size: (unsigned_number) @number
+ base: (binary_base) @punctuation.delimiter)
+;; Same as before but without the width (width extension)
+(hex_number
+ base: (hex_base) @punctuation.delimiter)
+(decimal_number
+ base: (decimal_base) @punctuation.delimiter)
+(octal_number
+ base: (octal_base) @punctuation.delimiter)
+(binary_number
+ base: (binary_base) @punctuation.delimiter)
+
+
+;; Arrays
+(unpacked_dimension
+ [(constant_expression) (constant_range)] @number)
+(packed_dimension
+ (constant_range) @number)
+(select
+ (constant_range) @number)
+(constant_select
+ (constant_range
+  (constant_expression) @number))
+(constant_bit_select
+ (constant_expression) @number)
+(bit_select
+ (expression) @number)
+(indexed_range
+ (expression) @number
+ (constant_expression) @number)
+(constant_indexed_range
+ (constant_expression) @number)
+(value_range ; inside {[min_range:max_range]}, place here to apply override
+ (expression) @constant)
+(dynamic_array_new
+ (expression) @constant)
+
+
+;; Misc
+;; Timeunit
+((time_unit) @constant.builtin)
+;; Enum labels
+(enum_name_declaration
+ (simple_identifier) @constant.builtin)
+;; Case item label (not radix)
+(case_item_expression
+ (expression
+  (primary
+   (hierarchical_identifier
+    (simple_identifier) @constant.builtin))))
+;; Hierarchical references, interface signals, class members, package scope
+(hierarchical_identifier
+ (simple_identifier) @punctuation.delimiter
+ "."
+ (simple_identifier))
+(method_call
+ (primary) @punctuation.delimiter
+ (["." "::"])
+ (method_call_body))
+(package_scope
+ (simple_identifier) @punctuation.delimiter)
+(method_call
+ (primary
+  (select
+   (simple_identifier) @punctuation.delimiter))
+ (method_call_body))
+;; Attributes
+(["(*" "*)"] @constant)
+(attribute_instance
+ (attr_spec (simple_identifier) @attribute))
+;; Typedefs
+(type_declaration
+ (class_type (simple_identifier) @type)
+ type_name: (simple_identifier) @constant)
+(type_declaration
+ type_name: (simple_identifier) @constant)
+("typedef" "class" (simple_identifier) @constant)
+;; Coverpoint & cross labels
+(cover_point
+ name: (simple_identifier) @constant)
+(cover_cross
+ name: (simple_identifier) @constant)
+;; Loop variables (foreach[i])
+(loop_variables
+ (simple_identifier) @constant)
+;; Bins values
+(bins_or_options
+ (expression
+  (primary
+   (concatenation
+    (expression) @constant))))
+;; Bins ranges
+(covergroup_value_range
+ (expression) @constant)
+;; Queue dimension
+(("$") @punctuation.special)
+;; Parameterized classes (e.g: uvm_config_db #(axi_stream_agent_config))
+(class_type
+ (parameter_value_assignment
+  (list_of_parameter_value_assignments) @punctuation.delimiter))
+
+
+;; System-tf
+([(system_tf_identifier)               ; System task/function
+  "$fatal" "$error" "$warning" "$info" ; (severity_system_task)
+  "$stop" "$finish" "$exit"])          ; (simulation_control_task)
+@function.builtin
+
+
+;; Errors
+(ERROR) @error

package/out/systemverilog/injections.scm

@@ -0,0 +1,8 @@
+([
+  (one_line_comment)
+  (block_comment)
+] @injection.content
+  (#set! injection.language "comment"))
+
+((macro_text) @injection.content
+  (#set! injection.language "verilog"))

package/out/typst/folds.scm

@@ -0,0 +1,11 @@
+[
+  (set)
+  (let)
+  (show)
+  (call)
+  (section)
+  (for)
+  (branch)
+  (content)
+  (raw_blck)
+] @fold

package/out/typst/highlights.scm

@@ -0,0 +1,141 @@
+; punctuation
+"#" @punctuation.special
+
+[
+  ":"
+  ";"
+  ","
+] @punctuation.delimiter
+
+; TODO: context blocks for "[" "]"?
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @punctuation.bracket
+
+; operators
+[
+  "-"
+  "+"
+  "*"
+  "/"
+  "=="
+  "!="
+  "<"
+  "<="
+  ">"
+  ">="
+  "="
+  "in"
+  "and"
+  "or"
+  "not"
+] @operator
+
+; keywords
+[
+  "import"
+  "include"
+] @keyword.import
+
+[
+  "let"
+  "set"
+  "show"
+] @keyword
+
+; control flow
+[
+  "for"
+  "while"
+  "break"
+  "continue"
+] @keyword.repeat
+
+[
+  "if"
+  "else"
+] @keyword.conditional
+
+; special case: #for (ident) in (expr)
+(for
+  "in" @keyword.repeat)
+
+; type literals
+(number) @number
+
+(string) @string
+
+(bool) @boolean
+
+(ident) @constant
+
+; name-value pairs
+(tagged
+  field: (ident) @variable.member)
+
+(call
+  item: (ident) @function.call)
+
+; text
+(text) @spell
+
+(heading
+  "=" @markup.heading.1) @markup.heading.1
+
+(heading
+  "==" @markup.heading.2) @markup.heading.2
+
+(heading
+  "===" @markup.heading.3) @markup.heading.3
+
+(heading
+  "====" @markup.heading.4) @markup.heading.4
+
+(heading
+  "=====" @markup.heading.5) @markup.heading.5
+
+(heading
+  "======" @markup.heading.6) @markup.heading.6
+
+(strong) @markup.strong
+
+(emph) @markup.italic
+
+((url) @markup.link.url
+  (#set! @markup.link.url url @markup.link.url))
+
+(call
+  item: (ident) @_link
+  (#eq? @_link "link")
+  (group
+    .
+    (string) @markup.link.url
+    (#offset! @markup.link.url 0 1 0 -1)
+    (#set! @markup.link.url url @markup.link.url)))
+
+; code blocks
+(raw_span) @markup.raw
+
+(raw_blck) @markup.raw
+
+(raw_blck
+  lang: (ident) @label)
+
+(raw_blck
+  (blob) @markup.raw.block)
+
+; refs and labels
+(label) @markup.link.label
+
+(ref) @markup.link
+
+; math
+(math) @markup.math
+
+; comments
+(comment) @comment @spell

package/out/typst/indents.scm

@@ -0,0 +1,14 @@
+[
+  (set)
+  (let)
+  (show)
+  (call)
+  (for)
+  (branch)
+] @indent.begin
+
+[
+  "]"
+  "}"
+  ")"
+] @indent.end @indent.branch

package/out/typst/injections.scm

@@ -0,0 +1,6 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+(raw_blck
+  (ident) @injection.language
+  (blob) @injection.content)

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "tree-sitter-wasm",
-  "version": "1.0.3",
+  "version": "1.0.4",
   "description": "Pre-built WebAssembly binaries and queries for tree-sitter grammars.",
   "keywords": [
     "incremental",
@@ -89,6 +89,7 @@
     "tree-sitter-embedded-template": "^0.25.0",
     "tree-sitter-erlang": "git+https://github.com/WhatsApp/tree-sitter-erlang.git#e446ec60022a7cafe157805742b41c04b499cc5d",
     "tree-sitter-fish": "git+https://github.com/ram02z/tree-sitter-fish.git#f435b0bd772578c70e5d158b85267bb886316f88",
+    "tree-sitter-fortran": "git+https://github.com/stadelmanma/tree-sitter-fortran.git#7edacd2b21aa80057d9725384a1304a1c758e0f8",
     "tree-sitter-gdscript": "^6.1.0",
     "tree-sitter-gdshader": "git+https://github.com/airblast-dev/tree-sitter-gdshader.git#68268631c8b6dc093985f1246b099f81b30ea7d1",
     "tree-sitter-git-config": "git+https://github.com/the-mikedavis/tree-sitter-git-config.git#0fbc9f99d5a28865f9de8427fb0672d66f9d83a5",
@@ -137,9 +138,12 @@
     "tree-sitter-scss": "^1.0.0",
     "tree-sitter-solidity": "^1.2.13",
     "tree-sitter-ssh-config": "git+https://github.com/tree-sitter-grammars/tree-sitter-ssh-config.git#71d2693deadaca8cdc09e38ba41d2f6042da1616",
+    "tree-sitter-svelte": "git+https://github.com/Himujjal/tree-sitter-svelte#60ea1d673a1a3eeeb597e098d9ada9ed0c79ef4b",
     "tree-sitter-swift": "^0.7.1",
+    "tree-sitter-systemverilog": "^0.3.1",
     "tree-sitter-templ": "git+https://github.com/vrischmann/tree-sitter-templ.git#68d6707ed20159ae7525241b8161c126dc1c620c",
     "tree-sitter-typescript": "^0.23.2",
+    "tree-sitter-typst": "git+https://github.com/uben0/tree-sitter-typst.git#46cf4ded12ee974a70bf8457263b67ad7ee0379d",
     "tree-sitter-vim": "git+https://github.com/tree-sitter-grammars/tree-sitter-vim.git#3092fcd99eb87bbd0fc434aa03650ba58bd5b43b",
     "tree-sitter-vimdoc": "git+https://github.com/neovim/tree-sitter-vimdoc.git#f061895a0eff1d5b90e4fb60d21d87be3267031a",
     "tree-sitter-vue": "git+https://github.com/tree-sitter-grammars/tree-sitter-vue.git#ce8011a414fdf8091f4e4071752efc376f4afb08",