skill-universe 1.1.0

package/src/skillc/error.gleam

@@ -0,0 +1,37 @@
+import gleam/int
+import gleam/result
+import simplifile
+
+pub type SkillError {
+  ParseError(file: String, message: String)
+  ValidationError(field: String, message: String)
+  TemplateError(line: Int, message: String)
+  ProviderError(provider: String, message: String)
+  FileError(path: String, error: simplifile.FileError)
+  RegistryError(message: String)
+  ImportError(source: String, message: String)
+}
+
+pub fn to_string(error: SkillError) -> String {
+  case error {
+    ParseError(file, message) -> "Parse error in " <> file <> ": " <> message
+    ValidationError(field, message) ->
+      "Validation error for field '" <> field <> "': " <> message
+    TemplateError(line, message) ->
+      "Template error at line " <> int.to_string(line) <> ": " <> message
+    ProviderError(provider, message) ->
+      "Provider error (" <> provider <> "): " <> message
+    FileError(path, error) ->
+      "File error at " <> path <> ": " <> simplifile.describe_error(error)
+    RegistryError(message) -> "Registry error: " <> message
+    ImportError(source, message) ->
+      "Import error (" <> source <> "): " <> message
+  }
+}
+
+pub fn map_file_error(
+  result: Result(a, simplifile.FileError),
+  path: String,
+) -> Result(a, SkillError) {
+  result.map_error(result, fn(e) { FileError(path, e) })
+}

package/src/skillc/fs.gleam

@@ -0,0 +1,31 @@
+import gleam/list
+import gleam/result
+import simplifile
+import skillc/error.{type SkillError, map_file_error}
+import skillc/path
+import skillc/types.{type FileCopy}
+
+pub fn copy_file_list(
+  files: List(FileCopy),
+  dest_dir: String,
+) -> Result(Nil, SkillError) {
+  case files {
+    [] -> Ok(Nil)
+    _ -> {
+      use _ <- result.try(
+        simplifile.create_directory_all(dest_dir)
+        |> map_file_error(dest_dir),
+      )
+      list.try_each(files, fn(f) {
+        let dest = dest_dir <> "/" <> f.relative_path
+        let parent = path.parent_dir(dest)
+        use _ <- result.try(
+          simplifile.create_directory_all(parent)
+          |> map_file_error(parent),
+        )
+        simplifile.copy_file(f.src, dest)
+        |> map_file_error(f.src)
+      })
+    }
+  }
+}