react-native-typerich 1.0.0 → 2.2.0

package/ios/cpp/TypeRichTextInputViewComponentDescriptor.h

@@ -0,0 +1,19 @@
+#pragma once
+#include "TypeRichTextInputViewShadowNode.h"
+#include <react/debug/react_native_assert.h>
+#include <react/renderer/components/TypeRichTextInputViewSpec/Props.h>
+#include <react/renderer/core/ConcreteComponentDescriptor.h>
+
+namespace facebook::react {
+class TypeRichTextInputViewComponentDescriptor final
+    : public ConcreteComponentDescriptor<TypeRichTextInputViewShadowNode> {
+public:
+  using ConcreteComponentDescriptor::ConcreteComponentDescriptor;
+  void adopt(ShadowNode &shadowNode) const override {
+    react_native_assert(
+        dynamic_cast<TypeRichTextInputViewShadowNode *>(&shadowNode));
+    ConcreteComponentDescriptor::adopt(shadowNode);
+  }
+};
+
+} // namespace facebook::react

package/ios/cpp/TypeRichTextInputViewShadowNode.h

@@ -0,0 +1,44 @@
+#pragma once
+#include "TypeRichTextInputViewState.h"
+#include <jsi/jsi.h>
+#include <react/renderer/components/TypeRichTextInputViewSpec/EventEmitters.h>
+#include <react/renderer/components/TypeRichTextInputViewSpec/Props.h>
+#include <react/renderer/components/view/ConcreteViewShadowNode.h>
+#include <react/renderer/core/LayoutConstraints.h>
+
+namespace facebook::react {
+
+JSI_EXPORT extern const char TypeRichTextInputViewComponentName[];
+
+/*
+ * `ShadowNode` for <TypeRichTextInputView> component.
+ */
+class TypeRichTextInputViewShadowNode
+    : public ConcreteViewShadowNode<
+          TypeRichTextInputViewComponentName, TypeRichTextInputViewProps,
+          TypeRichTextInputViewEventEmitter, TypeRichTextInputViewState> {
+public:
+  using ConcreteViewShadowNode::ConcreteViewShadowNode;
+  TypeRichTextInputViewShadowNode(const ShadowNodeFragment &fragment,
+                                  const ShadowNodeFamily::Shared &family,
+                                  ShadowNodeTraits traits);
+  TypeRichTextInputViewShadowNode(const ShadowNode &sourceShadowNode,
+                                  const ShadowNodeFragment &fragment);
+  void dirtyLayoutIfNeeded();
+  Size
+  measureContent(const LayoutContext &layoutContext,
+                 const LayoutConstraints &layoutConstraints) const override;
+
+  static ShadowNodeTraits BaseTraits() {
+    auto traits = ConcreteViewShadowNode::BaseTraits();
+    traits.set(ShadowNodeTraits::Trait::LeafYogaNode);
+    traits.set(ShadowNodeTraits::Trait::MeasurableYogaNode);
+    return traits;
+  }
+
+private:
+  int localForceHeightRecalculationCounter_;
+  id setupMockTextInputView_() const;
+};
+
+} // namespace facebook::react

package/ios/cpp/TypeRichTextInputViewShadowNode.mm

@@ -0,0 +1,110 @@
+#import "TypeRichTextInputViewShadowNode.h"
+#import "CoreText/CoreText.h"
+#import <TypeRichTextInputView.h>
+#import <React/RCTShadowView+Layout.h>
+#import <react/utils/ManagedObjectWrapper.h>
+#import <yoga/Yoga.h>
+#import <React/RCTLog.h>
+
+namespace facebook::react {
+
+extern const char TypeRichTextInputViewComponentName[] =
+    "TypeRichTextInputView";
+
+TypeRichTextInputViewShadowNode::TypeRichTextInputViewShadowNode(
+    const ShadowNodeFragment &fragment, const ShadowNodeFamily::Shared &family,
+    ShadowNodeTraits traits)
+    : ConcreteViewShadowNode(fragment, family, traits) {
+  localForceHeightRecalculationCounter_ = 0;
+}
+
+// mock input is used for the first measure calls that need to be done when the
+// real input isn't defined yet
+id TypeRichTextInputViewShadowNode::setupMockTextInputView_() const {
+  // it's rendered far away from the viewport
+  const int veryFarAway = 20000;
+  const int mockSize = 1000;
+  TypeRichTextInputView *mockTextInputView_ = [[TypeRichTextInputView alloc]
+      initWithFrame:(CGRectMake(veryFarAway, veryFarAway, mockSize, mockSize))];
+  const auto props = this->getProps();
+  mockTextInputView_.blockEmitting = YES;
+  [mockTextInputView_ updateProps:props oldProps:nullptr];
+  return mockTextInputView_;
+}
+
+TypeRichTextInputViewShadowNode::TypeRichTextInputViewShadowNode(
+    const ShadowNode &sourceShadowNode, const ShadowNodeFragment &fragment)
+    : ConcreteViewShadowNode(sourceShadowNode, fragment) {
+  dirtyLayoutIfNeeded();
+}
+
+void TypeRichTextInputViewShadowNode::dirtyLayoutIfNeeded() {
+  const auto state = this->getStateData();
+  const int receivedCounter = state.getForceHeightRecalculationCounter();
+
+  if (receivedCounter > localForceHeightRecalculationCounter_) {
+    localForceHeightRecalculationCounter_ = receivedCounter;
+    YGNodeMarkDirty(&yogaNode_);
+  }
+}
+
+Size TypeRichTextInputViewShadowNode::measureContent(
+    const LayoutContext &layoutContext,
+    const LayoutConstraints &layoutConstraints) const {
+  const auto state = this->getStateData();
+  const auto componentRef = state.getComponentViewRef();
+  RCTInternalGenericWeakWrapper *weakWrapper =
+      (RCTInternalGenericWeakWrapper *)unwrapManagedObject(componentRef);
+
+      RCTLogInfo(
+        @"[TypeRichTextInput] minH=%f maxH=%f",
+        layoutConstraints.minimumSize.height,
+        layoutConstraints.maximumSize.height
+      );
+      
+  if (weakWrapper != nullptr) {
+    id componentObject = weakWrapper.object;
+    TypeRichTextInputView *typedComponentObject =
+        (TypeRichTextInputView *)componentObject;
+
+    if (typedComponentObject != nullptr) {
+      __block CGSize estimatedSize;
+
+      // synchronously dispatch to main thread if needed
+      if ([NSThread isMainThread]) {
+        estimatedSize = [typedComponentObject
+            measureSize:layoutConstraints.maximumSize.width];
+      } else {
+        dispatch_sync(dispatch_get_main_queue(), ^{
+          estimatedSize = [typedComponentObject
+              measureSize:layoutConstraints.maximumSize.width];
+        });
+      }
+
+     return {estimatedSize.width,
+             MIN(estimatedSize.height, layoutConstraints.maximumSize.height)};
+    }
+  } else {
+    __block CGSize estimatedSize;
+
+    // synchronously dispatch to main thread if needed
+    if ([NSThread isMainThread]) {
+      TypeRichTextInputView *mockTextInputView = setupMockTextInputView_();
+      estimatedSize =
+          [mockTextInputView measureSize:layoutConstraints.maximumSize.width];
+    } else {
+      dispatch_sync(dispatch_get_main_queue(), ^{
+        TypeRichTextInputView *mockTextInputView = setupMockTextInputView_();
+        estimatedSize =
+            [mockTextInputView measureSize:layoutConstraints.maximumSize.width];
+      });
+    }
+
+     return {estimatedSize.width,
+             MIN(estimatedSize.height, layoutConstraints.maximumSize.height)};
+  }
+
+  return Size();
+}
+
+} // namespace facebook::react

package/ios/cpp/TypeRichTextInputViewState.cpp

@@ -0,0 +1,10 @@
+#include "TypeRichTextInputViewState.h"
+
+namespace facebook::react {
+int TypeRichTextInputViewState::getForceHeightRecalculationCounter() const {
+  return forceHeightRecalculationCounter_;
+}
+std::shared_ptr<void> TypeRichTextInputViewState::getComponentViewRef() const {
+  return componentViewRef_;
+}
+} // namespace facebook::react

package/ios/cpp/TypeRichTextInputViewState.h

@@ -0,0 +1,22 @@
+#pragma once
+#include <memory>
+
+namespace facebook::react {
+
+class TypeRichTextInputViewState {
+public:
+  TypeRichTextInputViewState()
+      : forceHeightRecalculationCounter_(0), componentViewRef_(nullptr) {}
+  TypeRichTextInputViewState(int counter, std::shared_ptr<void> ref) {
+    forceHeightRecalculationCounter_ = counter;
+    componentViewRef_ = ref;
+  }
+  int getForceHeightRecalculationCounter() const;
+  std::shared_ptr<void> getComponentViewRef() const;
+
+private:
+  int forceHeightRecalculationCounter_{};
+  std::shared_ptr<void> componentViewRef_{};
+};
+
+} // namespace facebook::react

package/ios/inputTextView/TypeRichUITextView.h

@@ -0,0 +1,14 @@
+//
+//  InputTextView.h
+//  Pods
+//
+//  Created by Div on 29/12/25.
+//
+
+#import <UIKit/UIKit.h>
+
+@class TypeRichTextInputView;
+
+@interface TypeRichUITextView : UITextView
+@property (nonatomic, weak) TypeRichTextInputView *owner;
+@end

package/ios/inputTextView/TypeRichUITextView.mm

@@ -0,0 +1,100 @@
+//
+//  InputTextView.m
+//  ReactNativeTypeRich
+//
+//  Created by Div on 29/12/25.
+//
+
+#import "TypeRichUITextView.h"
+#import "TypeRichTextInputView.h"
+
+@implementation TypeRichUITextView
+
+- (void)paste:(id)sender {
+  UIPasteboard *pb = UIPasteboard.generalPasteboard;
+
+  if ([self.owner isDisableImagePasting] &&
+      pb.hasImages &&
+      !pb.hasStrings) {
+    return;
+  }
+
+  if (
+    ![self.owner isDisableImagePasting]
+    && pb.hasImages
+  ) {
+    
+    UIImage *image = pb.image;
+    if (!image) {
+      [super paste:sender];
+      return;
+    }
+
+    // NSData *data = UIImagePNGRepresentation(image); // when the requirement is for transparency enable this
+    NSData *data = UIImageJPEGRepresentation(image, 0.8);
+    
+    if (!data) {
+      return;
+    }
+
+    NSString *fileName =
+      [NSString stringWithFormat:@"typerich_%@.png", NSUUID.UUID.UUIDString];
+
+    NSString *path =
+      [NSTemporaryDirectory() stringByAppendingPathComponent:fileName];
+
+    NSError *error = nil;
+    if (![data writeToFile:path options:NSDataWritingAtomic error:&error]) {
+      return;
+    }
+
+    [self.owner emitPasteImageEventWith:path
+                                      type:@"image/png"
+                                  fileName:fileName
+                                  fileSize:data.length];
+
+    // Prevent attachment insertion
+    return;
+  }
+
+  [super paste:sender];
+}
+
+
+- (BOOL)canPasteItemProviders:(NSArray<NSItemProvider *> *)itemProviders {
+  for (NSItemProvider *provider in itemProviders) {
+    if ([provider hasItemConformingToTypeIdentifier:@"public.text"]) {
+        return YES;
+      }
+
+    if (![self.owner isDisableImagePasting] &&
+        [provider hasItemConformingToTypeIdentifier:@"public.image"]) {
+      return YES;
+    }
+  }
+  return NO;
+}
+
+- (BOOL)canPerformAction:(SEL)action withSender:(id)sender {
+  if (action == @selector(paste:)) {
+    UIPasteboard *pb = UIPasteboard.generalPasteboard;
+
+    if (
+      [self.owner isDisableImagePasting] &&
+      pb.hasImages &&
+      !pb.hasStrings) {
+        return NO;
+    }
+    
+    // Allow paste if there is text OR image
+    if (pb.hasStrings || pb.hasImages) {
+      return YES;
+    }
+    return NO;
+  }
+
+  return [super canPerformAction:action withSender:sender];
+}
+
+@end
+

package/ios/modules/commands/TypeRichTextInputCommands.h

@@ -0,0 +1,24 @@
+//
+//  TypeRichTextInputCommands.h
+//  Pods
+//
+//  Created by Div on 29/12/25.
+//
+
+#import <UIKit/UIKit.h>
+#import "TypeRichTextInputView.h"
+
+@interface TypeRichTextInputCommands : NSObject
+@property (nonatomic, strong) NSOperationQueue *commandQueue;
+
+- (instancetype)initWithTextView:(UITextView *)textView
+                           owner:(TypeRichTextInputView *)owner;
+
+- (void)focus;
+- (void)blur;
+- (void)setText:(NSString *)text;
+- (void)setSelectionStart:(NSInteger)start end:(NSInteger)end;
+- (void)insertTextAtStart:(NSInteger)start
+                      end:(NSInteger)end
+                     text:(NSString *)text;
+@end