react-native-audio-api 0.11.0-alpha.0 → 0.11.0-alpha.10

package/ios/audioapi/ios/core/IOSAudioFileOptions.mm

@@ -1,135 +0,0 @@
-#import <AVFoundation/AVFoundation.h>
-#import <Foundation/Foundation.h>
-
-#include <audioapi/ios/core/IOSAudioFileOptions.h>
-
-namespace audioapi {
-
-IOSAudioFileOptions::IOSAudioFileOptions(float sampleRate, size_t channelCount, size_t bitRate, size_t flags)
-{
-  sampleRate_ = sampleRate;
-  channelCount_ = channelCount;
-  bitRate_ = bitRate;
-
-  format_ = static_cast<uint8_t>(((flags >> 0) & 0xF));
-  quality_ = static_cast<uint8_t>(((flags >> 4) & 0xF));
-  flacCompressionLevel_ = static_cast<uint8_t>(((flags >> 8) & 0xF));
-  directory_ = static_cast<uint8_t>(((flags >> 12) & 0xF));
-  bitDepth_ = static_cast<uint8_t>(((flags >> 16) & 0xF));
-}
-
-AudioFormatID IOSAudioFileOptions::getFormat() const
-{
-  switch (format_) {
-    case 1:
-      return kAudioFormatLinearPCM; // WAV <-> Linear PCM container
-    case 2:
-      return kAudioFormatLinearPCM; // CAF <-> Linear PCM container
-    case 3:
-      return kAudioFormatMPEG4AAC; // M4A <-> AAC
-    case 4:
-      return kAudioFormatFLAC; // FLAC <-> FLAC
-    default:
-      return kAudioFormatLinearPCM; // Default to Linear PCM
-  }
-}
-
-NSInteger IOSAudioFileOptions::getQuality() const
-{
-  switch (quality_) {
-    case 1:
-      return AVAudioQualityMin;
-    case 2:
-      return AVAudioQualityLow;
-    case 3:
-      return AVAudioQualityMedium;
-    case 4:
-      return AVAudioQualityHigh;
-    case 5:
-      return AVAudioQualityMax;
-    default:
-      return AVAudioQualityMedium; // Default to Medium
-  }
-}
-
-NSInteger IOSAudioFileOptions::getFlacCompressionLevel() const
-{
-  // Shift the quality from 1-9 to 0-8 for real values
-  // Default to 5 if out of range
-  return (flacCompressionLevel_ >= 1 && flacCompressionLevel_ <= 9) ? flacCompressionLevel_ - 1 : 5;
-}
-
-NSSearchPathDirectory IOSAudioFileOptions::getDirectory() const
-{
-  switch (directory_) {
-    case 1:
-      return NSDocumentDirectory;
-    case 2:
-      return NSCachesDirectory;
-    default:
-      return NSCachesDirectory; // Default to Caches
-  }
-}
-
-NSString *IOSAudioFileOptions::getFileExtension() const
-{
-  switch (format_) {
-    case 1:
-      return @"wav"; // WAV <-> Linear PCM container
-    case 2:
-      return @"caf"; // CAF <-> Linear PCM container
-    case 3:
-      return @"m4a"; // M4A <-> AAC
-    case 4:
-      return @"flac"; // FLAC <-> FLAC
-    default:
-      return @"wav"; // Default to WAV
-  }
-}
-
-NSInteger IOSAudioFileOptions::getBitDepth() const
-{
-  switch (bitDepth_) {
-    case 1:
-      return 16;
-    case 2:
-      return 24;
-    case 3:
-      return 32;
-    default:
-      return 24; // Default to 24-bit
-  }
-}
-
-NSDictionary *IOSAudioFileOptions::getFileSettings()
-{
-  AudioFormatID format = getFormat();
-  NSMutableDictionary *settings = [NSMutableDictionary dictionary];
-
-  settings[AVFormatIDKey] = @(format);
-  settings[AVSampleRateKey] = @(sampleRate_);
-  settings[AVNumberOfChannelsKey] = @(channelCount_);
-
-  settings[AVEncoderAudioQualityKey] = @(getQuality());
-
-  if (format == kAudioFormatMPEG4AAC) {
-    settings[AVEncoderBitRateKey] = @(bitRate_);
-  }
-
-  if (format == kAudioFormatLinearPCM) {
-    NSInteger bitDepth = getBitDepth();
-
-    settings[AVLinearPCMBitDepthKey] = @(bitDepth);
-    settings[AVLinearPCMIsFloatKey] = @(bitDepth == 32);
-    settings[AVLinearPCMIsBigEndianKey] = @(NO);
-    settings[AVLinearPCMIsNonInterleaved] = @(NO);
-  }
-
-  if (format == kAudioFormatFLAC) {
-    settings[@"FLACCompressionLevel"] = @(getFlacCompressionLevel());
-  }
-
-  return settings;
-}
-
-} // namespace audioapi

package/ios/audioapi/ios/core/IOSAudioFileWriter.h

@@ -1,38 +0,0 @@
-#pragma once
-
-#include <memory>
-#include <string>
-
-#ifndef __OBJC__ // when compiled as C++
-typedef struct objc_object AVAudioFile;
-typedef struct objc_object NSURL;
-typedef struct objc_object AudioBufferList;
-#endif // __OBJC__
-
-namespace audioapi {
-
-class IOSAudioFileOptions;
-
-class IOSAudioFileWriter {
- public:
-  IOSAudioFileWriter(float sampleRate, size_t channelCount, size_t bitRate, size_t iosFlags);
-  ~IOSAudioFileWriter();
-
-  void openFile(AVAudioFormat *bufferFormat);
-  std::string closeFile();
-
-  bool writeAudioData(const AudioBufferList *audioBufferList, int numFrames);
-
- private:
-  NSString *getISODateStringForDirectory();
-  NSString *getTimestampForFilename();
-  NSURL *getFileURL();
-
-  std::shared_ptr<IOSAudioFileOptions> fileOptions_;
-  AVAudioFile *audioFile_;
-  AVAudioFormat *bufferFormat_;
-  AVAudioConverter *converter_;
-  NSURL *fileURL_;
-};
-
-} // namespace audioapi

package/ios/audioapi/ios/core/IOSAudioFileWriter.mm

@@ -1,187 +0,0 @@
-#import <AVFoundation/AVFoundation.h>
-#import <Foundation/Foundation.h>
-
-#include <audioapi/ios/core/IOSAudioFileOptions.h>
-#include <audioapi/ios/core/IOSAudioFileWriter.h>
-
-namespace audioapi {
-IOSAudioFileWriter::IOSAudioFileWriter(float sampleRate, size_t channelCount, size_t bitRate, size_t iosFlags)
-{
-  fileOptions_ = std::make_shared<IOSAudioFileOptions>(sampleRate, channelCount, bitRate, iosFlags);
-}
-
-IOSAudioFileWriter::~IOSAudioFileWriter()
-{
-  fileURL_ = nil;
-  audioFile_ = nil;
-  converter_ = nil;
-  bufferFormat_ = nil;
-}
-
-void IOSAudioFileWriter::openFile(AVAudioFormat *bufferFormat)
-{
-  @autoreleasepool {
-    if (audioFile_ != nil) {
-      NSLog(@"⚠️ createFileForWriting: currentAudioFile_ already exists");
-      return;
-    }
-
-    bufferFormat_ = bufferFormat;
-
-    NSError *error = nil;
-    NSDictionary *settings = fileOptions_->getFileSettings();
-    fileURL_ = getFileURL();
-
-    NSLog(@"ℹ️ Creating audio file at URL: %@", [fileURL_ absoluteString]);
-
-    audioFile_ = [[AVAudioFile alloc] initForWriting:fileURL_
-                                            settings:settings
-                                        commonFormat:AVAudioPCMFormatFloat32
-                                         interleaved:bufferFormat.interleaved
-                                               error:&error];
-    converter_ = [[AVAudioConverter alloc] initFromFormat:bufferFormat toFormat:[audioFile_ processingFormat]];
-    converter_.sampleRateConverterAlgorithm = AVSampleRateConverterAlgorithm_Normal;
-    converter_.sampleRateConverterQuality = AVAudioQualityMax;
-    converter_.primeMethod = AVAudioConverterPrimeMethod_None;
-
-    NSLog(@"buferFormat: %@ fileFormat: %@", bufferFormat, [audioFile_ processingFormat]);
-
-    if (error != nil || audioFile_ == nil) {
-      NSLog(@"Error creating audio file for writing: %@", [error debugDescription]);
-      audioFile_ = nil;
-    }
-  }
-}
-
-std::string IOSAudioFileWriter::closeFile()
-{
-  @autoreleasepool {
-    std::string filePath = [[fileURL_ path] UTF8String];
-
-    if (audioFile_ == nil) {
-      return "";
-    }
-
-    // AVAudioFile automatically finalizes the file when deallocated
-    audioFile_ = nil;
-    fileURL_ = nil;
-    return filePath;
-  }
-}
-
-bool IOSAudioFileWriter::writeAudioData(const AudioBufferList *audioBufferList, int numFrames)
-{
-  if (audioFile_ == nil) {
-    NSLog(@"⚠️ writeAudioData: audioFile is nil, cannot write data");
-    return false;
-  }
-
-  // TODO: not sure if this is necessary
-  @autoreleasepool {
-    NSError *error = nil;
-    AVAudioFormat *filePCMFormat = [audioFile_ processingFormat];
-
-    if (audioBufferList->mNumberBuffers != filePCMFormat.channelCount ||
-        bufferFormat_.sampleRate != filePCMFormat.sampleRate ||
-        bufferFormat_.interleaved != filePCMFormat.interleaved) {
-      int outputFrameCount = ceil(numFrames * filePCMFormat.sampleRate / bufferFormat_.sampleRate);
-
-      AVAudioPCMBuffer *inputBuffer = [[AVAudioPCMBuffer alloc] initWithPCMFormat:bufferFormat_
-                                                                    frameCapacity:(AVAudioFrameCount)numFrames];
-
-      for (int i = 0; i < bufferFormat_.channelCount; i++) {
-        memcpy(
-            inputBuffer.mutableAudioBufferList->mBuffers[i].mData,
-            audioBufferList->mBuffers[i].mData,
-            audioBufferList->mBuffers[i].mDataByteSize);
-      }
-
-      inputBuffer.frameLength = numFrames;
-      AVAudioPCMBuffer *outputBuffer = [[AVAudioPCMBuffer alloc] initWithPCMFormat:filePCMFormat
-                                                                     frameCapacity:outputFrameCount];
-      outputBuffer.frameLength = outputFrameCount;
-
-      AVAudioConverterInputBlock inputBlock =
-          ^AVAudioBuffer *_Nullable(AVAudioPacketCount inNumberOfPackets, AVAudioConverterInputStatus *outStatus)
-      {
-        // this line is probably an delusion, but for my sanity lets keep it
-        inNumberOfPackets = numFrames;
-        *outStatus = AVAudioConverterInputStatus_HaveData;
-        return inputBuffer;
-      };
-
-      [converter_ convertToBuffer:outputBuffer error:&error withInputFromBlock:inputBlock];
-
-      if (error != nil) {
-        NSLog(@"Error during audio conversion: %@", [error debugDescription]);
-        return false;
-      }
-
-      [audioFile_ writeFromBuffer:outputBuffer error:&error];
-
-      if (error != nil) {
-        NSLog(@"Error writing audio data to file: %@", [error debugDescription]);
-        return false;
-      }
-    } else {
-      AVAudioPCMBuffer *processingBuffer = [[AVAudioPCMBuffer alloc] initWithPCMFormat:filePCMFormat
-                                                                      bufferListNoCopy:audioBufferList
-                                                                           deallocator:NULL];
-
-      [audioFile_ writeFromBuffer:processingBuffer error:&error];
-
-      if (error != nil) {
-        NSLog(@"Error writing audio data to file: %@", [error debugDescription]);
-        return false;
-      }
-    }
-
-    return true;
-  }
-}
-
-NSString *IOSAudioFileWriter::getISODateStringForDirectory()
-{
-  NSDateFormatter *fmt = [[NSDateFormatter alloc] init];
-  fmt.locale = [NSLocale localeWithLocaleIdentifier:@"en_US_POSIX"];
-  fmt.timeZone = [NSTimeZone timeZoneWithAbbreviation:@"UTC"]; // or local if you prefer
-  fmt.dateFormat = @"yyyy-MM-dd";
-  return [fmt stringFromDate:[NSDate date]];
-}
-
-NSString *IOSAudioFileWriter::getTimestampForFilename()
-{
-  NSDateFormatter *fmt = [[NSDateFormatter alloc] init];
-  fmt.locale = [NSLocale localeWithLocaleIdentifier:@"en_US_POSIX"];
-  fmt.timeZone = [NSTimeZone timeZoneWithAbbreviation:@"UTC"]; // or local if you prefer
-  fmt.dateFormat = @"yyyyMMdd_HHmmss_SSS";
-  return [fmt stringFromDate:[NSDate date]];
-}
-
-NSURL *IOSAudioFileWriter::getFileURL()
-{
-  NSError *error = nil;
-
-  NSSearchPathDirectory searchDirectory = fileOptions_->getDirectory();
-  NSString *directory = [NSString stringWithFormat:@"AudioAPI/%@", getISODateStringForDirectory()];
-
-  NSURL *baseURL = [[[NSFileManager defaultManager] URLsForDirectory:searchDirectory
-                                                           inDomains:NSUserDomainMask] firstObject];
-  NSURL *dirURL = [baseURL URLByAppendingPathComponent:directory isDirectory:YES];
-
-  [[NSFileManager defaultManager] createDirectoryAtURL:dirURL
-                           withIntermediateDirectories:YES
-                                            attributes:nil
-                                                 error:&error];
-
-  if (error != nil) {
-    NSLog(@"Error creating directory for audio recordings: %@", [error debugDescription]);
-    dirURL = baseURL;
-  }
-
-  NSString *fileName =
-      [NSString stringWithFormat:@"audio_%@.%@", getTimestampForFilename(), fileOptions_->getFileExtension()];
-  return [dirURL URLByAppendingPathComponent:fileName];
-}
-
-} // namespace audioapi

package/ios/audioapi/ios/system/LockScreenManager.h

@@ -1,24 +0,0 @@
-#pragma once
-
-#import <AVFoundation/AVFoundation.h>
-#import <Foundation/Foundation.h>
-#import <MediaPlayer/MediaPlayer.h>
-
-@class AudioAPIModule;
-
-@interface LockScreenManager : NSObject
-
-@property (nonatomic, weak) AudioAPIModule *audioAPIModule;
-
-@property (nonatomic, weak) MPNowPlayingInfoCenter *playingInfoCenter;
-@property (nonatomic, copy) NSString *artworkUrl;
-@property (nonatomic, assign) bool isReceivingRemoteCommands;
-
-- (instancetype)initWithAudioAPIModule:(AudioAPIModule *)audioAPIModule;
-- (void)cleanup;
-
-- (void)setLockScreenInfo:(NSDictionary *)info;
-- (void)resetLockScreenInfo;
-- (void)enableRemoteCommand:(NSString *)name enabled:(BOOL)enabled;
-
-@end

package/ios/audioapi/ios/system/LockScreenManager.mm

@@ -1,310 +0,0 @@
-#import <MediaPlayer/MediaPlayer.h>
-#import <audioapi/ios/AudioAPIModule.h>
-#import <audioapi/ios/system/LockScreenManager.h>
-
-#define LOCK_SCREEN_INFO                                          \
-  @{                                                              \
-    @"album" : MPMediaItemPropertyAlbumTitle,                     \
-    @"artist" : MPMediaItemPropertyArtist,                        \
-    @"duration" : MPMediaItemPropertyPlaybackDuration,            \
-    @"title" : MPMediaItemPropertyTitle,                          \
-    @"speed" : MPNowPlayingInfoPropertyPlaybackRate,              \
-    @"elapsedTime" : MPNowPlayingInfoPropertyElapsedPlaybackTime, \
-  }
-
-@implementation LockScreenManager
-
-- (instancetype)initWithAudioAPIModule:(AudioAPIModule *)audioAPIModule
-{
-  if (self = [super init]) {
-    self.audioAPIModule = audioAPIModule;
-    self.playingInfoCenter = [MPNowPlayingInfoCenter defaultCenter];
-    self.isReceivingRemoteCommands = false;
-  }
-
-  return self;
-}
-
-- (void)toggleRemoteCommands:(bool)enable
-{
-  if (enable && !self.isReceivingRemoteCommands) {
-    self.isReceivingRemoteCommands = true;
-    dispatch_async(dispatch_get_main_queue(), ^{
-      [[UIApplication sharedApplication] beginReceivingRemoteControlEvents];
-    });
-    return;
-  } else if (!enable && self.isReceivingRemoteCommands) {
-    self.isReceivingRemoteCommands = false;
-    dispatch_async(dispatch_get_main_queue(), ^{
-      [[UIApplication sharedApplication] endReceivingRemoteControlEvents];
-    });
-    return;
-  }
-}
-
-- (void)cleanup
-{
-  NSLog(@"[LockScreenManager] cleanup");
-  [self toggleRemoteCommands:false];
-  [self resetLockScreenInfo];
-}
-
-- (void)setLockScreenInfo:(NSDictionary *)info
-{
-  self.playingInfoCenter = [MPNowPlayingInfoCenter defaultCenter];
-  [self toggleRemoteCommands:true];
-
-  // now playing info(lock screen info)
-  NSMutableDictionary *lockScreenInfoDict;
-
-  if (self.playingInfoCenter.nowPlayingInfo == nil) {
-    lockScreenInfoDict = [NSMutableDictionary dictionary];
-  } else {
-    lockScreenInfoDict = [[NSMutableDictionary alloc] initWithDictionary:self.playingInfoCenter.nowPlayingInfo];
-  }
-
-  for (NSString *key in LOCK_SCREEN_INFO) {
-    if ([info objectForKey:key] != nil) {
-      [lockScreenInfoDict setValue:[info objectForKey:key] forKey:[LOCK_SCREEN_INFO objectForKey:key]];
-    }
-  }
-
-  self.playingInfoCenter.nowPlayingInfo = lockScreenInfoDict;
-
-  // playback state
-  NSString *state = [info objectForKey:@"state"];
-
-  if (state != nil) {
-    if ([state isEqualToString:@"state_playing"]) {
-      self.playingInfoCenter.playbackState = MPNowPlayingPlaybackStatePlaying;
-    } else if ([state isEqualToString:@"state_paused"]) {
-      self.playingInfoCenter.playbackState = MPNowPlayingPlaybackStatePaused;
-    }
-  }
-
-  self.playingInfoCenter.playbackState = MPNowPlayingPlaybackStatePaused;
-
-  // artwork
-  NSString *artworkUrl = [self getArtworkUrl:[info objectForKey:@"artwork"]];
-  [self updateArtworkIfNeeded:artworkUrl];
-}
-
-- (void)resetLockScreenInfo
-{
-  [self toggleRemoteCommands:false];
-  self.playingInfoCenter = [MPNowPlayingInfoCenter defaultCenter];
-  self.playingInfoCenter.nowPlayingInfo = nil;
-  self.artworkUrl = nil;
-}
-
-- (NSString *)getArtworkUrl:(NSString *)artwork
-{
-  NSString *artworkUrl = nil;
-
-  if (artwork) {
-    if ([artwork isKindOfClass:[NSString class]]) {
-      artworkUrl = artwork;
-    } else if ([[artwork valueForKey:@"uri"] isKindOfClass:[NSString class]]) {
-      artworkUrl = [artwork valueForKey:@"uri"];
-    }
-  }
-
-  return artworkUrl;
-}
-
-- (void)updateArtworkIfNeeded:(id)artworkUrl
-{
-  if (artworkUrl == nil) {
-    return;
-  }
-
-  MPNowPlayingInfoCenter *center = [MPNowPlayingInfoCenter defaultCenter];
-  if ([artworkUrl isEqualToString:self.artworkUrl] &&
-      [center.nowPlayingInfo objectForKey:MPMediaItemPropertyArtwork] != nil) {
-    return;
-  }
-
-  self.artworkUrl = artworkUrl;
-
-  // Custom handling of artwork in another thread, will be loaded async
-  dispatch_async(dispatch_get_global_queue(DISPATCH_QUEUE_PRIORITY_BACKGROUND, 0), ^{
-    UIImage *image = nil;
-
-    // check whether artwork path is present
-    if ([artworkUrl isEqual:@""]) {
-      return;
-    }
-
-    // artwork is url download from the interwebs
-    if ([artworkUrl hasPrefix:@"http://"] || [artworkUrl hasPrefix:@"https://"]) {
-      NSURL *imageURL = [NSURL URLWithString:artworkUrl];
-      NSData *imageData = [NSData dataWithContentsOfURL:imageURL];
-      image = [UIImage imageWithData:imageData];
-    } else {
-      NSString *localArtworkUrl = [artworkUrl stringByReplacingOccurrencesOfString:@"file://" withString:@""];
-      BOOL fileExists = [[NSFileManager defaultManager] fileExistsAtPath:localArtworkUrl];
-      if (fileExists) {
-        image = [UIImage imageNamed:localArtworkUrl];
-      }
-    }
-
-    // Check if image was available otherwise don't do anything
-    if (image == nil) {
-      return;
-    }
-
-    // check whether image is loaded
-    CGImageRef cgref = [image CGImage];
-    CIImage *cim = [image CIImage];
-
-    if (cim == nil && cgref == NULL) {
-      return;
-    }
-
-    dispatch_async(dispatch_get_main_queue(), ^{
-      // Check if URL wasn't changed in the meantime
-      if (![artworkUrl isEqual:self.artworkUrl]) {
-        return;
-      }
-
-      MPNowPlayingInfoCenter *center = [MPNowPlayingInfoCenter defaultCenter];
-      MPMediaItemArtwork *artwork = [[MPMediaItemArtwork alloc] initWithBoundsSize:image.size
-                                                                    requestHandler:^UIImage *_Nonnull(CGSize size) {
-                                                                      return image;
-                                                                    }];
-      NSMutableDictionary *mediaDict = (center.nowPlayingInfo != nil)
-          ? [[NSMutableDictionary alloc] initWithDictionary:center.nowPlayingInfo]
-          : [NSMutableDictionary dictionary];
-      [mediaDict setValue:artwork forKey:MPMediaItemPropertyArtwork];
-      center.nowPlayingInfo = mediaDict;
-    });
-  });
-}
-
-- (void)enableRemoteCommand:(NSString *)name enabled:(BOOL)enabled
-{
-  MPRemoteCommandCenter *remoteCenter = [MPRemoteCommandCenter sharedCommandCenter];
-
-  if ([name isEqual:@"remotePlay"]) {
-    [self enableCommand:remoteCenter.playCommand withSelector:@selector(onPlay:) enabled:enabled];
-  } else if ([name isEqual:@"remotePause"]) {
-    [self enableCommand:remoteCenter.pauseCommand withSelector:@selector(onPause:) enabled:enabled];
-  } else if ([name isEqual:@"remoteStop"]) {
-    [self enableCommand:remoteCenter.stopCommand withSelector:@selector(onStop:) enabled:enabled];
-  } else if ([name isEqual:@"remoteTogglePlayPause"]) {
-    [self enableCommand:remoteCenter.togglePlayPauseCommand withSelector:@selector(onTogglePlayPause:) enabled:enabled];
-  } else if ([name isEqual:@"remoteChangePlaybackRate"]) {
-    [self enableCommand:remoteCenter.changePlaybackRateCommand
-           withSelector:@selector(onChangePlaybackRate:)
-                enabled:enabled];
-  } else if ([name isEqual:@"remoteNextTrack"]) {
-    [self enableCommand:remoteCenter.nextTrackCommand withSelector:@selector(onNextTrack:) enabled:enabled];
-  } else if ([name isEqual:@"remotePreviousTrack"]) {
-    [self enableCommand:remoteCenter.previousTrackCommand withSelector:@selector(onPreviousTrack:) enabled:enabled];
-  } else if ([name isEqual:@"remoteSkipForward"]) {
-    remoteCenter.skipForwardCommand.preferredIntervals = @[ @15 ];
-    [self enableCommand:remoteCenter.skipForwardCommand withSelector:@selector(onSkipForward:) enabled:enabled];
-  } else if ([name isEqual:@"remoteSkipBackward"]) {
-    remoteCenter.skipBackwardCommand.preferredIntervals = @[ @15 ];
-    [self enableCommand:remoteCenter.skipBackwardCommand withSelector:@selector(onSkipBackward:) enabled:enabled];
-  } else if ([name isEqual:@"remoteSeekForward"]) {
-    [self enableCommand:remoteCenter.seekForwardCommand withSelector:@selector(onSeekForward:) enabled:enabled];
-  } else if ([name isEqual:@"remoteSeekBackward"]) {
-    [self enableCommand:remoteCenter.seekBackwardCommand withSelector:@selector(onSeekBackward:) enabled:enabled];
-  } else if ([name isEqual:@"remoteChangePlaybackPosition"]) {
-    [self enableCommand:remoteCenter.changePlaybackPositionCommand
-           withSelector:@selector(onChangePlaybackPosition:)
-                enabled:enabled];
-  }
-}
-
-- (void)enableCommand:(MPRemoteCommand *)command withSelector:(SEL)selector enabled:(BOOL)enabled
-{
-  [command removeTarget:self action:selector];
-  if (enabled) {
-    [command addTarget:self action:selector];
-  }
-  command.enabled = enabled;
-}
-
-- (MPRemoteCommandHandlerStatus)onPlay:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remotePlay" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onPause:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remotePause" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onStop:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteStop" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onTogglePlayPause:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteTogglePlayPause" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onChangePlaybackRate:(MPChangePlaybackRateCommandEvent *)event
-{
-  NSDictionary *body = @{@"value" : [NSNumber numberWithDouble:event.playbackRate]};
-
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteChangePlaybackRate" eventBody:body];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onNextTrack:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteNextTrack" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onPreviousTrack:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remotePreviousTrack" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onSeekForward:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteSeekForward" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onSeekBackward:(MPRemoteCommandEvent *)event
-{
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteSeekBackward" eventBody:nil];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onSkipForward:(MPSkipIntervalCommandEvent *)event
-{
-  NSDictionary *body = @{@"value" : [NSNumber numberWithDouble:event.interval]};
-
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteSkipForward" eventBody:body];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onSkipBackward:(MPSkipIntervalCommandEvent *)event
-{
-  NSDictionary *body = @{@"value" : [NSNumber numberWithDouble:event.interval]};
-
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteSkipBackward" eventBody:body];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-- (MPRemoteCommandHandlerStatus)onChangePlaybackPosition:(MPChangePlaybackPositionCommandEvent *)event
-{
-  NSDictionary *body = @{@"value" : [NSNumber numberWithDouble:event.positionTime]};
-
-  [self.audioAPIModule invokeHandlerWithEventName:@"remoteChangePlaybackPosition" eventBody:body];
-  return MPRemoteCommandHandlerStatusSuccess;
-}
-
-@end