react-native-tinyui 1.1.0 → 2.0.0

package/ios/SFSymbol/TinyuiSFSymbolEffects.mm

@@ -1,180 +0,0 @@
-#if TINYUI_FEATURE_SF_SYMBOL
-
-#import "TinyuiSFSymbolEffects.h"
-#include <cmath>
-
-// Keep the concrete receiver types so the compiler checks every Symbols API.
-#define TINYUI_LAYER_SCOPE(effect) \
-  if ([scope isEqual:@"byLayer"]) effect = [effect effectWithByLayer]; \
-  if ([scope isEqual:@"wholeSymbol"]) effect = [effect effectWithWholeSymbol];
-
-NSSymbolEffect *TinyuiSFSymbolEffect(NSDictionary *configuration)
-{
-  NSString *type = configuration[@"type"];
-  NSString *scope = configuration[@"scope"];
-  NSString *direction = configuration[@"direction"];
-  if ([type isEqual:@"pulse"]) {
-    NSSymbolPulseEffect *effect = NSSymbolPulseEffect.effect;
-    TINYUI_LAYER_SCOPE(effect);
-    return effect;
-  }
-  if ([type isEqual:@"bounce"]) {
-    NSSymbolBounceEffect *effect = NSSymbolBounceEffect.effect;
-    if ([direction isEqual:@"up"]) effect = NSSymbolBounceEffect.bounceUpEffect;
-    if ([direction isEqual:@"down"]) effect = NSSymbolBounceEffect.bounceDownEffect;
-    TINYUI_LAYER_SCOPE(effect);
-    return effect;
-  }
-  if ([type isEqual:@"scale"]) {
-    NSSymbolScaleEffect *effect = NSSymbolScaleEffect.effect;
-    if ([direction isEqual:@"up"]) effect = NSSymbolScaleEffect.scaleUpEffect;
-    if ([direction isEqual:@"down"]) effect = NSSymbolScaleEffect.scaleDownEffect;
-    TINYUI_LAYER_SCOPE(effect);
-    return effect;
-  }
-  if ([type isEqual:@"appear"]) {
-    NSSymbolAppearEffect *effect = NSSymbolAppearEffect.effect;
-    if ([direction isEqual:@"up"]) effect = NSSymbolAppearEffect.appearUpEffect;
-    if ([direction isEqual:@"down"]) effect = NSSymbolAppearEffect.appearDownEffect;
-    TINYUI_LAYER_SCOPE(effect);
-    return effect;
-  }
-  if ([type isEqual:@"disappear"]) {
-    NSSymbolDisappearEffect *effect = NSSymbolDisappearEffect.effect;
-    if ([direction isEqual:@"up"]) effect = NSSymbolDisappearEffect.disappearUpEffect;
-    if ([direction isEqual:@"down"]) effect = NSSymbolDisappearEffect.disappearDownEffect;
-    TINYUI_LAYER_SCOPE(effect);
-    return effect;
-  }
-  if ([type isEqual:@"variableColor"]) {
-    NSSymbolVariableColorEffect *effect = NSSymbolVariableColorEffect.effect;
-    if ([configuration[@"iteration"] isEqual:@"iterative"]) effect = [effect effectWithIterative];
-    if ([configuration[@"iteration"] isEqual:@"cumulative"]) effect = [effect effectWithCumulative];
-    if ([configuration[@"reversing"] isKindOfClass:NSNumber.class]) {
-      effect = [configuration[@"reversing"] boolValue]
-          ? [effect effectWithReversing] : [effect effectWithNonReversing];
-    }
-    if ([configuration[@"inactiveLayers"] isEqual:@"hide"]) effect = [effect effectWithHideInactiveLayers];
-    if ([configuration[@"inactiveLayers"] isEqual:@"dim"]) effect = [effect effectWithDimInactiveLayers];
-    return effect;
-  }
-  if (@available(iOS 18.0, *)) {
-    if ([type isEqual:@"wiggle"]) {
-      NSSymbolWiggleEffect *effect = NSSymbolWiggleEffect.effect;
-      if ([direction isEqual:@"up"]) effect = NSSymbolWiggleEffect.wiggleUpEffect;
-      if ([direction isEqual:@"down"]) effect = NSSymbolWiggleEffect.wiggleDownEffect;
-      if ([direction isEqual:@"left"]) effect = NSSymbolWiggleEffect.wiggleLeftEffect;
-      if ([direction isEqual:@"right"]) effect = NSSymbolWiggleEffect.wiggleRightEffect;
-      if ([direction isEqual:@"forward"]) effect = NSSymbolWiggleEffect.wiggleForwardEffect;
-      if ([direction isEqual:@"backward"]) effect = NSSymbolWiggleEffect.wiggleBackwardEffect;
-      if ([direction isEqual:@"clockwise"]) effect = NSSymbolWiggleEffect.wiggleClockwiseEffect;
-      if ([direction isEqual:@"counterClockwise"]) effect = NSSymbolWiggleEffect.wiggleCounterClockwiseEffect;
-      id angle = configuration[@"angle"];
-      if ([angle isKindOfClass:NSNumber.class] && std::isfinite([angle doubleValue])) {
-        effect = [NSSymbolWiggleEffect wiggleCustomAngleEffect:[angle doubleValue]];
-      }
-      TINYUI_LAYER_SCOPE(effect);
-      return effect;
-    }
-    if ([type isEqual:@"rotate"]) {
-      NSSymbolRotateEffect *effect = NSSymbolRotateEffect.effect;
-      if ([direction isEqual:@"clockwise"]) effect = NSSymbolRotateEffect.rotateClockwiseEffect;
-      if ([direction isEqual:@"counterClockwise"]) effect = NSSymbolRotateEffect.rotateCounterClockwiseEffect;
-      TINYUI_LAYER_SCOPE(effect);
-      return effect;
-    }
-    if ([type isEqual:@"breathe"]) {
-      NSSymbolBreatheEffect *effect = NSSymbolBreatheEffect.effect;
-      if ([configuration[@"style"] isEqual:@"plain"]) effect = NSSymbolBreatheEffect.breathePlainEffect;
-      if ([configuration[@"style"] isEqual:@"pulse"]) effect = NSSymbolBreatheEffect.breathePulseEffect;
-      TINYUI_LAYER_SCOPE(effect);
-      return effect;
-    }
-  }
-  if (@available(iOS 26.0, *)) {
-    if ([type isEqual:@"drawOn"]) {
-      NSSymbolDrawOnEffect *effect = NSSymbolDrawOnEffect.effect;
-      TINYUI_LAYER_SCOPE(effect);
-      if ([scope isEqual:@"individually"]) effect = [effect effectWithIndividually];
-      return effect;
-    }
-    if ([type isEqual:@"drawOff"]) {
-      NSSymbolDrawOffEffect *effect = NSSymbolDrawOffEffect.effect;
-      TINYUI_LAYER_SCOPE(effect);
-      if ([scope isEqual:@"individually"]) effect = [effect effectWithIndividually];
-      if ([configuration[@"reversed"] isKindOfClass:NSNumber.class]) {
-        effect = [configuration[@"reversed"] boolValue]
-            ? [effect effectWithReversed] : [effect effectWithNonReversed];
-      }
-      return effect;
-    }
-  }
-  return nil;
-}
-
-#undef TINYUI_LAYER_SCOPE
-
-NSSymbolEffectOptions *TinyuiSFSymbolOptions(NSDictionary *configuration)
-{
-  NSSymbolEffectOptions *options = NSSymbolEffectOptions.options;
-  if (![configuration isKindOfClass:NSDictionary.class]) return options;
-  id speedValue = configuration[@"speed"];
-  double speed = [speedValue isKindOfClass:NSNumber.class] ? [speedValue doubleValue] : 1;
-  if (std::isfinite(speed) && speed > 0) options = [options optionsWithSpeed:speed];
-  id repeat = configuration[@"repeat"];
-  if ([repeat isEqual:@NO]) return [options optionsWithNonRepeating];
-  BOOL countProvided = [repeat isKindOfClass:NSNumber.class];
-  // JS validates safe integers; cap the conversion at the native integer range.
-  NSInteger count = countProvided ? (NSInteger)fmin([repeat doubleValue], (double)NSIntegerMax / 2) : 1;
-  count = MAX(1, count);
-  id behaviorValue = configuration[@"repeatBehavior"];
-  NSString *behavior = [behaviorValue isKindOfClass:NSString.class] ? behaviorValue : nil;
-  id delayValue = configuration[@"repeatDelay"];
-  BOOL hasDelay = [delayValue isKindOfClass:NSNumber.class];
-  double delay = hasDelay ? [delayValue doubleValue] : 0;
-  if (!std::isfinite(delay) || delay < 0) delay = 0;
-  BOOL forever = [repeat isEqual:@"forever"] || behavior != nil || hasDelay;
-
-  if (@available(iOS 18.0, *)) {
-    NSSymbolEffectOptionsRepeatBehavior *repetition = nil;
-    if ([behavior isEqual:@"continuous"]) {
-      repetition = NSSymbolEffectOptionsRepeatBehavior.behaviorContinuous;
-    } else if (countProvided) {
-      repetition = hasDelay
-          ? [NSSymbolEffectOptionsRepeatBehavior behaviorPeriodicWithCount:count delay:delay]
-          : [NSSymbolEffectOptionsRepeatBehavior behaviorPeriodicWithCount:count];
-    } else if (forever) {
-      repetition = hasDelay
-          ? [NSSymbolEffectOptionsRepeatBehavior behaviorPeriodicWithDelay:delay]
-          : NSSymbolEffectOptionsRepeatBehavior.behaviorPeriodic;
-    }
-    if (repetition != nil) options = [options optionsWithRepeatBehavior:repetition];
-  } else {
-    if (countProvided) options = [options optionsWithRepeatCount:count];
-    else if (forever) options = [options optionsWithRepeating];
-  }
-  return options;
-}
-
-NSSymbolContentTransition *TinyuiSFSymbolTransition(NSDictionary *configuration)
-{
-  NSString *type = configuration[@"type"];
-  if ([type isEqual:@"automatic"]) return NSSymbolAutomaticContentTransition.transition;
-  if (![type isEqual:@"replace"] && ![type isEqual:@"magicReplace"]) return nil;
-
-  NSSymbolReplaceContentTransition *transition = NSSymbolReplaceContentTransition.transition;
-  NSString *direction = configuration[@"direction"];
-  if ([direction isEqual:@"downUp"]) transition = NSSymbolReplaceContentTransition.replaceDownUpTransition;
-  if ([direction isEqual:@"upUp"]) transition = NSSymbolReplaceContentTransition.replaceUpUpTransition;
-  if ([direction isEqual:@"offUp"]) transition = NSSymbolReplaceContentTransition.replaceOffUpTransition;
-  if ([configuration[@"scope"] isEqual:@"byLayer"]) transition = [transition transitionWithByLayer];
-  if ([configuration[@"scope"] isEqual:@"wholeSymbol"]) transition = [transition transitionWithWholeSymbol];
-  if (@available(iOS 18.0, *)) {
-    if ([type isEqual:@"magicReplace"]) {
-      return [NSSymbolReplaceContentTransition magicTransitionWithFallback:transition];
-    }
-  }
-  return transition;
-}
-
-#endif

package/ios/SFSymbol/TinyuiSFSymbolImage.h

@@ -1,8 +0,0 @@
-#pragma once
-
-#import <UIKit/UIKit.h>
-
-NS_ASSUME_NONNULL_BEGIN
-// Shared by Fabric measurement and the mounted view so their metrics match.
-UIImage * _Nullable TinyuiSFSymbolImage(NSDictionary *configuration, BOOL includeColors);
-NS_ASSUME_NONNULL_END

package/ios/SFSymbol/TinyuiSFSymbolImage.mm

@@ -1,141 +0,0 @@
-#if TINYUI_FEATURE_SF_SYMBOL
-
-#import "TinyuiSFSymbolImage.h"
-#import <React/RCTConvert.h>
-#include <cmath>
-
-static UIImageSymbolWeight symbolWeight(NSString *value)
-{
-  NSDictionary *weights = @{
-    @"ultraLight": @(UIImageSymbolWeightUltraLight), @"thin": @(UIImageSymbolWeightThin),
-    @"light": @(UIImageSymbolWeightLight), @"regular": @(UIImageSymbolWeightRegular),
-    @"medium": @(UIImageSymbolWeightMedium), @"semibold": @(UIImageSymbolWeightSemibold),
-    @"bold": @(UIImageSymbolWeightBold), @"heavy": @(UIImageSymbolWeightHeavy),
-    @"black": @(UIImageSymbolWeightBlack),
-  };
-  return (UIImageSymbolWeight)[weights[value ?: @""] integerValue];
-}
-
-static UIImageSymbolScale symbolScale(NSString *value)
-{
-  if ([value isEqual:@"small"]) return UIImageSymbolScaleSmall;
-  if ([value isEqual:@"medium"]) return UIImageSymbolScaleMedium;
-  if ([value isEqual:@"large"]) return UIImageSymbolScaleLarge;
-  if ([value isEqual:@"unspecified"]) return UIImageSymbolScaleUnspecified;
-  return UIImageSymbolScaleDefault;
-}
-
-static UIFontTextStyle textStyle(NSString *value)
-{
-  return @{
-    @"extraLargeTitle": UIFontTextStyleExtraLargeTitle,
-    @"extraLargeTitle2": UIFontTextStyleExtraLargeTitle2,
-    @"largeTitle": UIFontTextStyleLargeTitle, @"title1": UIFontTextStyleTitle1,
-    @"title2": UIFontTextStyleTitle2, @"title3": UIFontTextStyleTitle3,
-    @"headline": UIFontTextStyleHeadline, @"subheadline": UIFontTextStyleSubheadline,
-    @"body": UIFontTextStyleBody, @"callout": UIFontTextStyleCallout,
-    @"footnote": UIFontTextStyleFootnote, @"caption1": UIFontTextStyleCaption1,
-    @"caption2": UIFontTextStyleCaption2,
-  }[value ?: @""];
-}
-
-UIImage *TinyuiSFSymbolImage(NSDictionary *configuration, BOOL includeColors)
-{
-  if (![configuration isKindOfClass:NSDictionary.class]) return nil;
-  NSString *name = configuration[@"name"];
-  if (![name isKindOfClass:NSString.class] || name.length == 0) return nil;
-
-  CGFloat size = [configuration[@"size"] doubleValue];
-  if (!std::isfinite(size) || size <= 0) size = 17;
-  UIImageSymbolWeight weight = symbolWeight(configuration[@"weight"]);
-  UIImageSymbolScale scale = symbolScale(configuration[@"scale"]);
-  UIFontTextStyle style = textStyle(configuration[@"textStyle"]);
-  if (style != nil) {
-    // RN supplies the scale explicitly; use unscaled metrics here to avoid
-    // applying Dynamic Type twice and to keep Yoga and UIKit in agreement.
-    UITraitCollection *traits = [UITraitCollection
-        traitCollectionWithPreferredContentSizeCategory:UIContentSizeCategoryLarge];
-    UIFont *font = [UIFont preferredFontForTextStyle:style compatibleWithTraitCollection:traits];
-    size = font.pointSize;
-    if (weight == UIImageSymbolWeightUnspecified) {
-      NSNumber *fontWeight = font.fontDescriptor.fontAttributes[UIFontDescriptorTraitsAttribute][UIFontWeightTrait];
-      weight = UIImageSymbolWeightForFontWeight(fontWeight.doubleValue);
-    }
-  }
-  double fontScale = [configuration[@"fontScale"] doubleValue];
-  if (std::isfinite(fontScale) && fontScale > 0) size *= fontScale;
-
-  UIImageSymbolConfiguration *symbol = [UIImageSymbolConfiguration
-      configurationWithPointSize:size weight:weight scale:scale];
-  NSString *family = configuration[@"fontFamily"];
-  if ([family isKindOfClass:NSString.class] && family.length > 0) {
-    UIFont *font = [UIFont fontWithName:family size:size];
-    if (font != nil) {
-      symbol = [UIImageSymbolConfiguration configurationWithFont:font scale:scale];
-      if (weight != UIImageSymbolWeightUnspecified) {
-        symbol = [symbol configurationByApplyingConfiguration:
-            [UIImageSymbolConfiguration configurationWithWeight:weight]];
-      }
-    }
-  }
-
-  if (includeColors) {
-    NSString *mode = configuration[@"renderingMode"];
-    UIColor *color = [RCTConvert UIColor:configuration[@"color"]] ?: UIColor.labelColor;
-    UIImageSymbolConfiguration *colors = nil;
-    if ([mode isEqual:@"monochrome"]) {
-      colors = UIImageSymbolConfiguration.configurationPreferringMonochrome;
-    } else if ([mode isEqual:@"multicolor"]) {
-      colors = UIImageSymbolConfiguration.configurationPreferringMulticolor;
-    } else if ([mode isEqual:@"hierarchical"]) {
-      colors = [UIImageSymbolConfiguration configurationWithHierarchicalColor:color];
-    } else if ([mode isEqual:@"palette"]) {
-      NSMutableArray<UIColor *> *palette = [NSMutableArray array];
-      id values = configuration[@"paletteColors"];
-      if ([values isKindOfClass:NSArray.class]) {
-        for (id value in values) {
-          UIColor *paletteColor = [RCTConvert UIColor:value];
-          if (paletteColor != nil && palette.count < 3) [palette addObject:paletteColor];
-        }
-      }
-      if (palette.count == 0) [palette addObject:color];
-      colors = [UIImageSymbolConfiguration configurationWithPaletteColors:palette];
-    }
-    if (colors != nil) symbol = [symbol configurationByApplyingConfiguration:colors];
-  }
-
-  if (@available(iOS 26.0, *)) {
-    NSString *variableMode = configuration[@"variableValueMode"];
-    UIImageSymbolVariableValueMode variable = UIImageSymbolVariableValueModeAutomatic;
-    if ([variableMode isEqual:@"color"]) variable = UIImageSymbolVariableValueModeColor;
-    if ([variableMode isEqual:@"draw"]) variable = UIImageSymbolVariableValueModeDraw;
-    symbol = [symbol configurationByApplyingConfiguration:
-        [UIImageSymbolConfiguration configurationWithVariableValueMode:variable]];
-
-    NSString *colorMode = configuration[@"colorRenderingMode"];
-    UIImageSymbolColorRenderingMode rendering = UIImageSymbolColorRenderingModeAutomatic;
-    if ([colorMode isEqual:@"flat"]) rendering = UIImageSymbolColorRenderingModeFlat;
-    if ([colorMode isEqual:@"gradient"]) rendering = UIImageSymbolColorRenderingModeGradient;
-    symbol = [symbol configurationByApplyingConfiguration:
-        [UIImageSymbolConfiguration configurationWithColorRenderingMode:rendering]];
-  }
-
-  BOOL asset = [configuration[@"source"] isEqual:@"asset"];
-  id variableValue = configuration[@"variableValue"];
-  UIImage *image;
-  if ([variableValue isKindOfClass:NSNumber.class]) {
-    double value = [variableValue doubleValue];
-    value = std::isfinite(value) ? fmin(1, fmax(0, value)) : 0;
-    image = asset
-        ? [UIImage imageNamed:name inBundle:NSBundle.mainBundle variableValue:value withConfiguration:symbol]
-        : [UIImage systemImageNamed:name variableValue:value withConfiguration:symbol];
-  } else {
-    image = asset
-        ? [UIImage imageNamed:name inBundle:NSBundle.mainBundle withConfiguration:symbol]
-        : [UIImage systemImageNamed:name withConfiguration:symbol];
-  }
-  // Symbol content transitions are undefined for ordinary bitmap assets.
-  return image.isSymbolImage ? image : nil;
-}
-
-#endif