react-native-screens 5.0.0-alpha.2 → 5.0.0-alpha.3

package/ios/stack/header/RNSStackHeaderAppearanceMapper.mm

@@ -0,0 +1,88 @@
+#import "RNSStackHeaderAppearanceMapper.h"
+#import "RNSDefines.h"
+
+#import <React/RCTConvert.h>
+#import <React/RCTFont.h>
+
+@implementation RNSStackHeaderAppearanceMapper
+
++ (nullable UINavigationBarAppearance *)appearanceFromDictionary:(nullable NSDictionary *)appearanceDict
+{
+  if (appearanceDict.count == 0) {
+    return nil;
+  }
+
+  UINavigationBarAppearance *appearance = [UINavigationBarAppearance new];
+  [self applyTextAttributesFromDictionary:appearanceDict toAppearance:appearance];
+  return appearance;
+}
+
++ (nullable UINavigationBarAppearance *)scrollEdgeAppearanceFromDictionary:(nullable NSDictionary *)appearanceDict
+{
+  if (appearanceDict.count == 0) {
+    return nil;
+  }
+
+  UINavigationBarAppearance *appearance = [UINavigationBarAppearance new];
+
+  // A nil navigationItem.scrollEdgeAppearance natively resolves to the item's (or bar's)
+  // standard appearance with a transparent background. Start the explicit scroll edge
+  // appearance from the same transparent base so that a text-only appearance prop does
+  // not suddenly bring back the default bar background at the scroll edge.
+  [appearance configureWithTransparentBackground];
+
+  [self applyTextAttributesFromDictionary:appearanceDict toAppearance:appearance];
+  return appearance;
+}
+
++ (void)applyTextAttributesFromDictionary:(nullable NSDictionary *)appearanceDict
+                             toAppearance:(nonnull UINavigationBarAppearance *)appearance
+{
+  appearance.titleTextAttributes = [self textAttributes:appearance.titleTextAttributes
+                                  updatedWithDictionary:appearanceDict
+                                              keyPrefix:@"title"];
+  appearance.largeTitleTextAttributes = [self textAttributes:appearance.largeTitleTextAttributes
+                                       updatedWithDictionary:appearanceDict
+                                                   keyPrefix:@"largeTitle"];
+
+#if RNS_IPHONE_OS_VERSION_AVAILABLE(26_0)
+  if (@available(iOS 26.0, *)) {
+    // UIKit derives both the regular and the large subtitle appearance from
+    // subtitleTextAttributes; largeSubtitleTextAttributes is ignored.
+    appearance.subtitleTextAttributes = [self textAttributes:appearance.subtitleTextAttributes
+                                       updatedWithDictionary:appearanceDict
+                                                   keyPrefix:@"subtitle"];
+  }
+#endif // RNS_IPHONE_OS_VERSION_AVAILABLE(26_0)
+}
+
++ (nonnull NSDictionary *)textAttributes:(nullable NSDictionary *)baseAttributes
+                   updatedWithDictionary:(nullable NSDictionary *)appearanceDict
+                               keyPrefix:(nonnull NSString *)keyPrefix
+{
+  id fontFamily = appearanceDict[[keyPrefix stringByAppendingString:@"FontFamily"]];
+  id fontSize = appearanceDict[[keyPrefix stringByAppendingString:@"FontSize"]];
+  id fontWeight = appearanceDict[[keyPrefix stringByAppendingString:@"FontWeight"]];
+  id fontStyle = appearanceDict[[keyPrefix stringByAppendingString:@"FontStyle"]];
+  id fontColor = appearanceDict[[keyPrefix stringByAppendingString:@"FontColor"]];
+
+  NSMutableDictionary *textAttributes = [baseAttributes mutableCopy] ?: [NSMutableDictionary new];
+
+  if (fontFamily != nil || fontSize != nil || fontWeight != nil || fontStyle != nil) {
+    textAttributes[NSFontAttributeName] = [RCTFont updateFont:baseAttributes[NSFontAttributeName]
+                                                   withFamily:fontFamily
+                                                         size:fontSize
+                                                       weight:fontWeight
+                                                        style:fontStyle
+                                                      variant:nil
+                                              scaleMultiplier:1.0];
+  }
+
+  if (fontColor != nil) {
+    textAttributes[NSForegroundColorAttributeName] = [RCTConvert UIColor:fontColor];
+  }
+
+  return textAttributes;
+}
+
+@end

package/ios/stack/header/RNSStackHeaderConfigComponentView.h

@@ -5,6 +5,7 @@
 #import "RNSStackHeaderConfigDataProviding.h"
 #import "RNSStackHeaderEventsDelegate.h"
 #import "RNSStackHeaderItemInvalidationDelegate.h"
+#import "RNSStackScreenHeaderCoordinator.h"
 #import "RNSViewFrameChangeDelegate.h"
 
 NS_ASSUME_NONNULL_BEGIN
@@ -21,9 +22,17 @@ NS_ASSUME_NONNULL_BEGIN
 @property (nonatomic, readonly, nullable) NSString *largeTitle;
 @property (nonatomic, readonly, nullable) NSString *largeSubtitle;
 @property (nonatomic, readonly) BOOL largeTitleEnabled;
+@property (nonatomic, readonly, nullable) NSString *prompt;
+@property (nonatomic, readonly, nullable) NSString *backButtonTitle;
+@property (nonatomic, readonly) UINavigationItemBackButtonDisplayMode backButtonDisplayMode;
+@property (nonatomic, readonly) BOOL backButtonMenuEnabled;
 @property (nonatomic, readonly, nullable) RNSStackHeaderMenuData *titleMenu;
+@property (nonatomic, readonly, nullable) UINavigationBarAppearance *standardAppearance;
+@property (nonatomic, readonly, nullable) UINavigationBarAppearance *scrollEdgeAppearance;
 @property (nonatomic, readonly) NSArray<id> *children;
 
+@property (nonatomic, weak, nullable) RNSStackScreenHeaderCoordinator *headerCoordinator;
+
 - (void)resetProps;
 
 @end
@@ -34,7 +43,7 @@ NS_ASSUME_NONNULL_END
 
 #if defined(__cplusplus)
 
-#import <rnscreens/RNSStackHeaderConfigComponentDescriptor.h>
+#import <react/renderer/components/rnscreens/RNSStackHeaderConfigComponentDescriptor.h>
 
 @interface RNSStackHeaderConfigComponentView ()
 

package/ios/stack/header/RNSStackHeaderConfigComponentView.mm

@@ -1,6 +1,8 @@
 #import "RNSStackHeaderConfigComponentView.h"
 #import "RNSConversions.h"
+#import "RNSConversions-Stack.h"
 #import "RNSImageLoadingHelper.h"
+#import "RNSStackHeaderAppearanceMapper.h"
 #import "RNSStackHeaderConfigEventEmitter.h"
 #import "RNSStackHeaderConfigShadowStateProxy.h"
 #import "RNSStackHeaderItemComponentView.h"
@@ -12,7 +14,6 @@
 #import "RNSStackNavigationController.h"
 #import "RNSStackScreenComponentView.h"
 #import "RNSStackScreenController.h"
-#import "RNSStackScreenHeaderCoordinator.h"
 
 #import <React/RCTConversions.h>
 #import <React/RCTConvert.h>
@@ -21,7 +22,7 @@
 #import <react/renderer/components/rnscreens/Props.h>
 #import <react/renderer/components/rnscreens/RCTComponentViewHelpers.h>
 #import <react/utils/ManagedObjectWrapper.h>
-#import <rnscreens/RNSStackHeaderConfigComponentDescriptor.h>
+#import <react/renderer/components/rnscreens/RNSStackHeaderConfigComponentDescriptor.h>
 
 namespace react = facebook::react;
 
@@ -67,7 +68,13 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
   _largeTitle = nil;
   _largeSubtitle = nil;
   _largeTitleEnabled = NO;
+  _prompt = nil;
+  _backButtonTitle = nil;
+  _backButtonDisplayMode = UINavigationItemBackButtonDisplayModeDefault;
+  _backButtonMenuEnabled = YES;
   _titleMenu = nil;
+  _standardAppearance = nil;
+  _scrollEdgeAppearance = nil;
 }
 
 - (NSArray<id> *)children
@@ -123,18 +130,7 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
 {
   if (self.window != nil) {
     [[self requireNavigationController] setNavigationBarFrameChangeDelegate:self];
-    RNSStackScreenHeaderCoordinator *coordinator = [self headerCoordinator];
-    coordinator.configDataProvider = self;
-    coordinator.frameChangeDelegate = self;
-    coordinator.eventsDelegate = self;
-    coordinator.imageLoader = self;
-    [coordinator rebuild];
-  } else {
-    RNSStackScreenHeaderCoordinator *coordinator = [self headerCoordinator];
-    coordinator.configDataProvider = nil;
-    coordinator.frameChangeDelegate = nil;
-    coordinator.eventsDelegate = nil;
-    coordinator.imageLoader = nil;
+    [self.headerCoordinator rebuild];
   }
   [super didMoveToWindow];
 }
@@ -155,7 +151,7 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
     ((RNSStackHeaderItemSpacerComponentView *)childComponentView).invalidationDelegate = self;
   }
 
-  [[self headerCoordinator] rebuild];
+  [self.headerCoordinator rebuild];
 }
 
 - (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index
@@ -169,7 +165,7 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
   }
 
   [_children removeObjectAtIndex:index];
-  [[self headerCoordinator] rebuild];
+  [self.headerCoordinator rebuild];
 }
 
 #pragma mark - RNSStackHeaderItemInvalidationDelegate
@@ -178,22 +174,21 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
 {
   if (itemId == nil) {
     RCTLogWarn(@"[RNScreens] headerItemDidInvalidateWithId called with nil id, will run full header rebuild");
-    [[self headerCoordinator] rebuild];
+    [self.headerCoordinator rebuild];
     return;
   }
-  [[self headerCoordinator] rebuildItemWithId:itemId];
+  [self.headerCoordinator rebuildItemWithId:itemId];
 }
 
 - (void)headerItemMenuDidChangeWithId:(NSString *)itemId
 {
   if (itemId == nil) {
     RCTLogWarn(@"[RNScreens] headerItemMenuDidChangeWithId called with nil id, will run full header rebuild");
-    [[self headerCoordinator] rebuild];
+    [self.headerCoordinator rebuild];
     return;
   }
-  RNSStackScreenHeaderCoordinator *coordinator = [self headerCoordinator];
-  [coordinator resetTrackerForItemWithId:itemId];
-  [coordinator reapplyMenuForItemWithId:itemId];
+  [self.headerCoordinator resetTrackerForItemWithId:itemId];
+  [self.headerCoordinator reapplyMenuForItemWithId:itemId];
 }
 
 /**
@@ -204,15 +199,15 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
   if (itemId == nil) {
     RCTLogWarn(
         @"[RNScreens] headerItemMenuDidUpdateFromCommandWithId called with nil id, will run full header rebuild");
-    [[self headerCoordinator] rebuild];
+    [self.headerCoordinator rebuild];
     return;
   }
-  [[self headerCoordinator] reapplyMenuForItemWithId:itemId];
+  [self.headerCoordinator reapplyMenuForItemWithId:itemId];
 }
 
 - (void)headerItemSpacerDidInvalidate
 {
-  [[self headerCoordinator] rebuild];
+  [self.headerCoordinator rebuild];
 }
 
 #pragma mark - RNSStackHeaderEventsDelegate
@@ -295,11 +290,11 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
         (oldItemData.itemType == RNSMenuItemTypeAutomatic &&
          [RNSStackHeaderMenuFinder singleSelectionRootForElementWithId:menuItemId inMenu:locator.rootMenu] != nil);
     if (isToggle) {
-      [[self headerCoordinator] setToggleState:updateOptions.toggleState
-                              forMenuElementId:menuItemId
-                                 trackerItemId:locator.trackerItemId
-                                      rootMenu:locator.rootMenu
-                                    parentMenu:locator.searchResult.parentMenu];
+      [self.headerCoordinator setToggleState:updateOptions.toggleState
+                            forMenuElementId:menuItemId
+                               trackerItemId:locator.trackerItemId
+                                    rootMenu:locator.rootMenu
+                                  parentMenu:locator.searchResult.parentMenu];
     }
   }
 
@@ -318,7 +313,7 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
                                     replacingChildWithId:menuItemId
                                              withElement:newItemData];
       }
-      [[self headerCoordinator] reapplyTitleMenu];
+      [self.headerCoordinator reapplyTitleMenu];
       break;
     case RNSMenuElementPositionOverflow:
       // TODO: handle overflow menu
@@ -366,7 +361,7 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
                                     replacingChildWithId:menuElementId
                                              withElement:newMenuItem];
       }
-      [[self headerCoordinator] reapplyTitleMenu];
+      [self.headerCoordinator reapplyTitleMenu];
       break;
     case RNSMenuElementPositionOverflow:
       // TODO: handle overflow menu
@@ -444,6 +439,34 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
     _largeTitleEnabled = newHeaderProps.largeTitleEnabled;
   }
 
+  if (oldHeaderProps.prompt != newHeaderProps.prompt) {
+    _prompt = RCTNSStringFromStringNilIfEmpty(newHeaderProps.prompt);
+  }
+
+  if (oldHeaderProps.backButtonTitle != newHeaderProps.backButtonTitle) {
+    _backButtonTitle = RCTNSStringFromStringNilIfEmpty(newHeaderProps.backButtonTitle);
+  }
+
+  if (oldHeaderProps.backButtonDisplayMode != newHeaderProps.backButtonDisplayMode) {
+    _backButtonDisplayMode =
+        rnscreens::conversion::UINavigationItemBackButtonDisplayModeFromReactRNSStackHeaderConfigIOSBackButtonDisplayMode(
+            newHeaderProps.backButtonDisplayMode);
+  }
+
+  if (oldHeaderProps.backButtonMenuEnabled != newHeaderProps.backButtonMenuEnabled) {
+    _backButtonMenuEnabled = newHeaderProps.backButtonMenuEnabled;
+  }
+
+  if (oldHeaderProps.standardAppearance != newHeaderProps.standardAppearance) {
+    _standardAppearance = [RNSStackHeaderAppearanceMapper
+        appearanceFromDictionary:[self dictionaryFromAppearanceProp:newHeaderProps.standardAppearance]];
+  }
+
+  if (oldHeaderProps.scrollEdgeAppearance != newHeaderProps.scrollEdgeAppearance) {
+    _scrollEdgeAppearance = [RNSStackHeaderAppearanceMapper
+        scrollEdgeAppearanceFromDictionary:[self dictionaryFromAppearanceProp:newHeaderProps.scrollEdgeAppearance]];
+  }
+
   if (oldHeaderProps.titleMenu != newHeaderProps.titleMenu) {
     _titleMenu = [RNSStackHeaderMenuMapper
         menuFromDictionary:rnscreens::conversion::RNSConvertFollyDynamicToId(newHeaderProps.titleMenu)];
@@ -452,14 +475,14 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
 
   [super updateProps:props oldProps:oldProps];
 
-  [[self headerCoordinator] applyConfigProperties];
+  [self.headerCoordinator applyConfigProperties];
 
   if (titleMenuDidChange) {
     // title menu is a prop on the navigation item, not on one of the bar button items
     // thus it is not configured with matching RNSStackHeaderItemComponentView
     // but here directly
-    [[self headerCoordinator] resetTitleMenuTracker];
-    [[self headerCoordinator] reapplyTitleMenu];
+    [self.headerCoordinator resetTitleMenuTracker];
+    [self.headerCoordinator reapplyTitleMenu];
   }
 }
 
@@ -482,6 +505,15 @@ static void RNSAssertIsValidHeaderChild(UIView *child)
 
 #pragma mark - Private
 
+- (nullable NSDictionary *)dictionaryFromAppearanceProp:(const folly::dynamic &)appearanceProp
+{
+  if (appearanceProp.type() != folly::dynamic::OBJECT) {
+    return nil;
+  }
+
+  return rnscreens::conversion::RNSConvertFollyDynamicToId(appearanceProp);
+}
+
 - (nullable RNSStackScreenHeaderCoordinator *)headerCoordinator
 {
   if (self.superview == nil) {

package/ios/stack/header/RNSStackHeaderConfigDataProviding.h

@@ -14,7 +14,13 @@ NS_ASSUME_NONNULL_BEGIN
 @property (nonatomic, readonly, nullable) NSString *largeTitle;
 @property (nonatomic, readonly, nullable) NSString *largeSubtitle;
 @property (nonatomic, readonly) BOOL largeTitleEnabled;
+@property (nonatomic, readonly, nullable) NSString *prompt;
+@property (nonatomic, readonly, nullable) NSString *backButtonTitle;
+@property (nonatomic, readonly) UINavigationItemBackButtonDisplayMode backButtonDisplayMode;
+@property (nonatomic, readonly) BOOL backButtonMenuEnabled;
 @property (nonatomic, readonly, nullable) RNSStackHeaderMenuData *titleMenu;
+@property (nonatomic, readonly, nullable) UINavigationBarAppearance *standardAppearance;
+@property (nonatomic, readonly, nullable) UINavigationBarAppearance *scrollEdgeAppearance;
 
 /**
  Children are expected to conform to either RNSStackHeaderItemDataProviding

package/ios/stack/header/RNSStackHeaderConfigShadowStateProxy.mm

@@ -2,7 +2,7 @@
 #import "RNSStackHeaderConfigComponentView.h"
 
 #import <React/RCTConversions.h>
-#import <rnscreens/RNSStackHeaderConfigComponentDescriptor.h>
+#import <react/renderer/components/rnscreens/RNSStackHeaderConfigComponentDescriptor.h>
 
 namespace react = facebook::react;
 

package/ios/stack/header/RNSStackHeaderIconResolver.mm

@@ -1,4 +1,5 @@
 #import "RNSStackHeaderIconResolver.h"
+#import <React/RCTLog.h>
 
 @implementation RNSStackHeaderIconResolver
 
@@ -18,11 +19,17 @@
   switch (iconData.iconType) {
     case RNSStackHeaderIconTypeSfSymbol: {
       UIImage *image = [UIImage systemImageNamed:iconData.resourceName];
+      if (image == nil && iconData.resourceName != nil) {
+        RCTLogWarn(@"[RNScreens] Failed to load SF Symbol \"%@\" for header icon", iconData.resourceName);
+      }
       iconData.resolvedImage = image;
       return image;
     }
     case RNSStackHeaderIconTypeXcasset: {
       UIImage *image = [UIImage imageNamed:iconData.resourceName];
+      if (image == nil && iconData.resourceName != nil) {
+        RCTLogWarn(@"[RNScreens] Failed to load xcasset \"%@\" for header icon", iconData.resourceName);
+      }
       iconData.resolvedImage = image;
       return image;
     }

package/ios/stack/header/RNSStackHeaderItemComponentView.h

@@ -12,11 +12,13 @@ NS_ASSUME_NONNULL_BEGIN
 
 @property (nonatomic, readonly) RNSHeaderItemPlacement placement;
 @property (nonatomic, readonly, nullable) NSString *itemId;
+@property (nonatomic, readonly, nullable) NSString *identifier;
 @property (nonatomic, readonly, nullable) NSString *title;
 @property (nonatomic, readonly, nullable) RNSStackHeaderIconData *icon;
 @property (nonatomic, readonly, nullable) RNSStackHeaderMenuData *menu;
 @property (nonatomic, readonly, nullable) UIView *customView;
 @property (nonatomic, readonly) BOOL respondsToOnPress;
+@property (nonatomic, readonly) BOOL hidesSharedBackground;
 
 @property (nonatomic, nullable) NSString *titleProp;
 @property (nonatomic, nullable) RNSStackHeaderIconData *iconProp;
@@ -42,7 +44,7 @@ NS_ASSUME_NONNULL_END
 
 #if defined(__cplusplus)
 
-#import <rnscreens/RNSStackHeaderItemComponentDescriptor.h>
+#import <react/renderer/components/rnscreens/RNSStackHeaderItemComponentDescriptor.h>
 
 @interface RNSStackHeaderItemComponentView ()
 

package/ios/stack/header/RNSStackHeaderItemComponentView.mm

@@ -13,7 +13,7 @@
 #import <React/RCTLog.h>
 #import <react/renderer/components/rnscreens/Props.h>
 #import <react/renderer/components/rnscreens/RCTComponentViewHelpers.h>
-#import <rnscreens/RNSStackHeaderItemComponentDescriptor.h>
+#import <react/renderer/components/rnscreens/RNSStackHeaderItemComponentDescriptor.h>
 
 namespace react = facebook::react;
 
@@ -45,12 +45,14 @@ namespace react = facebook::react;
 - (void)resetProps
 {
   _itemId = nil;
+  _identifier = nil;
   [self setTitleProp:nil];
   [self setIconProp:nil];
   [self setMenuProp:nil];
   _placement = RNSHeaderItemPlacementTrailing;
   _didSetHeaderItemPlacement = NO;
   _respondsToOnPress = NO;
+  _hidesSharedBackground = NO;
 }
 
 - (void)setTitleProp:(NSString *)titleProp
@@ -183,11 +185,17 @@ RNS_IGNORE_SUPER_CALL_END
     _itemId = RCTNSStringFromStringNilIfEmpty(newItemProps.itemId);
   }
 
+  if (oldItemProps.identifier != newItemProps.identifier) {
+    _identifier = RCTNSStringFromStringNilIfEmpty(newItemProps.identifier);
+    needsUpdate = YES;
+  }
+
   if (oldItemProps.placement != newItemProps.placement) {
     if (_didSetHeaderItemPlacement) {
       RCTLogWarn(@"[RNScreens] Changing header item placement at runtime is not supported");
     } else {
-      _placement = rnscreens::conversion::convert<RNSHeaderItemPlacement>(newItemProps.placement);
+      _placement =
+          rnscreens::conversion::RNSHeaderItemPlacementFromReactRNSStackHeaderItemIOSPlacement(newItemProps.placement);
     }
   }
   _didSetHeaderItemPlacement = YES;
@@ -214,6 +222,11 @@ RNS_IGNORE_SUPER_CALL_END
     needsUpdate = YES;
   }
 
+  if (oldItemProps.hidesSharedBackground != newItemProps.hidesSharedBackground) {
+    _hidesSharedBackground = newItemProps.hidesSharedBackground;
+    needsUpdate = YES;
+  }
+
   [super updateProps:props oldProps:oldProps];
 
   if (needsUpdate) {

package/ios/stack/header/RNSStackHeaderItemDataProviding.h

@@ -12,11 +12,13 @@ NS_ASSUME_NONNULL_BEGIN
 
 @property (nonatomic, readonly) RNSHeaderItemPlacement placement;
 @property (nonatomic, readonly, nullable) NSString *itemId;
+@property (nonatomic, readonly, nullable) NSString *identifier;
 @property (nonatomic, readonly, nullable) NSString *title;
 @property (nonatomic, readonly, nullable) RNSStackHeaderIconData *icon;
 @property (nonatomic, readonly, nullable) RNSStackHeaderMenuData *menu;
 @property (nonatomic, readonly, nullable) UIView *customView;
 @property (nonatomic, readonly) BOOL respondsToOnPress;
+@property (nonatomic, readonly) BOOL hidesSharedBackground;
 
 @end
 

package/ios/stack/header/RNSStackHeaderItemShadowStateProxy.mm

@@ -2,7 +2,7 @@
 #import "RNSStackHeaderItemComponentView.h"
 
 #import <React/RCTConversions.h>
-#import <rnscreens/RNSStackHeaderItemComponentDescriptor.h>
+#import <react/renderer/components/rnscreens/RNSStackHeaderItemComponentDescriptor.h>
 
 namespace react = facebook::react;
 

package/ios/stack/header/RNSStackHeaderItemSpacerComponentView.mm

@@ -43,7 +43,8 @@ namespace react = facebook::react;
     if (_didSetHeaderItemSpacerPlacement) {
       RCTLogWarn(@"[RNScreens] Changing header item spacer placement at runtime is not supported");
     } else {
-      _placement = rnscreens::conversion::convert<RNSHeaderItemSpacerPlacement>(newSpacerProps.placement);
+      _placement = rnscreens::conversion::RNSHeaderItemSpacerPlacementFromReactRNSStackHeaderItemSpacerIOSPlacement(
+          newSpacerProps.placement);
     }
   }
   _didSetHeaderItemSpacerPlacement = YES;

package/ios/stack/header/RNSStackHeaderMenuMapper.mm

@@ -88,18 +88,22 @@ static NSSet<NSString *> *const kRNSAllowedMenuItemKeys = [NSSet
 
 + (void)validateMenuKeys:(NSDictionary *)dict
 {
+#ifndef NS_BLOCK_ASSERTIONS
   for (NSString *key in dict) {
     RCTAssert([kRNSAllowedMenuKeys containsObject:key], @"[RNScreens] Invalid key \"%@\" found in menu", key);
   }
+#endif // !NS_BLOCK_ASSERTIONS
   RCTAssert(dict[@"children"], @"[RNScreens] missing key \"children\" in menu");
   RCTAssert(dict[@"id"], @"[RNScreens] missing id on one of menu elements");
 }
 
 + (void)validateMenuItemKeys:(NSDictionary *)dict
 {
+#ifndef NS_BLOCK_ASSERTIONS
   for (NSString *key in dict) {
     RCTAssert([kRNSAllowedMenuItemKeys containsObject:key], @"[RNScreens] Invalid key \"%@\" found in menu item", key);
   }
+#endif // !NS_BLOCK_ASSERTIONS
   RCTAssert(dict[@"id"], @"[RNScreens] missing id on one of menu elements");
 }
 

package/ios/stack/host/RNSStackNavigationBar.h

@@ -0,0 +1,25 @@
+#pragma once
+
+#import <UIKit/UIKit.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+/**
+ * Navigation bar subclass used by RNSStackNavigationController.
+ *
+ * Its responsibility is to suppress the back button's navigation history
+ * menu (long press and pointer secondary click).
+ */
+@interface RNSStackNavigationBar : UINavigationBar
+
+#if !TARGET_OS_TV
+/**
+ * When NO, the back button's navigation history menu (long press and pointer
+ * secondary click) is suppressed. Tapping the back button is unaffected.
+ */
+@property (nonatomic) BOOL backButtonMenuEnabled;
+#endif // !TARGET_OS_TV
+
+@end
+
+NS_ASSUME_NONNULL_END

package/ios/stack/host/RNSStackNavigationBar.mm

@@ -0,0 +1,80 @@
+#import "RNSStackNavigationBar.h"
+#import "UINavigationBar+RNSUtility.h"
+
+static void *const RNSBackButtonMenuEnabledKVOContext = (void *)&RNSBackButtonMenuEnabledKVOContext;
+
+@implementation RNSStackNavigationBar
+#if !TARGET_OS_TV
+{
+  UIControl *_Nullable _observedBackButtonWrapper;
+}
+
+- (instancetype)initWithFrame:(CGRect)frame
+{
+  if (self = [super initWithFrame:frame]) {
+    _backButtonMenuEnabled = YES;
+  }
+  return self;
+}
+
+- (void)setBackButtonMenuEnabled:(BOOL)backButtonMenuEnabled
+{
+  _backButtonMenuEnabled = backButtonMenuEnabled;
+  [self enforceBackButtonMenuState];
+}
+
+- (void)layoutSubviews
+{
+  [super layoutSubviews];
+  // The back button wrapper may have been replaced by this layout pass
+  [self enforceBackButtonMenuState];
+}
+
+- (void)enforceBackButtonMenuState
+{
+  UIView *wrapperView = [self rnscreens_findBackButtonWrapperView];
+  if (wrapperView != _observedBackButtonWrapper) {
+    [_observedBackButtonWrapper removeObserver:self
+                                    forKeyPath:@"contextMenuInteractionEnabled"
+                                       context:RNSBackButtonMenuEnabledKVOContext];
+    _observedBackButtonWrapper = nil;
+
+    if ([wrapperView isKindOfClass:UIControl.class]) {
+      _observedBackButtonWrapper = (UIControl *)wrapperView;
+      [_observedBackButtonWrapper addObserver:self
+                                   forKeyPath:@"contextMenuInteractionEnabled"
+                                      options:NSKeyValueObservingOptionNew
+                                      context:RNSBackButtonMenuEnabledKVOContext];
+    }
+  }
+
+  _observedBackButtonWrapper.contextMenuInteractionEnabled = _backButtonMenuEnabled;
+}
+
+- (void)observeValueForKeyPath:(NSString *)keyPath
+                      ofObject:(id)object
+                        change:(NSDictionary<NSKeyValueChangeKey, id> *)change
+                       context:(void *)context
+{
+  if (context != RNSBackButtonMenuEnabledKVOContext) {
+    [super observeValueForKeyPath:keyPath ofObject:object change:change context:context];
+    return;
+  }
+
+  // UIKit re-asserts the interaction on every back button reconfigure
+  // - flip it back off immediately.
+  if (!_backButtonMenuEnabled && [change[NSKeyValueChangeNewKey] boolValue] && object == _observedBackButtonWrapper) {
+    _observedBackButtonWrapper.contextMenuInteractionEnabled = NO;
+  }
+}
+
+- (void)dealloc
+{
+  [_observedBackButtonWrapper removeObserver:self
+                                  forKeyPath:@"contextMenuInteractionEnabled"
+                                     context:RNSBackButtonMenuEnabledKVOContext];
+}
+
+#endif // !TARGET_OS_TV
+
+@end

package/ios/stack/host/RNSStackNavigationBarCoordinator.h

@@ -10,6 +10,14 @@ NS_ASSUME_NONNULL_BEGIN
     forNavigationController:(UINavigationController *)navigationController
                    animated:(BOOL)animated;
 
+#if !TARGET_OS_TV
+/**
+ * Enables or disables the back button's long-press navigation history menu.
+ * Takes effect only when the navigation bar is an RNSStackNavigationBar.
+ */
+- (void)setBackButtonMenuEnabled:(BOOL)enabled forNavigationController:(UINavigationController *)navigationController;
+#endif // !TARGET_OS_TV
+
 - (void)initializeNavigationBarOfNavigationController:(UINavigationController *)navigationController;
 
 @end