skydive-cli 0.2.0-beta.742 → 0.3.0-beta.764

package/dist/js/chat/tui/chunks/grammars/assets/ruby.highlights.scm

@@ -0,0 +1,154 @@
+(identifier) @variable
+
+((identifier) @function.method
+ (#is-not? local))
+
+[
+  "alias"
+  "and"
+  "begin"
+  "break"
+  "case"
+  "class"
+  "def"
+  "do"
+  "else"
+  "elsif"
+  "end"
+  "ensure"
+  "for"
+  "if"
+  "in"
+  "module"
+  "next"
+  "or"
+  "rescue"
+  "retry"
+  "return"
+  "then"
+  "unless"
+  "until"
+  "when"
+  "while"
+  "yield"
+] @keyword
+
+((identifier) @keyword
+ (#match? @keyword "^(private|protected|public)$"))
+
+(constant) @constructor
+
+; Function calls
+
+"defined?" @function.method.builtin
+
+(call
+  method: [(identifier) (constant)] @function.method)
+
+((identifier) @function.method.builtin
+ (#eq? @function.method.builtin "require"))
+
+; Function definitions
+
+(alias (identifier) @function.method)
+(setter (identifier) @function.method)
+(method name: [(identifier) (constant)] @function.method)
+(singleton_method name: [(identifier) (constant)] @function.method)
+
+; Identifiers
+
+[
+  (class_variable)
+  (instance_variable)
+] @property
+
+((identifier) @constant.builtin
+ (#match? @constant.builtin "^__(FILE|LINE|ENCODING)__$"))
+
+(file) @constant.builtin
+(line) @constant.builtin
+(encoding) @constant.builtin
+
+(hash_splat_nil
+  "**" @operator) @constant.builtin
+
+((constant) @constant
+ (#match? @constant "^[A-Z\\d_]+$"))
+
+[
+  (self)
+  (super)
+] @variable.builtin
+
+(block_parameter (identifier) @variable.parameter)
+(block_parameters (identifier) @variable.parameter)
+(destructured_parameter (identifier) @variable.parameter)
+(hash_splat_parameter (identifier) @variable.parameter)
+(lambda_parameters (identifier) @variable.parameter)
+(method_parameters (identifier) @variable.parameter)
+(splat_parameter (identifier) @variable.parameter)
+
+(keyword_parameter name: (identifier) @variable.parameter)
+(optional_parameter name: (identifier) @variable.parameter)
+
+; Literals
+
+[
+  (string)
+  (bare_string)
+  (subshell)
+  (heredoc_body)
+  (heredoc_beginning)
+] @string
+
+[
+  (simple_symbol)
+  (delimited_symbol)
+  (hash_key_symbol)
+  (bare_symbol)
+] @string.special.symbol
+
+(regex) @string.special.regex
+(escape_sequence) @escape
+
+[
+  (integer)
+  (float)
+] @number
+
+[
+  (nil)
+  (true)
+  (false)
+] @constant.builtin
+
+(interpolation
+  "#{" @punctuation.special
+  "}" @punctuation.special) @embedded
+
+(comment) @comment
+
+; Operators
+
+[
+"="
+"=>"
+"->"
+] @operator
+
+[
+  ","
+  ";"
+  "."
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "%w("
+  "%i("
+] @punctuation.bracket

package/dist/js/chat/tui/chunks/grammars/assets/rust.highlights.scm

@@ -0,0 +1,161 @@
+; Identifiers
+
+(type_identifier) @type
+(primitive_type) @type.builtin
+(field_identifier) @property
+
+; Identifier conventions
+
+; Assume all-caps names are constants
+((identifier) @constant
+ (#match? @constant "^[A-Z][A-Z\\d_]+$'"))
+
+; Assume uppercase names are enum constructors
+((identifier) @constructor
+ (#match? @constructor "^[A-Z]"))
+
+; Assume that uppercase names in paths are types
+((scoped_identifier
+  path: (identifier) @type)
+ (#match? @type "^[A-Z]"))
+((scoped_identifier
+  path: (scoped_identifier
+    name: (identifier) @type))
+ (#match? @type "^[A-Z]"))
+((scoped_type_identifier
+  path: (identifier) @type)
+ (#match? @type "^[A-Z]"))
+((scoped_type_identifier
+  path: (scoped_identifier
+    name: (identifier) @type))
+ (#match? @type "^[A-Z]"))
+
+; Assume all qualified names in struct patterns are enum constructors. (They're
+; either that, or struct names; highlighting both as constructors seems to be
+; the less glaring choice of error, visually.)
+(struct_pattern
+  type: (scoped_type_identifier
+    name: (type_identifier) @constructor))
+
+; Function calls
+
+(call_expression
+  function: (identifier) @function)
+(call_expression
+  function: (field_expression
+    field: (field_identifier) @function.method))
+(call_expression
+  function: (scoped_identifier
+    "::"
+    name: (identifier) @function))
+
+(generic_function
+  function: (identifier) @function)
+(generic_function
+  function: (scoped_identifier
+    name: (identifier) @function))
+(generic_function
+  function: (field_expression
+    field: (field_identifier) @function.method))
+
+(macro_invocation
+  macro: (identifier) @function.macro
+  "!" @function.macro)
+
+; Function definitions
+
+(function_item (identifier) @function)
+(function_signature_item (identifier) @function)
+
+(line_comment) @comment
+(block_comment) @comment
+
+(line_comment (doc_comment)) @comment.documentation
+(block_comment (doc_comment)) @comment.documentation
+
+"(" @punctuation.bracket
+")" @punctuation.bracket
+"[" @punctuation.bracket
+"]" @punctuation.bracket
+"{" @punctuation.bracket
+"}" @punctuation.bracket
+
+(type_arguments
+  "<" @punctuation.bracket
+  ">" @punctuation.bracket)
+(type_parameters
+  "<" @punctuation.bracket
+  ">" @punctuation.bracket)
+
+"::" @punctuation.delimiter
+":" @punctuation.delimiter
+"." @punctuation.delimiter
+"," @punctuation.delimiter
+";" @punctuation.delimiter
+
+(parameter (identifier) @variable.parameter)
+
+(lifetime (identifier) @label)
+
+"as" @keyword
+"async" @keyword
+"await" @keyword
+"break" @keyword
+"const" @keyword
+"continue" @keyword
+"default" @keyword
+"dyn" @keyword
+"else" @keyword
+"enum" @keyword
+"extern" @keyword
+"fn" @keyword
+"for" @keyword
+"gen" @keyword
+"if" @keyword
+"impl" @keyword
+"in" @keyword
+"let" @keyword
+"loop" @keyword
+"macro_rules!" @keyword
+"match" @keyword
+"mod" @keyword
+"move" @keyword
+"pub" @keyword
+"raw" @keyword
+"ref" @keyword
+"return" @keyword
+"static" @keyword
+"struct" @keyword
+"trait" @keyword
+"type" @keyword
+"union" @keyword
+"unsafe" @keyword
+"use" @keyword
+"where" @keyword
+"while" @keyword
+"yield" @keyword
+(crate) @keyword
+(mutable_specifier) @keyword
+(use_list (self) @keyword)
+(scoped_use_list (self) @keyword)
+(scoped_identifier (self) @keyword)
+(super) @keyword
+
+(self) @variable.builtin
+
+(char_literal) @string
+(string_literal) @string
+(raw_string_literal) @string
+
+(boolean_literal) @constant.builtin
+(integer_literal) @constant.builtin
+(float_literal) @constant.builtin
+
+(escape_sequence) @escape
+
+(attribute_item) @attribute
+(inner_attribute_item) @attribute
+
+"*" @operator
+"&" @operator
+"'" @operator

package/dist/js/chat/tui/chunks/grammars/assets/toml.highlights.scm

@@ -0,0 +1,53 @@
+; Properties
+;-----------
+
+(bare_key) @type
+
+(quoted_key) @string
+
+(pair
+  (bare_key)) @property
+
+(pair
+  (dotted_key
+    (bare_key) @property))
+
+; Literals
+;---------
+
+(boolean) @boolean
+
+(comment) @comment
+
+(string) @string
+
+[
+  (integer)
+  (float)
+] @number
+
+[
+  (offset_date_time)
+  (local_date_time)
+  (local_date)
+  (local_time)
+] @string.special
+
+; Punctuation
+;------------
+
+[
+  "."
+  ","
+] @punctuation.delimiter
+
+"=" @operator
+
+[
+  "["
+  "]"
+  "[["
+  "]]"
+  "{"
+  "}"
+] @punctuation.bracket

package/dist/js/chat/tui/chunks/grammars/assets/yaml.highlights.scm

@@ -0,0 +1,79 @@
+(boolean_scalar) @boolean
+
+(null_scalar) @constant.builtin
+
+[
+  (double_quote_scalar)
+  (single_quote_scalar)
+  (block_scalar)
+  (string_scalar)
+] @string
+
+[
+  (integer_scalar)
+  (float_scalar)
+] @number
+
+(comment) @comment
+
+[
+  (anchor_name)
+  (alias_name)
+] @label
+
+(tag) @type
+
+[
+  (yaml_directive)
+  (tag_directive)
+  (reserved_directive)
+] @attribute
+
+(block_mapping_pair
+  key: (flow_node
+    [
+      (double_quote_scalar)
+      (single_quote_scalar)
+    ] @property))
+
+(block_mapping_pair
+  key: (flow_node
+    (plain_scalar
+      (string_scalar) @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      [
+        (double_quote_scalar)
+        (single_quote_scalar)
+      ] @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      (plain_scalar
+        (string_scalar) @property))))
+
+[
+  ","
+  "-"
+  ":"
+  ">"
+  "?"
+  "|"
+] @punctuation.delimiter
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "*"
+  "&"
+  "---"
+  "..."
+] @punctuation.special

package/dist/js/chat/tui/chunks/grammars/grammars.ts

@@ -0,0 +1,146 @@
+/**
+ * Extra tree-sitter grammars for the chat TUI, on top of OpenTUI's five
+ * bundled ones (javascript, typescript, markdown, zig). Without these, every
+ * fenced code block and every diff/file-review pane in a non-js/ts language
+ * renders unhighlighted.
+ *
+ * Each entry pairs a prebuilt `.wasm` parser with its co-versioned
+ * `highlights.scm` query. `scripts/fetch-grammars.ts` vendors both from the
+ * same npm package into ./assets and records the versions in manifest.json —
+ * grammar and query MUST match or `Query` compilation throws at runtime.
+ *
+ * ── Why the `with { type: 'file' }` imports ──────────────────────────────
+ * The chat TUI always runs under Bun (the `chat` command re-execs itself
+ * under Bun before it touches OpenTUI). Under Bun these imports resolve to a
+ * real filesystem path in dev, and `bun build --compile` embeds each asset
+ * into the binary's virtual filesystem and rewrites the path to `/$bunfs`.
+ * OpenTUI loads its own bundled grammars exactly this way.
+ *
+ * Rolldown (tsdown, the npm build) CANNOT parse `.wasm`/`.scm` as modules, so
+ * this file is externalized in tsdown.config.mts and copied verbatim into
+ * dist/js/chat/tui/chunks/grammars/ alongside its assets; the bundled
+ * bin.mjs reaches it through a dynamic import that Bun resolves at runtime.
+ * Keep every asset reference a static `with { type: 'file' }` import so the
+ * compiled binary discovers and embeds them — a runtime `Bun.file(path)` on
+ * a computed path would not be embedded.
+ */
+import type { FiletypeParserOptions } from '@opentui/core';
+
+import python_wasm from './assets/python.wasm' with { type: 'file' };
+import python_scm from './assets/python.highlights.scm' with { type: 'file' };
+import bash_wasm from './assets/bash.wasm' with { type: 'file' };
+import bash_scm from './assets/bash.highlights.scm' with { type: 'file' };
+import go_wasm from './assets/go.wasm' with { type: 'file' };
+import go_scm from './assets/go.highlights.scm' with { type: 'file' };
+import rust_wasm from './assets/rust.wasm' with { type: 'file' };
+import rust_scm from './assets/rust.highlights.scm' with { type: 'file' };
+import c_wasm from './assets/c.wasm' with { type: 'file' };
+import c_scm from './assets/c.highlights.scm' with { type: 'file' };
+import cpp_wasm from './assets/cpp.wasm' with { type: 'file' };
+import cpp_scm from './assets/cpp.highlights.scm' with { type: 'file' };
+import java_wasm from './assets/java.wasm' with { type: 'file' };
+import java_scm from './assets/java.highlights.scm' with { type: 'file' };
+import ruby_wasm from './assets/ruby.wasm' with { type: 'file' };
+import ruby_scm from './assets/ruby.highlights.scm' with { type: 'file' };
+import css_wasm from './assets/css.wasm' with { type: 'file' };
+import css_scm from './assets/css.highlights.scm' with { type: 'file' };
+import html_wasm from './assets/html.wasm' with { type: 'file' };
+import html_scm from './assets/html.highlights.scm' with { type: 'file' };
+import json_wasm from './assets/json.wasm' with { type: 'file' };
+import json_scm from './assets/json.highlights.scm' with { type: 'file' };
+import yaml_wasm from './assets/yaml.wasm' with { type: 'file' };
+import yaml_scm from './assets/yaml.highlights.scm' with { type: 'file' };
+import toml_wasm from './assets/toml.wasm' with { type: 'file' };
+import toml_scm from './assets/toml.highlights.scm' with { type: 'file' };
+import lua_wasm from './assets/lua.wasm' with { type: 'file' };
+import lua_scm from './assets/lua.highlights.scm' with { type: 'file' };
+
+/**
+ * `aliases` are the alternate names a code fence or file extension may use
+ * for the language (```sh → bash, ```py → python). OpenTUI's markdown
+ * injection resolver looks up a fence's info-string against each parser's
+ * registered aliases, so listing them here is what makes ```sh highlight.
+ * The canonical `filetype` need not be repeated in its own alias list.
+ */
+export const EXTRA_GRAMMARS: FiletypeParserOptions[] = [
+  {
+    filetype: 'python',
+    aliases: ['py', 'python3'],
+    wasm: python_wasm,
+    queries: { highlights: [python_scm] },
+  },
+  {
+    filetype: 'bash',
+    aliases: ['sh', 'shell', 'zsh', 'shellscript'],
+    wasm: bash_wasm,
+    queries: { highlights: [bash_scm] },
+  },
+  {
+    filetype: 'go',
+    aliases: ['golang'],
+    wasm: go_wasm,
+    queries: { highlights: [go_scm] },
+  },
+  {
+    filetype: 'rust',
+    aliases: ['rs'],
+    wasm: rust_wasm,
+    queries: { highlights: [rust_scm] },
+  },
+  {
+    filetype: 'c',
+    aliases: ['h'],
+    wasm: c_wasm,
+    queries: { highlights: [c_scm] },
+  },
+  {
+    filetype: 'cpp',
+    aliases: ['c++', 'cc', 'cxx', 'hpp', 'hxx', 'hh'],
+    wasm: cpp_wasm,
+    queries: { highlights: [cpp_scm] },
+  },
+  {
+    filetype: 'java',
+    wasm: java_wasm,
+    queries: { highlights: [java_scm] },
+  },
+  {
+    filetype: 'ruby',
+    aliases: ['rb'],
+    wasm: ruby_wasm,
+    queries: { highlights: [ruby_scm] },
+  },
+  {
+    filetype: 'css',
+    wasm: css_wasm,
+    queries: { highlights: [css_scm] },
+  },
+  {
+    filetype: 'html',
+    aliases: ['htm'],
+    wasm: html_wasm,
+    queries: { highlights: [html_scm] },
+  },
+  {
+    filetype: 'json',
+    aliases: ['jsonc'],
+    wasm: json_wasm,
+    queries: { highlights: [json_scm] },
+  },
+  {
+    filetype: 'yaml',
+    aliases: ['yml'],
+    wasm: yaml_wasm,
+    queries: { highlights: [yaml_scm] },
+  },
+  {
+    filetype: 'toml',
+    wasm: toml_wasm,
+    queries: { highlights: [toml_scm] },
+  },
+  {
+    filetype: 'lua',
+    wasm: lua_wasm,
+    queries: { highlights: [lua_scm] },
+  },
+];

package/dist/js/{install-Cv3sBZxr.mjs → install-DEZmJLGH.mjs}

@@ -8,7 +8,7 @@ import fs from "node:fs";
 
 //#region package.json
 var name = "skydive-cli";
-var version$1 = "0.2.0-beta.742";
+var version$1 = "0.3.0-beta.764";
 
 //#endregion
 //#region src/auth/organization.ts

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "skydive-cli",
-  "version": "0.2.0-beta.742",
+  "version": "0.3.0-beta.764",
   "description": "Skydive CLI — cloud agents from the command line",
   "homepage": "https://skydive.com",
   "license": "MIT",