react-native-nitro-xlsx 0.2.5 → 0.2.6

package/thirdparty/OpenXLSX/OpenXLSX/OpenXLSX.hpp

@@ -0,0 +1,63 @@
+/*
+
+   ____                               ____      ___ ____       ____  ____      ___
+  6MMMMb                              `MM(      )M' `MM'      6MMMMb\`MM(      )M'
+ 8P    Y8                              `MM.     d'   MM      6M'    ` `MM.     d'
+6M      Mb __ ____     ____  ___  __    `MM.   d'    MM      MM        `MM.   d'
+MM      MM `M6MMMMb   6MMMMb `MM 6MMb    `MM. d'     MM      YM.        `MM. d'
+MM      MM  MM'  `Mb 6M'  `Mb MMM9 `Mb    `MMd       MM       YMMMMb     `MMd
+MM      MM  MM    MM MM    MM MM'   MM     dMM.      MM           `Mb     dMM.
+MM      MM  MM    MM MMMMMMMM MM    MM    d'`MM.     MM            MM    d'`MM.
+YM      M9  MM    MM MM       MM    MM   d'  `MM.    MM            MM   d'  `MM.
+ 8b    d8   MM.  ,M9 YM    d9 MM    MM  d'    `MM.   MM    / L    ,M9  d'    `MM.
+  YMMMM9    MMYMMM9   YMMMM9 _MM_  _MM_M(_    _)MM_ _MMMMMMM MYMMMM9 _M(_    _)MM_
+            MM
+            MM
+           _MM_
+
+  Copyright (c) 2018, Kenneth Troldal Balslev
+
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without
+  modification, are permitted provided that the following conditions are met:
+  - Redistributions of source code must retain the above copyright
+    notice, this list of conditions and the following disclaimer.
+  - Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the
+    documentation and/or other materials provided with the distribution.
+  - Neither the name of the author nor the
+    names of any contributors may be used to endorse or promote products
+    derived from this software without specific prior written permission.
+
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+  ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+  WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+  DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
+  DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+  (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+  LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
+  ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+ */
+
+#ifndef OPENXLSX_OPENXLSX_HPP
+#define OPENXLSX_OPENXLSX_HPP
+
+#include "headers/XLCell.hpp"
+#include "headers/XLCellRange.hpp"
+#include "headers/XLCellReference.hpp"
+#include "headers/XLCellValue.hpp"
+#include "headers/XLColumn.hpp"
+#include "headers/XLDateTime.hpp"
+#include "headers/XLDocument.hpp"
+#include "headers/XLException.hpp"
+#include "headers/XLFormula.hpp"
+#include "headers/XLRow.hpp"
+#include "headers/XLSheet.hpp"
+#include "headers/XLWorkbook.hpp"
+#include "headers/XLZipArchive.hpp"
+
+#endif    // OPENXLSX_OPENXLSX_HPP

package/thirdparty/OpenXLSX/OpenXLSX/OpenXLSXConfig.cmake

@@ -0,0 +1,11 @@
+include("${CMAKE_CURRENT_LIST_DIR}/OpenXLSXTargets.cmake")
+# # TBD: the below do not appear to be necessary, nor do they seem to have any effect?
+# if (OPENXLSX_ENABLE_NOWIDE)
+#     find_dependency(Boost 1.74 CONFIG)
+# endif()
+# if (OPENXLSX_ENABLE_LIBZIP)
+#     find_dependency(LibZip 1.7 CONFIG)
+# endif()
+# if (OPENXLSX_ENABLE_LIBPUGIXML)
+#     find_dependency(PugiXML 1.14 CONFIG)
+# endif()

package/thirdparty/OpenXLSX/OpenXLSX/cmake/bundle_static_library.cmake

@@ -0,0 +1,198 @@
+# MIT License
+# 
+# Copyright (c) 2019 Cristian Adam
+# 
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+# 
+# The above copyright notice and this permission notice shall be included in all
+# copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+function(bundle_static_library tgt_name bundled_tgt_name)
+  list(APPEND static_libs ${tgt_name})
+
+  function(_recursively_collect_dependencies input_target)
+    set(_input_link_libraries LINK_LIBRARIES)
+    get_target_property(_input_type ${input_target} TYPE)
+    if (${_input_type} STREQUAL "INTERFACE_LIBRARY")
+      set(_input_link_libraries INTERFACE_LINK_LIBRARIES)
+    endif()
+    get_target_property(public_dependencies ${input_target} ${_input_link_libraries})
+    foreach(dependency IN LISTS public_dependencies)
+      if(TARGET ${dependency})
+        get_target_property(alias ${dependency} ALIASED_TARGET)
+        if (TARGET ${alias})
+          set(dependency ${alias})
+        endif()
+        get_target_property(_type ${dependency} TYPE)
+        if (${_type} STREQUAL "STATIC_LIBRARY")
+          list(APPEND static_libs ${dependency})
+        endif()
+
+        get_property(library_already_added
+          GLOBAL PROPERTY _${tgt_name}_static_bundle_${dependency})
+        if (NOT library_already_added)
+          set_property(GLOBAL PROPERTY _${tgt_name}_static_bundle_${dependency} ON)
+          _recursively_collect_dependencies(${dependency})
+        endif()
+      endif()
+    endforeach()
+    set(static_libs ${static_libs} PARENT_SCOPE)
+  endfunction()
+
+  _recursively_collect_dependencies(${tgt_name})
+
+  list(REMOVE_DUPLICATES static_libs)
+
+  set(bundled_tgt_full_name 
+    ${CMAKE_BINARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}${bundled_tgt_name}${CMAKE_STATIC_LIBRARY_SUFFIX})
+
+  if (CMAKE_CXX_COMPILER_ID MATCHES "^(Clang|GNU)$")
+    file(WRITE ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in
+      "CREATE ${bundled_tgt_full_name}\n" )
+        
+    foreach(tgt IN LISTS static_libs)
+      file(APPEND ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in
+        "ADDLIB $<TARGET_FILE:${tgt}>\n")
+    endforeach()
+    
+    file(APPEND ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in "SAVE\n")
+    file(APPEND ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in "END\n")
+
+    file(GENERATE
+      OUTPUT ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar
+      INPUT ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in)
+
+    set(ar_tool ${CMAKE_AR})
+    if (CMAKE_INTERPROCEDURAL_OPTIMIZATION)
+      set(ar_tool ${CMAKE_CXX_COMPILER_AR})
+    endif()
+
+    add_custom_command(
+      COMMAND ${ar_tool} -M < ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar
+      OUTPUT ${bundled_tgt_full_name}
+      COMMENT "Bundling ${bundled_tgt_name}"
+      VERBATIM)
+  elseif(MSVC)
+    find_program(lib_tool lib)
+
+    foreach(tgt IN LISTS static_libs)
+      list(APPEND static_libs_full_names $<TARGET_FILE:${tgt}>)
+    endforeach()
+
+    add_custom_command(
+      COMMAND ${lib_tool} /NOLOGO /OUT:${bundled_tgt_full_name} ${static_libs_full_names}
+      OUTPUT ${bundled_tgt_full_name}
+      COMMENT "Bundling ${bundled_tgt_name}"
+      VERBATIM)
+  else()
+    message(FATAL_ERROR "Unknown bundle scenario!")
+  endif()
+
+  add_custom_target(bundling_target ALL DEPENDS ${bundled_tgt_full_name})
+  add_dependencies(bundling_target ${tgt_name})
+
+  add_library(${bundled_tgt_name} STATIC IMPORTED)
+  set_target_properties(${bundled_tgt_name} 
+    PROPERTIES 
+      IMPORTED_LOCATION ${bundled_tgt_full_name}
+      INTERFACE_INCLUDE_DIRECTORIES $<TARGET_PROPERTY:${tgt_name},INTERFACE_INCLUDE_DIRECTORIES>)
+  add_dependencies(${bundled_tgt_name} bundling_target)
+
+endfunction()
+
+
+#=======================================================================================================================
+# BEGIN OF FUNCTION: bundle_static_library_simplified
+# Purpose: replace ${CMAKE_BINARY_DIR} with ${CMAKE_LIBRARY_OUTPUT_DIRECTORY} and process a *known* list of dependencies
+#            without the need for the function to _recursively_collect_dependencies
+#          Also: better understand the function through learning by doing
+# Status: 2026-03-24 - static_libs_system is no longer in use, static_libs must contain full paths (generator expressions if needed) to static targets
+# Parameters:
+#   lib_name            original library name for which dependencies shall be statically linked
+#   lib_name_combined   output library name that includes the dependencies
+#   static_libs         list of dependencies to link into lib_name_combined
+#   static_libs_system  list of fully resolved dependencies (of preinstalled libraries) to link into lib_name_combined
+#=======================================================================================================================
+function(bundle_static_library_simplified lib_name lib_name_combined static_libs static_libs_system)
+    set(full_lib_name_combined "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_STATIC_LIBRARY_PREFIX}${lib_name_combined}${CMAKE_STATIC_LIBRARY_SUFFIX}")
+
+    if (CMAKE_CXX_COMPILER_ID MATCHES "^(Clang|GNU)$")
+        file(WRITE ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar.in
+          "CREATE ${full_lib_name_combined}\n" )
+
+        foreach(tgt IN LISTS static_libs)
+            message( STATUS "bundle_static_library_simplified: static target is ${tgt}" )
+            file(APPEND ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar.in
+                    "ADDLIB ${tgt}\n")
+                    # "ADDLIB $<TARGET_FILE:${tgt}>\n")
+        endforeach()
+        foreach(tgt IN LISTS static_libs_system)
+            message( STATUS "bundle_static_library_simplified: installed static target is ${tgt}" )
+            file(APPEND ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar.in
+                    "ADDLIB ${tgt}>\n")
+        endforeach()
+
+        file(APPEND ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar.in "SAVE\n")
+        file(APPEND ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar.in "END\n")
+
+        file(GENERATE
+             OUTPUT ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar
+             INPUT ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar.in)
+
+        set(ar_tool ${CMAKE_AR})
+        if (CMAKE_INTERPROCEDURAL_OPTIMIZATION)
+            set(ar_tool ${CMAKE_CXX_COMPILER_AR})
+        endif()
+
+        add_custom_command(
+            COMMAND ${ar_tool} -M < ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${lib_name_combined}.ar
+            OUTPUT ${full_lib_name_combined}
+            COMMENT "Bundling ${lib_name_combined}"
+            VERBATIM)
+    elseif(MSVC) # untested, unsupported ATM
+        message( FATAL_ERROR "OPENXLSX_BUNDLED_STATIC_LIB is not yet supported for MSVC" )
+
+        find_program(lib_tool lib)
+
+        # foreach(tgt IN LISTS static_libs)
+        #     list(APPEND static_libs_full_names $<TARGET_FILE:${tgt}>)
+        # endforeach()
+
+        add_custom_command(
+            # COMMAND ${lib_tool} /NOLOGO /OUT:${full_lib_name_combined} ${static_libs_full_names}
+            COMMAND ${lib_tool} /NOLOGO /OUT:${full_lib_name_combined} ${static_libs}
+            OUTPUT ${full_lib_name_combined}
+            COMMENT "Bundling ${lib_name_combined}"
+            VERBATIM)
+    else()
+        message(FATAL_ERROR "Unknown bundle scenario!")
+    endif()
+
+    add_custom_target(bundling_target ALL DEPENDS ${full_lib_name_combined}) # NOTE: this line is actually the only one required to *just* build the bundled static library
+
+    # Everything below here might one day be useful to link against the bundled library from CMake configurations, but I currently do not know how to accomplish that
+    add_dependencies(bundling_target ${lib_name})
+
+    add_library(${lib_name_combined} STATIC IMPORTED)
+    set_target_properties(${lib_name_combined}
+      PROPERTIES
+        IMPORTED_LOCATION ${full_lib_name_combined}
+        INTERFACE_INCLUDE_DIRECTORIES $<TARGET_PROPERTY:${lib_name},INTERFACE_INCLUDE_DIRECTORIES>)
+    add_dependencies(${lib_name_combined} bundling_target)
+endfunction()
+#=======================================================================================================================
+# END OF FUNCTION: bundle_static_library_simplified
+#=======================================================================================================================

package/thirdparty/OpenXLSX/OpenXLSX/cmake/patch_pkg_config.cmake

@@ -0,0 +1,69 @@
+# ============================================================================
+# Author: Lars Uffmann (coding23@uffmann.name)
+# Purpose: Patch an upstream package config (.pc) file Libs property to include an additional subdirectory {exec_prefix}/lib/SUBDIR
+
+# Function: pkg_config_add_library_subdir
+# Purpose: patch a package config file IN_PKG_CONFIG to contain an additional library directory LIB_SUBDIR and write the output to OUT_PKG_CONFIG
+# Parameters:
+#   IN_PKG_CONFIG
+#   OUT_PKG_CONFIG
+#   LIB_SUBDIR
+# Returns: Writes the patched output file to the indicated location. Calling process has to verify success by checking existence of OUT_PKG_CONFIG
+#
+function(pkg_config_add_library_subdir IN_PKG_CONFIG OUT_PKG_CONFIG LIB_SUBDIR)
+    message( DEBUG "prefixing ${IN_PKG_CONFIG} Libs: setting with '-L{exec_prefix}/lib/${LIB_SUBDIR}' and writing to ${OUT_PKG_CONFIG}" )
+
+    set(NEW_LIB_DIR "-L\${exec_prefix}/lib/${LIB_SUBDIR}")
+
+    file(READ "${IN_PKG_CONFIG}" PKG_CONFIG_RAW)
+
+    # normalize newlines, then join continuation lines, if any
+    string(REPLACE "\r\n" "\n"  PKG_CONFIG_RAW "${PKG_CONFIG_RAW}")
+    string(REPLACE "\r" "\n"    PKG_CONFIG_RAW "${PKG_CONFIG_RAW}")
+    string(REPLACE "\\\n" " "   PKG_CONFIG_RAW "${PKG_CONFIG_RAW}")
+
+    # optional: collapse multiple whitespaces
+    string(REGEX REPLACE "[ \t]+" " " PKG_CONFIG_RAW "${PKG_CONFIG_RAW}")
+
+    # save and reload file as list of strings:
+    file(WRITE "${OUT_PKG_CONFIG}" "${PKG_CONFIG_RAW}")
+    file(STRINGS "${OUT_PKG_CONFIG}" PKG_CONFIG_LINES)
+
+    # initialize text block variables
+    set(BEFORE "")
+    set(LIBS "")
+    set(AFTER "")
+    set(found_libs FALSE)
+
+    # message( STATUS "PKG_CONFIG_LINES is:" )
+    foreach(line IN LISTS PKG_CONFIG_LINES)
+        # message( STATUS "   ${line}" )
+        string(STRIP "${line}" line)
+        if(line MATCHES "^[Ll]ibs[ \t]*:.*")
+            string(REGEX REPLACE "^[Ll]ibs[ \t]*:[ \t]*" "" _Libs_Line "${line}")
+            # message( STATUS "   This is the Libs line: |${_Libs_Line}|" )
+            if(NOT found_libs)
+                set(found_libs TRUE)
+                set(LIBS "Libs: ${NEW_LIB_DIR}")    # begin Libs line with NEW_LIB_DIR
+            endif()
+            if(NOT "${_Libs_Line}" STREQUAL "") # for non-empty Libs entries
+                set(LIBS "${LIBS} ${_Libs_Line}")   # append them to the collapsed Libs line
+            endif()
+        else()                                  # line is not a Libs line
+            if(NOT found_libs)                      # if no Libs line was found so far
+                set(BEFORE "${BEFORE}${line}\n")        # append line to "BEFORE" block
+            else()                                  # else: at least one Libs line was already processed
+                set(AFTER "${AFTER}${line}\n")          # append line to "AFTER" block
+            endif()
+        endif()
+    endforeach()
+
+    # if a LIBS line was generated, append a line break
+    if(NOT "${LIBS}" STREQUAL "")
+        set(LIBS "${LIBS}\n")
+    endif()
+
+    # add header comment explaining the automated patch and write the finalized outfile
+    set(HEADER "# Patched by OpenXLSX installer: prepended ${NEW_LIB_DIR} to Libs to accommodate custom library location\n")
+    file(WRITE "${OUT_PKG_CONFIG}" "${HEADER}${BEFORE}${LIBS}${AFTER}")
+endfunction()