react-native-daro 1.0.15 → 1.0.16

package/ios/Fabric/DaroMFabricEventSink.mm

@@ -0,0 +1,31 @@
+#import <React/RCTDefines.h>
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
+#import <Foundation/Foundation.h>
+#include <string>
+
+NSDictionary *DaroMFabricEventBody(NSDictionary *body)
+{
+  return [body isKindOfClass:NSDictionary.class] ? body : @{};
+}
+
+std::string DaroMFabricEventString(NSDictionary *body, NSString *key)
+{
+  id value = body[key];
+  return [value isKindOfClass:NSString.class] ? std::string([value UTF8String]) : "";
+}
+
+double DaroMFabricEventDouble(NSDictionary *body, NSString *key)
+{
+  id value = body[key];
+  return [value respondsToSelector:@selector(doubleValue)] ? [value doubleValue] : 0;
+}
+
+int DaroMFabricEventInt(NSDictionary *body, NSString *key)
+{
+  id value = body[key];
+  return [value respondsToSelector:@selector(intValue)] ? [value intValue] : 0;
+}
+
+#endif

package/ios/Fabric/DaroMFabricPropApplier.mm

@@ -0,0 +1,123 @@
+#import <React/RCTDefines.h>
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
+#import <React/RCTLog.h>
+#import <UIKit/UIKit.h>
+#include <folly/dynamic.h>
+#include <string>
+
+static NSString *DaroMFabricSetterNameForKey(NSString *key)
+{
+  if (key.length == 0) {
+    return nil;
+  }
+
+  NSString *first = [[key substringToIndex:1] uppercaseString];
+  NSString *rest = [key substringFromIndex:1];
+  return [NSString stringWithFormat:@"set%@%@:", first, rest];
+}
+
+void DaroMFabricSetValue(UIView *view, NSString *key, id value)
+{
+  SEL setter = NSSelectorFromString(DaroMFabricSetterNameForKey(key));
+  if (![view respondsToSelector:setter]) {
+    return;
+  }
+
+  [view setValue:value forKey:key];
+}
+
+void DaroMFabricPerformSelector(UIView *view, SEL selector)
+{
+  if (![view respondsToSelector:selector]) {
+    return;
+  }
+
+  IMP imp = [view methodForSelector:selector];
+  auto function = reinterpret_cast<void (*)(id, SEL)>(imp);
+  function(view, selector);
+}
+
+void DaroMFabricPerformSelectorWithObject(UIView *view, SEL selector, id object)
+{
+  if (![view respondsToSelector:selector]) {
+    return;
+  }
+
+  IMP imp = [view methodForSelector:selector];
+  auto function = reinterpret_cast<void (*)(id, SEL, id)>(imp);
+  function(view, selector, object);
+}
+
+void DaroMFabricPerformSelectorWithTwoObjects(UIView *view, SEL selector, id firstObject, id secondObject)
+{
+  if (![view respondsToSelector:selector]) {
+    return;
+  }
+
+  IMP imp = [view methodForSelector:selector];
+  auto function = reinterpret_cast<void (*)(id, SEL, id, id)>(imp);
+  function(view, selector, firstObject, secondObject);
+}
+
+UIView *DaroMFabricCreateSwiftView(NSString *className)
+{
+  Class viewClass = NSClassFromString(className);
+  if (![viewClass isSubclassOfClass:UIView.class]) {
+    RCTLogError(@"%@ is not available as a UIView subclass.", className);
+    return [UIView new];
+  }
+
+  return [[viewClass alloc] init];
+}
+
+NSString *DaroMFabricNSStringFromStdString(const std::string &value)
+{
+  return [NSString stringWithUTF8String:value.c_str()];
+}
+
+static id DaroMFabricNSObjectFromDynamic(const folly::dynamic &value)
+{
+  switch (value.type()) {
+    case folly::dynamic::NULLT:
+      return (id)kCFNull;
+    case folly::dynamic::BOOL:
+      return value.getBool() ? @YES : @NO;
+    case folly::dynamic::INT64:
+      return @(value.getInt());
+    case folly::dynamic::DOUBLE:
+      return @(value.getDouble());
+    case folly::dynamic::STRING:
+      return [[NSString alloc] initWithBytes:value.c_str() length:value.size() encoding:NSUTF8StringEncoding];
+    case folly::dynamic::ARRAY: {
+      NSMutableArray *array = [[NSMutableArray alloc] initWithCapacity:value.size()];
+      for (const auto &item : value) {
+        id converted = DaroMFabricNSObjectFromDynamic(item);
+        if (converted != nil) {
+          [array addObject:converted];
+        }
+      }
+      return array;
+    }
+    case folly::dynamic::OBJECT: {
+      NSMutableDictionary *dictionary = [[NSMutableDictionary alloc] initWithCapacity:value.size()];
+      for (const auto &item : value.items()) {
+        id key = DaroMFabricNSObjectFromDynamic(item.first);
+        id converted = DaroMFabricNSObjectFromDynamic(item.second);
+        if (key != nil && converted != nil && [key conformsToProtocol:@protocol(NSCopying)]) {
+          dictionary[key] = converted;
+        }
+      }
+      return dictionary;
+    }
+  }
+}
+
+id DaroMFabricIdFromDynamic(const folly::dynamic &value)
+{
+  id converted = DaroMFabricNSObjectFromDynamic(value);
+  return converted == (id)kCFNull ? nil : converted;
+}
+
+#endif

package/ios/Fabric/DaroMNativeAdComponentView.mm

@@ -0,0 +1,294 @@
+#import <React/RCTDefines.h>
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
+#import <React/RCTComponent.h>
+#import <React/RCTFabricComponentsPlugins.h>
+#import <React/RCTViewComponentView.h>
+#import <react/renderer/components/DaroReactNativeSpec/ComponentDescriptors.h>
+#import <react/renderer/components/DaroReactNativeSpec/EventEmitters.h>
+#import <react/renderer/components/DaroReactNativeSpec/Props.h>
+#import <react/renderer/components/DaroReactNativeSpec/RCTComponentViewHelpers.h>
+#include <folly/dynamic.h>
+#include <string>
+
+using namespace facebook::react;
+
+extern UIView *DaroMFabricCreateSwiftView(NSString *className);
+extern void DaroMFabricSetValue(UIView *view, NSString *key, id value);
+extern void DaroMFabricPerformSelector(UIView *view, SEL selector);
+extern void DaroMFabricPerformSelectorWithObject(UIView *view, SEL selector, id object);
+extern void DaroMFabricPerformSelectorWithTwoObjects(UIView *view, SEL selector, id firstObject, id secondObject);
+extern NSString *DaroMFabricNSStringFromStdString(const std::string &value);
+extern id DaroMFabricIdFromDynamic(const folly::dynamic &value);
+extern NSDictionary *DaroMFabricEventBody(NSDictionary *body);
+extern std::string DaroMFabricEventString(NSDictionary *body, NSString *key);
+extern double DaroMFabricEventDouble(NSDictionary *body, NSString *key);
+extern int DaroMFabricEventInt(NSDictionary *body, NSString *key);
+
+static NSString *DaroMFabricAdChoicesPositionString(DaroMNativeAdViewAdChoicesPosition position)
+{
+  switch (position) {
+    case DaroMNativeAdViewAdChoicesPosition::TopLeft:
+      return @"topLeft";
+    case DaroMNativeAdViewAdChoicesPosition::TopRight:
+      return @"topRight";
+    case DaroMNativeAdViewAdChoicesPosition::BottomLeft:
+      return @"bottomLeft";
+    case DaroMNativeAdViewAdChoicesPosition::BottomRight:
+    default:
+      return @"bottomRight";
+  }
+}
+
+@interface DaroMNativeAdViewComponentView : RCTViewComponentView <RCTDaroMNativeAdViewViewProtocol>
+@end
+
+@implementation DaroMNativeAdViewComponentView {
+  UIView *_nativeAdView;
+}
+
++ (void)load
+{
+  [super load];
+}
+
+- (instancetype)initWithFrame:(CGRect)frame
+{
+  if (self = [super initWithFrame:frame]) {
+    static const auto defaultProps = std::make_shared<const DaroMNativeAdViewProps>();
+    _props = defaultProps;
+    [self createNativeAdView];
+  }
+
+  return self;
+}
+
+- (void)createNativeAdView
+{
+  _nativeAdView = DaroMFabricCreateSwiftView(@"RNDaroMNativeAdView");
+  _nativeAdView.frame = self.bounds;
+  _nativeAdView.autoresizingMask = UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
+  DaroMFabricPerformSelectorWithObject(_nativeAdView, NSSelectorFromString(@"setAssetSearchRootView:"), _nativeAdView);
+  [self addSubview:_nativeAdView];
+  [self installEventHandlers];
+}
+
+- (void)installEventHandlers
+{
+  __weak DaroMNativeAdViewComponentView *weakSelf = self;
+
+  RCTDirectEventBlock onAdLoadedEvent = ^(NSDictionary *body) {
+    DaroMNativeAdViewComponentView *strongSelf = weakSelf;
+    if (!strongSelf) {
+      return;
+    }
+
+    auto eventEmitter = std::static_pointer_cast<const DaroMNativeAdViewEventEmitter>(strongSelf->_eventEmitter);
+    if (!eventEmitter) {
+      return;
+    }
+
+    NSDictionary *eventBody = DaroMFabricEventBody(body);
+    eventEmitter->onAdLoadedEvent({
+        .adUnitId = DaroMFabricEventString(eventBody, @"adUnitId"),
+        .latencyMillis = DaroMFabricEventDouble(eventBody, @"latencyMillis"),
+    });
+  };
+
+  RCTDirectEventBlock onAdLoadFailedEvent = ^(NSDictionary *body) {
+    DaroMNativeAdViewComponentView *strongSelf = weakSelf;
+    if (!strongSelf) {
+      return;
+    }
+
+    auto eventEmitter = std::static_pointer_cast<const DaroMNativeAdViewEventEmitter>(strongSelf->_eventEmitter);
+    if (!eventEmitter) {
+      return;
+    }
+
+    NSDictionary *eventBody = DaroMFabricEventBody(body);
+    eventEmitter->onAdLoadFailedEvent({
+        .adUnitId = DaroMFabricEventString(eventBody, @"adUnitId"),
+        .code = DaroMFabricEventInt(eventBody, @"code"),
+        .message = DaroMFabricEventString(eventBody, @"message"),
+        .latencyMillis = DaroMFabricEventDouble(eventBody, @"latencyMillis"),
+    });
+  };
+
+  RCTDirectEventBlock onAdClickedEvent = ^(NSDictionary *body) {
+    DaroMNativeAdViewComponentView *strongSelf = weakSelf;
+    if (!strongSelf) {
+      return;
+    }
+
+    auto eventEmitter = std::static_pointer_cast<const DaroMNativeAdViewEventEmitter>(strongSelf->_eventEmitter);
+    if (!eventEmitter) {
+      return;
+    }
+
+    NSDictionary *eventBody = DaroMFabricEventBody(body);
+    eventEmitter->onAdClickedEvent({
+        .adUnitId = DaroMFabricEventString(eventBody, @"adUnitId"),
+        .latencyMillis = DaroMFabricEventDouble(eventBody, @"latencyMillis"),
+    });
+  };
+
+  RCTDirectEventBlock onAdImpressionRecordedEvent = ^(NSDictionary *body) {
+    DaroMNativeAdViewComponentView *strongSelf = weakSelf;
+    if (!strongSelf) {
+      return;
+    }
+
+    auto eventEmitter = std::static_pointer_cast<const DaroMNativeAdViewEventEmitter>(strongSelf->_eventEmitter);
+    if (!eventEmitter) {
+      return;
+    }
+
+    NSDictionary *eventBody = DaroMFabricEventBody(body);
+    eventEmitter->onAdImpressionRecordedEvent({
+        .adUnitId = DaroMFabricEventString(eventBody, @"adUnitId"),
+        .latencyMillis = DaroMFabricEventDouble(eventBody, @"latencyMillis"),
+    });
+  };
+
+  DaroMFabricSetValue(_nativeAdView, @"onAdLoadedEvent", onAdLoadedEvent);
+  DaroMFabricSetValue(_nativeAdView, @"onAdLoadFailedEvent", onAdLoadFailedEvent);
+  DaroMFabricSetValue(_nativeAdView, @"onAdClickedEvent", onAdClickedEvent);
+  DaroMFabricSetValue(_nativeAdView, @"onAdImpressionRecordedEvent", onAdImpressionRecordedEvent);
+}
+
++ (ComponentDescriptorProvider)componentDescriptorProvider
+{
+  return concreteComponentDescriptorProvider<DaroMNativeAdViewComponentDescriptor>();
+}
+
+- (void)updateProps:(const Props::Shared &)props oldProps:(const Props::Shared &)oldProps
+{
+  const auto &oldComponentProps = *std::static_pointer_cast<const DaroMNativeAdViewProps>(_props);
+  const auto &newComponentProps = *std::static_pointer_cast<const DaroMNativeAdViewProps>(props);
+  NSMutableArray<NSString *> *changedProps = [NSMutableArray new];
+
+  if (oldComponentProps.adUnitId != newComponentProps.adUnitId) {
+    DaroMFabricSetValue(_nativeAdView, @"adUnitId", DaroMFabricNSStringFromStdString(newComponentProps.adUnitId));
+    [changedProps addObject:@"adUnitId"];
+  }
+
+  if (oldComponentProps.loadOnMount != newComponentProps.loadOnMount) {
+    DaroMFabricSetValue(_nativeAdView, @"loadOnMount", @(newComponentProps.loadOnMount));
+    [changedProps addObject:@"loadOnMount"];
+  }
+
+  if (oldComponentProps.adChoicesPosition != newComponentProps.adChoicesPosition) {
+    DaroMFabricSetValue(
+        _nativeAdView, @"adChoicesPosition", DaroMFabricAdChoicesPositionString(newComponentProps.adChoicesPosition));
+    [changedProps addObject:@"adChoicesPosition"];
+  }
+
+  if (oldComponentProps.titleView != newComponentProps.titleView) {
+    DaroMFabricSetValue(_nativeAdView, @"titleView", @(newComponentProps.titleView));
+    [changedProps addObject:@"titleView"];
+  }
+
+  if (oldComponentProps.bodyView != newComponentProps.bodyView) {
+    DaroMFabricSetValue(_nativeAdView, @"bodyView", @(newComponentProps.bodyView));
+    [changedProps addObject:@"bodyView"];
+  }
+
+  if (oldComponentProps.callToActionView != newComponentProps.callToActionView) {
+    DaroMFabricSetValue(_nativeAdView, @"callToActionView", @(newComponentProps.callToActionView));
+    [changedProps addObject:@"callToActionView"];
+  }
+
+  if (oldComponentProps.iconView != newComponentProps.iconView) {
+    DaroMFabricSetValue(_nativeAdView, @"iconView", @(newComponentProps.iconView));
+    [changedProps addObject:@"iconView"];
+  }
+
+  if (oldComponentProps.mediaView != newComponentProps.mediaView) {
+    DaroMFabricSetValue(_nativeAdView, @"mediaView", @(newComponentProps.mediaView));
+    [changedProps addObject:@"mediaView"];
+  }
+
+  if (oldComponentProps.titleViewStyleProps != newComponentProps.titleViewStyleProps) {
+    DaroMFabricSetValue(_nativeAdView, @"titleViewStyleProps", DaroMFabricIdFromDynamic(newComponentProps.titleViewStyleProps));
+    [changedProps addObject:@"titleViewStyleProps"];
+  }
+
+  if (oldComponentProps.bodyViewStyleProps != newComponentProps.bodyViewStyleProps) {
+    DaroMFabricSetValue(_nativeAdView, @"bodyViewStyleProps", DaroMFabricIdFromDynamic(newComponentProps.bodyViewStyleProps));
+    [changedProps addObject:@"bodyViewStyleProps"];
+  }
+
+  if (oldComponentProps.callToActionViewStyleProps != newComponentProps.callToActionViewStyleProps) {
+    DaroMFabricSetValue(
+        _nativeAdView, @"callToActionViewStyleProps", DaroMFabricIdFromDynamic(newComponentProps.callToActionViewStyleProps));
+    [changedProps addObject:@"callToActionViewStyleProps"];
+  }
+
+  if (oldComponentProps.iconViewStyleProps != newComponentProps.iconViewStyleProps) {
+    DaroMFabricSetValue(_nativeAdView, @"iconViewStyleProps", DaroMFabricIdFromDynamic(newComponentProps.iconViewStyleProps));
+    [changedProps addObject:@"iconViewStyleProps"];
+  }
+
+  if (oldComponentProps.mediaViewStyleProps != newComponentProps.mediaViewStyleProps) {
+    DaroMFabricSetValue(_nativeAdView, @"mediaViewStyleProps", DaroMFabricIdFromDynamic(newComponentProps.mediaViewStyleProps));
+    [changedProps addObject:@"mediaViewStyleProps"];
+  }
+
+  [super updateProps:props oldProps:oldProps];
+
+  DaroMFabricPerformSelectorWithObject(_nativeAdView, NSSelectorFromString(@"applyReactProps:"), changedProps);
+}
+
+- (void)updateLayoutMetrics:(const LayoutMetrics &)layoutMetrics oldLayoutMetrics:(const LayoutMetrics &)oldLayoutMetrics
+{
+  [super updateLayoutMetrics:layoutMetrics oldLayoutMetrics:oldLayoutMetrics];
+  _nativeAdView.frame = self.bounds;
+}
+
+- (void)mountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index
+{
+  DaroMFabricPerformSelectorWithTwoObjects(
+      _nativeAdView, NSSelectorFromString(@"insertMountedSubview:atIndex:"), childComponentView, @(index));
+}
+
+- (void)unmountChildComponentView:(UIView<RCTComponentViewProtocol> *)childComponentView index:(NSInteger)index
+{
+  [childComponentView removeFromSuperview];
+  DaroMFabricPerformSelector(_nativeAdView, NSSelectorFromString(@"refreshMountedAssetViews"));
+}
+
+- (void)loadAd
+{
+  DaroMFabricPerformSelector(_nativeAdView, NSSelectorFromString(@"loadAd"));
+}
+
+- (void)handleCommand:(const NSString *)commandName args:(const NSArray *)args
+{
+  RCTDaroMNativeAdViewHandleCommand(self, commandName, args);
+}
+
+- (void)prepareForRecycle
+{
+  [super prepareForRecycle];
+  DaroMFabricSetValue(_nativeAdView, @"onAdLoadedEvent", nil);
+  DaroMFabricSetValue(_nativeAdView, @"onAdLoadFailedEvent", nil);
+  DaroMFabricSetValue(_nativeAdView, @"onAdClickedEvent", nil);
+  DaroMFabricSetValue(_nativeAdView, @"onAdImpressionRecordedEvent", nil);
+  DaroMFabricPerformSelectorWithObject(_nativeAdView, NSSelectorFromString(@"setAssetSearchRootView:"), nil);
+  DaroMFabricPerformSelector(_nativeAdView, NSSelectorFromString(@"prepareForReuse"));
+  DaroMFabricPerformSelectorWithObject(_nativeAdView, NSSelectorFromString(@"setAssetSearchRootView:"), _nativeAdView);
+  [self installEventHandlers];
+  static const auto defaultProps = std::make_shared<const DaroMNativeAdViewProps>();
+  _props = defaultProps;
+}
+
+@end
+
+Class<RCTComponentViewProtocol> DaroMNativeAdViewCls(void)
+{
+  return DaroMNativeAdViewComponentView.class;
+}
+
+#endif

package/ios/{DaroMAdBannerViewManager.m → Paper/DaroMAdBannerViewManager.m}

@@ -4,12 +4,14 @@
 
 RCT_EXPORT_VIEW_PROPERTY(adUnitId, NSString)
 RCT_EXPORT_VIEW_PROPERTY(adFormat, NSString)
+RCT_EXPORT_VIEW_PROPERTY(loadOnMount, BOOL)
+RCT_EXPORT_VIEW_PROPERTY(isVisible, BOOL)
 
 RCT_EXPORT_VIEW_PROPERTY(onAdLoadedEvent, RCTDirectEventBlock)
 RCT_EXPORT_VIEW_PROPERTY(onAdLoadFailedEvent, RCTDirectEventBlock)
 RCT_EXPORT_VIEW_PROPERTY(onAdClickedEvent, RCTDirectEventBlock)
 RCT_EXPORT_VIEW_PROPERTY(onAdImpressionRecordedEvent, RCTDirectEventBlock)
 
-RCT_EXTERN_METHOD(loadAd)
+RCT_EXTERN_METHOD(loadAd : (nonnull NSNumber *)viewTag)
 
 @end

package/ios/Paper/DaroMAdBannerViewManager.swift

@@ -0,0 +1,21 @@
+import React
+
+@objc(DaroMAdBannerViewManager)
+class DaroMAdBannerViewManager: RCTViewManager {
+  override func view() -> DaroMAdBannerView {
+    DaroMAdBannerView()
+  }
+
+  @objc override static func requiresMainQueueSetup() -> Bool {
+    false
+  }
+
+  @objc(loadAd:)
+  func loadAd(viewTag: NSNumber) {
+    bridge?.uiManager.addUIBlock({ _, viewRegistry in
+      if let view = viewRegistry?[viewTag] as? DaroMAdBannerView {
+        view.loadAd()
+      }
+    })
+  }
+}

package/ios/{DaroMNativeAdViewManager.m → Paper/DaroMNativeAdViewManager.m}

@@ -3,12 +3,13 @@
 @interface RCT_EXTERN_MODULE (DaroMNativeAdViewManager, RCTViewManager)
 
 RCT_EXPORT_VIEW_PROPERTY(adUnitId, NSString)
+RCT_EXPORT_VIEW_PROPERTY(loadOnMount, BOOL)
+RCT_EXPORT_VIEW_PROPERTY(adChoicesPosition, NSString)
 
 RCT_EXPORT_VIEW_PROPERTY(titleView, NSNumber)
 RCT_EXPORT_VIEW_PROPERTY(bodyView, NSNumber)
 RCT_EXPORT_VIEW_PROPERTY(callToActionView, NSNumber)
 RCT_EXPORT_VIEW_PROPERTY(iconView, NSNumber)
-RCT_EXPORT_VIEW_PROPERTY(optionsView, NSNumber)
 RCT_EXPORT_VIEW_PROPERTY(mediaView, NSNumber)
 
 RCT_EXPORT_VIEW_PROPERTY(titleViewStyleProps, NSDictionary)

package/ios/Paper/DaroMNativeAdViewManager.swift

@@ -0,0 +1,22 @@
+import React
+import UIKit
+
+@objc(DaroMNativeAdViewManager)
+class DaroMNativeAdViewManager: RCTViewManager {
+  override func view() -> RNDaroMNativeAdView {
+    RNDaroMNativeAdView(assetResolver: DaroMBridgeNativeAssetResolver(bridge: bridge))
+  }
+
+  @objc override static func requiresMainQueueSetup() -> Bool {
+    false
+  }
+
+  @objc(loadAd:)
+  func loadAd(viewTag: NSNumber) {
+    bridge?.uiManager.addUIBlock({ _, viewRegistry in
+      if let view = viewRegistry?[viewTag] as? RNDaroMNativeAdView {
+        view.loadAd()
+      }
+    })
+  }
+}

package/ios/Shared/DaroMAdEventSink.swift

@@ -0,0 +1,24 @@
+import React
+
+final class DaroMAdEventSink {
+  var onAdLoadedEvent: RCTDirectEventBlock?
+  var onAdLoadFailedEvent: RCTDirectEventBlock?
+  var onAdClickedEvent: RCTDirectEventBlock?
+  var onAdImpressionRecordedEvent: RCTDirectEventBlock?
+
+  func emitAdLoaded(_ body: [AnyHashable: Any]?) {
+    onAdLoadedEvent?(body)
+  }
+
+  func emitAdLoadFailed(_ body: [AnyHashable: Any]?) {
+    onAdLoadFailedEvent?(body)
+  }
+
+  func emitAdClicked(_ body: [AnyHashable: Any]?) {
+    onAdClickedEvent?(body)
+  }
+
+  func emitAdImpressionRecorded(_ body: [AnyHashable: Any]?) {
+    onAdImpressionRecordedEvent?(body)
+  }
+}