react-native-enriched 0.0.0 → 0.1.0

package/ios/utils/LayoutManagerExtension.mm

@@ -0,0 +1,171 @@
+#import "LayoutManagerExtension.h"
+#import <objc/runtime.h>
+#import "EnrichedTextInputView.h"
+#import "StyleHeaders.h"
+#import "ParagraphsUtils.h"
+
+@implementation NSLayoutManager (LayoutManagerExtension)
+
+static void const *kInputKey = &kInputKey;
+
+- (id)input {
+  return objc_getAssociatedObject(self, kInputKey);
+}
+
+- (void)setInput:(id)value {
+  objc_setAssociatedObject(
+    self,
+    kInputKey,
+    value,
+    OBJC_ASSOCIATION_RETAIN_NONATOMIC
+  );
+}
+
++ (void)load {
+  static dispatch_once_t onceToken;
+  dispatch_once(&onceToken, ^{
+    Class myClass = [NSLayoutManager class];
+    SEL originalSelector = @selector(drawBackgroundForGlyphRange:atPoint:);
+    SEL swizzledSelector = @selector(my_drawBackgroundForGlyphRange:atPoint:);
+    Method originalMethod = class_getInstanceMethod(myClass, originalSelector);
+    Method swizzledMethod = class_getInstanceMethod(myClass, swizzledSelector);
+    
+    BOOL didAddMethod = class_addMethod(myClass, originalSelector,
+      method_getImplementation(swizzledMethod),
+      method_getTypeEncoding(swizzledMethod)
+    );
+    
+    if(didAddMethod) {
+      class_replaceMethod(myClass, swizzledSelector,
+        method_getImplementation(originalMethod),
+        method_getTypeEncoding(originalMethod)
+      );
+    } else {
+      method_exchangeImplementations(originalMethod, swizzledMethod);
+    }
+  });
+}
+
+- (void)my_drawBackgroundForGlyphRange:(NSRange)glyphRange atPoint:(CGPoint)origin {
+  [self my_drawBackgroundForGlyphRange:glyphRange atPoint:origin];
+  
+  EnrichedTextInputView *typedInput = (EnrichedTextInputView *)self.input;
+  if(typedInput == nullptr) { return; }
+  
+  BlockQuoteStyle *bqStyle = typedInput->stylesDict[@([BlockQuoteStyle getStyleType])];
+  if(bqStyle == nullptr) { return; }
+  
+  NSRange inputRange = NSMakeRange(0, typedInput->textView.textStorage.length);
+  
+  // it isn't the most performant but we have to check for all the blockquotes each time and redraw them
+  NSArray *allBlockquotes = [bqStyle findAllOccurences:inputRange];
+  
+  for(StylePair *pair in allBlockquotes) {
+    NSRange paragraphRange = [typedInput->textView.textStorage.string paragraphRangeForRange:[pair.rangeValue rangeValue]];
+    NSRange paragraphGlyphRange = [self glyphRangeForCharacterRange:paragraphRange actualCharacterRange:nullptr];
+    [self enumerateLineFragmentsForGlyphRange:paragraphGlyphRange
+      usingBlock:^(CGRect rect, CGRect usedRect, NSTextContainer * _Nonnull textContainer, NSRange glyphRange, BOOL * _Nonnull stop) {
+        CGFloat paddingLeft = origin.x;
+        CGFloat paddingTop = origin.y;
+        CGFloat x = paddingLeft;
+        CGFloat y = paddingTop + rect.origin.y;
+        CGFloat width = [typedInput->config blockquoteBorderWidth];
+        CGFloat height = rect.size.height;
+        
+        CGRect lineRect = CGRectMake(x, y, width, height);
+        [[typedInput->config blockquoteBorderColor] setFill];
+        UIRectFill(lineRect);
+      }
+    ];
+  }
+    
+  UnorderedListStyle *ulStyle = typedInput->stylesDict[@([UnorderedListStyle getStyleType])];
+  OrderedListStyle *olStyle = typedInput->stylesDict[@([OrderedListStyle getStyleType])];
+  if(ulStyle == nullptr || olStyle == nullptr) { return; }
+  
+  // also not the most performant but we redraw all the lists
+  NSMutableArray *allLists = [[NSMutableArray alloc] init];
+  [allLists addObjectsFromArray:[ulStyle findAllOccurences:inputRange]];
+  [allLists addObjectsFromArray:[olStyle findAllOccurences:inputRange]];
+  
+  for(StylePair *pair in allLists) {
+    NSParagraphStyle *pStyle = (NSParagraphStyle *)pair.styleValue;
+    NSDictionary *markerAttributes = @{
+      NSFontAttributeName: [typedInput->config orderedListMarkerFont],
+      NSForegroundColorAttributeName: [typedInput->config orderedListMarkerColor]
+    };
+    
+    NSArray *paragraphs = [ParagraphsUtils getSeparateParagraphsRangesIn:typedInput->textView range:[pair.rangeValue rangeValue]];
+    
+    for(NSValue *paragraph in paragraphs) {
+      NSRange paragraphGlyphRange = [self glyphRangeForCharacterRange:[paragraph rangeValue] actualCharacterRange:nullptr];
+      
+      [self enumerateLineFragmentsForGlyphRange:paragraphGlyphRange
+        usingBlock:^(CGRect rect, CGRect usedRect, NSTextContainer *container, NSRange lineGlyphRange, BOOL *stop) {
+          NSString *marker = [self markerForList:pStyle.textLists.firstObject charIndex:[self characterIndexForGlyphAtIndex:lineGlyphRange.location] input:typedInput];
+          
+          if(pStyle.textLists.firstObject.markerFormat == NSTextListMarkerDecimal) {
+            CGFloat gapWidth = [typedInput->config orderedListGapWidth];
+            CGFloat markerWidth = [marker sizeWithAttributes:markerAttributes].width;
+            CGFloat markerX = usedRect.origin.x - gapWidth - markerWidth/2;
+            
+            [marker drawAtPoint:CGPointMake(markerX, usedRect.origin.y + origin.y) withAttributes:markerAttributes];
+          } else {
+            CGFloat gapWidth = [typedInput->config unorderedListGapWidth];
+            CGFloat bulletSize = [typedInput->config unorderedListBulletSize];
+            CGFloat bulletX = usedRect.origin.x - gapWidth - bulletSize/2;
+            CGFloat centerY = CGRectGetMidY(usedRect);
+            
+            CGContextRef context = UIGraphicsGetCurrentContext();
+            CGContextSaveGState(context); {
+              [[typedInput->config unorderedListBulletColor] setFill];
+              CGContextAddArc(context, bulletX, centerY, bulletSize/2, 0, 2 * M_PI, YES);
+              CGContextFillPath(context);
+            }
+            CGContextRestoreGState(context);
+          }
+          // only first line of a list gets its marker drawn
+          *stop = YES;
+        }
+      ];
+    }
+  }
+}
+
+- (NSString *)markerForList:(NSTextList *)list charIndex:(NSUInteger)index input:(EnrichedTextInputView *)input {
+  if(list.markerFormat == NSTextListMarkerDecimal) {
+    NSString *fullText = input->textView.textStorage.string;
+    NSInteger itemNumber = 1;
+    
+    NSRange currentParagraph = [fullText paragraphRangeForRange:NSMakeRange(index, 0)];
+    if(currentParagraph.location > 0) {
+      OrderedListStyle *olStyle = input->stylesDict[@([OrderedListStyle getStyleType])];
+      
+      NSInteger prevParagraphsCount = 0;
+      NSInteger recentParagraphLocation = [fullText paragraphRangeForRange:NSMakeRange(currentParagraph.location - 1, 0)].location;
+      
+      // seek for previous lists
+      while(true) {
+        if([olStyle detectStyle:NSMakeRange(recentParagraphLocation, 0)]) {
+          prevParagraphsCount += 1;
+          
+          if(recentParagraphLocation > 0) {
+            recentParagraphLocation = [fullText paragraphRangeForRange:NSMakeRange(recentParagraphLocation - 1, 0)].location;
+          } else {
+            break;
+          }
+        } else {
+          break;
+        }
+      }
+      
+      itemNumber = prevParagraphsCount + 1;
+    }
+    
+    return [NSString stringWithFormat:@"%ld.", (long)(itemNumber)];
+  } else {
+    return @"•";
+  }
+}
+
+@end

package/ios/utils/LinkData.h

@@ -0,0 +1,9 @@
+#pragma once
+#import <UIKit/UIKit.h>
+
+@interface LinkData : NSObject
+
+@property NSString *text;
+@property NSString *url;
+
+@end

package/ios/utils/LinkData.mm

@@ -0,0 +1,4 @@
+#import "LinkData.h"
+
+@implementation LinkData
+@end

package/ios/utils/MentionParams.h

@@ -0,0 +1,9 @@
+#pragma once
+#import <UIKit/UIKit.h>
+
+@interface MentionParams : NSObject
+@property NSString *text;
+@property NSString *indicator;
+@property NSString *attributes;
+@end
+

package/ios/utils/MentionParams.mm

@@ -0,0 +1,4 @@
+#import "MentionParams.h"
+
+@implementation MentionParams
+@end

package/ios/utils/MentionStyleProps.h

@@ -0,0 +1,13 @@
+#pragma once
+#import <UIKit/UIKit.h>
+#import "TextDecorationLineEnum.h"
+#import "string"
+#import <folly/dynamic.h>
+
+@interface MentionStyleProps : NSObject
+@property UIColor *color;
+@property UIColor *backgroundColor;
+@property TextDecorationLineEnum decorationLine;
++ (NSDictionary *)getSinglePropsFromFollyDynamic:(folly::dynamic)folly;
++ (NSDictionary *)getComplexPropsFromFollyDynamic:(folly::dynamic)folly;
+@end

package/ios/utils/MentionStyleProps.mm

@@ -0,0 +1,56 @@
+#import "MentionStyleProps.h"
+#import <React/RCTConversions.h>
+#import "StringExtension.h"
+
+@implementation MentionStyleProps
+
++ (MentionStyleProps *)getSingleMentionStylePropsFromFollyDynamic:(folly::dynamic)folly {
+  MentionStyleProps *nativeProps = [[MentionStyleProps alloc] init];
+  
+  if(folly["color"].isNumber()) {
+    facebook::react::SharedColor color = facebook::react::SharedColor(facebook::react::Color(folly["color"].asInt()));
+    nativeProps.color = RCTUIColorFromSharedColor(color);
+  } else {
+    nativeProps.color = [UIColor blueColor];
+  }
+  
+  if(folly["backgroundColor"].isNumber()) {
+    facebook::react::SharedColor bgColor = facebook::react::SharedColor(facebook::react::Color(folly["backgroundColor"].asInt()));
+    nativeProps.backgroundColor = RCTUIColorFromSharedColor(bgColor);
+  } else {
+    nativeProps.backgroundColor = [UIColor yellowColor];
+  }
+  
+  if(folly["textDecorationLine"].isString()) {
+    std::string textDecorationLine = folly["textDecorationLine"].asString();
+    nativeProps.decorationLine = [[NSString fromCppString:textDecorationLine] isEqualToString:DecorationUnderline] ? DecorationUnderline : DecorationNone;
+  } else {
+    nativeProps.decorationLine = DecorationUnderline;
+  }
+  
+  return nativeProps;
+}
+
++ (NSDictionary *)getSinglePropsFromFollyDynamic:(folly::dynamic)folly {
+  MentionStyleProps *nativeProps = [MentionStyleProps getSingleMentionStylePropsFromFollyDynamic:folly];
+  // the single props need to be somehow distinguishable in config
+  NSDictionary *dict = @{@"all": nativeProps};
+  return dict;
+}
+
++ (NSDictionary *)getComplexPropsFromFollyDynamic:(folly::dynamic)folly {
+  NSMutableDictionary *dict = [[NSMutableDictionary alloc] init];
+  
+  for(const auto& obj: folly.items()) {
+    if(obj.first.isString() && obj.second.isObject()) {
+      std::string key = obj.first.asString();
+      MentionStyleProps *props = [MentionStyleProps getSingleMentionStylePropsFromFollyDynamic:obj.second];
+      dict[[NSString fromCppString:key]] = props;
+    }
+  }
+  
+  return dict;
+}
+
+@end
+

package/ios/utils/OccurenceUtils.h

@@ -0,0 +1,37 @@
+#pragma once
+#import "StylePair.h"
+#import "EnrichedTextInputView.h"
+
+
+@interface OccurenceUtils : NSObject
++ (BOOL)detect
+  :(NSAttributedStringKey _Nonnull)key
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition;
++ (BOOL)detectMultiple
+  :(NSArray<NSAttributedStringKey> *_Nonnull)keys
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition;
++ (BOOL)any
+  :(NSAttributedStringKey _Nonnull)key
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition;
++ (BOOL)anyMultiple
+  :(NSArray<NSAttributedStringKey> *_Nonnull)keys
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition;
++ (NSArray<StylePair *> *_Nullable)all
+  :(NSAttributedStringKey _Nonnull)key
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition;
++ (NSArray<StylePair *> *_Nullable)allMultiple
+  :(NSArray<NSAttributedStringKey> *_Nonnull)keys
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition;
+@end

package/ios/utils/OccurenceUtils.mm

@@ -0,0 +1,124 @@
+#import "OccurenceUtils.h"
+
+@implementation OccurenceUtils
+
++ (BOOL)detect
+  :(NSAttributedStringKey _Nonnull)key
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition
+{
+  __block NSInteger totalLength = 0;
+  [input->textView.textStorage enumerateAttribute:key inRange:range options:0 usingBlock:
+    ^(id  _Nullable value, NSRange range, BOOL * _Nonnull stop) {
+      if(condition(value, range)) {
+        totalLength += range.length;
+      }
+    }
+  ];
+  return totalLength == range.length;
+}
+
++ (BOOL)detectMultiple
+  :(NSArray<NSAttributedStringKey> *_Nonnull)keys
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition
+{
+  __block NSInteger totalLength = 0;
+  for(NSString* key in keys) {
+    [input->textView.textStorage enumerateAttribute:key inRange:range options:0 usingBlock:
+      ^(id  _Nullable value, NSRange range, BOOL * _Nonnull stop) {
+        if(condition(value, range)) {
+          totalLength += range.length;
+        }
+      }
+    ];
+  }
+  return totalLength == range.length;
+}
+
++ (BOOL)any
+  :(NSAttributedStringKey _Nonnull)key
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition
+{
+  __block BOOL found = NO;
+  [input->textView.textStorage enumerateAttribute:key inRange:range options:0 usingBlock:
+    ^(id  _Nullable value, NSRange range, BOOL * _Nonnull stop) {
+      if(condition(value, range)) {
+        found = YES;
+        *stop = YES;
+      }
+    }
+  ];
+  return found;
+}
+
++ (BOOL)anyMultiple
+  :(NSArray<NSAttributedStringKey> *_Nonnull)keys
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition
+{
+  __block BOOL found = NO;
+  for(NSString *key in keys) {
+    [input->textView.textStorage enumerateAttribute:key inRange:range options:0 usingBlock:
+      ^(id  _Nullable value, NSRange range, BOOL * _Nonnull stop) {
+        if(condition(value, range)) {
+          found = YES;
+          *stop = YES;
+        }
+      }
+    ];
+    if(found) {
+      return YES;
+    }
+  }
+  return NO;
+}
+
++ (NSArray<StylePair *> *_Nullable)all
+  :(NSAttributedStringKey _Nonnull)key
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition
+{
+  __block NSMutableArray<StylePair *> *occurences = [[NSMutableArray<StylePair *> alloc] init];
+  [input->textView.textStorage enumerateAttribute:key inRange:range options:0 usingBlock:
+    ^(id  _Nullable value, NSRange range, BOOL * _Nonnull stop) {
+      if(condition(value, range)) {
+        StylePair *pair = [[StylePair alloc] init];
+        pair.rangeValue = [NSValue valueWithRange:range];
+        pair.styleValue = value;
+        [occurences addObject:pair];
+      }
+    }
+  ];
+  return occurences;
+}
+
++ (NSArray<StylePair *> *_Nullable)allMultiple
+  :(NSArray<NSAttributedStringKey> *_Nonnull)keys
+  withInput:(EnrichedTextInputView* _Nonnull)input
+  inRange:(NSRange)range
+  withCondition:(BOOL (NS_NOESCAPE ^_Nonnull)(id _Nullable value, NSRange range))condition
+{
+  __block NSMutableArray<StylePair *> *occurences = [[NSMutableArray<StylePair *> alloc] init];
+  for(NSString *key in keys) {
+    [input->textView.textStorage enumerateAttribute:key inRange:range options:0 usingBlock:
+      ^(id  _Nullable value, NSRange range, BOOL * _Nonnull stop) {
+        if(condition(value, range)) {
+          StylePair *pair = [[StylePair alloc] init];
+          pair.rangeValue = [NSValue valueWithRange:range];
+          pair.styleValue = value;
+          [occurences addObject:pair];
+        }
+      }
+    ];
+  }
+  return occurences;
+}
+
+@end

package/ios/utils/ParagraphsUtils.h

@@ -0,0 +1,7 @@
+#pragma once
+#import <UIKit/UIKit.h>
+
+@interface ParagraphsUtils : NSObject
++ (NSArray *)getSeparateParagraphsRangesIn:(UITextView *)textView range:(NSRange)range;
++ (NSArray *)getNonNewlineRangesIn:(UITextView *)textView range:(NSRange)range;
+@end

package/ios/utils/ParagraphsUtils.mm

@@ -0,0 +1,54 @@
+#import "ParagraphsUtils.h"
+
+@implementation ParagraphsUtils
+
++ (NSArray *)getSeparateParagraphsRangesIn:(UITextView *)textView range:(NSRange)range {
+  // just in case, get full paragraphs range
+  NSRange fullRange = [textView.textStorage.string paragraphRangeForRange:range];
+  
+  // we are in an empty paragraph
+  if(fullRange.length == 0) {
+    return @[[NSValue valueWithRange:fullRange]];
+  }
+  
+  NSMutableArray *results = [[NSMutableArray alloc] init];
+  
+  NSInteger lastStart = fullRange.location;
+  for(int i = fullRange.location; i < fullRange.location + fullRange.length; i++) {
+    unichar currentChar = [textView.textStorage.string characterAtIndex:i];
+    if([[NSCharacterSet newlineCharacterSet] characterIsMember:currentChar]) {
+      NSRange paragraphRange = [textView.textStorage.string paragraphRangeForRange:NSMakeRange(lastStart, i - lastStart)];
+      [results addObject: [NSValue valueWithRange:paragraphRange]];
+      lastStart = i+1;
+    }
+  }
+  
+  if(lastStart < fullRange.location + fullRange.length) {
+    NSRange paragraphRange = [textView.textStorage.string paragraphRangeForRange:NSMakeRange(lastStart, fullRange.location + fullRange.length - lastStart)];
+    [results addObject: [NSValue valueWithRange:paragraphRange]];
+  }
+  
+  return results;
+}
+
++ (NSArray *)getNonNewlineRangesIn:(UITextView *)textView range:(NSRange)range {
+  NSMutableArray *nonNewlineRanges = [[NSMutableArray alloc] init];
+  int lastRangeLocation = range.location;
+  
+  for(int i = range.location; i < range.location + range.length; i++) {
+    unichar currentChar = [textView.textStorage.string characterAtIndex:i];
+    if([[NSCharacterSet newlineCharacterSet] characterIsMember:currentChar]) {
+      if(i - lastRangeLocation > 0) {
+        [nonNewlineRanges addObject:[NSValue valueWithRange:NSMakeRange(lastRangeLocation, i - lastRangeLocation)]];
+      }
+      lastRangeLocation = i+1;
+    }
+  }
+  if(lastRangeLocation < range.location + range.length) {
+    [nonNewlineRanges addObject:[NSValue valueWithRange:NSMakeRange(lastRangeLocation, range.location + range.length - lastRangeLocation)]];
+  }
+  
+  return nonNewlineRanges;
+}
+
+@end

package/ios/utils/StringExtension.h

@@ -0,0 +1,15 @@
+#import <UIKit/UIKit.h>
+#include "string"
+#pragma once
+
+@interface NSString (StringExtension)
+- (std::string)toCppString;
++ (NSString *)fromCppString:(std::string)string;
++ (NSString *)stringByEscapingHtml:(NSString *)html;
++ (NSString *)stringByUnescapingHtml:(NSString *)html;
+@end
+
+@interface NSMutableString (StringExtension)
+- (std::string)toCppString;
++ (NSMutableString *)fromCppString:(std::string)string;
+@end

package/ios/utils/StringExtension.mm

@@ -0,0 +1,57 @@
+#import "StringExtension.h"
+
+@implementation NSString (StringExtension)
+
+- (std::string)toCppString {
+  return std::string([self UTF8String]);
+}
+
++ (NSString *)fromCppString:(std::string)string {
+  return [NSString stringWithUTF8String:string.c_str()];
+}
+
++ (NSString *)stringByEscapingHtml:(NSString *)html {
+  NSMutableString *escaped = [html mutableCopy];
+  NSDictionary *escapeMap = @{
+    @"&": @"&",
+    @"<": @"&lt;",
+    @">": @"&gt;",
+    @"\"": @"&quot;",
+    @"'": @"&apos;"
+  };
+  
+  for(NSString *key in escapeMap) {
+    [escaped replaceOccurrencesOfString:key withString:escapeMap[key] options:NSLiteralSearch range:NSMakeRange(0, escaped.length)];
+  }
+  return escaped;
+}
+
++ (NSString *)stringByUnescapingHtml:(NSString *)html {
+  NSMutableString *unescaped = [html mutableCopy];
+  NSDictionary *unescapeMap = @{
+    @"&amp;": @"&",
+    @"&lt;": @"<",
+    @"&gt;": @">",
+    @"&quot;": @"\"",
+    @"&apos;": @"'",
+  };
+  
+  for(NSString *key in unescapeMap) {
+    [unescaped replaceOccurrencesOfString:key withString:unescapeMap[key] options:NSLiteralSearch range:NSMakeRange(0, unescaped.length)];
+  }
+  return unescaped;
+}
+
+@end
+
+@implementation NSMutableString (StringExtension)
+
+- (std::string)toCppString {
+  return std::string([self UTF8String]);
+}
+
++ (NSMutableString *)fromCppString:(std::string)string {
+  return [NSMutableString stringWithUTF8String:string.c_str()];
+}
+
+@end

package/ios/utils/StyleHeaders.h

@@ -0,0 +1,74 @@
+#pragma once
+#import "BaseStyleProtocol.h"
+#import "LinkData.h"
+#import "MentionParams.h"
+
+@interface BoldStyle : NSObject <BaseStyleProtocol>
+@end
+
+@interface ItalicStyle : NSObject <BaseStyleProtocol>
+@end
+
+@interface UnderlineStyle : NSObject <BaseStyleProtocol>
+@end
+
+@interface StrikethroughStyle : NSObject <BaseStyleProtocol>
+@end
+
+@interface InlineCodeStyle : NSObject <BaseStyleProtocol>
+- (void)handleNewlines;
+@end
+
+@interface LinkStyle : NSObject <BaseStyleProtocol>
+- (void)addLink:(NSString*)text url:(NSString*)url range:(NSRange)range manual:(BOOL)manual;
+- (LinkData *)getLinkDataAt:(NSUInteger)location;
+- (NSRange)getFullLinkRangeAt:(NSUInteger)location;
+- (void)manageLinkTypingAttributes;
+- (void)handleAutomaticLinks:(NSString *)word inRange:(NSRange)wordRange;
+- (void)handleManualLinks:(NSString *)word inRange:(NSRange)wordRange;
+- (BOOL)handleLeadingLinkReplacement:(NSRange)range replacementText:(NSString *)text;
+@end
+
+@interface MentionStyle : NSObject<BaseStyleProtocol>
+- (void)addMention:(NSString *)indicator text:(NSString *)text attributes:(NSString *)attributes;
+- (void)addMentionAtRange:(NSRange)range params:(MentionParams *)params;
+- (void)startMentionWithIndicator:(NSString *)indicator;
+- (void)handleExistingMentions;
+- (void)manageMentionEditing;
+- (void)manageMentionTypingAttributes;
+- (BOOL)handleLeadingMentionReplacement:(NSRange)range replacementText:(NSString *)text;
+- (MentionParams *)getMentionParamsAt:(NSUInteger)location;
+- (NSRange)getFullMentionRangeAt:(NSUInteger)location;
+- (NSValue *)getActiveMentionRange;
+@end
+
+@interface HeadingStyleBase : NSObject<BaseStyleProtocol> {
+  id input;
+}
+- (CGFloat)getHeadingFontSize;
+- (BOOL)isHeadingBold;
+@end
+
+@interface H1Style : HeadingStyleBase
+@end
+
+@interface H2Style : HeadingStyleBase
+@end
+
+@interface H3Style : HeadingStyleBase
+@end
+
+@interface UnorderedListStyle : NSObject<BaseStyleProtocol>
+- (BOOL)handleBackspaceInRange:(NSRange)range replacementText:(NSString *)text;
+- (BOOL)tryHandlingListShorcutInRange:(NSRange)range replacementText:(NSString *)text;
+@end
+
+@interface OrderedListStyle : NSObject<BaseStyleProtocol>
+- (BOOL)handleBackspaceInRange:(NSRange)range replacementText:(NSString *)text;
+- (BOOL)tryHandlingListShorcutInRange:(NSRange)range replacementText:(NSString *)text;
+@end
+
+@interface BlockQuoteStyle : NSObject<BaseStyleProtocol>
+- (BOOL)handleBackspaceInRange:(NSRange)range replacementText:(NSString *)text;
+- (void)manageBlockquoteColor;
+@end

package/ios/utils/StylePair.h

@@ -0,0 +1,9 @@
+#pragma once
+#import <UIkit/UIKit.h>
+
+@interface StylePair : NSObject
+
+@property NSValue *rangeValue;
+@property id styleValue;
+
+@end

package/ios/utils/StylePair.mm

@@ -0,0 +1,4 @@
+#import "StylePair.h"
+
+@implementation StylePair
+@end

package/ios/utils/StyleTypeEnum.h

@@ -0,0 +1,22 @@
+#pragma once
+#import <UIKit/UIKit.h>
+
+// the order is aligned with the order of tags in parser
+typedef NS_ENUM(NSInteger, StyleType) {
+  BlockQuote,
+  CodeBlock,
+  UnorderedList,
+  OrderedList,
+  H1,
+  H2,
+  H3,
+  Link,
+  Mention,
+  Image,
+  InlineCode,
+  Bold,
+  Italic,
+  Underline,
+  Strikethrough,
+  None,
+};