react-native-wgpu 0.5.13 → 0.5.14

package/apple/ApplePlatformContext.mm

@@ -1,302 +0,0 @@
-#include "ApplePlatformContext.h"
-
-#include <TargetConditionals.h>
-
-#import <AVFoundation/AVFoundation.h>
-#import <CoreVideo/CoreVideo.h>
-#import <React/RCTBlobManager.h>
-#import <React/RCTBridge+Private.h>
-#import <ReactCommon/RCTTurboModule.h>
-
-#include "AppleVideoPlayer.h"
-
-#include "RNWebGPUManager.h"
-#include "WebGPUModule.h"
-
-namespace rnwgpu {
-
-void checkIfUsingSimulatorWithAPIValidation() {
-#if TARGET_OS_SIMULATOR
-  NSDictionary *environment = [[NSProcessInfo processInfo] environment];
-  NSString *metalDeviceWrapperType = environment[@"METAL_DEVICE_WRAPPER_TYPE"];
-
-  if ([metalDeviceWrapperType isEqualToString:@"1"]) {
-    throw std::runtime_error(
-        "To use React Native WebGPU project on the iOS simulator, you need to "
-        "disable the Metal validation API. In 'Edit Scheme,' uncheck 'Metal "
-        "Validation.'");
-  }
-#endif
-}
-
-ApplePlatformContext::ApplePlatformContext() {
-  checkIfUsingSimulatorWithAPIValidation();
-}
-
-wgpu::Surface ApplePlatformContext::makeSurface(wgpu::Instance instance,
-                                                void *surface, int width,
-                                                int height) {
-  wgpu::SurfaceSourceMetalLayer metalSurfaceDesc;
-  metalSurfaceDesc.layer = surface;
-  wgpu::SurfaceDescriptor surfaceDescriptor;
-  surfaceDescriptor.nextInChain = &metalSurfaceDesc;
-  return instance.CreateSurface(&surfaceDescriptor);
-}
-
-static std::span<const uint8_t> nsDataToSpan(NSData *data) {
-  return {static_cast<const uint8_t *>(data.bytes), data.length};
-}
-
-ImageData ApplePlatformContext::createImageBitmap(std::string blobId,
-                                                  double offset, double size) {
-  RCTBlobManager *blobManager =
-      [[RCTBridge currentBridge] moduleForClass:RCTBlobManager.class];
-  NSData *blobData =
-      [blobManager resolve:[NSString stringWithUTF8String:blobId.c_str()]
-                    offset:(long)offset
-                      size:(long)size];
-
-  if (!blobData) {
-    throw std::runtime_error("Couldn't retrieve blob data");
-  }
-
-  return createImageBitmapFromData(nsDataToSpan(blobData));
-}
-
-void ApplePlatformContext::createImageBitmapAsync(
-    std::string blobId, double offset, double size,
-    std::function<void(ImageData)> onSuccess,
-    std::function<void(std::string)> onError) {
-  // Resolve blob on current thread (requires RCTBridge access)
-  RCTBlobManager *blobManager =
-      [[RCTBridge currentBridge] moduleForClass:RCTBlobManager.class];
-  NSData *blobData =
-      [blobManager resolve:[NSString stringWithUTF8String:blobId.c_str()]
-                    offset:(long)offset
-                      size:(long)size];
-
-  if (!blobData) {
-    onError("Couldn't retrieve blob data");
-    return;
-  }
-
-  // blobData is alive during this synchronous call;
-  // createImageBitmapFromDataAsync copies the span before dispatching
-  createImageBitmapFromDataAsync(nsDataToSpan(blobData), std::move(onSuccess),
-                                 std::move(onError));
-}
-
-ImageData
-ApplePlatformContext::createImageBitmapFromData(std::span<const uint8_t> data) {
-  // This avoids a copy by assuming the UIImage/NSImage constructors
-  // decode `nsData` eagerly before the memory for the wrapped `data`
-  // is freed.
-  //
-  // Since we get the `CGImageRef` from `image` and then throw
-  // it away, that's a fairly safe assumption.
-  NSData *nsData =
-      [NSData dataWithBytesNoCopy:const_cast<uint8_t *>(data.data())
-                           length:data.size()
-                     freeWhenDone:NO];
-
-#if !TARGET_OS_OSX
-  UIImage *image = [UIImage imageWithData:nsData];
-#else
-  NSImage *image = [[NSImage alloc] initWithData:nsData];
-#endif
-  if (!image) {
-    throw std::runtime_error("Couldn't decode image");
-  }
-
-#if !TARGET_OS_OSX
-  CGImageRef cgImage = image.CGImage;
-#else
-  CGImageRef cgImage = [image CGImageForProposedRect:NULL
-                                             context:NULL
-                                               hints:NULL];
-#endif
-  size_t width = CGImageGetWidth(cgImage);
-  size_t height = CGImageGetHeight(cgImage);
-  size_t bitsPerComponent = 8;
-  size_t bytesPerRow = width * 4;
-
-  ImageData result;
-  result.width = static_cast<int>(width);
-  result.height = static_cast<int>(height);
-  result.data.resize(height * bytesPerRow);
-  result.format = wgpu::TextureFormat::RGBA8Unorm;
-
-  CGColorSpaceRef colorSpace = CGColorSpaceCreateDeviceRGB();
-  CGContextRef context = CGBitmapContextCreate(
-      result.data.data(), width, height, bitsPerComponent, bytesPerRow,
-      colorSpace, kCGImageAlphaPremultipliedLast | kCGBitmapByteOrder32Big);
-
-  CGContextDrawImage(context, CGRectMake(0, 0, width, height), cgImage);
-
-  CGContextRelease(context);
-  CGColorSpaceRelease(colorSpace);
-
-  return result;
-}
-
-void ApplePlatformContext::createImageBitmapFromDataAsync(
-    std::span<const uint8_t> data, std::function<void(ImageData)> onSuccess,
-    std::function<void(std::string)> onError) {
-  // Copy span data into shared_ptr so the dispatch_async block owns the memory
-  auto ownedData =
-      std::make_shared<std::vector<uint8_t>>(data.begin(), data.end());
-
-  dispatch_async(dispatch_get_global_queue(QOS_CLASS_USER_INITIATED, 0), ^{
-    @autoreleasepool {
-      try {
-        auto result = createImageBitmapFromData(*ownedData);
-        onSuccess(std::move(result));
-      } catch (const std::exception &e) {
-        onError(e.what());
-      }
-    }
-  });
-}
-
-VideoFrameHandle
-ApplePlatformContext::loadVideoFrame(const std::string &path) {
-  NSString *nsPath = [NSString stringWithUTF8String:path.c_str()];
-  NSURL *url = [nsPath hasPrefix:@"file://"]
-                   ? [NSURL URLWithString:nsPath]
-                   : [NSURL fileURLWithPath:nsPath];
-  AVURLAsset *asset = [AVURLAsset assetWithURL:url];
-
-  NSArray<AVAssetTrack *> *videoTracks =
-      [asset tracksWithMediaType:AVMediaTypeVideo];
-  if (videoTracks.count == 0) {
-    throw std::runtime_error("loadVideoFrame: no video track in file");
-  }
-  AVAssetTrack *videoTrack = videoTracks.firstObject;
-
-  NSError *error = nil;
-  AVAssetReader *reader = [AVAssetReader assetReaderWithAsset:asset
-                                                        error:&error];
-  if (error || !reader) {
-    throw std::runtime_error(
-        std::string("loadVideoFrame: AVAssetReader init failed: ") +
-        [[error localizedDescription] UTF8String]);
-  }
-
-  NSDictionary *outputSettings = @{
-    (NSString *)kCVPixelBufferPixelFormatTypeKey :
-        @(kCVPixelFormatType_32BGRA),
-    (NSString *)kCVPixelBufferIOSurfacePropertiesKey : @{},
-    (NSString *)kCVPixelBufferMetalCompatibilityKey : @YES,
-  };
-  AVAssetReaderTrackOutput *output =
-      [AVAssetReaderTrackOutput assetReaderTrackOutputWithTrack:videoTrack
-                                                 outputSettings:outputSettings];
-  output.alwaysCopiesSampleData = NO;
-  if (![reader canAddOutput:output]) {
-    throw std::runtime_error("loadVideoFrame: cannot add output");
-  }
-  [reader addOutput:output];
-
-  if (![reader startReading]) {
-    throw std::runtime_error(
-        std::string("loadVideoFrame: startReading failed: ") +
-        [[reader.error localizedDescription] UTF8String]);
-  }
-
-  CMSampleBufferRef sampleBuffer = [output copyNextSampleBuffer];
-  if (!sampleBuffer) {
-    throw std::runtime_error("loadVideoFrame: no sample buffer");
-  }
-
-  CVPixelBufferRef pixelBuffer = CMSampleBufferGetImageBuffer(sampleBuffer);
-  if (!pixelBuffer) {
-    CFRelease(sampleBuffer);
-    throw std::runtime_error("loadVideoFrame: no pixel buffer");
-  }
-
-  IOSurfaceRef ioSurface = CVPixelBufferGetIOSurface(pixelBuffer);
-  if (!ioSurface) {
-    CFRelease(sampleBuffer);
-    throw std::runtime_error(
-        "loadVideoFrame: pixel buffer is not IOSurface-backed");
-  }
-
-  // Retain the IOSurface so it survives past the sample buffer's lifetime.
-  CFRetain(ioSurface);
-
-  VideoFrameHandle handle;
-  handle.handle = (void *)ioSurface;
-  handle.width = static_cast<uint32_t>(CVPixelBufferGetWidth(pixelBuffer));
-  handle.height = static_cast<uint32_t>(CVPixelBufferGetHeight(pixelBuffer));
-  handle.deleter = [ioSurface]() { CFRelease(ioSurface); };
-
-  CFRelease(sampleBuffer);
-  [reader cancelReading];
-
-  return handle;
-}
-
-std::unique_ptr<IVideoPlayer>
-ApplePlatformContext::createVideoPlayer(const std::string &path,
-                                         VideoPixelFormat format) {
-  return createAppleVideoPlayer(path, format);
-}
-
-std::string ApplePlatformContext::writeTestVideoFile() {
-  return writeAppleTestVideoFile();
-}
-
-VideoFrameHandle ApplePlatformContext::wrapNativeBuffer(void *pointer) {
-  return wrapCVPixelBuffer(static_cast<CVPixelBufferRef>(pointer));
-}
-
-VideoFrameHandle
-ApplePlatformContext::createTestVideoFrame(uint32_t width, uint32_t height) {
-  NSDictionary *attrs = @{
-    (NSString *)kCVPixelBufferIOSurfacePropertiesKey : @{},
-    (NSString *)kCVPixelBufferMetalCompatibilityKey : @YES,
-  };
-  CVPixelBufferRef pixelBuffer = NULL;
-  CVReturn err = CVPixelBufferCreate(
-      kCFAllocatorDefault, width, height, kCVPixelFormatType_32BGRA,
-      (__bridge CFDictionaryRef)attrs, &pixelBuffer);
-  if (err != kCVReturnSuccess || !pixelBuffer) {
-    throw std::runtime_error("createTestVideoFrame: CVPixelBufferCreate "
-                             "failed");
-  }
-
-  CVPixelBufferLockBaseAddress(pixelBuffer, 0);
-  uint8_t *base =
-      static_cast<uint8_t *>(CVPixelBufferGetBaseAddress(pixelBuffer));
-  size_t rowBytes = CVPixelBufferGetBytesPerRow(pixelBuffer);
-  for (uint32_t y = 0; y < height; ++y) {
-    uint8_t *row = base + y * rowBytes;
-    for (uint32_t x = 0; x < width; ++x) {
-      // RGB gradient + diagonal stripes, in BGRA byte order.
-      uint8_t r = static_cast<uint8_t>((x * 255) / std::max(width - 1, 1u));
-      uint8_t g = static_cast<uint8_t>((y * 255) / std::max(height - 1, 1u));
-      uint8_t b = static_cast<uint8_t>(((x + y) & 0x20) ? 220 : 30);
-      row[x * 4 + 0] = b;
-      row[x * 4 + 1] = g;
-      row[x * 4 + 2] = r;
-      row[x * 4 + 3] = 0xFF;
-    }
-  }
-  CVPixelBufferUnlockBaseAddress(pixelBuffer, 0);
-
-  IOSurfaceRef ioSurface = CVPixelBufferGetIOSurface(pixelBuffer);
-  if (!ioSurface) {
-    CFRelease(pixelBuffer);
-    throw std::runtime_error(
-        "createTestVideoFrame: pixel buffer is not IOSurface-backed");
-  }
-
-  VideoFrameHandle handle;
-  handle.handle = (void *)ioSurface;
-  handle.width = width;
-  handle.height = height;
-  handle.deleter = [pixelBuffer]() { CFRelease(pixelBuffer); };
-  return handle;
-}
-
-} // namespace rnwgpu

package/apple/AppleVideoPlayer.h

@@ -1,31 +0,0 @@
-#pragma once
-
-#include "PlatformContext.h"
-
-#include <memory>
-#include <string>
-
-#ifdef __OBJC__
-#import <CoreVideo/CoreVideo.h>
-#endif
-
-namespace rnwgpu {
-
-// Factory: creates a new IVideoPlayer backed by AVPlayer +
-// AVPlayerItemVideoOutput. `format` selects the surface layout.
-std::unique_ptr<IVideoPlayer>
-createAppleVideoPlayer(const std::string &path, VideoPixelFormat format);
-
-// Generate a small procedurally-animated test video and write it to a
-// temporary file. Returns the absolute path. Used by the SharedTextureMemory
-// example so it doesn't need a bundled .mp4.
-std::string writeAppleTestVideoFile();
-
-#ifdef __OBJC__
-// Build a VideoFrameHandle from an existing CVPixelBuffer. CFRetains the
-// pixel buffer so the caller can release their reference immediately. Reads
-// IOSurface, dimensions, pixel format, and YUV matrix off the buffer.
-VideoFrameHandle wrapCVPixelBuffer(CVPixelBufferRef pixelBuffer);
-#endif
-
-} // namespace rnwgpu

package/apple/AppleVideoPlayer.mm

@@ -1,314 +0,0 @@
-#include "AppleVideoPlayer.h"
-
-#import <AVFoundation/AVFoundation.h>
-#import <CoreVideo/CoreVideo.h>
-
-#include <stdexcept>
-
-namespace rnwgpu {
-
-namespace {
-
-// 3x4 row-major matrices mapping [Y, Cb, Cr, 1] to gamma-encoded R'G'B' (NOT
-// linear): YCbCr is derived from gamma-encoded RGB, so this conversion stays in
-// the encoded domain. The sRGB decode in srcTransferFunctionParameters
-// linearizes afterward (see GPUExternalTexture.cpp). Limited-range (video
-// range) means luma is 16..235, chroma is 16..240 (8-bit).
-// Reference: https://en.wikipedia.org/wiki/YCbCr (BT.601 / BT.709).
-static constexpr float kBT709LimitedToRgb[12] = {
-    1.164383f, 0.000000f, 1.792741f, -0.972945f, //
-    1.164383f, -0.213249f, -0.532909f, 0.301517f, //
-    1.164383f, 2.112402f, 0.000000f, -1.133402f, //
-};
-static constexpr float kBT601LimitedToRgb[12] = {
-    1.164383f, 0.000000f, 1.596027f, -0.874202f, //
-    1.164383f, -0.391762f, -0.812968f, 0.531668f, //
-    1.164383f, 2.017232f, 0.000000f, -1.085631f, //
-};
-static constexpr float kBT2020LimitedToRgb[12] = {
-    1.164383f, 0.000000f, 1.678674f, -0.915688f, //
-    1.164383f, -0.187326f, -0.650424f, 0.347459f, //
-    1.164383f, 2.141772f, 0.000000f, -1.148145f, //
-};
-
-// Pick the right YUV→RGB matrix from the pixel buffer's color attachments.
-// Falls back to BT.709 limited range (the right call for ≥720p H.264, which
-// is what AVPlayer hands us for Big Buck Bunny and most streamed media).
-static void fillYuvMatrix(CVPixelBufferRef pixelBuffer, float out[12]) {
-  CFTypeRef matrixKey = CVBufferGetAttachment(
-      pixelBuffer, kCVImageBufferYCbCrMatrixKey, nullptr);
-  const float *src = kBT709LimitedToRgb;
-  if (matrixKey) {
-    auto matrix = (CFStringRef)matrixKey;
-    if (CFEqual(matrix, kCVImageBufferYCbCrMatrix_ITU_R_601_4) ||
-        CFEqual(matrix, kCVImageBufferYCbCrMatrix_SMPTE_240M_1995)) {
-      src = kBT601LimitedToRgb;
-    } else if (CFEqual(matrix, kCVImageBufferYCbCrMatrix_ITU_R_2020)) {
-      src = kBT2020LimitedToRgb;
-    }
-  }
-  for (int i = 0; i < 12; ++i) {
-    out[i] = src[i];
-  }
-}
-
-// Map a CVPixelBuffer's pixel format to our VideoPixelFormat enum.
-static VideoPixelFormat pixelFormatFromCVPixelBuffer(
-    CVPixelBufferRef pixelBuffer) {
-  OSType type = CVPixelBufferGetPixelFormatType(pixelBuffer);
-  switch (type) {
-    case kCVPixelFormatType_420YpCbCr8BiPlanarVideoRange:
-    case kCVPixelFormatType_420YpCbCr8BiPlanarFullRange:
-      return VideoPixelFormat::NV12;
-    default:
-      return VideoPixelFormat::BGRA8;
-  }
-}
-
-class AppleVideoPlayer : public IVideoPlayer {
-public:
-  AppleVideoPlayer(AVPlayer *player, AVPlayerItemVideoOutput *output,
-                   id loopObserver)
-      : _player(player), _output(output), _loopObserver(loopObserver) {}
-
-  ~AppleVideoPlayer() override {
-    if (_loopObserver) {
-      [[NSNotificationCenter defaultCenter] removeObserver:_loopObserver];
-      _loopObserver = nil;
-    }
-    [_player pause];
-    _player = nil;
-    _output = nil;
-  }
-
-  VideoFrameHandle copyLatestFrame() override {
-    CMTime currentTime = [_output itemTimeForHostTime:CACurrentMediaTime()];
-    if (![_output hasNewPixelBufferForItemTime:currentTime]) {
-      return {};
-    }
-    // copyPixelBufferForItemTime returns a +1 retained CVPixelBuffer; we then
-    // hand it to wrapCVPixelBuffer which adds another retain. Balance with a
-    // CFRelease here so we don't leak.
-    CVPixelBufferRef pixelBuffer =
-        [_output copyPixelBufferForItemTime:currentTime
-                         itemTimeForDisplay:nullptr];
-    if (!pixelBuffer) {
-      return {};
-    }
-    try {
-      auto handle = wrapCVPixelBuffer(pixelBuffer);
-      CFRelease(pixelBuffer);
-      return handle;
-    } catch (...) {
-      CFRelease(pixelBuffer);
-      throw;
-    }
-  }
-
-  void play() override { [_player play]; }
-  void pause() override { [_player pause]; }
-
-private:
-  AVPlayer *_player;
-  AVPlayerItemVideoOutput *_output;
-  id _loopObserver;
-};
-
-} // namespace
-
-VideoFrameHandle wrapCVPixelBuffer(CVPixelBufferRef pixelBuffer) {
-  if (!pixelBuffer) {
-    throw std::runtime_error("wrapCVPixelBuffer: pointer is null");
-  }
-  IOSurfaceRef ioSurface = CVPixelBufferGetIOSurface(pixelBuffer);
-  if (!ioSurface) {
-    throw std::runtime_error(
-        "wrapCVPixelBuffer: pixel buffer is not IOSurface-backed (was the "
-        "camera/video pipeline configured for Metal/IOSurface output?)");
-  }
-
-  // Retain the pixel buffer so the caller can release theirs immediately.
-  CFRetain(pixelBuffer);
-
-  VideoFrameHandle handle;
-  handle.handle = (void *)ioSurface;
-  handle.width = static_cast<uint32_t>(CVPixelBufferGetWidth(pixelBuffer));
-  handle.height = static_cast<uint32_t>(CVPixelBufferGetHeight(pixelBuffer));
-  handle.pixelFormat = pixelFormatFromCVPixelBuffer(pixelBuffer);
-  if (handle.pixelFormat == VideoPixelFormat::NV12) {
-    fillYuvMatrix(pixelBuffer, handle.yuvToRgbMatrix);
-  }
-  handle.deleter = [pixelBuffer]() { CFRelease(pixelBuffer); };
-  return handle;
-}
-
-std::unique_ptr<IVideoPlayer>
-createAppleVideoPlayer(const std::string &path, VideoPixelFormat format) {
-  NSString *nsPath = [NSString stringWithUTF8String:path.c_str()];
-  NSURL *url;
-  if ([nsPath hasPrefix:@"http://"] || [nsPath hasPrefix:@"https://"] ||
-      [nsPath hasPrefix:@"file://"]) {
-    url = [NSURL URLWithString:nsPath];
-  } else {
-    url = [NSURL fileURLWithPath:nsPath];
-  }
-
-  AVPlayerItem *item = [AVPlayerItem playerItemWithURL:url];
-  if (!item) {
-    throw std::runtime_error("createAppleVideoPlayer: failed to create "
-                             "AVPlayerItem");
-  }
-
-  // NV12 (kCVPixelFormatType_420YpCbCr8BiPlanarVideoRange) lets us hand the
-  // IOSurface straight to Dawn as a multi-planar texture for
-  // importExternalTexture. BGRA is the "decode + convert" path for the
-  // single-plane SharedTextureMemory demo.
-  OSType pixelFormat = format == VideoPixelFormat::NV12
-                          ? kCVPixelFormatType_420YpCbCr8BiPlanarVideoRange
-                          : kCVPixelFormatType_32BGRA;
-  NSDictionary *outputSettings = @{
-    (NSString *)kCVPixelBufferPixelFormatTypeKey : @(pixelFormat),
-    (NSString *)kCVPixelBufferIOSurfacePropertiesKey : @{},
-    (NSString *)kCVPixelBufferMetalCompatibilityKey : @YES,
-  };
-  AVPlayerItemVideoOutput *output = [[AVPlayerItemVideoOutput alloc]
-      initWithPixelBufferAttributes:outputSettings];
-  [item addOutput:output];
-
-  AVPlayer *player = [AVPlayer playerWithPlayerItem:item];
-  player.actionAtItemEnd = AVPlayerActionAtItemEndNone;
-
-  // Loop on end-of-stream by seeking back to zero.
-  __weak AVPlayer *weakPlayer = player;
-  id loopObserver = [[NSNotificationCenter defaultCenter]
-      addObserverForName:AVPlayerItemDidPlayToEndTimeNotification
-                  object:item
-                   queue:[NSOperationQueue mainQueue]
-              usingBlock:^(NSNotification * /*note*/) {
-                [weakPlayer seekToTime:kCMTimeZero];
-                [weakPlayer play];
-              }];
-
-  return std::make_unique<AppleVideoPlayer>(player, output, loopObserver);
-}
-
-std::string writeAppleTestVideoFile() {
-  NSString *tmpDir = NSTemporaryDirectory();
-  NSString *outputPath =
-      [tmpDir stringByAppendingPathComponent:@"rnwgpu-test-video.mp4"];
-  NSURL *outputURL = [NSURL fileURLWithPath:outputPath];
-
-  // If the file already exists, reuse it. This makes the example zero-cost on
-  // subsequent runs.
-  if ([[NSFileManager defaultManager] fileExistsAtPath:outputPath]) {
-    return [outputPath UTF8String];
-  }
-
-  NSError *error = nil;
-  AVAssetWriter *writer = [AVAssetWriter assetWriterWithURL:outputURL
-                                                   fileType:AVFileTypeMPEG4
-                                                      error:&error];
-  if (error || !writer) {
-    throw std::runtime_error(
-        std::string("writeTestVideoFile: AVAssetWriter init failed: ") +
-        [[error localizedDescription] UTF8String]);
-  }
-
-  const int kWidth = 256;
-  const int kHeight = 256;
-  const int kFps = 30;
-  const int kSeconds = 3;
-  const int kTotalFrames = kFps * kSeconds;
-
-  NSDictionary *videoSettings = @{
-    AVVideoCodecKey : AVVideoCodecTypeH264,
-    AVVideoWidthKey : @(kWidth),
-    AVVideoHeightKey : @(kHeight),
-  };
-  AVAssetWriterInput *writerInput =
-      [AVAssetWriterInput assetWriterInputWithMediaType:AVMediaTypeVideo
-                                         outputSettings:videoSettings];
-  writerInput.expectsMediaDataInRealTime = NO;
-
-  NSDictionary *bufferAttrs = @{
-    (NSString *)kCVPixelBufferPixelFormatTypeKey :
-        @(kCVPixelFormatType_32BGRA),
-    (NSString *)kCVPixelBufferWidthKey : @(kWidth),
-    (NSString *)kCVPixelBufferHeightKey : @(kHeight),
-    (NSString *)kCVPixelBufferIOSurfacePropertiesKey : @{},
-  };
-  AVAssetWriterInputPixelBufferAdaptor *adaptor =
-      [AVAssetWriterInputPixelBufferAdaptor
-          assetWriterInputPixelBufferAdaptorWithAssetWriterInput:writerInput
-                                     sourcePixelBufferAttributes:bufferAttrs];
-  [writer addInput:writerInput];
-
-  if (![writer startWriting]) {
-    throw std::runtime_error(
-        std::string("writeTestVideoFile: startWriting failed: ") +
-        [[writer.error localizedDescription] UTF8String]);
-  }
-  [writer startSessionAtSourceTime:kCMTimeZero];
-
-  for (int i = 0; i < kTotalFrames; ++i) {
-    // Spin briefly if the input is not ready (the adaptor pool fills up).
-    while (!writerInput.isReadyForMoreMediaData) {
-      [NSThread sleepForTimeInterval:0.005];
-    }
-
-    CVPixelBufferRef pixelBuffer = NULL;
-    CVReturn err = CVPixelBufferPoolCreatePixelBuffer(
-        kCFAllocatorDefault, adaptor.pixelBufferPool, &pixelBuffer);
-    if (err != kCVReturnSuccess || !pixelBuffer) {
-      throw std::runtime_error("writeTestVideoFile: pool exhausted");
-    }
-
-    CVPixelBufferLockBaseAddress(pixelBuffer, 0);
-    uint8_t *base =
-        static_cast<uint8_t *>(CVPixelBufferGetBaseAddress(pixelBuffer));
-    size_t rowBytes = CVPixelBufferGetBytesPerRow(pixelBuffer);
-    // Procedural pattern: scrolling diagonal stripes + per-frame color shift.
-    int phase = i * 6;
-    for (int y = 0; y < kHeight; ++y) {
-      uint8_t *row = base + y * rowBytes;
-      for (int x = 0; x < kWidth; ++x) {
-        uint8_t r = static_cast<uint8_t>((x + phase) & 0xFF);
-        uint8_t g = static_cast<uint8_t>((y + phase * 2) & 0xFF);
-        uint8_t b =
-            static_cast<uint8_t>(((x + y + phase) & 0x40) ? 220 : 30);
-        row[x * 4 + 0] = b;
-        row[x * 4 + 1] = g;
-        row[x * 4 + 2] = r;
-        row[x * 4 + 3] = 0xFF;
-      }
-    }
-    CVPixelBufferUnlockBaseAddress(pixelBuffer, 0);
-
-    CMTime pts = CMTimeMake(i, kFps);
-    if (![adaptor appendPixelBuffer:pixelBuffer withPresentationTime:pts]) {
-      CFRelease(pixelBuffer);
-      throw std::runtime_error(
-          std::string("writeTestVideoFile: appendPixelBuffer failed: ") +
-          [[writer.error localizedDescription] UTF8String]);
-    }
-    CFRelease(pixelBuffer);
-  }
-
-  [writerInput markAsFinished];
-  dispatch_semaphore_t sem = dispatch_semaphore_create(0);
-  [writer finishWritingWithCompletionHandler:^{
-    dispatch_semaphore_signal(sem);
-  }];
-  dispatch_semaphore_wait(sem, DISPATCH_TIME_FOREVER);
-
-  if (writer.status != AVAssetWriterStatusCompleted) {
-    throw std::runtime_error(
-        std::string("writeTestVideoFile: writer finished with status ") +
-        std::to_string(static_cast<long>(writer.status)) + ": " +
-        [[writer.error localizedDescription] UTF8String]);
-  }
-
-  return [outputPath UTF8String];
-}
-
-} // namespace rnwgpu

package/apple/MetalView.h

@@ -1,13 +0,0 @@
-#pragma once
-
-#import "RNWGUIKit.h"
-#import "WebGPUModule.h"
-
-@interface MetalView : RNWGPlatformView
-
-@property NSNumber *contextId;
-
-- (void)configure;
-- (void)update;
-
-@end