squircle-view 0.0.0-stage → 0.2.0

package/ios/Geometry/SquirclePath.mm

@@ -0,0 +1,39 @@
+//
+//  SquirclePath.mm
+//  Pods
+//
+//  Created by rit3zh CX on 10/7/26.
+//
+
+#import "SquirclePath.h"
+
+void SquirclePathAppend(
+    CGMutablePathRef path,
+    const squircle::Rect &rect,
+    const squircle::CornerRadii &radii,
+    double smoothing) {
+  for (const auto &element : squircle::buildPath(rect, radii, smoothing)) {
+    const auto &points = element.points;
+    switch (element.verb) {
+      case squircle::Verb::Move:
+        CGPathMoveToPoint(path, NULL, points[0].x, points[0].y);
+        break;
+      case squircle::Verb::Line:
+        CGPathAddLineToPoint(path, NULL, points[0].x, points[0].y);
+        break;
+      case squircle::Verb::Cubic:
+        CGPathAddCurveToPoint(
+            path, NULL, points[0].x, points[0].y, points[1].x, points[1].y, points[2].x, points[2].y);
+        break;
+      case squircle::Verb::Close:
+        CGPathCloseSubpath(path);
+        break;
+    }
+  }
+}
+
+CGPathRef SquirclePathCreate(const squircle::Rect &rect, const squircle::CornerRadii &radii, double smoothing) {
+  CGMutablePathRef path = CGPathCreateMutable();
+  SquirclePathAppend(path, rect, radii, smoothing);
+  return path;
+}

package/ios/Layers/SquircleBorderLayer.h

@@ -0,0 +1,24 @@
+//
+//  SquircleBorderLayer.h
+//  Pods
+//
+//  Created by rit3zh CX on 10/7/26.
+//
+
+#import <QuartzCore/QuartzCore.h>
+#import <UIKit/UIKit.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface SquircleBorderLayer : CALayer
+
+- (void)updateWithBorderPath:(CGPathRef)borderPath
+                      insets:(UIEdgeInsets)insets
+                    topColor:(UIColor *)topColor
+                  rightColor:(UIColor *)rightColor
+                 bottomColor:(UIColor *)bottomColor
+                   leftColor:(UIColor *)leftColor;
+
+@end
+
+NS_ASSUME_NONNULL_END

package/ios/Layers/SquircleBorderLayer.m

@@ -0,0 +1,102 @@
+//
+//  SquircleBorderLayer.m
+//  Pods
+//
+//  Created by rit3zh CX on 10/7/26.
+//
+
+#import "SquircleBorderLayer.h"
+
+static CGPoint SquircleSpokePoint(CGPoint corner, CGFloat dx, CGFloat dy, CGSize half) {
+  CGFloat scale = CGFLOAT_MAX;
+  if (dx != 0) {
+    scale = MIN(scale, half.width / fabs(dx));
+  }
+  if (dy != 0) {
+    scale = MIN(scale, half.height / fabs(dy));
+  }
+  if (scale == CGFLOAT_MAX) {
+    return corner;
+  }
+  return CGPointMake(corner.x + dx * scale, corner.y + dy * scale);
+}
+
+static void SquircleFillWedge(CGContextRef context, UIColor *color, const CGPoint points[5]) {
+  CGContextSetFillColorWithColor(context, color.CGColor);
+  CGContextBeginPath(context);
+  CGContextAddLines(context, points, 5);
+  CGContextClosePath(context);
+  CGContextFillPath(context);
+}
+
+@implementation SquircleBorderLayer {
+  CGPathRef _borderPath;
+  UIEdgeInsets _insets;
+  UIColor *_topColor;
+  UIColor *_rightColor;
+  UIColor *_bottomColor;
+  UIColor *_leftColor;
+}
+
+- (instancetype)init {
+  if (self = [super init]) {
+    self.needsDisplayOnBoundsChange = YES;
+  }
+  return self;
+}
+
+- (void)dealloc {
+  CGPathRelease(_borderPath);
+}
+
+- (void)updateWithBorderPath:(CGPathRef)borderPath
+                      insets:(UIEdgeInsets)insets
+                    topColor:(UIColor *)topColor
+                  rightColor:(UIColor *)rightColor
+                 bottomColor:(UIColor *)bottomColor
+                   leftColor:(UIColor *)leftColor {
+  if (_borderPath != borderPath) {
+    CGPathRelease(_borderPath);
+    _borderPath = CGPathRetain(borderPath);
+  }
+  _insets = insets;
+  _topColor = topColor;
+  _rightColor = rightColor;
+  _bottomColor = bottomColor;
+  _leftColor = leftColor;
+  [self setNeedsDisplay];
+}
+
+- (void)drawInContext:(CGContextRef)context {
+  if (_borderPath == NULL) {
+    return;
+  }
+
+  const CGSize size = self.bounds.size;
+  const CGSize half = CGSizeMake(size.width / 2, size.height / 2);
+  const CGPoint center = CGPointMake(half.width, half.height);
+  const CGPoint topLeft = CGPointZero;
+  const CGPoint topRight = CGPointMake(size.width, 0);
+  const CGPoint bottomRight = CGPointMake(size.width, size.height);
+  const CGPoint bottomLeft = CGPointMake(0, size.height);
+
+  const CGPoint topLeftSpoke = SquircleSpokePoint(topLeft, _insets.left, _insets.top, half);
+  const CGPoint topRightSpoke = SquircleSpokePoint(topRight, -_insets.right, _insets.top, half);
+  const CGPoint bottomRightSpoke = SquircleSpokePoint(bottomRight, -_insets.right, -_insets.bottom, half);
+  const CGPoint bottomLeftSpoke = SquircleSpokePoint(bottomLeft, _insets.left, -_insets.bottom, half);
+
+  CGContextAddPath(context, _borderPath);
+  CGContextEOClip(context);
+
+  const CGPoint top[5] = {topLeft, topRight, topRightSpoke, center, topLeftSpoke};
+  const CGPoint right[5] = {topRight, bottomRight, bottomRightSpoke, center, topRightSpoke};
+  const CGPoint bottom[5] = {bottomRight, bottomLeft, bottomLeftSpoke, center, bottomRightSpoke};
+  const CGPoint left[5] = {bottomLeft, topLeft, topLeftSpoke, center, bottomLeftSpoke};
+
+  SquircleFillWedge(context, _topColor, top);
+  SquircleFillWedge(context, _rightColor, right);
+  SquircleFillWedge(context, _bottomColor, bottom);
+  SquircleFillWedge(context, _leftColor, left);
+}
+
+@end

package/ios/Views/SquircleView.h

@@ -0,0 +1,16 @@
+//
+//  SquircleView.h
+//  Pods
+//
+//  Created by rit3zh CX on 10/7/26.
+//
+
+#import <React/RCTViewComponentView.h>
+#import <UIKit/UIKit.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface SquircleView : RCTViewComponentView
+@end
+
+NS_ASSUME_NONNULL_END

package/ios/Views/SquircleView.mm

@@ -0,0 +1,337 @@
+//
+//  SquircleView.mm
+//  Pods
+//
+//  Created by rit3zh CX on 10/7/26.
+//
+
+#import "SquircleView.h"
+
+#import <objc/runtime.h>
+
+#import <optional>
+
+#import <React/RCTConversions.h>
+#import <React/RCTUtils.h>
+#import <react/featureflags/ReactNativeFeatureFlags.h>
+#import <react/renderer/components/SquircleViewSpec/ComponentDescriptors.h>
+#import <react/renderer/components/SquircleViewSpec/Props.h>
+
+#import "SquircleBorderLayer.h"
+#import "SquirclePath.h"
+
+using namespace facebook::react;
+
+static const CGFloat SquircleBackgroundZPosition = -1024;
+static const CGFloat SquircleBorderZPosition = -1023;
+
+@interface RCTViewComponentView (SquircleView)
+- (UIView *)currentContainerView;
+- (void)invalidateLayer;
+@end
+
+namespace {
+
+struct SquircleGeometryKey {
+  squircle::Rect bounds;
+  squircle::CornerRadii radii;
+  squircle::Insets insets;
+  double smoothing;
+
+  bool operator==(const SquircleGeometryKey &other) const = default;
+};
+
+squircle::CornerRadii SquircleCornerRadiiFromBorderRadii(const BorderRadii &radii) {
+  return {
+      {radii.topLeft.horizontal, radii.topLeft.vertical},
+      {radii.topRight.horizontal, radii.topRight.vertical},
+      {radii.bottomRight.horizontal, radii.bottomRight.vertical},
+      {radii.bottomLeft.horizontal, radii.bottomLeft.vertical}};
+}
+
+squircle::Insets SquircleInsetsFromBorderWidths(const BorderWidths &widths) {
+  return {widths.top, widths.right, widths.bottom, widths.left};
+}
+
+UIColor *SquircleResolvedColor(const SharedColor &color, UITraitCollection *traitCollection) {
+  UIColor *resolved = RCTUIColorFromSharedColor(color) ?: UIColor.blackColor;
+  return [resolved resolvedColorWithTraitCollection:traitCollection];
+}
+
+} // namespace
+
+@implementation SquircleView {
+  CGFloat _borderSmoothing;
+  BOOL _needsSquircleUpdate;
+  std::optional<SquircleGeometryKey> _geometryKey;
+  CGPathRef _outerPath;
+  CGPathRef _innerPath;
+  CGPathRef _borderPath;
+  CGPathRef _strokePath;
+  CAShapeLayer *_backgroundLayer;
+  CAShapeLayer *_borderShapeLayer;
+  SquircleBorderLayer *_multicolorBorderLayer;
+  CAShapeLayer *_clipLayer;
+}
+
++ (ComponentDescriptorProvider)componentDescriptorProvider {
+  return concreteComponentDescriptorProvider<SquircleViewComponentDescriptor>();
+}
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const SquircleViewProps>();
+    _props = defaultProps;
+  }
+  return self;
+}
+
+- (void)dealloc {
+  [self releasePaths];
+}
+
+#pragma mark - RCTComponentViewProtocol
+
+- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps {
+  const auto &newProps = static_cast<const SquircleViewProps &>(*props);
+  const CGFloat smoothing = squircle::clampSmoothing(newProps.borderSmoothing);
+  if (smoothing != _borderSmoothing) {
+    _borderSmoothing = smoothing;
+    _needsSquircleUpdate = YES;
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
+- (void)finalizeUpdates:(RNComponentViewUpdateMask)updateMask {
+  [super finalizeUpdates:updateMask];
+
+  if (_needsSquircleUpdate) {
+    [self invalidateLayer];
+  }
+}
+
+- (void)prepareForRecycle {
+  [super prepareForRecycle];
+
+  _borderSmoothing = 0;
+  _needsSquircleUpdate = NO;
+  [self removeSquircleLayers];
+}
+
+#pragma mark - Layer
+
+- (void)invalidateLayer {
+  _needsSquircleUpdate = NO;
+
+  const auto borderMetrics = _props->resolveBorderMetrics(_layoutMetrics);
+  const auto radii = SquircleCornerRadiiFromBorderRadii(borderMetrics.borderRadii);
+  const CGSize size = self.layer.bounds.size;
+
+  if (_borderSmoothing <= 0 || !squircle::hasRoundedCorner(radii) || size.width <= 0 || size.height <= 0) {
+    [self removeSquircleLayers];
+    [super invalidateLayer];
+    return;
+  }
+
+  UIColor *backgroundColor = self.backgroundColor;
+  self.backgroundColor = nil;
+  [super invalidateLayer];
+  self.backgroundColor = backgroundColor;
+
+  const SquircleGeometryKey key{
+      .bounds = {0, 0, size.width, size.height},
+      .radii = radii,
+      .insets = SquircleInsetsFromBorderWidths(borderMetrics.borderWidths),
+      .smoothing = _borderSmoothing,
+  };
+  [self updateGeometry:key];
+
+  [CATransaction begin];
+  [CATransaction setDisableActions:YES];
+  [self hideDefaultBackgroundAndBorder];
+  [self updateBackgroundWithColor:backgroundColor];
+  [self updateBorderWithMetrics:borderMetrics];
+  [self updateClipping];
+  [CATransaction commit];
+}
+
+- (void)updateGeometry:(const SquircleGeometryKey &)key {
+  if (_geometryKey == key) {
+    return;
+  }
+
+  [self releasePaths];
+  _geometryKey = key;
+
+  const auto innerRect = squircle::insetRect(key.bounds, key.insets);
+  const auto innerRadii = squircle::insetRadii(key.radii, key.insets);
+
+  _outerPath = SquirclePathCreate(key.bounds, key.radii, key.smoothing);
+  _innerPath = SquirclePathCreate(innerRect, innerRadii, key.smoothing);
+
+  CGMutablePathRef borderPath = CGPathCreateMutableCopy(_outerPath);
+  SquirclePathAppend(borderPath, innerRect, innerRadii, key.smoothing);
+  _borderPath = borderPath;
+}
+
+- (CGPathRef)strokePath {
+  if (_strokePath == NULL && _geometryKey) {
+    const auto &key = *_geometryKey;
+    const squircle::Insets half{
+        key.insets.top / 2, key.insets.right / 2, key.insets.bottom / 2, key.insets.left / 2};
+    _strokePath = SquirclePathCreate(
+        squircle::insetRect(key.bounds, half), squircle::insetRadii(key.radii, half), key.smoothing);
+  }
+  return _strokePath;
+}
+
+- (void)releasePaths {
+  CGPathRelease(_outerPath);
+  CGPathRelease(_innerPath);
+  CGPathRelease(_borderPath);
+  CGPathRelease(_strokePath);
+  _outerPath = NULL;
+  _innerPath = NULL;
+  _borderPath = NULL;
+  _strokePath = NULL;
+  _geometryKey.reset();
+}
+
+// RCTViewComponentView draws non-uniform borders into a private sublayer; it has to be hidden
+// while the squircle border is rendered in its place.
+- (nullable CALayer *)defaultBorderLayer {
+  static Ivar ivar = class_getInstanceVariable([RCTViewComponentView class], "_borderLayer");
+  return ivar != nullptr ? object_getIvar(self, ivar) : nil;
+}
+
+- (void)hideDefaultBackgroundAndBorder {
+  CALayer *layer = self.layer;
+  layer.backgroundColor = nil;
+  layer.borderWidth = 0;
+  layer.borderColor = nil;
+  layer.cornerRadius = 0;
+  [self defaultBorderLayer].hidden = YES;
+}
+
+- (void)updateBackgroundWithColor:(nullable UIColor *)backgroundColor {
+  CALayer *layer = self.layer;
+  UIColor *color = [backgroundColor resolvedColorWithTraitCollection:self.traitCollection];
+  const CGFloat alpha = color != nil ? CGColorGetAlpha(color.CGColor) : 0;
+
+  if (alpha > 0) {
+    if (_backgroundLayer == nil) {
+      _backgroundLayer = [CAShapeLayer layer];
+      _backgroundLayer.zPosition = SquircleBackgroundZPosition;
+      [layer addSublayer:_backgroundLayer];
+    }
+    _backgroundLayer.frame = layer.bounds;
+    _backgroundLayer.path = _outerPath;
+    _backgroundLayer.fillColor = color.CGColor;
+  } else {
+    [_backgroundLayer removeFromSuperlayer];
+    _backgroundLayer = nil;
+  }
+
+  const BOOL hasShadow = layer.shadowOpacity > 0 && CGColorGetAlpha(layer.shadowColor) > 0;
+  layer.shadowPath = hasShadow && alpha > 0.999 ? _outerPath : nil;
+}
+
+- (void)updateBorderWithMetrics:(const BorderMetrics &)metrics {
+  const auto &widths = metrics.borderWidths;
+  if (widths.left <= 0 && widths.top <= 0 && widths.right <= 0 && widths.bottom <= 0) {
+    [self removeBorderLayers];
+    return;
+  }
+
+  CALayer *layer = self.layer;
+  UITraitCollection *traitCollection = self.traitCollection;
+  UIColor *top = SquircleResolvedColor(metrics.borderColors.top, traitCollection);
+  UIColor *right = SquircleResolvedColor(metrics.borderColors.right, traitCollection);
+  UIColor *bottom = SquircleResolvedColor(metrics.borderColors.bottom, traitCollection);
+  UIColor *left = SquircleResolvedColor(metrics.borderColors.left, traitCollection);
+
+  const BOOL uniformColor = CGColorEqualToColor(top.CGColor, right.CGColor) &&
+      CGColorEqualToColor(top.CGColor, bottom.CGColor) && CGColorEqualToColor(top.CGColor, left.CGColor);
+
+  if (!uniformColor) {
+    [_borderShapeLayer removeFromSuperlayer];
+    _borderShapeLayer = nil;
+
+    if (_multicolorBorderLayer == nil) {
+      _multicolorBorderLayer = [SquircleBorderLayer layer];
+      _multicolorBorderLayer.zPosition = SquircleBorderZPosition;
+      _multicolorBorderLayer.contentsScale = RCTScreenScale();
+      [layer addSublayer:_multicolorBorderLayer];
+    }
+    _multicolorBorderLayer.frame = layer.bounds;
+    [_multicolorBorderLayer updateWithBorderPath:_borderPath
+                                          insets:UIEdgeInsetsMake(widths.top, widths.left, widths.bottom, widths.right)
+                                        topColor:top
+                                      rightColor:right
+                                     bottomColor:bottom
+                                       leftColor:left];
+    return;
+  }
+
+  [_multicolorBorderLayer removeFromSuperlayer];
+  _multicolorBorderLayer = nil;
+
+  if (_borderShapeLayer == nil) {
+    _borderShapeLayer = [CAShapeLayer layer];
+    _borderShapeLayer.zPosition = SquircleBorderZPosition;
+    [layer addSublayer:_borderShapeLayer];
+  }
+  _borderShapeLayer.frame = layer.bounds;
+
+  const BorderStyle style = metrics.borderStyles.left;
+  if (style != BorderStyle::Solid && metrics.borderStyles.isUniform() && widths.isUniform()) {
+    const CGFloat width = widths.left;
+    const BOOL dotted = style == BorderStyle::Dotted;
+    _borderShapeLayer.path = [self strokePath];
+    _borderShapeLayer.fillColor = nil;
+    _borderShapeLayer.strokeColor = top.CGColor;
+    _borderShapeLayer.lineWidth = width;
+    _borderShapeLayer.lineCap = dotted ? kCALineCapRound : kCALineCapButt;
+    _borderShapeLayer.lineDashPattern = dotted ? @[ @0, @(width * 2) ] : @[ @(width * 3), @(width * 3) ];
+  } else {
+    _borderShapeLayer.path = _borderPath;
+    _borderShapeLayer.fillRule = kCAFillRuleEvenOdd;
+    _borderShapeLayer.fillColor = top.CGColor;
+    _borderShapeLayer.strokeColor = nil;
+    _borderShapeLayer.lineDashPattern = nil;
+  }
+}
+
+- (void)updateClipping {
+  UIView *containerView = self.currentContainerView;
+  if (!containerView.clipsToBounds) {
+    return;
+  }
+
+  if (_clipLayer == nil) {
+    _clipLayer = [CAShapeLayer layer];
+  }
+  _clipLayer.frame = containerView.bounds;
+  _clipLayer.path = ReactNativeFeatureFlags::enableIOSViewClipToPaddingBox() ? _innerPath : _outerPath;
+  containerView.layer.cornerRadius = 0;
+  containerView.layer.mask = _clipLayer;
+}
+
+- (void)removeBorderLayers {
+  [_borderShapeLayer removeFromSuperlayer];
+  _borderShapeLayer = nil;
+  [_multicolorBorderLayer removeFromSuperlayer];
+  _multicolorBorderLayer = nil;
+}
+
+- (void)removeSquircleLayers {
+  [_backgroundLayer removeFromSuperlayer];
+  _backgroundLayer = nil;
+  [self removeBorderLayers];
+  _clipLayer = nil;
+  [self defaultBorderLayer].hidden = NO;
+  [self releasePaths];
+}
+
+@end

package/lib/module/components/index.js

@@ -0,0 +1,4 @@
+"use strict";
+
+export { SquircleView } from './squircle-view';
+//# sourceMappingURL=index.js.map

package/lib/module/components/index.js.map

@@ -0,0 +1 @@
+{"version":3,"names":["SquircleView"],"sourceRoot":"../../../src","sources":["components/index.ts"],"mappings":";;AAAA,SAASA,YAAY,QAAQ,iBAAiB","ignoreList":[]}

package/lib/module/components/squircle-view.js

@@ -0,0 +1,22 @@
+"use strict";
+
+import * as React from 'react';
+import { useMemo } from 'react';
+import { View } from 'react-native';
+import { COMPONENT_NAMES } from "../constants/index.js";
+import { splitSquircleStyle } from "../utils/index.js";
+import { jsx as _jsx } from "react/jsx-runtime";
+const SquircleView = ({
+  style,
+  borderSmoothing: _borderSmoothing,
+  ...rest
+}) => {
+  const squircleStyle = useMemo(() => splitSquircleStyle(style), [style]);
+  return /*#__PURE__*/_jsx(View, {
+    ...rest,
+    style: squircleStyle.style
+  });
+};
+SquircleView.displayName = COMPONENT_NAMES.SQUIRCLE_VIEW;
+export { SquircleView };
+//# sourceMappingURL=squircle-view.js.map

package/lib/module/components/squircle-view.js.map

@@ -0,0 +1 @@
+{"version":3,"names":["React","useMemo","View","COMPONENT_NAMES","splitSquircleStyle","jsx","_jsx","SquircleView","style","borderSmoothing","_borderSmoothing","rest","squircleStyle","displayName","SQUIRCLE_VIEW"],"sourceRoot":"../../../src","sources":["components/squircle-view.tsx"],"mappings":";;AAAA,OAAO,KAAKA,KAAK,MAAM,OAAO;AAC9B,SAASC,OAAO,QAAQ,OAAO;AAC/B,SAASC,IAAI,QAAwB,cAAc;AACnD,SAASC,eAAe,QAAQ,uBAAc;AAE9C,SAASC,kBAAkB,QAAQ,mBAAU;AAAC,SAAAC,GAAA,IAAAC,IAAA;AAG9C,MAAMC,YAA0C,GAAGA,CAAC;EAClDC,KAAK;EACLC,eAAe,EAAEC,gBAAgB;EACjC,GAAGC;AACe,CAAC,KAA0C;EAC7D,MAAMC,aAAa,GAAGX,OAAO,CAC3B,MAAMG,kBAAkB,CAAgCI,KAAK,CAAC,EAC9D,CAACA,KAAK,CACR,CAAC;EAED,oBAAOF,IAAA,CAACJ,IAAI;IAAA,GAAKS,IAAI;IAAEH,KAAK,EAAEI,aAAa,CAACJ;EAAM,CAAE,CAAC;AACvD,CAAC;AAEDD,YAAY,CAACM,WAAW,GAAGV,eAAe,CAACW,aAAa;AAExD,SAASP,YAAY","ignoreList":[]}

package/lib/module/components/squircle-view.native.js

@@ -0,0 +1,23 @@
+"use strict";
+
+import * as React from 'react';
+import { useMemo } from 'react';
+import { COMPONENT_NAMES, DEFAULT_BORDER_SMOOTHING } from "../constants/index.js";
+import { splitSquircleStyle } from "../utils/index.js";
+import { NativeSquircleView } from "../views/index.js";
+import { jsx as _jsx } from "react/jsx-runtime";
+const SquircleView = ({
+  style,
+  borderSmoothing,
+  ...rest
+}) => {
+  const squircleStyle = useMemo(() => splitSquircleStyle(style), [style]);
+  return /*#__PURE__*/_jsx(NativeSquircleView, {
+    ...rest,
+    style: squircleStyle.style,
+    borderSmoothing: squircleStyle.borderSmoothing ?? borderSmoothing ?? DEFAULT_BORDER_SMOOTHING
+  });
+};
+SquircleView.displayName = COMPONENT_NAMES.SQUIRCLE_VIEW;
+export { SquircleView };
+//# sourceMappingURL=squircle-view.native.js.map

package/lib/module/components/squircle-view.native.js.map

@@ -0,0 +1 @@
+{"version":3,"names":["React","useMemo","COMPONENT_NAMES","DEFAULT_BORDER_SMOOTHING","splitSquircleStyle","NativeSquircleView","jsx","_jsx","SquircleView","style","borderSmoothing","rest","squircleStyle","displayName","SQUIRCLE_VIEW"],"sourceRoot":"../../../src","sources":["components/squircle-view.native.tsx"],"mappings":";;AAAA,OAAO,KAAKA,KAAK,MAAM,OAAO;AAC9B,SAASC,OAAO,QAAQ,OAAO;AAE/B,SAASC,eAAe,EAAEC,wBAAwB,QAAQ,uBAAc;AAExE,SAASC,kBAAkB,QAAQ,mBAAU;AAC7C,SAASC,kBAAkB,QAAQ,mBAAU;AAAC,SAAAC,GAAA,IAAAC,IAAA;AAE9C,MAAMC,YAA0C,GAAGA,CAAC;EAClDC,KAAK;EACLC,eAAe;EACf,GAAGC;AACe,CAAC,KAAwB;EAC3C,MAAMC,aAAa,GAAGX,OAAO,CAC3B,MAAMG,kBAAkB,CAACK,KAAK,CAAC,EAC/B,CAACA,KAAK,CACR,CAAC;EAED,oBACEF,IAAA,CAACF,kBAAkB;IAAA,GACbM,IAAI;IACRF,KAAK,EAAEG,aAAa,CAACH,KAAM;IAC3BC,eAAe,EACbE,aAAa,CAACF,eAAe,IAC7BA,eAAe,IACfP;EACD,CACF,CAAC;AAEN,CAAC;AAEDK,YAAY,CAACK,WAAW,GAAGX,eAAe,CAACY,aAAa;AAExD,SAASN,YAAY","ignoreList":[]}

package/lib/module/constants/index.js

@@ -0,0 +1,5 @@
+"use strict";
+
+export * from "./native.constants.js";
+export * from "./squircle.constants.js";
+//# sourceMappingURL=index.js.map

package/lib/module/constants/index.js.map

@@ -0,0 +1 @@
+{"version":3,"names":[],"sourceRoot":"../../../src","sources":["constants/index.ts"],"mappings":";;AAAA,cAAc,uBAAoB;AAClC,cAAc,yBAAsB","ignoreList":[]}

package/lib/module/constants/native.constants.js

@@ -0,0 +1,10 @@
+"use strict";
+
+const NATIVE_VIEW_NAMES = {
+  SQUIRCLE_VIEW: 'SquircleView'
+};
+const COMPONENT_NAMES = {
+  SQUIRCLE_VIEW: 'SquircleView'
+};
+export { NATIVE_VIEW_NAMES, COMPONENT_NAMES };
+//# sourceMappingURL=native.constants.js.map

package/lib/module/constants/native.constants.js.map

@@ -0,0 +1 @@
+{"version":3,"names":["NATIVE_VIEW_NAMES","SQUIRCLE_VIEW","COMPONENT_NAMES"],"sourceRoot":"../../../src","sources":["constants/native.constants.ts"],"mappings":";;AAAA,MAAMA,iBAAiB,GAAG;EACxBC,aAAa,EAAE;AACjB,CAA2C;AAE3C,MAAMC,eAAe,GAAG;EACtBD,aAAa,EAAE;AACjB,CAA2C;AAE3C,SAASD,iBAAiB,EAAEE,eAAe","ignoreList":[]}

package/lib/module/constants/squircle.constants.js

@@ -0,0 +1,5 @@
+"use strict";
+
+const DEFAULT_BORDER_SMOOTHING = 0;
+export { DEFAULT_BORDER_SMOOTHING };
+//# sourceMappingURL=squircle.constants.js.map

package/lib/module/constants/squircle.constants.js.map

@@ -0,0 +1 @@
+{"version":3,"names":["DEFAULT_BORDER_SMOOTHING"],"sourceRoot":"../../../src","sources":["constants/squircle.constants.ts"],"mappings":";;AAAA,MAAMA,wBAAgC,GAAG,CAAC;AAE1C,SAASA,wBAAwB","ignoreList":[]}

package/lib/module/index.js

@@ -0,0 +1,4 @@
+"use strict";
+
+export * from "./root/index.js";
+//# sourceMappingURL=index.js.map

package/lib/module/index.js.map

@@ -0,0 +1 @@
+{"version":3,"names":[],"sourceRoot":"../../src","sources":["index.ts"],"mappings":";;AAAA,cAAc,iBAAQ","ignoreList":[]}

package/lib/module/interfaces/index.js

@@ -0,0 +1,5 @@
+"use strict";
+
+export * from "./squircle-style.interface.js";
+export * from "./squircle-view.interface.js";
+//# sourceMappingURL=index.js.map

package/lib/module/interfaces/index.js.map

@@ -0,0 +1 @@
+{"version":3,"names":[],"sourceRoot":"../../../src","sources":["interfaces/index.ts"],"mappings":";;AAAA,cAAc,+BAA4B;AAC1C,cAAc,8BAA2B","ignoreList":[]}

package/lib/module/interfaces/squircle-style.interface.js

@@ -0,0 +1,4 @@
+"use strict";
+
+export {};
+//# sourceMappingURL=squircle-style.interface.js.map

package/lib/module/interfaces/squircle-style.interface.js.map

@@ -0,0 +1 @@
+{"version":3,"names":[],"sourceRoot":"../../../src","sources":["interfaces/squircle-style.interface.ts"],"mappings":"","ignoreList":[]}

package/lib/module/interfaces/squircle-view.interface.js

@@ -0,0 +1,4 @@
+"use strict";
+
+export {};
+//# sourceMappingURL=squircle-view.interface.js.map

package/lib/module/interfaces/squircle-view.interface.js.map

@@ -0,0 +1 @@
+{"version":3,"names":[],"sourceRoot":"../../../src","sources":["interfaces/squircle-view.interface.ts"],"mappings":"","ignoreList":[]}

package/lib/module/package.json

@@ -0,0 +1 @@
+{"type":"module"}

package/lib/module/root/index.js

@@ -0,0 +1,4 @@
+"use strict";
+
+export { SquircleView } from "../components/index.js";
+//# sourceMappingURL=index.js.map

package/lib/module/root/index.js.map

@@ -0,0 +1 @@
+{"version":3,"names":["SquircleView"],"sourceRoot":"../../../src","sources":["root/index.ts"],"mappings":";;AAAA,SAASA,YAAY,QAAQ,wBAAe","ignoreList":[]}