react-native 0.83.0-nightly-20251104-502efe1cc → 0.84.0-nightly-20251105-5ec5cc3a3

package/React/CxxModule/RCTCxxModule.h

@@ -1,29 +0,0 @@
-/*
- * Copyright (c) Meta Platforms, Inc. and affiliates.
- *
- * This source code is licensed under the MIT license found in the
- * LICENSE file in the root directory of this source tree.
- */
-
-#import <memory>
-
-#import <Foundation/Foundation.h>
-
-#import <React/RCTBridgeModule.h>
-
-namespace facebook::xplat::module {
-class CxxModule;
-} // namespace facebook::xplat::module
-
-/**
- * Subclass RCTCxxModule to use cross-platform CxxModule on iOS.
- *
- * Subclasses must implement the createModule method to lazily produce the module. When running under the Cxx bridge
- * modules will be accessed directly, under the Objective-C bridge method access is wrapped through RCTCxxMethod.
- */
-@interface RCTCxxModule : NSObject <RCTBridgeModule>
-
-// To be implemented by subclasses
-- (std::unique_ptr<facebook::xplat::module::CxxModule>)createModule;
-
-@end

package/React/CxxModule/RCTCxxModule.mm

@@ -1,87 +0,0 @@
-/*
- * Copyright (c) Meta Platforms, Inc. and affiliates.
- *
- * This source code is licensed under the MIT license found in the
- * LICENSE file in the root directory of this source tree.
- */
-
-#import "RCTCxxModule.h"
-
-#import <React/RCTBridge.h>
-#import <React/RCTLog.h>
-#import <cxxreact/CxxModule.h>
-#import <react/utils/FollyConvert.h>
-
-#import "RCTCxxMethod.h"
-
-using namespace facebook::react;
-
-@implementation RCTCxxModule {
-  std::unique_ptr<facebook::xplat::module::CxxModule> _module;
-}
-
-+ (NSString *)moduleName
-{
-  return @"";
-}
-
-+ (BOOL)requiresMainQueueSetup
-{
-  return NO;
-}
-
-- (void)lazyInit
-{
-  if (!_module) {
-    _module = [self createModule];
-
-    if (_module) {
-      RCTAssert(
-          [RCTBridgeModuleNameForClass([self class]) isEqualToString:@(_module->getName().c_str())],
-          @"CxxModule class name %@ does not match runtime name %s",
-          RCTBridgeModuleNameForClass([self class]),
-          _module->getName().c_str());
-    }
-  }
-}
-
-- (std::unique_ptr<facebook::xplat::module::CxxModule>)createModule
-{
-  RCTAssert(NO, @"Subclass %@ must override createModule", [self class]);
-  return nullptr;
-}
-
-- (NSArray<id<RCTBridgeMethod>> *)methodsToExport
-{
-  [self lazyInit];
-  if (!_module) {
-    return nil;
-  }
-
-  NSMutableArray *moduleMethods = [NSMutableArray new];
-  for (const auto &method : _module->getMethods()) {
-    [moduleMethods addObject:[[RCTCxxMethod alloc] initWithCxxMethod:method]];
-  }
-  return moduleMethods;
-}
-
-- (NSDictionary<NSString *, id> *)constantsToExport
-{
-  return [self getConstants];
-}
-
-- (NSDictionary<NSString *, id> *)getConstants
-{
-  [self lazyInit];
-  if (!_module) {
-    return nil;
-  }
-
-  NSMutableDictionary *moduleConstants = [NSMutableDictionary new];
-  for (const auto &c : _module->getConstants()) {
-    moduleConstants[@(c.first.c_str())] = convertFollyDynamicToId(c.second);
-  }
-  return moduleConstants;
-}
-
-@end