react-native-skia 3.0.1 → 3.0.3

package/apple/SkiaGraphiteView.mm

@@ -1,180 +0,0 @@
-#import "SkiaGraphiteView.h"
-
-#import <React/RCTConversions.h>
-#import <React/RCTConvert.h>
-#import <React/RCTFabricComponentsPlugins.h>
-#import <React/RCTLog.h>
-
-#import <react/renderer/components/rnskia/ComponentDescriptors.h>
-#import <react/renderer/components/rnskia/EventEmitters.h>
-#import <react/renderer/components/rnskia/Props.h>
-#import <react/renderer/components/rnskia/RCTComponentViewHelpers.h>
-
-using namespace facebook::react;
-
-#if defined(SK_GRAPHITE)
-
-#import <QuartzCore/CADisplayLink.h>
-
-#import "RNSkAppleView.h"
-#import "RNSkGraphiteView.h"
-#import "RNSkPlatformContext.h"
-#import "RNSkiaModule.h"
-
-@implementation SkiaGraphiteView {
-#if !TARGET_OS_OSX
-  CADisplayLink *_displayLink;
-#endif
-}
-
-- (instancetype)initWithFrame:(CGRect)frame {
-  if (self = [super initWithFrame:frame]) {
-    // Pass SkManager as a raw pointer to avoid circular dependencies
-    auto skManager = [RNSkiaModule latestActiveSkManager].get();
-    [self initCommon:skManager
-             factory:[](std::shared_ptr<RNSkia::RNSkPlatformContext> context) {
-               return std::make_shared<RNSkAppleView<RNSkia::RNSkGraphiteView>>(
-                   context);
-             }];
-    static const auto defaultProps =
-        std::make_shared<const SkiaGraphiteViewProps>();
-    _props = defaultProps;
-  }
-  return self;
-}
-
-- (std::shared_ptr<RNSkia::RNSkGraphiteView>)graphiteView {
-  auto impl = [self impl];
-  if (impl == nullptr) {
-    return nullptr;
-  }
-  return std::static_pointer_cast<RNSkia::RNSkGraphiteView>(
-      impl->getDrawView());
-}
-
-#pragma mark - Frames
-
-// Presents on the display link: armed when a recording is submitted, paused
-// again once the queue is empty. macOS has no CADisplayLink on the minimum
-// deployment target, so frames are presented as soon as the main thread gets
-// to them there.
-- (void)scheduleFrame {
-#if !TARGET_OS_OSX
-  if (_displayLink == nil) {
-    _displayLink = [CADisplayLink displayLinkWithTarget:self
-                                               selector:@selector(onFrame:)];
-    [_displayLink addToRunLoop:[NSRunLoop mainRunLoop]
-                       forMode:NSRunLoopCommonModes];
-  }
-  _displayLink.paused = NO;
-#else
-  auto view = [self graphiteView];
-  if (view) {
-    view->presentFrame();
-  }
-#endif
-}
-
-#if !TARGET_OS_OSX
-- (void)onFrame:(CADisplayLink *)link {
-  auto view = [self graphiteView];
-  if (view == nullptr || !view->presentFrame()) {
-    link.paused = YES;
-  }
-}
-
-- (void)stopDisplayLink {
-  [_displayLink invalidate];
-  _displayLink = nil;
-}
-#endif
-
-#pragma mark - Lifecycle
-
-#if !TARGET_OS_OSX
-- (void)willMoveToSuperview:(UIView *)newSuperView {
-  [super willMoveToSuperview:newSuperView];
-#else
-- (void)viewWillMoveToSuperview:(NSView *)newSuperView {
-  [super viewWillMoveToSuperview:newSuperView];
-#endif // !TARGET_OS_OSX
-  if (newSuperView != nullptr) {
-    if (auto view = [self graphiteView]) {
-      __weak SkiaGraphiteView *weakSelf = self;
-      view->setFrameScheduler([weakSelf]() { [weakSelf scheduleFrame]; });
-    }
-  }
-}
-
-- (void)removeFromSuperview {
-#if !TARGET_OS_OSX
-  [self stopDisplayLink];
-#endif
-  [super removeFromSuperview];
-}
-
-- (void)prepareForRecycle {
-#if !TARGET_OS_OSX
-  [self stopDisplayLink];
-#endif
-  [super prepareForRecycle];
-}
-
-- (void)dealloc {
-#if !TARGET_OS_OSX
-  [self stopDisplayLink];
-#endif
-}
-
-#pragma mark - RCTComponentViewProtocol
-
-+ (ComponentDescriptorProvider)componentDescriptorProvider {
-  return concreteComponentDescriptorProvider<
-      SkiaGraphiteViewComponentDescriptor>();
-}
-
-- (void)updateProps:(const Props::Shared &)props
-           oldProps:(const Props::Shared &)oldProps {
-  const auto &newProps =
-      *std::static_pointer_cast<const SkiaGraphiteViewProps>(props);
-  [super updateProps:props oldProps:oldProps];
-  int nativeId =
-      [[RCTConvert NSString:RCTNSStringFromString(newProps.nativeId)] intValue];
-  [self setNativeId:nativeId];
-  [self setDebugMode:newProps.debug];
-  [self setOpaque:newProps.opaque];
-  [self setHighBitDepth:newProps.highBitDepth];
-}
-
-@end
-
-#else // SK_GRAPHITE
-
-@implementation SkiaGraphiteView
-
-- (instancetype)initWithFrame:(CGRect)frame {
-  if (self = [super initWithFrame:frame]) {
-    static dispatch_once_t once;
-    dispatch_once(&once, ^{
-      RCTLogError(@"SkiaGraphiteView requires the Graphite backend. Rebuild "
-                  @"with SK_GRAPHITE enabled; the view renders nothing.");
-    });
-    static const auto defaultProps =
-        std::make_shared<const SkiaGraphiteViewProps>();
-    _props = defaultProps;
-  }
-  return self;
-}
-
-+ (ComponentDescriptorProvider)componentDescriptorProvider {
-  return concreteComponentDescriptorProvider<
-      SkiaGraphiteViewComponentDescriptor>();
-}
-
-@end
-
-#endif // SK_GRAPHITE
-
-Class<RCTComponentViewProtocol> SkiaGraphiteViewCls(void) {
-  return SkiaGraphiteView.class;
-}

package/apple/SkiaPictureView.h

@@ -1,7 +0,0 @@
-#pragma once
-
-#import "SkiaUIView.h"
-
-@interface SkiaPictureView : SkiaUIView
-
-@end

package/apple/SkiaPictureView.mm

@@ -1,70 +0,0 @@
-#import "SkiaPictureView.h"
-
-#import "RNSkAppleView.h"
-#import "RNSkPictureView.h"
-#import "RNSkPlatformContext.h"
-
-#import "RNSkiaModule.h"
-#import "SkiaUIView.h"
-
-#import <React/RCTConversions.h>
-#import <React/RCTConvert.h>
-#import <React/RCTFabricComponentsPlugins.h>
-
-#import <react/renderer/components/rnskia/ComponentDescriptors.h>
-#import <react/renderer/components/rnskia/EventEmitters.h>
-#import <react/renderer/components/rnskia/Props.h>
-#import <react/renderer/components/rnskia/RCTComponentViewHelpers.h>
-
-using namespace facebook::react;
-
-@implementation SkiaPictureView
-
-- (instancetype)initWithFrame:(CGRect)frame {
-  if (self = [super initWithFrame:frame]) {
-    // Pass SkManager as a raw pointer to avoid circular dependencies
-    auto skManager = [RNSkiaModule latestActiveSkManager].get();
-    [self initCommon:skManager
-             factory:[](std::shared_ptr<RNSkia::RNSkPlatformContext> context) {
-               return std::make_shared<RNSkAppleView<RNSkia::RNSkPictureView>>(
-                   context);
-             }];
-    static const auto defaultProps =
-        std::make_shared<const SkiaPictureViewProps>();
-    _props = defaultProps;
-  }
-  return self;
-}
-
-#pragma mark - RCTComponentViewProtocol
-
-+ (ComponentDescriptorProvider)componentDescriptorProvider {
-  return concreteComponentDescriptorProvider<
-      SkiaPictureViewComponentDescriptor>();
-}
-
-- (void)updateProps:(const Props::Shared &)props
-           oldProps:(const Props::Shared &)oldProps {
-  const auto &newProps =
-      *std::static_pointer_cast<const SkiaPictureViewProps>(props);
-  [super updateProps:props oldProps:oldProps];
-  int nativeId =
-      [[RCTConvert NSString:RCTNSStringFromString(newProps.nativeId)] intValue];
-  [self setNativeId:nativeId];
-  [self setDebugMode:newProps.debug];
-  [self setOpaque:newProps.opaque];
-  [self setHighBitDepth:newProps.highBitDepth];
-  if (newProps.colorSpace == "" || newProps.colorSpace == "srgb") {
-    bool useP3 = false;
-    [self setUseP3ColorSpace:useP3];
-  } else if (newProps.colorSpace == "p3") {
-    bool useP3 = true;
-    [self setUseP3ColorSpace:useP3];
-  }
-}
-
-@end
-
-Class<RCTComponentViewProtocol> SkiaPictureViewCls(void) {
-  return SkiaPictureView.class;
-}

package/apple/SkiaUIView.h

@@ -1,31 +0,0 @@
-#pragma once
-
-#import <memory>
-#import <string>
-
-#import <CoreFoundation/CoreFoundation.h>
-#if !TARGET_OS_OSX
-#import <UIKit/UIKit.h>
-#else
-#import <React/RCTUIKit.h>
-#endif // !TARGET_OS_OSX
-
-#import <React/RCTViewComponentView.h>
-
-#import "RNSkAppleView.h"
-#import "RNSkManager.h"
-
-@interface SkiaUIView : RCTViewComponentView
-
-- (void)initCommon:(RNSkia::RNSkManager *)manager
-           factory:(std::function<std::shared_ptr<RNSkBaseAppleView>(
-                        std::shared_ptr<RNSkia::RNSkPlatformContext>)>)factory;
-- (std::shared_ptr<RNSkBaseAppleView>)impl;
-
-- (void)setDebugMode:(bool)debugMode;
-- (void)setOpaque:(bool)opaque;
-- (void)setNativeId:(size_t)nativeId;
-- (void)setUseP3ColorSpace:(bool)useP3ColorSpace;
-- (void)setHighBitDepth:(bool)highBitDepth;
-
-@end

package/apple/SkiaUIView.mm

@@ -1,164 +0,0 @@
-#import <QuartzCore/CATransaction.h>
-
-#import "RNSkiaModule.h"
-#import "SkiaUIView.h"
-
-#include <utility>
-#include <vector>
-
-#import "RNSkManager.h"
-
-@implementation SkiaUIView {
-  std::shared_ptr<RNSkBaseAppleView> _impl;
-  RNSkia::RNSkManager *_manager;
-  std::function<std::shared_ptr<RNSkBaseAppleView>(
-      std::shared_ptr<RNSkia::RNSkPlatformContext>)>
-      _factory;
-  bool _debugMode;
-  bool _opaque;
-  bool _useP3ColorSpace;
-  bool _highBitDepth;
-  size_t _nativeId;
-}
-
-#pragma mark Initialization and destruction
-
-- (void)initCommon:(RNSkia::RNSkManager *)manager
-           factory:(std::function<std::shared_ptr<RNSkBaseAppleView>(
-                        std::shared_ptr<RNSkia::RNSkPlatformContext>)>)factory {
-  _manager = manager;
-  _nativeId = 0;
-  _debugMode = false;
-  _factory = factory;
-}
-
-#pragma mark Lifecycle
-
-#if !TARGET_OS_OSX
-- (void)willMoveToSuperview:(UIView *)newSuperView {
-#else
-- (void)viewWillMoveToSuperview:(NSView *)newSuperView {
-#endif // !TARGET_OS_OSX
-  if (newSuperView != nullptr) {
-    // Create implementation view when the parent view is set
-    if (_impl == nullptr && _manager != nullptr) {
-      _impl = _factory(_manager->getPlatformContext());
-      if (_impl == nullptr) {
-        throw std::runtime_error(
-            "Expected Skia view implementation, got nullptr.");
-      }
-      [self.layer addSublayer:_impl->getLayer()];
-      if (_nativeId != 0) {
-        _manager->setSkiaView(_nativeId, _impl->getDrawView());
-      }
-      _impl->getDrawView()->setShowDebugOverlays(_debugMode);
-      _impl->setUseP3ColorSpace(_useP3ColorSpace);
-      _impl->setHighBitDepth(_highBitDepth);
-    }
-  }
-}
-
-- (void)removeFromSuperview {
-  // Cleanup when removed from view hierarchy
-  if (_impl != nullptr) {
-    [_impl->getLayer() removeFromSuperlayer];
-
-    if (_nativeId != 0 && _manager != nullptr) {
-      _manager->setSkiaView(_nativeId, nullptr);
-    }
-
-    _impl = nullptr;
-  }
-
-  [super removeFromSuperview];
-}
-
-- (void)dealloc {
-  [self unregisterView];
-}
-
-- (void)prepareForRecycle {
-  [super prepareForRecycle];
-  [self unregisterView];
-}
-
-- (void)finalizeUpdates:(RNComponentViewUpdateMask)updateMask {
-  [super finalizeUpdates:updateMask];
-  if (updateMask == RNComponentViewUpdateMaskAll) {
-    // this flag is only set when the view is inserted and we want to set the
-    // manager here since the view could be recycled or the app could be
-    // refreshed and we would have a stale manager then
-    _manager = [RNSkiaModule latestActiveSkManager].get();
-  }
-}
-
-- (void)unregisterView {
-  if (_manager != nullptr && _nativeId != 0) {
-    _manager->unregisterSkiaView(_nativeId);
-  }
-}
-
-#pragma Render
-
-- (void)drawRect:(CGRect)rect {
-  // We override drawRect to ensure we to direct rendering when the
-  // underlying OS view needs to render:
-  if (_impl != nullptr) {
-    _impl->getDrawView()->redraw();
-  }
-}
-
-#pragma mark Layout
-
-- (void)layoutSubviews {
-  [super layoutSubviews];
-  if (_impl != nullptr) {
-    [CATransaction begin];
-    [CATransaction setDisableActions:YES];
-    _impl->setSize(self.bounds.size.width, self.bounds.size.height);
-    [CATransaction commit];
-  }
-}
-
-#pragma mark Properties
-
-- (void)setDebugMode:(bool)debugMode {
-  _debugMode = debugMode;
-  if (_impl != nullptr) {
-    _impl->getDrawView()->setShowDebugOverlays(debugMode);
-  }
-}
-
-- (void)setOpaque:(bool)opaque {
-  _opaque = opaque;
-}
-
-- (void)setNativeId:(size_t)nativeId {
-  _nativeId = nativeId;
-
-  if (_impl != nullptr) {
-    _manager->registerSkiaView(nativeId, _impl->getDrawView());
-  }
-}
-
-- (void)setUseP3ColorSpace:(bool)useP3ColorSpace {
-  _useP3ColorSpace = useP3ColorSpace;
-  if (_impl != nullptr) {
-    _impl->setUseP3ColorSpace(_useP3ColorSpace);
-  }
-}
-
-- (void)setHighBitDepth:(bool)highBitDepth {
-  _highBitDepth = highBitDepth;
-  if (_impl != nullptr) {
-    _impl->setHighBitDepth(_highBitDepth);
-  }
-}
-
-#pragma mark External API
-
-- (std::shared_ptr<RNSkBaseAppleView>)impl {
-  return _impl;
-}
-
-@end