react-native-screens 3.13.1 → 3.14.0

package/ios/RNSScreenStackHeaderSubview.mm

@@ -0,0 +1,137 @@
+#import "RNSScreenStackHeaderSubview.h"
+#import "RNSConvert.h"
+
+#ifdef RN_FABRIC_ENABLED
+#import <react/renderer/components/rnscreens/ComponentDescriptors.h>
+#import <react/renderer/components/rnscreens/EventEmitters.h>
+#import <react/renderer/components/rnscreens/RCTComponentViewHelpers.h>
+
+#import <React/RCTConversions.h>
+#import "RCTFabricComponentsPlugins.h"
+#endif
+
+@implementation RNSScreenStackHeaderSubview
+
+#pragma mark - Common
+
+#ifdef RN_FABRIC_ENABLED
+
+#pragma mark - Fabric specific
+
+- (instancetype)initWithFrame:(CGRect)frame
+{
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const facebook::react::RNSScreenStackHeaderSubviewProps>();
+    _props = defaultProps;
+  }
+
+  return self;
+}
+
+#pragma mark - RCTComponentViewProtocol
+
+- (void)prepareForRecycle
+{
+  [super prepareForRecycle];
+}
+
+- (void)updateProps:(facebook::react::Props::Shared const &)props
+           oldProps:(facebook::react::Props::Shared const &)oldProps
+{
+  const auto &newHeaderSubviewProps =
+      *std::static_pointer_cast<const facebook::react::RNSScreenStackHeaderSubviewProps>(props);
+  const auto &oldHeaderSubviewProps =
+      *std::static_pointer_cast<const facebook::react::RNSScreenStackHeaderSubviewProps>(_props);
+
+  if (newHeaderSubviewProps.type != oldHeaderSubviewProps.type) {
+    _type = [RNSConvert RNSScreenStackHeaderSubviewTypeFromCppEquivalent:newHeaderSubviewProps.type];
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
++ (facebook::react::ComponentDescriptorProvider)componentDescriptorProvider
+{
+  return facebook::react::concreteComponentDescriptorProvider<
+      facebook::react::RNSScreenStackHeaderSubviewComponentDescriptor>();
+}
+
+- (void)updateLayoutMetrics:(const facebook::react::LayoutMetrics &)layoutMetrics
+           oldLayoutMetrics:(const facebook::react::LayoutMetrics &)oldLayoutMetrics
+{
+  CGRect frame = RCTCGRectFromRect(layoutMetrics.frame);
+  // CALayer will crash if we pass NaN or Inf values.
+  // It's unclear how to detect this case on cross-platform manner holistically, so we have to do it on the mounting
+  // layer as well. NaN/Inf is a kinda valid result of some math operations. Even if we can (and should) detect (and
+  // report early) incorrect (NaN and Inf) values which come from JavaScript side, we sometimes cannot backtrace the
+  // sources of a calculation that produced an incorrect/useless result.
+  if (!std::isfinite(frame.size.width) || !std::isfinite(frame.size.height)) {
+    RCTLogWarn(
+        @"-[UIView(ComponentViewProtocol) updateLayoutMetrics:oldLayoutMetrics:]: Received invalid layout metrics (%@) for a view (%@).",
+        NSStringFromCGRect(frame),
+        self);
+  } else {
+    self.bounds = CGRect{CGPointZero, frame.size};
+  }
+}
+
+#else
+#pragma mark - Paper specific
+
+- (instancetype)initWithBridge:(RCTBridge *)bridge
+{
+  if (self = [super init]) {
+    _bridge = bridge;
+  }
+  return self;
+}
+
+- (void)reactSetFrame:(CGRect)frame
+{
+  // Block any attempt to set coordinates on RNSScreenStackHeaderSubview. This
+  // makes UINavigationBar the only one to control the position of header content.
+  [super reactSetFrame:CGRectMake(0, 0, frame.size.width, frame.size.height)];
+}
+
+#endif // RN_FABRIC_ENABLED
+@end
+
+@implementation RNSScreenStackHeaderSubviewManager
+
+RCT_EXPORT_MODULE()
+
+RCT_EXPORT_VIEW_PROPERTY(type, RNSScreenStackHeaderSubviewType)
+
+#ifdef RN_FABRIC_ENABLED
+#else
+- (UIView *)view
+{
+  return [[RNSScreenStackHeaderSubview alloc] initWithBridge:self.bridge];
+}
+#endif
+
+@end
+
+#ifdef RN_FABRIC_ENABLED
+Class<RCTComponentViewProtocol> RNSScreenStackHeaderSubviewCls(void)
+{
+  return RNSScreenStackHeaderSubview.class;
+}
+#endif
+
+@implementation RCTConvert (RNSScreenStackHeaderSubview)
+
+RCT_ENUM_CONVERTER(
+    RNSScreenStackHeaderSubviewType,
+    (@{
+      @"back" : @(RNSScreenStackHeaderSubviewTypeBackButton),
+      @"left" : @(RNSScreenStackHeaderSubviewTypeLeft),
+      @"right" : @(RNSScreenStackHeaderSubviewTypeRight),
+      @"title" : @(RNSScreenStackHeaderSubviewTypeTitle),
+      @"center" : @(RNSScreenStackHeaderSubviewTypeCenter),
+      @"searchBar" : @(RNSScreenStackHeaderSubviewTypeSearchBar),
+    }),
+    RNSScreenStackHeaderSubviewTypeTitle,
+    integerValue)
+
+@end

package/ios/RNSScreenViewEvent.h

@@ -0,0 +1,12 @@
+#import <React/RCTBridge+Private.h>
+#import <React/RCTEventDispatcherProtocol.h>
+
+@interface RNSScreenViewEvent : NSObject <RCTEvent>
+
+- (instancetype)initWithEventName:(NSString *)eventName
+                         reactTag:(NSNumber *)reactTag
+                         progress:(double)progress
+                          closing:(int)closing
+                     goingForward:(int)goingForward;
+
+@end

package/ios/RNSScreenViewEvent.mm

@@ -0,0 +1,59 @@
+#import "RNSScreenViewEvent.h"
+#import <React/RCTAssert.h>
+
+@implementation RNSScreenViewEvent {
+  double _progress;
+  int _closing;
+  int _goingForward;
+}
+
+@synthesize viewTag = _viewTag;
+@synthesize eventName = _eventName;
+
+- (instancetype)initWithEventName:(NSString *)eventName
+                         reactTag:(NSNumber *)reactTag
+                         progress:(double)progress
+                          closing:(int)closing
+                     goingForward:(int)goingForward
+{
+  RCTAssertParam(reactTag);
+
+  if ((self = [super init])) {
+    _eventName = [eventName copy];
+    _viewTag = reactTag;
+    _progress = progress;
+    _closing = closing;
+    _goingForward = goingForward;
+  }
+  return self;
+}
+
+RCT_NOT_IMPLEMENTED(-(instancetype)init)
+
+- (NSDictionary *)body
+{
+  NSDictionary *body = @{
+    @"progress" : @(_progress),
+    @"closing" : @(_closing ? 1 : 0),
+    @"goingForward" : @(_goingForward ? 1 : 0),
+  };
+
+  return body;
+}
+
+- (BOOL)canCoalesce
+{
+  return NO;
+}
+
++ (NSString *)moduleDotMethod
+{
+  return @"RCTEventEmitter.receiveEvent";
+}
+
+- (NSArray *)arguments
+{
+  return @[ self.viewTag, RCTNormalizeInputEventName(self.eventName), [self body] ];
+}
+
+@end

package/ios/{RNSScreenWindowTraits.m → RNSScreenWindowTraits.mm}

@@ -1,5 +1,4 @@
 #import "RNSScreenWindowTraits.h"
-#import "RNSScreen.h"
 #import "RNSScreenContainer.h"
 #import "RNSScreenStack.h"
 
@@ -56,7 +55,9 @@
   } else
 #endif
   {
-    [UIApplication.sharedApplication.keyWindow.rootViewController setNeedsUpdateOfHomeIndicatorAutoHidden];
+    if (@available(iOS 11.0, *)) {
+      [UIApplication.sharedApplication.keyWindow.rootViewController setNeedsUpdateOfHomeIndicatorAutoHidden];
+    }
   }
 #endif
 }

package/ios/RNSSearchBar.h

@@ -1,19 +1,32 @@
 #import <UIKit/UIKit.h>
 
+#ifdef RN_FABRIC_ENABLED
+#import <React/RCTViewComponentView.h>
+#endif
+
 #import <React/RCTBridge.h>
 #import <React/RCTComponent.h>
 #import <React/RCTViewManager.h>
 
-@interface RNSSearchBar : UIView <UISearchBarDelegate>
+@interface RNSSearchBar :
+#ifdef RN_FABRIC_ENABLED
+    RCTViewComponentView <UISearchBarDelegate>
+#else
+    UIView <UISearchBarDelegate>
+#endif
 
 @property (nonatomic) BOOL hideWhenScrolling;
 
 @property (nonatomic, retain) UISearchController *controller;
+
+#ifdef RN_FABRIC_ENABLED
+#else
 @property (nonatomic, copy) RCTBubblingEventBlock onChangeText;
 @property (nonatomic, copy) RCTBubblingEventBlock onCancelButtonPress;
 @property (nonatomic, copy) RCTBubblingEventBlock onSearchButtonPress;
 @property (nonatomic, copy) RCTBubblingEventBlock onFocus;
 @property (nonatomic, copy) RCTBubblingEventBlock onBlur;
+#endif
 
 @end
 

package/ios/RNSSearchBar.mm

@@ -0,0 +1,351 @@
+#import <UIKit/UIKit.h>
+
+#import "RNSSearchBar.h"
+
+#import <React/RCTBridge.h>
+#import <React/RCTComponent.h>
+#import <React/RCTUIManager.h>
+
+#ifdef RN_FABRIC_ENABLED
+#import <React/RCTConversions.h>
+#import <react/renderer/components/rnscreens/ComponentDescriptors.h>
+#import <react/renderer/components/rnscreens/EventEmitters.h>
+#import <react/renderer/components/rnscreens/Props.h>
+#import <react/renderer/components/rnscreens/RCTComponentViewHelpers.h>
+#import "RCTFabricComponentsPlugins.h"
+#import "RNSConvert.h"
+#endif
+
+@implementation RNSSearchBar {
+  __weak RCTBridge *_bridge;
+  UISearchController *_controller;
+  UIColor *_textColor;
+}
+
+@synthesize controller = _controller;
+
+- (instancetype)initWithBridge:(RCTBridge *)bridge
+{
+  if (self = [super init]) {
+    _bridge = bridge;
+    [self initCommonProps];
+  }
+  return self;
+}
+
+#ifdef RN_FABRIC_ENABLED
+- (instancetype)init
+{
+  if (self = [super init]) {
+    static const auto defaultProps = std::make_shared<const facebook::react::RNSSearchBarProps>();
+    _props = defaultProps;
+    [self initCommonProps];
+  }
+  return self;
+}
+#endif
+
+- (void)initCommonProps
+{
+  _controller = [[UISearchController alloc] initWithSearchResultsController:nil];
+  _controller.searchBar.delegate = self;
+  _hideWhenScrolling = YES;
+}
+
+- (void)emitOnFocusEvent
+{
+#ifdef RN_FABRIC_ENABLED
+  if (_eventEmitter != nullptr) {
+    std::dynamic_pointer_cast<const facebook::react::RNSSearchBarEventEmitter>(_eventEmitter)
+        ->onFocus(facebook::react::RNSSearchBarEventEmitter::OnFocus{});
+  }
+#else
+  if (self.onFocus) {
+    self.onFocus(@{});
+  }
+#endif
+}
+
+- (void)emitOnBlurEvent
+{
+#ifdef RN_FABRIC_ENABLED
+  if (_eventEmitter != nullptr) {
+    std::dynamic_pointer_cast<const facebook::react::RNSSearchBarEventEmitter>(_eventEmitter)
+        ->onBlur(facebook::react::RNSSearchBarEventEmitter::OnBlur{});
+  }
+#else
+  if (self.onBlur) {
+    self.onBlur(@{});
+  }
+#endif
+}
+
+- (void)emitOnSearchButtonPressEventWithText:(NSString *)text
+{
+#ifdef RN_FABRIC_ENABLED
+  if (_eventEmitter != nullptr) {
+    std::dynamic_pointer_cast<const facebook::react::RNSSearchBarEventEmitter>(_eventEmitter)
+        ->onSearchButtonPress(
+            facebook::react::RNSSearchBarEventEmitter::OnSearchButtonPress{.text = RCTStringFromNSString(text)});
+  }
+#else
+  if (self.onSearchButtonPress) {
+    self.onSearchButtonPress(@{
+      @"text" : text,
+    });
+  }
+#endif
+}
+
+- (void)emitOnCancelButtonPressEvent
+{
+#ifdef RN_FABRIC_ENABLED
+  if (_eventEmitter != nullptr) {
+    std::dynamic_pointer_cast<const facebook::react::RNSSearchBarEventEmitter>(_eventEmitter)
+        ->onCancelButtonPress(facebook::react::RNSSearchBarEventEmitter::OnCancelButtonPress{});
+  }
+#else
+  if (self.onCancelButtonPress) {
+    self.onCancelButtonPress(@{});
+  }
+#endif
+}
+
+- (void)emitOnChangeTextEventWithText:(NSString *)text
+{
+#ifdef RN_FABRIC_ENABLED
+  if (_eventEmitter != nullptr) {
+    std::dynamic_pointer_cast<const facebook::react::RNSSearchBarEventEmitter>(_eventEmitter)
+        ->onChangeText(facebook::react::RNSSearchBarEventEmitter::OnChangeText{.text = RCTStringFromNSString(text)});
+  }
+#else
+  if (self.onChangeText) {
+    self.onChangeText(@{
+      @"text" : text,
+    });
+  }
+#endif
+}
+
+- (void)setObscureBackground:(BOOL)obscureBackground
+{
+  if (@available(iOS 9.1, *)) {
+    [_controller setObscuresBackgroundDuringPresentation:obscureBackground];
+  }
+}
+
+- (void)setHideNavigationBar:(BOOL)hideNavigationBar
+{
+  [_controller setHidesNavigationBarDuringPresentation:hideNavigationBar];
+}
+
+- (void)setHideWhenScrolling:(BOOL)hideWhenScrolling
+{
+  _hideWhenScrolling = hideWhenScrolling;
+}
+
+- (void)setAutoCapitalize:(UITextAutocapitalizationType)autoCapitalize
+{
+  [_controller.searchBar setAutocapitalizationType:autoCapitalize];
+}
+
+- (void)setPlaceholder:(NSString *)placeholder
+{
+  [_controller.searchBar setPlaceholder:placeholder];
+}
+
+- (void)setBarTintColor:(UIColor *)barTintColor
+{
+#if defined(__IPHONE_OS_VERSION_MAX_ALLOWED) && defined(__IPHONE_13_0) && \
+    __IPHONE_OS_VERSION_MAX_ALLOWED >= __IPHONE_13_0 && !TARGET_OS_TV
+  if (@available(iOS 13.0, *)) {
+    [_controller.searchBar.searchTextField setBackgroundColor:barTintColor];
+  }
+#endif
+}
+
+- (void)setTintColor:(UIColor *)tintColor
+{
+  [_controller.searchBar setTintColor:tintColor];
+}
+
+- (void)setTextColor:(UIColor *)textColor
+{
+#if defined(__IPHONE_OS_VERSION_MAX_ALLOWED) && defined(__IPHONE_13_0) && \
+    __IPHONE_OS_VERSION_MAX_ALLOWED >= __IPHONE_13_0 && !TARGET_OS_TV
+  _textColor = textColor;
+  if (@available(iOS 13.0, *)) {
+    [_controller.searchBar.searchTextField setTextColor:_textColor];
+  }
+#endif
+}
+
+- (void)setCancelButtonText:(NSString *)text
+{
+  [_controller.searchBar setValue:text forKey:@"cancelButtonText"];
+}
+
+- (void)hideCancelButton
+{
+#if !TARGET_OS_TV
+  if (@available(iOS 13, *)) {
+    // On iOS 13+ UISearchController automatically shows/hides cancel button
+    // https://developer.apple.com/documentation/uikit/uisearchcontroller/3152926-automaticallyshowscancelbutton?language=objc
+  } else {
+    [_controller.searchBar setShowsCancelButton:NO animated:YES];
+  }
+#endif
+}
+
+- (void)showCancelButton
+{
+#if !TARGET_OS_TV
+  if (@available(iOS 13, *)) {
+    // On iOS 13+ UISearchController automatically shows/hides cancel button
+    // https://developer.apple.com/documentation/uikit/uisearchcontroller/3152926-automaticallyshowscancelbutton?language=objc
+  } else {
+    [_controller.searchBar setShowsCancelButton:YES animated:YES];
+  }
+#endif
+}
+
+#pragma mark delegate methods
+
+- (void)searchBarTextDidBeginEditing:(UISearchBar *)searchBar
+{
+#if defined(__IPHONE_OS_VERSION_MAX_ALLOWED) && defined(__IPHONE_13_0) && \
+    __IPHONE_OS_VERSION_MAX_ALLOWED >= __IPHONE_13_0 && !TARGET_OS_TV
+  if (@available(iOS 13.0, *)) {
+    // for some reason, the color does not change when set at the beginning,
+    // so we apply it again here
+    if (_textColor != nil) {
+      [_controller.searchBar.searchTextField setTextColor:_textColor];
+    }
+  }
+#endif
+
+  [self showCancelButton];
+  [self becomeFirstResponder];
+  [self emitOnFocusEvent];
+}
+
+- (void)searchBarTextDidEndEditing:(UISearchBar *)searchBar
+{
+  [self emitOnBlurEvent];
+  [self hideCancelButton];
+}
+
+- (void)searchBar:(UISearchBar *)searchBar textDidChange:(NSString *)searchText
+{
+  [self emitOnChangeTextEventWithText:_controller.searchBar.text];
+}
+
+- (void)searchBarSearchButtonClicked:(UISearchBar *)searchBar
+{
+  [self emitOnSearchButtonPressEventWithText:_controller.searchBar.text];
+}
+
+#if !TARGET_OS_TV
+- (void)searchBarCancelButtonClicked:(UISearchBar *)searchBar
+{
+  _controller.searchBar.text = @"";
+  [self resignFirstResponder];
+  [self hideCancelButton];
+
+  [self emitOnCancelButtonPressEvent];
+  [self emitOnChangeTextEventWithText:_controller.searchBar.text];
+}
+#endif // !TARGET_OS_TV
+
+#pragma mark-- Fabric specific
+
+#ifdef RN_FABRIC_ENABLED
+- (void)updateProps:(facebook::react::Props::Shared const &)props
+           oldProps:(facebook::react::Props::Shared const &)oldProps
+{
+  const auto &oldScreenProps = *std::static_pointer_cast<const facebook::react::RNSSearchBarProps>(_props);
+  const auto &newScreenProps = *std::static_pointer_cast<const facebook::react::RNSSearchBarProps>(props);
+
+  [self setHideWhenScrolling:newScreenProps.hideWhenScrolling];
+
+  if (oldScreenProps.cancelButtonText != newScreenProps.cancelButtonText) {
+    [self setCancelButtonText:RCTNSStringFromStringNilIfEmpty(newScreenProps.cancelButtonText)];
+  }
+
+  if (oldScreenProps.obscureBackground != newScreenProps.obscureBackground) {
+    [self setObscureBackground:newScreenProps.obscureBackground];
+  }
+
+  if (oldScreenProps.hideNavigationBar != newScreenProps.hideNavigationBar) {
+    [self setHideNavigationBar:newScreenProps.hideNavigationBar];
+  }
+
+  if (oldScreenProps.placeholder != newScreenProps.placeholder) {
+    [self setPlaceholder:RCTNSStringFromStringNilIfEmpty(newScreenProps.placeholder)];
+  }
+
+  if (oldScreenProps.autoCapitalize != newScreenProps.autoCapitalize) {
+    [self setAutoCapitalize:[RNSConvert UITextAutocapitalizationTypeFromCppEquivalent:newScreenProps.autoCapitalize]];
+  }
+
+  if (oldScreenProps.tintColor != newScreenProps.tintColor) {
+    [self setTintColor:RCTUIColorFromSharedColor(newScreenProps.tintColor)];
+  }
+
+  if (oldScreenProps.barTintColor != newScreenProps.barTintColor) {
+    [self setBarTintColor:RCTUIColorFromSharedColor(newScreenProps.barTintColor)];
+  }
+
+  if (oldScreenProps.textColor != newScreenProps.textColor) {
+    [self setTextColor:RCTUIColorFromSharedColor(newScreenProps.textColor)];
+  }
+
+  [super updateProps:props oldProps:oldProps];
+}
+
++ (facebook::react::ComponentDescriptorProvider)componentDescriptorProvider
+{
+  return facebook::react::concreteComponentDescriptorProvider<facebook::react::RNSSearchBarComponentDescriptor>();
+}
+
+#else
+#endif
+
+@end
+
+#ifdef RN_FABRIC_ENABLED
+Class<RCTComponentViewProtocol> RNSSearchBarCls(void)
+{
+  return RNSSearchBar.class;
+}
+#endif
+
+@implementation RNSSearchBarManager
+
+RCT_EXPORT_MODULE()
+
+#ifdef RN_FABRIC_ENABLED
+#else
+- (UIView *)view
+{
+  return [[RNSSearchBar alloc] initWithBridge:self.bridge];
+}
+#endif
+
+RCT_EXPORT_VIEW_PROPERTY(obscureBackground, BOOL)
+RCT_EXPORT_VIEW_PROPERTY(hideNavigationBar, BOOL)
+RCT_EXPORT_VIEW_PROPERTY(hideWhenScrolling, BOOL)
+RCT_EXPORT_VIEW_PROPERTY(autoCapitalize, UITextAutocapitalizationType)
+RCT_EXPORT_VIEW_PROPERTY(placeholder, NSString)
+RCT_EXPORT_VIEW_PROPERTY(barTintColor, UIColor)
+RCT_EXPORT_VIEW_PROPERTY(tintColor, UIColor)
+RCT_EXPORT_VIEW_PROPERTY(textColor, UIColor)
+RCT_EXPORT_VIEW_PROPERTY(cancelButtonText, NSString)
+
+RCT_EXPORT_VIEW_PROPERTY(onChangeText, RCTBubblingEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onCancelButtonPress, RCTBubblingEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onSearchButtonPress, RCTBubblingEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onFocus, RCTBubblingEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onBlur, RCTBubblingEventBlock)
+
+@end

package/lib/commonjs/fabric/FullWindowOverlay.js

@@ -0,0 +1,26 @@
+"use strict";
+
+Object.defineProperty(exports, "__esModule", {
+  value: true
+});
+exports.default = void 0;
+
+var _react = _interopRequireDefault(require("react"));
+
+var _FullWindowOverlayNativeComponent = _interopRequireDefault(require("./FullWindowOverlayNativeComponent"));
+
+function _interopRequireDefault(obj) { return obj && obj.__esModule ? obj : { default: obj }; }
+
+function _extends() { _extends = Object.assign || function (target) { for (var i = 1; i < arguments.length; i++) { var source = arguments[i]; for (var key in source) { if (Object.prototype.hasOwnProperty.call(source, key)) { target[key] = source[key]; } } } return target; }; return _extends.apply(this, arguments); }
+
+function FullWindowOverlay(props) {
+  return /*#__PURE__*/_react.default.createElement(_FullWindowOverlayNativeComponent.default, _extends({}, props, {
+    style: [{
+      flex: 1
+    }, props.style]
+  }));
+}
+
+var _default = FullWindowOverlay;
+exports.default = _default;
+//# sourceMappingURL=FullWindowOverlay.js.map

package/lib/commonjs/fabric/FullWindowOverlay.js.map

@@ -0,0 +1 @@
+{"version":3,"sources":["FullWindowOverlay.js"],"names":["FullWindowOverlay","props","flex","style"],"mappings":";;;;;;;AAAA;;AACA;;;;;;AAEA,SAASA,iBAAT,CAA2BC,KAA3B,EAAkC;AAChC,sBACE,6BAAC,yCAAD,eACMA,KADN;AAEE,IAAA,KAAK,EAAE,CAAC;AAAEC,MAAAA,IAAI,EAAE;AAAR,KAAD,EAAcD,KAAK,CAACE,KAApB;AAFT,KADF;AAMD;;eAEcH,iB","sourcesContent":["import React from 'react';\nimport FullWindowOverlayNativeComponent from './FullWindowOverlayNativeComponent';\n\nfunction FullWindowOverlay(props) {\n  return (\n    <FullWindowOverlayNativeComponent\n      {...props}\n      style={[{ flex: 1 }, props.style]}\n    />\n  );\n}\n\nexport default FullWindowOverlay;\n"]}

package/lib/commonjs/fabric/FullWindowOverlayNativeComponent.js

@@ -0,0 +1,21 @@
+"use strict";
+
+Object.defineProperty(exports, "__esModule", {
+  value: true
+});
+exports.default = void 0;
+
+var _codegenNativeComponent = _interopRequireDefault(require("react-native/Libraries/Utilities/codegenNativeComponent"));
+
+function _interopRequireDefault(obj) { return obj && obj.__esModule ? obj : { default: obj }; }
+
+/**
+ * 
+ * @format
+ */
+
+/* eslint-disable */
+var _default = (0, _codegenNativeComponent.default)('RNSFullWindowOverlay', {});
+
+exports.default = _default;
+//# sourceMappingURL=FullWindowOverlayNativeComponent.js.map

package/lib/commonjs/fabric/FullWindowOverlayNativeComponent.js.map

@@ -0,0 +1 @@
+{"version":3,"sources":["FullWindowOverlayNativeComponent.js"],"names":[],"mappings":";;;;;;;AAKA;;;;AALA;AACA;AACA;AACA;;AACA;eAWgB,qCACd,sBADc,EAEd,EAFc,C","sourcesContent":["/**\n * @flow strict-local\n * @format\n */\n/* eslint-disable */\nimport codegenNativeComponent from 'react-native/Libraries/Utilities/codegenNativeComponent';\nimport type { ViewProps } from 'react-native/Libraries/Components/View/ViewPropTypes';\nimport type { HostComponent } from 'react-native/Libraries/Renderer/shims/ReactNativeTypes';\n\ntype NativeProps = $ReadOnly<{|\n  ...ViewProps,\n|}>;\n\ntype ComponentType = HostComponent<NativeProps>;\n\nexport default (codegenNativeComponent<NativeProps>(\n  'RNSFullWindowOverlay',\n  {}\n): ComponentType);\n"]}

package/lib/commonjs/fabric/ScreenContainer.js

@@ -0,0 +1,28 @@
+"use strict";
+
+Object.defineProperty(exports, "__esModule", {
+  value: true
+});
+exports.default = void 0;
+
+var _react = _interopRequireDefault(require("react"));
+
+var _ScreenContainerNativeComponent = _interopRequireDefault(require("./ScreenContainerNativeComponent"));
+
+function _interopRequireDefault(obj) { return obj && obj.__esModule ? obj : { default: obj }; }
+
+function _extends() { _extends = Object.assign || function (target) { for (var i = 1; i < arguments.length; i++) { var source = arguments[i]; for (var key in source) { if (Object.prototype.hasOwnProperty.call(source, key)) { target[key] = source[key]; } } } return target; }; return _extends.apply(this, arguments); }
+
+function ScreenContainer(props) {
+  return /*#__PURE__*/_react.default.createElement(_ScreenContainerNativeComponent.default, _extends({}, props, {
+    style: [{
+      flex: 1,
+      alignItems: 'center',
+      justifyContent: 'center'
+    }, props.style]
+  }));
+}
+
+var _default = ScreenContainer;
+exports.default = _default;
+//# sourceMappingURL=ScreenContainer.js.map