react-native-screens 5.0.0-alpha.3 → 5.0.0-alpha.4

package/ios/helpers/image/RNSImageLoadingHelper.mm

@@ -59,6 +59,15 @@
       }];
 }
 
++ (nullable UIImage *)symbolImageNamed:(nonnull NSString *)name
+{
+  UIImage *image = [UIImage systemImageNamed:name];
+  if (image == nil) {
+    image = [UIImage imageNamed:name];
+  }
+  return image;
+}
+
 + (nullable UIImage *)handleRenderingModeForImage:(nullable UIImage *)image isTemplate:(BOOL)isTemplate
 {
   if (isTemplate) {

package/ios/legacy/RNSBarButtonItem.mm

@@ -89,6 +89,21 @@ static UIMenuOptions RNSMakeUIMenuOptionsFromConfig(NSDictionary *config);
   }
 #endif
 
+// tvOS and visionOS are excluded on purpose: `visibilityPriority` exists there, but the only
+// supported value is `standard`, which is already the default.
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(27_0) && !TARGET_OS_TV && !TARGET_OS_VISION
+  if (@available(iOS 27.0, *)) {
+    NSString *visibilityPriority = dict[@"visibilityPriority"];
+    if ([visibilityPriority isEqualToString:@"low"]) {
+      self.visibilityPriority = UIBarButtonItemVisibilityPriorityLow;
+    } else if ([visibilityPriority isEqualToString:@"high"]) {
+      self.visibilityPriority = UIBarButtonItemVisibilityPriorityHigh;
+    } else if ([visibilityPriority isEqualToString:@"standard"]) {
+      self.visibilityPriority = UIBarButtonItemVisibilityPriorityStandard;
+    }
+  }
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(27_0) && !TARGET_OS_TV && !TARGET_OS_VISION
+
   NSString *variant = dict[@"variant"];
   if (variant) {
     if ([variant isEqualToString:@"done"]) {

package/ios/legacy/RNSConvert.h

@@ -4,6 +4,7 @@
 #if defined(__cplusplus)
 #import <react/renderer/components/rnscreens/Props.h>
 #endif // __cplusplus
+#import "RNSDefines.h"
 #import "RNSLegacyEnums.h"
 
 #if defined(__cplusplus)
@@ -31,6 +32,11 @@ namespace react = facebook::react;
 + (RNSScreenStackHeaderSubviewType)RNSScreenStackHeaderSubviewTypeFromCppEquivalent:
     (react::RNSScreenStackHeaderSubviewType)subviewType;
 
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(27_0)
++ (UIBarButtonItemVisibilityPriority)UIBarButtonItemVisibilityPriorityFromCppEquivalent:
+    (react::RNSScreenStackHeaderSubviewVisibilityPriority)visibilityPriority API_AVAILABLE(ios(27.0));
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(27_0)
+
 + (RNSScreenReplaceAnimation)RNSScreenReplaceAnimationFromCppEquivalent:
     (react::RNSScreenReplaceAnimation)replaceAnimation;
 

package/ios/legacy/RNSConvert.mm

@@ -118,6 +118,23 @@
   }
 }
 
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(27_0)
++ (UIBarButtonItemVisibilityPriority)UIBarButtonItemVisibilityPriorityFromCppEquivalent:
+    (react::RNSScreenStackHeaderSubviewVisibilityPriority)visibilityPriority
+{
+  switch (visibilityPriority) {
+    using enum react::RNSScreenStackHeaderSubviewVisibilityPriority;
+
+    case Low:
+      return UIBarButtonItemVisibilityPriorityLow;
+    case High:
+      return UIBarButtonItemVisibilityPriorityHigh;
+    case Standard:
+      return UIBarButtonItemVisibilityPriorityStandard;
+  }
+}
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(27_0)
+
 + (RNSScreenReplaceAnimation)RNSScreenReplaceAnimationFromCppEquivalent:
     (react::RNSScreenReplaceAnimation)replaceAnimation
 {

package/ios/legacy/RNSNavigationBar.h

@@ -0,0 +1,31 @@
+#pragma once
+
+#import <UIKit/UIKit.h>
+#import "RNSDefines.h"
+
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+
+NS_ASSUME_NONNULL_BEGIN
+
+@protocol RNSNavigationBarLayoutDelegate <NSObject>
+
+- (void)navigationBarDidLayoutSubviews:(UINavigationBar *)navigationBar;
+
+@end
+
+/**
+ * Navigation bar used by the legacy stack (`RNSNavigationController`).
+ *
+ * It reports its layout passes to the `layoutDelegate`. On iOS 26+ UIKit can move the content of the navigation bar
+ * (e.g. on rotation or fold of iPhone Duo, or during the bar minimization on iOS 27) without any layout pass of the
+ * navigation controller's view, and layout of the bar is the only callback we receive in such a case.
+ */
+@interface RNSNavigationBar : UINavigationBar
+
+@property (nonatomic, weak, nullable) id<RNSNavigationBarLayoutDelegate> layoutDelegate;
+
+@end
+
+NS_ASSUME_NONNULL_END
+
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV

package/ios/legacy/RNSNavigationBar.mm

@@ -0,0 +1,15 @@
+#import "RNSNavigationBar.h"
+
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+
+@implementation RNSNavigationBar
+
+- (void)layoutSubviews
+{
+  [super layoutSubviews];
+  [_layoutDelegate navigationBarDidLayoutSubviews:self];
+}
+
+@end
+
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV

package/ios/legacy/RNSScreen.mm

@@ -53,6 +53,9 @@ struct ContentWrapperBox {
 
 @implementation RNSScreenView {
   __weak RCTScrollViewComponentView *_sheetsScrollView;
+  /// Tag of `_sheetsScrollView` at the time we started observing it. Fabric changes the tag when it recycles
+  /// the view, so a mismatch means the instance now belongs to some other component.
+  NSInteger _sheetsScrollViewTag;
 
   /// Up-to-date only when sheet is in `fitToContents` mode.
   CGFloat _sheetContentHeight;
@@ -99,6 +102,7 @@ struct ContentWrapperBox {
   _sheetExpandsWhenScrolledToEdge = YES;
 #endif // !TARGET_OS_TV
   _sheetsScrollView = nil;
+  _sheetsScrollViewTag = 0;
   _sheetContentHeight = 0.0;
   _markedForUnmountInCurrentTransaction = NO;
   _synchronousShadowStateUpdatesEnabled = YES;
@@ -134,16 +138,24 @@ RNS_IGNORE_SUPER_CALL_END
   if (_state != nullptr) {
     RNSScreenStackHeaderConfig *config = [self findHeaderConfig];
 
-    // * in large title, ScrollView handles the offset of content so we cannot set it here also
-    // * TODO: Why is it assumed in comment above, that large title uses scrollview here? What if only SafeAreaView is
+    // The content offset sent to the shadow tree must match the screen's native origin in the navigation controller's
+    // view. It is used by measurements & hit testing only, the size is delivered separately (`frameSize`).
+    // * On iOS 26+ (see `+[RNSScreenStackHeaderConfig screensExtendUnderOpaqueNavigationBar]`) the screen is always
+    // laid out under the navigation bar, so the origin is 0 and the `SafeAreaView` rendered by `ScreenStackItem`
+    // insets the content below an opaque bar. All branches below evaluate to 0 in that case.
+    // * Below iOS 26, when config.translucent == true, we use `edgesForExtendedLayout` and the screen is laid out
+    // under the navigation bar, therefore there is no need to set content offset in shadow tree.
+    // * Below iOS 26, in large title, ScrollView handles the offset of content so we cannot set it here also.
+    // TODO: Why is it assumed in comment above, that large title uses scrollview here? What if only SafeAreaView is
     // used?
-    // * When config.translucent == true, we currently use `edgesForExtendedLayout` and the screen is laid out under the
-    // navigation bar, therefore there is no need to set content offset in shadow tree.
     // * When this view is the modal root controller (presented in separate view hierarchy) it does not have navigation
     // bar! We send non-zero size to JS, for some reason. TODO: this needs to be investigated.
-    const CGFloat effectiveContentOffsetY = config.largeTitle || config.translucent || self.isPresentedAsNativeModal
-        ? 0
-        : [_controller calculateHeaderHeightIsModal:self.isPresentedAsNativeModal];
+    // * Otherwise the offset must match the actual native origin of the screen. We can not derive it from the
+    // navigation bar geometry, because UIKit does not always lay out the screen right below the navigation bar
+    // (e.g. on iOS 26 `edgesForExtendedLayout` ignores the navigation bar's origin offset).
+    // See https://github.com/software-mansion/react-native-screens-labs/issues/1841
+    const CGFloat effectiveContentOffsetY =
+        config.largeTitle || config.translucent || self.isPresentedAsNativeModal ? 0 : [self originInNavigationView].y;
 
     auto newState = react::RNSScreenState{RCTSizeFromCGSize(self.bounds.size), {0, effectiveContentOffsetY}};
 
@@ -176,6 +188,17 @@ RNS_IGNORE_SUPER_CALL_END
   }
 }
 
+// Returns origin of the screen in the coordinate space of its navigation controller's view, which matches
+// the coordinate space of the screen stack in the shadow tree.
+- (CGPoint)originInNavigationView
+{
+  UIView *navigationView = _controller.navigationController.view;
+  if (navigationView == nil || ![self isDescendantOfView:navigationView]) {
+    return CGPointZero;
+  }
+  return [self convertPoint:CGPointZero toView:navigationView];
+}
+
 - (void)applyFrameCorrectionForDescendantScrollView
 {
   // A dismissed sheet can still receive a layout pass after React has deleted it. By then Fabric
@@ -194,6 +217,8 @@ RNS_IGNORE_SUPER_CALL_END
     // we are going to overwrite it anyway.
     [scrollView addObserver:self forKeyPath:@"bounds" options:0 context:nil];
   }
+  // Refreshed even for the same instance: Fabric might have recycled it back into this sheet.
+  _sheetsScrollViewTag = scrollView != nil ? scrollView.tag : 0;
   if (scrollView != nil) {
     [self correctScrollViewFrame:scrollView withHeader:nil];
   }
@@ -222,6 +247,16 @@ RNS_IGNORE_SUPER_CALL_END
     return;
   }
 
+  // The sheet's content can remove its scroll view while the sheet stays presented. Fabric then recycles
+  // the instance (possibly into another screen), which changes its tag. Stop observing it instead of
+  // forcing it to this screen's frame. See #4785.
+  if (scrollView.tag != _sheetsScrollViewTag) {
+    [scrollView removeObserver:self forKeyPath:@"bounds" context:nil];
+    _sheetsScrollView = nil;
+    _sheetsScrollViewTag = 0;
+    return;
+  }
+
   RNSScreenContentWrapper *_Nullable contentWrapper = _contentWrapperBox.contentWrapper;
   if (contentWrapper != nil && [contentWrapper coerceChildScrollViewComponentSizeToSize:self.frame.size]) {
     return;
@@ -784,6 +819,7 @@ RNS_IGNORE_SUPER_CALL_END
   if (_sheetsScrollView != nil) {
     [_sheetsScrollView removeObserver:self forKeyPath:@"bounds" context:nil];
     _sheetsScrollView = nil;
+    _sheetsScrollViewTag = 0;
   }
 
   // We want to run after container updates are performed (transitions etc.)
@@ -1428,6 +1464,7 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
   BOOL _isSwiping;
   BOOL _shouldNotify;
   BOOL _isRemovedFromParent;
+  BOOL _hasNotifiedDismissed;
 }
 
 #pragma mark - Common
@@ -1439,6 +1476,7 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
     _fakeView = [UIView new];
     _shouldNotify = YES;
     _isRemovedFromParent = NO;
+    _hasNotifiedDismissed = NO;
   }
   return self;
 }
@@ -1535,7 +1573,7 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
       [self.screenView notifyDismissCancelledWithDismissCount:_dismissCount];
     } else {
       // screen dismissed, send event
-      [self.screenView notifyDismissedWithCount:_dismissCount];
+      [self notifyDismissedIfNeeded];
     }
   }
   // same flow as in viewDidAppear
@@ -1553,10 +1591,12 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
   [super viewDidLayoutSubviews];
 
   // The below code makes the screen view adapt dimensions provided by the system. We take these
-  // into account only when the view is mounted under RNSNavigationController in which case system
-  // provides additional padding to account for possible header, and in the case when screen is
-  // shown as a native modal, as the final dimensions of the modal on iOS 12+ are shorter than the
-  // screen size
+  // into account only when the view is mounted under RNSNavigationController, in which case the
+  // navigation controller sizes the screen (below iOS 26 an opaque navigation bar is excluded from
+  // the screen's frame, on iOS 26+ the screen always spans under the bar, see
+  // `+[RNSScreenStackHeaderConfig screensExtendUnderOpaqueNavigationBar]`), and in the case when
+  // screen is shown as a native modal, as the final dimensions of the modal on iOS 12+ are shorter
+  // than the screen size.
   BOOL isDisplayedWithinUINavController = [self.parentViewController isKindOfClass:[RNSNavigationController class]];
   BOOL isTabScreen = [self.parentViewController isKindOfClass:RNSTabBarController.class];
 
@@ -1620,6 +1660,12 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
     return 0;
   }
 
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(27_0) && !TARGET_OS_TV
+  if (@available(iOS 27.0, *)) {
+    return [self calculateMinimizationAwareHeaderHeightInNavigationController:navctr];
+  }
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(27_0) && !TARGET_OS_TV
+
   CGFloat navbarHeight = navctr.navigationBar.frame.size.height;
 #if !TARGET_OS_TV
   CGFloat navbarInset = navctr.navigationBar.frame.origin.y;
@@ -1631,6 +1677,35 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
   return navbarHeight + navbarInset;
 }
 
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(27_0) && !TARGET_OS_TV
+// On iOS 27 the navigation bar can minimize in response to scrolling (`UIBarMinimization`). The frame of
+// `UINavigationBar` does not follow the minimization, only its subviews (background, content view, large title,
+// search bar) do - they are shifted up within the bar. Therefore we measure the bottom edge of the subviews
+// instead, in the coordinate space of the navigation controller's view. The value is clamped to the bar's frame,
+// which is the maximum extent of the bar in the expanded state.
+- (CGFloat)calculateMinimizationAwareHeaderHeightInNavigationController:(UINavigationController *)navctr
+    API_AVAILABLE(ios(27.0))
+{
+  UINavigationBar *navbar = navctr.navigationBar;
+  CGFloat navbarMaxY = CGRectGetMaxY([navbar convertRect:navbar.bounds toView:navctr.view]);
+  CGFloat maxY = -CGFLOAT_MAX;
+
+  for (UIView *subview in navbar.subviews) {
+    if (subview.isHidden || CGRectIsEmpty(subview.frame)) {
+      continue;
+    }
+    maxY = MAX(maxY, CGRectGetMaxY([navbar convertRect:subview.frame toView:navctr.view]));
+  }
+
+  if (maxY == -CGFLOAT_MAX) {
+    // No measurable subviews, same as the pre-iOS 27 formula.
+    return navbarMaxY;
+  }
+
+  return MIN(maxY, navbarMaxY);
+}
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(27_0) && !TARGET_OS_TV
+
 - (void)calculateAndNotifyHeaderHeightChangeIsModal:(BOOL)isModal
 {
   CGFloat totalHeight = [self calculateHeaderHeightIsModal:isModal];
@@ -1698,6 +1773,34 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
   _isRemovedFromParent = YES;
 }
 
+- (BOOL)isNativelyDismissedFromContainer
+{
+  if (self.presentingViewController != nil) {
+    return NO;
+  }
+  if (self.parentViewController == nil) {
+    return YES;
+  }
+  if ([self.parentViewController isKindOfClass:UINavigationController.class]) {
+    UINavigationController *navigationController = (UINavigationController *)self.parentViewController;
+    return ![navigationController.viewControllers containsObject:self];
+  }
+  return NO;
+}
+
+- (void)notifyDismissedIfNeeded
+{
+  if (_hasNotifiedDismissed || self.screenView.preventNativeDismiss) {
+    return;
+  }
+  if (![self isNativelyDismissedFromContainer]) {
+    return;
+  }
+  _hasNotifiedDismissed = YES;
+  _isRemovedFromParent = YES;
+  [self.screenView notifyDismissedWithCount:_dismissCount];
+}
+
 #pragma mark - transition progress related methods
 
 - (void)setupProgressNotification
@@ -1720,12 +1823,19 @@ Class<RCTComponentViewProtocol> RNSScreenCls(void)
       [self->_animationTimer addToRunLoop:[NSRunLoop currentRunLoop] forMode:NSDefaultRunLoopMode];
     };
 
+    BOOL notifyDismissWhenTransitionEnds = _closing;
     [self.transitionCoordinator
         animateAlongsideTransition:animation
                         completion:^(id<UIViewControllerTransitionCoordinatorContext> _Nonnull context) {
                           [self->_animationTimer setPaused:YES];
                           [self->_animationTimer invalidate];
                           [self->_fakeView removeFromSuperview];
+                          // iOS 27 can skip viewDidDisappear when a tab switch
+                          // interrupts popToRoot. If this screen was popped,
+                          // notify JS when the transition ends.
+                          if (notifyDismissWhenTransitionEnds) {
+                            [self notifyDismissedIfNeeded];
+                          }
                         }];
   }
 }

package/ios/legacy/RNSScreenContentWrapper.mm

@@ -53,6 +53,9 @@ namespace react = facebook::react;
 {
   UIViewController *controller = screenCtrl;
   float headerHeightErrata = 0.f;
+  // When screens extend under opaque navigation bars (iOS 26+), the `SafeAreaView` rendered inside this wrapper insets
+  // the content below the bar, so the bar height is already part of the wrapper's frame and must not be added again.
+  const BOOL wrapperFrameIncludesNavigationBar = [RNSScreenStackHeaderConfig screensExtendUnderOpaqueNavigationBar];
 
   do {
     if ([controller isKindOfClass:RNSScreen.class]) {
@@ -60,7 +63,7 @@ namespace react = facebook::react;
       if ([currentScreen.screenView registerContentWrapper:self contentHeightErrata:headerHeightErrata]) {
         break;
       }
-    } else if ([controller isKindOfClass:RNSNavigationController.class]) {
+    } else if (!wrapperFrameIncludesNavigationBar && [controller isKindOfClass:RNSNavigationController.class]) {
       RNSNavigationController *navigationController = static_cast<RNSNavigationController *>(controller);
       UINavigationBar *navigationBar = navigationController.navigationBar;
 

package/ios/legacy/RNSScreenStack.mm

@@ -12,6 +12,7 @@
 #import <react/renderer/components/rnscreens/RCTComponentViewHelpers.h>
 #import "RCTSurfaceTouchHandler+RNSUtility.h"
 #import "RNSDefines.h"
+#import "RNSNavigationBar.h"
 #import "RNSPercentDrivenInteractiveTransition.h"
 #import "RNSScreen.h"
 #import "RNSScreenStackAnimator.h"
@@ -24,6 +25,10 @@
 #import "UIView+RNSUtility.h"
 #import "integrations/RNSDismissibleModalProtocol.h"
 
+#if TARGET_OS_TV
+#import <React/RCTTVRemoteHandler.h>
+#endif // TARGET_OS_TV
+
 namespace react = facebook::react;
 
 @interface RNSScreenStackView () <UINavigationControllerDelegate,
@@ -36,9 +41,36 @@ namespace react = facebook::react;
 @property (nonatomic) BOOL updatingModals;
 @property (nonatomic) BOOL scheduleModalsUpdate;
 
+#if TARGET_OS_TV
+@property (nonatomic, assign) BOOL disableDefaultMenuAction;
+@property (nonatomic, assign) BOOL observingTVMenuKeyNotifications;
+#endif // TARGET_OS_TV
+
+@end
+
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+@interface RNSNavigationController () <RNSNavigationBarLayoutDelegate>
 @end
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
 
-@implementation RNSNavigationController
+@implementation RNSNavigationController {
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+  CGRect _lastNavigationBarFrame;
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+}
+
+- (instancetype)init
+{
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+  self = [super initWithNavigationBarClass:RNSNavigationBar.class toolbarClass:nil];
+  if (self != nil && [self.navigationBar isKindOfClass:RNSNavigationBar.class]) {
+    static_cast<RNSNavigationBar *>(self.navigationBar).layoutDelegate = self;
+  }
+#else // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+  self = [super init];
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0) && !TARGET_OS_TV
+  return self;
+}
 
 #if !TARGET_OS_TV
 - (UIViewController *)childViewControllerForStatusBarStyle
@@ -59,25 +91,34 @@ namespace react = facebook::react;
 - (void)viewDidLayoutSubviews
 {
   [super viewDidLayoutSubviews];
+
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0)
+  if (@available(iOS 26.0, *)) {
+    [self requestLayoutIfNavigationBarFrameChanged];
+  }
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0)
+
   if ([self.topViewController isKindOfClass:[RNSScreen class]]) {
     RNSScreen *screenController = (RNSScreen *)self.topViewController;
-    BOOL isNotDismissingModal = screenController.presentedViewController == nil ||
-        (screenController.presentedViewController != nil &&
-         ![screenController.presentedViewController isBeingDismissed]);
-    BOOL isPresentingSearchController =
-        [screenController.presentedViewController isKindOfClass:UISearchController.class];
-
-    // Calculate header height during simple transition from one screen to another.
-    // If RNSScreen includes a navigation controller of type RNSNavigationController, it should not calculate
-    // header height, as it could have nested stack.
-    if (![screenController hasNestedStack] && (isPresentingSearchController || isNotDismissingModal)) {
-      [screenController calculateAndNotifyHeaderHeightChangeIsModal:NO];
-    }
-
+    [self notifyHeaderHeightChangeToScreen:screenController];
     [self maybeUpdateHeaderLayoutInfoInShadowTree:screenController];
   }
 }
 
+- (void)notifyHeaderHeightChangeToScreen:(RNSScreen *)screenController
+{
+  BOOL isNotDismissingModal = screenController.presentedViewController == nil ||
+      (screenController.presentedViewController != nil && ![screenController.presentedViewController isBeingDismissed]);
+  BOOL isPresentingSearchController = [screenController.presentedViewController isKindOfClass:UISearchController.class];
+
+  // Calculate header height during simple transition from one screen to another.
+  // If RNSScreen includes a navigation controller of type RNSNavigationController, it should not calculate
+  // header height, as it could have nested stack.
+  if (![screenController hasNestedStack] && (isPresentingSearchController || isNotDismissingModal)) {
+    [screenController calculateAndNotifyHeaderHeightChangeIsModal:NO];
+  }
+}
+
 - (UIInterfaceOrientationMask)supportedInterfaceOrientations
 {
   return [self topViewController].supportedInterfaceOrientations;
@@ -116,7 +157,61 @@ namespace react = facebook::react;
 
   [headerConfig updateHeaderStateInShadowTreeInContextOfNavigationBar:self.navigationBar];
 }
-#endif
+
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0)
+- (void)requestLayoutIfNavigationBarFrameChanged API_AVAILABLE(ios(26.0))
+{
+  // UIKit positions the navigation bar during layout of our view, but on iOS 26+ it does so after it has computed
+  // the safe area insets of the top view controller. The insets are therefore derived from the previous frame of
+  // the bar and they are not corrected until the next layout pass, which nobody requests.
+  // Since on iOS 26+ the screen is always laid out under the navigation bar, anything that relies on the insets
+  // (`SafeAreaView` rendered by `ScreenStackItem`, content inset adjustment of a scroll view) is misplaced by
+  // the distance the bar has travelled.
+  //
+  // When the frame of the bar has changed, we request another layout pass, in which UIKit computes the insets with
+  // the bar already in place. It runs in the same frame. The frame of the bar does not depend on the insets of
+  // the top view controller, so the bar is not moved in the additional pass and we do not request yet another one.
+  const CGRect navigationBarFrame = self.navigationBar.frame;
+  if (!CGRectEqualToRect(navigationBarFrame, _lastNavigationBarFrame)) {
+    _lastNavigationBarFrame = navigationBarFrame;
+    [self.view setNeedsLayout];
+  }
+}
+
+#pragma mark - RNSNavigationBarLayoutDelegate
+
+- (void)navigationBarDidLayoutSubviews:(UINavigationBar *)navigationBar
+{
+  // On iOS 26+ UIKit can position the content of the navigation bar after `viewDidLayoutSubviews`, in a layout pass
+  // that follows layout of the bar itself (e.g. title view on rotation of iPhone Duo), or without any layout pass of
+  // our view at all (bar minimization on iOS 27). None of our views receives a callback when it is moved this way,
+  // therefore we request layout of the header subviews. They are laid out later in the same layout pass, after their
+  // ancestors, and update their position in the shadow tree then.
+  // See https://github.com/software-mansion/react-native-screens-labs/issues/1841
+  if (@available(iOS 26.0, *)) {
+    if (![self.topViewController isKindOfClass:[RNSScreen class]]) {
+      return;
+    }
+
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(27_0)
+    // The bar minimization (iOS 27+) changes the visible height of the bar without changing its frame and without
+    // layout of our view, so this is the only place where we can follow it.
+    if (@available(iOS 27.0, *)) {
+      [self notifyHeaderHeightChangeToScreen:static_cast<RNSScreen *>(self.topViewController)];
+    }
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(27_0)
+
+    auto headerConfig = static_cast<RNSScreen *>(self.topViewController).screenView.findHeaderConfig;
+    if (headerConfig == nil || !headerConfig.shouldHeaderBeVisible) {
+      return;
+    }
+
+    [headerConfig setNeedsLayoutForHeaderSubviewsInNavigationBar:navigationBar];
+  }
+}
+
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0)
+#endif // !TARGET_OS_TV
 
 - (void)willMoveToParentViewController:(UIViewController *)parent
 {
@@ -283,8 +378,81 @@ RNS_IGNORE_SUPER_CALL_END
   [super didMoveToWindow];
   // for handling nested stacks
   [self maybeAddToParentAndUpdateContainer];
+#if TARGET_OS_TV
+  if (self.window != nil) {
+    [self registerForTVMenuKeyNotificationsIfNeeded];
+    [self syncTVMenuKeyHandling];
+  } else {
+    [self unregisterForTVMenuKeyNotificationsIfNeeded];
+  }
+#endif // TARGET_OS_TV
+}
+
+#if TARGET_OS_TV
+
+- (void)registerForTVMenuKeyNotificationsIfNeeded
+{
+  if (_observingTVMenuKeyNotifications) {
+    return;
+  }
+  _observingTVMenuKeyNotifications = YES;
+  NSNotificationCenter *center = NSNotificationCenter.defaultCenter;
+  [center addObserver:self
+             selector:@selector(handleTVMenuKeyNotification:)
+                 name:RCTTVEnableMenuKeyNotification
+               object:nil];
+  [center addObserver:self
+             selector:@selector(handleTVMenuKeyNotification:)
+                 name:RCTTVDisableMenuKeyNotification
+               object:nil];
+}
+
+- (void)unregisterForTVMenuKeyNotificationsIfNeeded
+{
+  if (!_observingTVMenuKeyNotifications) {
+    return;
+  }
+  _observingTVMenuKeyNotifications = NO;
+  NSNotificationCenter *center = NSNotificationCenter.defaultCenter;
+  [center removeObserver:self name:RCTTVEnableMenuKeyNotification object:nil];
+  [center removeObserver:self name:RCTTVDisableMenuKeyNotification object:nil];
+}
+
+- (void)handleTVMenuKeyNotification:(NSNotification *)notification
+{
+  [self syncTVMenuKeyHandling];
+}
+
+- (BOOL)shouldDisableUIKitMenuBackGesture
+{
+  return _disableDefaultMenuAction && [RCTTVRemoteHandler useMenuKey];
+}
+
+- (nullable UITapGestureRecognizer *)uiKitMenuBackGestureRecognizer
+{
+  for (UIGestureRecognizer *recognizer in _controller.view.gestureRecognizers) {
+    if (![recognizer isKindOfClass:UITapGestureRecognizer.class]) {
+      continue;
+    }
+    UITapGestureRecognizer *tapRecognizer = (UITapGestureRecognizer *)recognizer;
+    if ([tapRecognizer.allowedPressTypes containsObject:@(UIPressTypeMenu)]) {
+      return tapRecognizer;
+    }
+  }
+  return nil;
 }
 
+- (void)syncTVMenuKeyHandling
+{
+  UITapGestureRecognizer *menuBackGesture = [self uiKitMenuBackGestureRecognizer];
+  if (menuBackGesture == nil) {
+    return;
+  }
+  menuBackGesture.enabled = ![self shouldDisableUIKitMenuBackGesture];
+}
+
+#endif // TARGET_OS_TV
+
 - (void)maybeAddToParentAndUpdateContainer
 {
   BOOL wasScreenMounted = _controller.parentViewController != nil;
@@ -997,6 +1165,15 @@ RNS_IGNORE_SUPER_CALL_END
 }
 #endif
 
+#if TARGET_OS_TV
+- (void)navigationController:(UINavigationController *)navigationController
+       didShowViewController:(UIViewController *)viewController
+                    animated:(BOOL)animated
+{
+  [self syncTVMenuKeyHandling];
+}
+#endif // TARGET_OS_TV
+
 - (void)markChildUpdated
 {
   // In native stack this should be called only for `preload` purposes.
@@ -1279,6 +1456,13 @@ RNS_IGNORE_SUPER_CALL_END
     _controller.view.backgroundColor = _nativeContainerBackgroundColor;
   }
 
+#if TARGET_OS_TV
+  if (newScreenProps.disableDefaultMenuAction != oldScreenProps.disableDefaultMenuAction) {
+    _disableDefaultMenuAction = newScreenProps.disableDefaultMenuAction;
+    [self syncTVMenuKeyHandling];
+  }
+#endif // TARGET_OS_TV
+
   [super updateProps:props oldProps:oldProps];
 }
 
@@ -1375,6 +1559,9 @@ RNS_IGNORE_SUPER_CALL_END
 - (void)prepareForRecycle
 {
   [super prepareForRecycle];
+#if TARGET_OS_TV
+  [self unregisterForTVMenuKeyNotificationsIfNeeded];
+#endif // TARGET_OS_TV
   _reactSubviews = [NSMutableArray new];
 
   for (UIViewController *controller in _presentedModals) {