react-native-audio-api 0.11.0-alpha.1 → 0.11.0-alpha.10

package/ios/audioapi/ios/core/IOSAudioFileOptions.h

@@ -1,36 +0,0 @@
-#pragma once
-
-#ifndef __OBJC__ // when compiled as C++
-typedef struct objc_object AVAudioFile;
-typedef struct objc_object NSURL;
-typedef struct objc_object AudioBufferList;
-#endif // __OBJC__
-
-namespace audioapi {
-
-class IOSAudioFileOptions {
- public:
-  IOSAudioFileOptions(float sampleRate, size_t channelCount, size_t bitRate, size_t flags);
-  ~IOSAudioFileOptions() = default;
-
-  AudioFormatID getFormat() const;
-  NSInteger getQuality() const;
-  NSInteger getFlacCompressionLevel() const;
-  NSSearchPathDirectory getDirectory() const;
-  NSString *getFileExtension() const;
-  NSInteger getBitDepth() const;
-  NSDictionary *getFileSettings();
-  float getSampleRate();
-
- private:
-  uint8_t format_;
-  uint8_t quality_;
-  uint8_t flacCompressionLevel_;
-  uint8_t directory_;
-  uint8_t bitDepth_;
-  float sampleRate_;
-  size_t channelCount_;
-  size_t bitRate_;
-};
-
-} // namespace audioapi

package/ios/audioapi/ios/core/IOSAudioFileOptions.mm

@@ -1,140 +0,0 @@
-#import <AVFoundation/AVFoundation.h>
-#import <Foundation/Foundation.h>
-
-#include <audioapi/ios/core/IOSAudioFileOptions.h>
-
-namespace audioapi {
-
-IOSAudioFileOptions::IOSAudioFileOptions(float sampleRate, size_t channelCount, size_t bitRate, size_t flags)
-{
-  sampleRate_ = sampleRate;
-  channelCount_ = channelCount;
-  bitRate_ = bitRate;
-
-  format_ = static_cast<uint8_t>(((flags >> 0) & 0xF));
-  quality_ = static_cast<uint8_t>(((flags >> 4) & 0xF));
-  flacCompressionLevel_ = static_cast<uint8_t>(((flags >> 8) & 0xF));
-  directory_ = static_cast<uint8_t>(((flags >> 12) & 0xF));
-  bitDepth_ = static_cast<uint8_t>(((flags >> 16) & 0xF));
-}
-
-AudioFormatID IOSAudioFileOptions::getFormat() const
-{
-  switch (format_) {
-    case 1:
-      return kAudioFormatLinearPCM; // WAV <-> Linear PCM container
-    case 2:
-      return kAudioFormatLinearPCM; // CAF <-> Linear PCM container
-    case 3:
-      return kAudioFormatMPEG4AAC; // M4A <-> AAC
-    case 4:
-      return kAudioFormatFLAC; // FLAC <-> FLAC
-    default:
-      return kAudioFormatLinearPCM; // Default to Linear PCM
-  }
-}
-
-NSInteger IOSAudioFileOptions::getQuality() const
-{
-  switch (quality_) {
-    case 1:
-      return AVAudioQualityMin;
-    case 2:
-      return AVAudioQualityLow;
-    case 3:
-      return AVAudioQualityMedium;
-    case 4:
-      return AVAudioQualityHigh;
-    case 5:
-      return AVAudioQualityMax;
-    default:
-      return AVAudioQualityMedium; // Default to Medium
-  }
-}
-
-NSInteger IOSAudioFileOptions::getFlacCompressionLevel() const
-{
-  // Shift the quality from 1-9 to 0-8 for real values
-  // Default to 5 if out of range
-  return (flacCompressionLevel_ >= 1 && flacCompressionLevel_ <= 9) ? flacCompressionLevel_ - 1 : 5;
-}
-
-NSSearchPathDirectory IOSAudioFileOptions::getDirectory() const
-{
-  switch (directory_) {
-    case 1:
-      return NSDocumentDirectory;
-    case 2:
-      return NSCachesDirectory;
-    default:
-      return NSCachesDirectory; // Default to Caches
-  }
-}
-
-NSString *IOSAudioFileOptions::getFileExtension() const
-{
-  switch (format_) {
-    case 1:
-      return @"wav"; // WAV <-> Linear PCM container
-    case 2:
-      return @"caf"; // CAF <-> Linear PCM container
-    case 3:
-      return @"m4a"; // M4A <-> AAC
-    case 4:
-      return @"flac"; // FLAC <-> FLAC
-    default:
-      return @"wav"; // Default to WAV
-  }
-}
-
-NSInteger IOSAudioFileOptions::getBitDepth() const
-{
-  switch (bitDepth_) {
-    case 1:
-      return 16;
-    case 2:
-      return 24;
-    case 3:
-      return 32;
-    default:
-      return 24; // Default to 24-bit
-  }
-}
-
-NSDictionary *IOSAudioFileOptions::getFileSettings()
-{
-  AudioFormatID format = getFormat();
-  NSMutableDictionary *settings = [NSMutableDictionary dictionary];
-
-  settings[AVFormatIDKey] = @(format);
-  settings[AVSampleRateKey] = @(sampleRate_);
-  settings[AVNumberOfChannelsKey] = @(channelCount_);
-
-  settings[AVEncoderAudioQualityKey] = @(getQuality());
-
-  if (format == kAudioFormatMPEG4AAC) {
-    settings[AVEncoderBitRateKey] = @(bitRate_);
-  }
-
-  if (format == kAudioFormatLinearPCM) {
-    NSInteger bitDepth = getBitDepth();
-
-    settings[AVLinearPCMBitDepthKey] = @(bitDepth);
-    settings[AVLinearPCMIsFloatKey] = @(bitDepth == 32);
-    settings[AVLinearPCMIsBigEndianKey] = @(NO);
-    settings[AVLinearPCMIsNonInterleaved] = @(NO);
-  }
-
-  if (format == kAudioFormatFLAC) {
-    settings[@"FLACCompressionLevel"] = @(getFlacCompressionLevel());
-  }
-
-  return settings;
-}
-
-float IOSAudioFileOptions::getSampleRate()
-{
-  return sampleRate_;
-}
-
-} // namespace audioapi

package/ios/audioapi/ios/core/IOSAudioFileWriter.mm

@@ -1,223 +0,0 @@
-#import <AVFoundation/AVFoundation.h>
-#import <Foundation/Foundation.h>
-
-#include <audioapi/ios/core/IOSAudioFileOptions.h>
-#include <audioapi/ios/core/IOSAudioFileWriter.h>
-
-constexpr double BYTES_TO_MB = 1024.0 * 1024.0;
-
-namespace audioapi {
-IOSAudioFileWriter::IOSAudioFileWriter(float sampleRate, size_t channelCount, size_t bitRate, size_t iosFlags)
-{
-  fileOptions_ = std::make_shared<IOSAudioFileOptions>(sampleRate, channelCount, bitRate, iosFlags);
-}
-
-IOSAudioFileWriter::~IOSAudioFileWriter()
-{
-  fileURL_ = nil;
-  audioFile_ = nil;
-  converter_ = nil;
-  bufferFormat_ = nil;
-}
-
-std::string IOSAudioFileWriter::openFile(AVAudioFormat *bufferFormat, size_t maxInputBufferLength)
-{
-  @autoreleasepool {
-    if (audioFile_ != nil) {
-      NSLog(@"⚠️ createFileForWriting: currentAudioFile_ already exists");
-      return "";
-    }
-    framesWritten_.store(0);
-
-    bufferFormat_ = bufferFormat;
-
-    NSError *error = nil;
-    NSDictionary *settings = fileOptions_->getFileSettings();
-    fileURL_ = getFileURL();
-
-    NSLog(@"ℹ️ Creating audio file at URL: %@", [fileURL_ absoluteString]);
-
-    audioFile_ = [[AVAudioFile alloc] initForWriting:fileURL_
-                                            settings:settings
-                                        commonFormat:AVAudioPCMFormatFloat32
-                                         interleaved:bufferFormat.interleaved
-                                               error:&error];
-    converter_ = [[AVAudioConverter alloc] initFromFormat:bufferFormat toFormat:[audioFile_ processingFormat]];
-    converter_.sampleRateConverterAlgorithm = AVSampleRateConverterAlgorithm_Normal;
-    converter_.sampleRateConverterQuality = AVAudioQualityMax;
-    converter_.primeMethod = AVAudioConverterPrimeMethod_None;
-
-    converterInputBufferSize_ = maxInputBufferLength;
-    converterOutputBufferSize_ = std::max(
-        (double)maxInputBufferLength, fileOptions_->getSampleRate() / bufferFormat.sampleRate * maxInputBufferLength);
-
-    converterInputBuffer_ = [[AVAudioPCMBuffer alloc] initWithPCMFormat:bufferFormat
-                                                          frameCapacity:(AVAudioFrameCount)maxInputBufferLength];
-    converterOutputBuffer_ = [[AVAudioPCMBuffer alloc] initWithPCMFormat:[audioFile_ processingFormat]
-                                                           frameCapacity:(AVAudioFrameCount)maxInputBufferLength];
-
-    if (error != nil || audioFile_ == nil) {
-      NSLog(@"Error creating audio file for writing: %@", [error debugDescription]);
-      audioFile_ = nil;
-
-      return "";
-    }
-
-    return [[fileURL_ path] UTF8String];
-  }
-}
-
-std::tuple<double, double> IOSAudioFileWriter::closeFile()
-{
-  @autoreleasepool {
-    NSError *error;
-    std::string filePath = [[fileURL_ path] UTF8String];
-
-    if (audioFile_ == nil) {
-      return {0, 0};
-    }
-
-    // AVAudioFile automatically finalizes the file when deallocated
-    audioFile_ = nil;
-
-    double fileDuration = CMTimeGetSeconds([[AVURLAsset URLAssetWithURL:fileURL_ options:nil] duration]);
-    double fileSizeBytesMb =
-        static_cast<double>([[[NSFileManager defaultManager] attributesOfItemAtPath:fileURL_.path
-                                                                              error:&error] fileSize]) /
-        BYTES_TO_MB;
-
-    NSLog(
-        @"ℹ️ Closed audio file at path: %s, duration: %.2f sec, size: %.2f MB",
-        filePath.c_str(),
-        fileDuration,
-        fileSizeBytesMb);
-
-    if (error != nil) {
-      NSLog(@"⚠️ closeFile: error while retrieving file size");
-      fileSizeBytesMb = 0;
-    }
-
-    fileURL_ = nil;
-
-    return {fileSizeBytesMb, fileDuration};
-  }
-}
-
-bool IOSAudioFileWriter::writeAudioData(const AudioBufferList *audioBufferList, int numFrames)
-{
-  if (audioFile_ == nil) {
-    NSLog(@"⚠️ writeAudioData: audioFile is nil, cannot write data");
-    return false;
-  }
-
-  @autoreleasepool {
-    NSError *error = nil;
-    AVAudioFormat *fileFormat = [audioFile_ processingFormat];
-
-    if (bufferFormat_.sampleRate == fileFormat.sampleRate && bufferFormat_.channelCount == fileFormat.channelCount &&
-        bufferFormat_.isInterleaved == fileFormat.isInterleaved) {
-      AVAudioPCMBuffer *processingBuffer = [[AVAudioPCMBuffer alloc] initWithPCMFormat:fileFormat
-                                                                      bufferListNoCopy:audioBufferList
-                                                                           deallocator:NULL];
-      processingBuffer.frameLength = (AVAudioFrameCount)numFrames;
-
-      [audioFile_ writeFromBuffer:processingBuffer error:&error];
-
-      if (error != nil) {
-        NSLog(@"Error writing audio data to file: %@", [error debugDescription]);
-        return false;
-      }
-
-      framesWritten_.fetch_add(numFrames);
-      return true;
-    }
-
-    size_t outputFrameCount = ceil(numFrames * fileFormat.sampleRate / bufferFormat_.sampleRate);
-
-    for (size_t i = 0; i < bufferFormat_.channelCount; ++i) {
-      memcpy(
-          converterInputBuffer_.mutableAudioBufferList->mBuffers[i].mData,
-          audioBufferList->mBuffers[i].mData,
-          audioBufferList->mBuffers[i].mDataByteSize);
-    }
-
-    converterInputBuffer_.frameLength = numFrames;
-
-    AVAudioConverterInputBlock inputBlock =
-        ^AVAudioBuffer *_Nullable(AVAudioPacketCount inNumberOfPackets, AVAudioConverterInputStatus *outStatus)
-    {
-      // this line is probably an delusion, but for my sanity lets keep it
-      inNumberOfPackets = numFrames;
-      *outStatus = AVAudioConverterInputStatus_HaveData;
-      return converterInputBuffer_;
-    };
-
-    [converter_ convertToBuffer:converterOutputBuffer_ error:&error withInputFromBlock:inputBlock];
-
-    if (error != nil) {
-      NSLog(@"Error during audio conversion: %@", [error debugDescription]);
-      return false;
-    }
-
-    [audioFile_ writeFromBuffer:converterOutputBuffer_ error:&error];
-
-    if (error != nil) {
-      NSLog(@"Error writing audio data to file: %@", [error debugDescription]);
-      return false;
-    }
-
-    framesWritten_.fetch_add(numFrames);
-    return true;
-  }
-}
-
-NSString *IOSAudioFileWriter::getISODateStringForDirectory()
-{
-  NSDateFormatter *fmt = [[NSDateFormatter alloc] init];
-  fmt.locale = [NSLocale localeWithLocaleIdentifier:@"en_US_POSIX"];
-  fmt.timeZone = [NSTimeZone timeZoneWithAbbreviation:@"UTC"]; // or local if you prefer
-  fmt.dateFormat = @"yyyy-MM-dd";
-  return [fmt stringFromDate:[NSDate date]];
-}
-
-NSString *IOSAudioFileWriter::getTimestampForFilename()
-{
-  NSDateFormatter *fmt = [[NSDateFormatter alloc] init];
-  fmt.locale = [NSLocale localeWithLocaleIdentifier:@"en_US_POSIX"];
-  fmt.timeZone = [NSTimeZone timeZoneWithAbbreviation:@"UTC"]; // or local if you prefer
-  fmt.dateFormat = @"yyyyMMdd_HHmmss_SSS";
-  return [fmt stringFromDate:[NSDate date]];
-}
-
-NSURL *IOSAudioFileWriter::getFileURL()
-{
-  NSError *error = nil;
-
-  NSSearchPathDirectory searchDirectory = fileOptions_->getDirectory();
-  NSString *directory = [NSString stringWithFormat:@"AudioAPI/%@", getISODateStringForDirectory()];
-
-  NSURL *baseURL = [[[NSFileManager defaultManager] URLsForDirectory:searchDirectory
-                                                           inDomains:NSUserDomainMask] firstObject];
-  NSURL *dirURL = [baseURL URLByAppendingPathComponent:directory isDirectory:YES];
-
-  [[NSFileManager defaultManager] createDirectoryAtURL:dirURL
-                           withIntermediateDirectories:YES
-                                            attributes:nil
-                                                 error:&error];
-
-  if (error != nil) {
-    NSLog(@"Error creating directory for audio recordings: %@", [error debugDescription]);
-    dirURL = baseURL;
-  }
-
-  NSString *fileName =
-      [NSString stringWithFormat:@"audio_%@.%@", getTimestampForFilename(), fileOptions_->getFileExtension()];
-  return [dirURL URLByAppendingPathComponent:fileName];
-}
-
-double IOSAudioFileWriter::getCurrentDuration() const
-{
-  return static_cast<double>(framesWritten_.load()) / bufferFormat_.sampleRate;
-}
-
-} // namespace audioapi

package/ios/audioapi/ios/core/IOSRecorderCallback.mm

@@ -1,189 +0,0 @@
-#import <AVFoundation/AVFoundation.h>
-#import <Foundation/Foundation.h>
-
-#include <audioapi/HostObjects/sources/AudioBufferHostObject.h>
-#include <audioapi/core/utils/Constants.h>
-#include <audioapi/dsp/VectorMath.h>
-#include <audioapi/events/AudioEventHandlerRegistry.h>
-#include <audioapi/ios/core/IOSRecorderCallback.h>
-#include <audioapi/utils/AudioArray.h>
-#include <audioapi/utils/AudioBus.h>
-#include <audioapi/utils/CircularAudioArray.h>
-#include <algorithm>
-
-namespace audioapi {
-
-IOSRecorderCallback::IOSRecorderCallback(
-    const std::shared_ptr<AudioEventHandlerRegistry> &audioEventHandlerRegistry,
-    float sampleRate,
-    size_t bufferLength,
-    size_t channelCount,
-    uint64_t callbackId)
-    : audioEventHandlerRegistry_(audioEventHandlerRegistry),
-      sampleRate_(sampleRate),
-      bufferLength_(bufferLength),
-      channelCount_(channelCount),
-      callbackId_(callbackId)
-{
-  ringBufferSize_ = std::max((int)bufferLength_ * 2, 8192);
-  circularBus_.resize(channelCount_);
-
-  for (size_t i = 0; i < channelCount_; ++i) {
-    auto busAudioArray = std::make_shared<CircularAudioArray>(ringBufferSize_);
-    circularBus_[i] = busAudioArray;
-  }
-}
-
-IOSRecorderCallback::~IOSRecorderCallback()
-{
-  @autoreleasepool {
-    converter_ = nil;
-    bufferFormat_ = nil;
-    callbackFormat_ = nil;
-    converterInputBuffer_ = nil;
-    converterOutputBuffer_ = nil;
-
-    for (size_t i = 0; i < channelCount_; ++i) {
-      circularBus_[i].reset();
-    }
-  }
-}
-
-void IOSRecorderCallback::prepare(AVAudioFormat *bufferFormat, size_t maxInputBufferLength)
-{
-  @autoreleasepool {
-    bufferFormat_ = bufferFormat;
-    converterInputBufferSize_ = maxInputBufferLength;
-
-    converterOutputBufferSize_ =
-        std::max((double)maxInputBufferLength, sampleRate_ / bufferFormat.sampleRate * maxInputBufferLength);
-
-    callbackFormat_ = [[AVAudioFormat alloc] initWithCommonFormat:AVAudioPCMFormatFloat32
-                                                       sampleRate:sampleRate_
-                                                         channels:channelCount_
-                                                      interleaved:NO];
-
-    converter_ = [[AVAudioConverter alloc] initFromFormat:bufferFormat toFormat:callbackFormat_];
-    converter_.sampleRateConverterAlgorithm = AVSampleRateConverterAlgorithm_Normal;
-    converter_.sampleRateConverterQuality = AVAudioQualityMax;
-    converter_.primeMethod = AVAudioConverterPrimeMethod_None;
-
-    converterInputBuffer_ = [[AVAudioPCMBuffer alloc] initWithPCMFormat:bufferFormat_
-                                                          frameCapacity:(AVAudioFrameCount)converterInputBufferSize_];
-    converterOutputBuffer_ = [[AVAudioPCMBuffer alloc] initWithPCMFormat:callbackFormat_
-                                                           frameCapacity:(AVAudioFrameCount)converterOutputBufferSize_];
-  }
-}
-
-void IOSRecorderCallback::cleanup()
-{
-  @autoreleasepool {
-    sendRemainingData();
-
-    converter_ = nil;
-    bufferFormat_ = nil;
-    callbackFormat_ = nil;
-    converterInputBuffer_ = nil;
-    converterOutputBuffer_ = nil;
-
-    for (size_t i = 0; i < channelCount_; ++i) {
-      circularBus_[i].reset();
-    }
-  }
-}
-
-void IOSRecorderCallback::receiveAudioData(const AudioBufferList *inputBuffer, int numFrames)
-{
-  @autoreleasepool {
-    NSError *error = nil;
-
-    if (bufferFormat_.sampleRate == sampleRate_ && bufferFormat_.channelCount == channelCount_ &&
-        !bufferFormat_.isInterleaved) {
-      // Directly write to circular buffer
-      for (size_t i = 0; i < channelCount_; ++i) {
-        auto *inputChannel = static_cast<float *>(inputBuffer->mBuffers[i].mData);
-        circularBus_[i]->push_back(inputChannel, numFrames);
-      }
-
-      emitAudioData();
-      return;
-    }
-
-    size_t outputFrameCount = ceil(numFrames * (sampleRate_ / bufferFormat_.sampleRate));
-
-    for (size_t i = 0; i < bufferFormat_.channelCount; ++i) {
-      memcpy(
-          converterInputBuffer_.mutableAudioBufferList->mBuffers[i].mData,
-          inputBuffer->mBuffers[i].mData,
-          inputBuffer->mBuffers[i].mDataByteSize);
-    }
-
-    converterInputBuffer_.frameLength = numFrames;
-
-    AVAudioConverterInputBlock inputBlock =
-        ^AVAudioBuffer *_Nullable(AVAudioPacketCount inNumberOfPackets, AVAudioConverterInputStatus *outStatus)
-    {
-      // this line is probably an delusion, but for my sanity lets keep it
-      inNumberOfPackets = numFrames;
-      *outStatus = AVAudioConverterInputStatus_HaveData;
-      return converterInputBuffer_;
-    };
-
-    [converter_ convertToBuffer:converterOutputBuffer_ error:&error withInputFromBlock:inputBlock];
-
-    if (error != nil) {
-      NSLog(@"Error during audio conversion: %@", [error debugDescription]);
-      return;
-    }
-
-    for (size_t i = 0; i < channelCount_; ++i) {
-      auto *inputChannel = static_cast<float *>(converterOutputBuffer_.audioBufferList->mBuffers[i].mData);
-      circularBus_[i]->push_back(inputChannel, outputFrameCount);
-    }
-
-    emitAudioData();
-  }
-}
-
-void IOSRecorderCallback::emitAudioData()
-{
-  while (circularBus_[0]->getNumberOfAvailableFrames() >= bufferLength_) {
-    auto bus = std::make_shared<AudioBus>(bufferLength_, channelCount_, sampleRate_);
-
-    for (size_t i = 0; i < channelCount_; ++i) {
-      auto *outputChannel = bus->getChannel(i)->getData();
-      circularBus_[i]->pop_front(outputChannel, bufferLength_);
-    }
-
-    invokeCallback(bus, bufferLength_);
-  }
-}
-
-void IOSRecorderCallback::invokeCallback(const std::shared_ptr<AudioBus> &bus, int numFrames)
-{
-  auto audioBuffer = std::make_shared<AudioBuffer>(bus);
-  auto audioBufferHostObject = std::make_shared<AudioBufferHostObject>(audioBuffer);
-
-  std::unordered_map<std::string, EventValue> eventPayload = {};
-  eventPayload.insert({"buffer", audioBufferHostObject});
-  eventPayload.insert({"numFrames", numFrames});
-
-  if (audioEventHandlerRegistry_) {
-    audioEventHandlerRegistry_->invokeHandlerWithEventBody("audioReady", callbackId_, eventPayload);
-  }
-}
-
-void IOSRecorderCallback::sendRemainingData()
-{
-  auto numberOfFrames = circularBus_[0]->getNumberOfAvailableFrames();
-  auto bus = std::make_shared<AudioBus>(circularBus_[0]->getNumberOfAvailableFrames(), channelCount_, sampleRate_);
-
-  for (size_t i = 0; i < channelCount_; ++i) {
-    auto *outputChannel = bus->getChannel(i)->getData();
-    circularBus_[i]->pop_front(outputChannel, numberOfFrames);
-  }
-
-  invokeCallback(bus, numberOfFrames);
-}
-
-} // namespace audioapi

package/ios/audioapi/ios/system/LockScreenManager.h

@@ -1,24 +0,0 @@
-#pragma once
-
-#import <AVFoundation/AVFoundation.h>
-#import <Foundation/Foundation.h>
-#import <MediaPlayer/MediaPlayer.h>
-
-@class AudioAPIModule;
-
-@interface LockScreenManager : NSObject
-
-@property (nonatomic, weak) AudioAPIModule *audioAPIModule;
-
-@property (nonatomic, weak) MPNowPlayingInfoCenter *playingInfoCenter;
-@property (nonatomic, copy) NSString *artworkUrl;
-@property (nonatomic, assign) bool isReceivingRemoteCommands;
-
-- (instancetype)initWithAudioAPIModule:(AudioAPIModule *)audioAPIModule;
-- (void)cleanup;
-
-- (void)setLockScreenInfo:(NSDictionary *)info;
-- (void)resetLockScreenInfo;
-- (void)enableRemoteCommand:(NSString *)name enabled:(BOOL)enabled;
-
-@end