parser-lr 0.4.1 → 0.6.0

package/grammars/grammar.grammar

@@ -0,0 +1,428 @@
+// Meta-grammar for parser-lr grammar files (.grammar).
+// Dogfood target: this file should parse itself once lexer, table build, and parse are wired.
+//
+// Calc example (parse + ast + transform):
+//
+//   grammar
+//       expr = term { #add plus term | #sub minus term } ;
+//       term = factor { #mul star factor | #div slash factor } ;
+//       factor = #number number | #group lpar expr rpar ;
+//
+//   ast
+//       expr = #binary [left]:expr [operator]:operator [right]:expr
+//            | #literal number
+//            | #grouped expr ;
+//       operator = #plus plus | #minus minus | #star star | #slash slash ;
+//
+//   transform
+//       expr ->
+//           #add fold-left(expr.#binary, left, operator, right)
+//         | #sub fold-left(expr.#binary, left, operator, right)
+//         | #term pass(term) ;
+//       term ->
+//           #mul fold-left(expr.#binary, left, operator, right)
+//         | #div fold-left(expr.#binary, left, operator, right)
+//         | #factor pass(factor) ;
+//       factor ->
+//           #number expr.#literal(number)
+//         | #group pass(expr) ;
+
+name "grammar" ;
+
+tokens
+    name_kw = /name/ ;
+    tokens_kw = /tokens/ ;
+    skip_kw = /skip/ ;
+    states_kw = /states/ ;
+    start_kw = /start/ ;
+    grammar_kw = /grammar/ ;
+    ast_kw = /ast/ ;
+    transform_kw = /transform/ ;
+    pass_kw = /pass/ ;
+    drop_kw = /drop/ ;
+    fold_left_kw = /fold-left/ ;
+    fold_right_kw = /fold-right/ ;
+    flatten_kw = /flatten/ ;
+
+    identifier = /[A-Za-z_][A-Za-z0-9_$]*/ ;
+
+    equal = /=/ ;
+    semicolon = /;/ ;
+    comma = /,/ ;
+    bar = /\|/ ;
+    hash = /#/ ;
+    arrow = /->/ ;
+    colon = /:/ ;
+    dot = /\./ ;
+
+    lpar = /\(/ ;
+    rpar = /\)/ ;
+    lbracket = /\[/ ;
+    rbracket = /\]/ ;
+    lbrace = /\{/ ;
+    rbrace = /\}/ ;
+
+    // Lexer: / pattern / then zero or more flag letters from g i m s u y
+    regex_literal = /\/(\\.|[^\\\/])+\/[gimsuy]*/ ;
+    string_literal = /"(?:\\.|[^"\\])*"/ ;
+
+skip
+    whitespace = /[ \t\r\n]+/ ;
+    comment = /\/\/[^\n\r]*/ ;
+
+start grammar_file ;
+
+grammar
+    grammar_file =
+        name_decl
+        { section }
+        start_decl
+        grammar_section
+        [ ast_section ]
+        [ transform_section ]
+    ;
+
+    name_decl =
+        name_kw grammar_name semicolon
+    ;
+
+    grammar_name =
+        identifier
+      | string_literal
+    ;
+
+    section =
+        token_section
+      | skip_section
+      | states_section
+    ;
+
+    token_section =
+        tokens_kw token_def { token_def }
+    ;
+
+    skip_section =
+        skip_kw token_def { token_def }
+    ;
+
+    states_section =
+        states_kw state_name { comma state_name } semicolon
+    ;
+
+    token_def =
+        identifier equal regex_literal semicolon
+    ;
+
+    state_name =
+        identifier
+    ;
+
+    start_decl =
+        start_kw identifier semicolon
+    ;
+
+    grammar_section =
+        grammar_kw production { production }
+    ;
+
+    ast_section =
+        ast_kw ast_type { ast_type }
+    ;
+
+    transform_section =
+        transform_kw transform_rule { transform_rule }
+    ;
+
+    production =
+        identifier equal expression semicolon
+    ;
+
+    ast_type =
+        identifier equal expression semicolon
+    ;
+
+    transform_rule =
+        identifier arrow labeled_transform { bar labeled_transform } semicolon
+    ;
+
+    labeled_transform =
+        hash identifier transform_expr
+    ;
+
+    transform_expr =
+        drop_kw
+      | pass_expr
+      | fold_left_expr
+      | fold_right_expr
+      | flatten_expr
+      | build_expr
+    ;
+
+    pass_expr =
+        pass_kw lpar reference rpar
+    ;
+
+    fold_left_expr =
+        fold_left_kw lpar build_target comma reference_list rpar
+    ;
+
+    fold_right_expr =
+        fold_right_kw lpar build_target comma reference_list rpar
+    ;
+
+    flatten_expr =
+        flatten_kw lpar build_target comma reference comma reference rpar
+    ;
+
+    build_expr =
+        build_target [ lpar reference_list rpar ]
+    ;
+
+    build_target =
+        identifier dot hash identifier
+    ;
+
+    reference_list =
+        reference { comma reference }
+    ;
+
+    reference =
+        identifier
+    ;
+
+    expression =
+        choice
+    ;
+
+    choice =
+        alternative { bar alternative }
+    ;
+
+    alternative =
+        labeled_alternative
+    ;
+
+    labeled_alternative =
+        [ hash identifier ] sequence
+    ;
+
+    sequence =
+        factor { factor }
+    ;
+
+    factor =
+        bracketed
+      | repeat
+      | group
+      | primary
+    ;
+
+    bracketed =
+        lbracket expression rbracket [ colon identifier ]
+    ;
+
+    repeat =
+        lbrace expression rbrace
+    ;
+
+    group =
+        lpar expression rpar
+    ;
+
+    primary =
+        string_literal
+      | identifier
+    ;
+
+ast
+    grammar_file =
+        name_decl
+        { section }
+        start_decl
+        grammar_section
+        [ ast_section ]
+        [ transform_section ]
+    ;
+
+    name_decl =
+        name_kw grammar_name semicolon
+    ;
+
+    grammar_name =
+        identifier
+      | string_literal
+    ;
+
+    section =
+        token_section
+      | skip_section
+      | states_section
+    ;
+
+    token_section =
+        tokens_kw token_def { token_def }
+    ;
+
+    skip_section =
+        skip_kw token_def { token_def }
+    ;
+
+    states_section =
+        states_kw state_name { comma state_name } semicolon
+    ;
+
+    token_def =
+        identifier equal regex_literal semicolon
+    ;
+
+    state_name =
+        identifier
+    ;
+
+    start_decl =
+        start_kw identifier semicolon
+    ;
+
+    grammar_section =
+        grammar_kw production { production }
+    ;
+
+    ast_section =
+        ast_kw ast_type { ast_type }
+    ;
+
+    transform_section =
+        transform_kw transform_rule { transform_rule }
+    ;
+
+    production =
+        identifier equal expression semicolon
+    ;
+
+    ast_type =
+        identifier equal expression semicolon
+    ;
+
+    transform_rule =
+        identifier arrow labeled_transform { bar labeled_transform } semicolon
+    ;
+
+    labeled_transform =
+        hash identifier transform_expr
+    ;
+
+    transform_expr =
+        drop_kw
+      | pass_expr
+      | fold_left_expr
+      | fold_right_expr
+      | flatten_expr
+      | build_expr
+    ;
+
+    pass_expr =
+        pass_kw lpar reference rpar
+    ;
+
+    fold_left_expr =
+        fold_left_kw lpar build_target comma reference_list rpar
+    ;
+
+    fold_right_expr =
+        fold_right_kw lpar build_target comma reference_list rpar
+    ;
+
+    flatten_expr =
+        flatten_kw lpar build_target comma reference comma reference rpar
+    ;
+
+    build_expr =
+        build_target [ lpar reference_list rpar ]
+    ;
+
+    build_target =
+        identifier dot hash identifier
+    ;
+
+    reference_list =
+        reference { comma reference }
+    ;
+
+    reference =
+        identifier
+    ;
+
+    expression =
+        choice
+    ;
+
+    choice =
+        alternative { bar alternative }
+    ;
+
+    alternative =
+        labeled_alternative
+    ;
+
+    labeled_alternative =
+        [ hash identifier ] sequence
+    ;
+
+    sequence =
+        factor { factor }
+    ;
+
+    factor =
+        bracketed
+      | repeat
+      | group
+      | primary
+    ;
+
+    bracketed =
+        lbracket expression rbracket [ colon identifier ]
+    ;
+
+    repeat =
+        lbrace expression rbrace
+    ;
+
+    group =
+        lpar expression rpar
+    ;
+
+    primary =
+        string_literal
+      | identifier
+    ;
+
+transform
+    grammar_file$repeat_0 ->
+        #main flatten(grammar_file.#sections, section, grammar_file$repeat_0) ;
+
+    token_section$repeat_1 ->
+        #main flatten(token_section.#definitions, token_def, token_section$repeat_1) ;
+
+    skip_section$repeat_2 ->
+        #main flatten(skip_section.#definitions, token_def, skip_section$repeat_2) ;
+
+    grammar_section$repeat_4 ->
+        #main flatten(grammar_section.#productions, production, grammar_section$repeat_4) ;
+
+    ast_section$repeat_5 ->
+        #main flatten(ast_section.#types, ast_type, ast_section$repeat_5) ;
+
+    transform_section$repeat_6 ->
+        #main flatten(transform_section.#rules, transform_rule, transform_section$repeat_6) ;
+
+    transform_rule$repeat_7 ->
+        #main flatten(transform_rule.#alternatives, labeled_transform, transform_rule$repeat_7) ;
+
+    reference_list$repeat_8 ->
+        #main flatten(reference_list.#references, reference, reference_list$repeat_8) ;
+
+    choice$repeat_9 ->
+        #main flatten(choice.#alternatives, alternative, choice$repeat_9) ;
+
+    sequence$repeat_10 ->
+        #main flatten(sequence.#factors, factor, sequence$repeat_10) ;

package/grammars/lisp.grammar

@@ -0,0 +1,95 @@
+// Very simple Lisp: s-expressions with numbers, symbols, and strings.
+//
+// Example:
+//
+//   ; factorial sketch
+//   (def factorial (n)
+//     (if (= n 0)
+//       1
+//       (* n (factorial (- n 1)))))
+//
+//   (quote hello)
+//   (+ 1 2 3)
+
+name "lisp" ;
+
+tokens
+    lpar = /\(/ ;
+    rpar = /\)/ ;
+
+    number = /[+-]?[0-9]+/ ;
+    symbol = /[a-zA-Z+*\-\/=<>?!_][a-zA-Z0-9+*\-\/=<>?!_]*/ ;
+    string = /"(?:\\.|[^"\\])*"/ ;
+
+skip
+    whitespace = /[ \t\r\n]+/ ;
+    comment = /;[^\n\r]*/ ;
+
+start program ;
+
+grammar
+    program =
+        { [item]:form }
+    ;
+
+    form =
+        #list list
+      | #atom atom
+    ;
+
+    list =
+        [open]:lpar
+        { [element]:form }
+        [close]:rpar
+    ;
+
+    atom =
+        #number [value]:number
+      | #symbol [value]:symbol
+      | #string [value]:string
+    ;
+
+ast
+    program =
+        { form }
+    ;
+
+    form =
+        #list list
+      | #atom atom
+    ;
+
+    list =
+        [open]:lpar
+        { [element]:form }
+        [close]:rpar
+    ;
+
+    atom =
+        #number [value]:number
+      | #symbol [value]:symbol
+      | #string [value]:string
+    ;
+
+transform
+    program ->
+        #main pass(program$repeat_0) ;
+
+    program$repeat_0 ->
+        #main flatten(program.#program, item, program$repeat_0) ;
+
+    form ->
+        #list pass(list)
+      | #atom pass(atom) ;
+
+    list ->
+        #main list.#list(open, list$repeat_1, close) ;
+
+    list$repeat_1 ->
+        #main flatten(form.#elements, element, list$repeat_1) ;
+
+    atom ->
+        #number atom.#number(value)
+      | #symbol atom.#symbol(value)
+      | #string atom.#string(value)
+    ;

package/package.json

@@ -1,7 +1,7 @@
 {
     "name": "parser-lr",
     "author": "Adam R Moss <adamrmoss@gmail.com>",
-    "version": "0.4.1",
+    "version": "0.6.0",
     "description": "Shift-reduce parser library for EBNF grammars",
     "license": "MIT",
     "repository": {
@@ -22,16 +22,21 @@
     "exports": {
         ".": {
             "types": "./dist/lib/index.d.ts",
-            "import": "./dist/lib/index.js"
+            "import": "./dist/lib/index.js",
+            "require": "./dist/lib-cjs/index.js",
+            "default": "./dist/lib/index.js"
         }
     },
     "bin": {
         "parser-lr": "bin/parser-lr.js"
     },
     "files": [
+        "README.md",
+        "LICENSE",
         "bin",
         "dist",
-        "docs"
+        "docs",
+        "grammars"
     ],
     "publishConfig": {
         "access": "public",
@@ -41,9 +46,10 @@
         "bootstrap": "npm link && parser-lr table generate -g grammars/grammar.grammar -o src/lib/grammar/grammar.json -a lalr",
         "build": "npm run build:clean && npm run build:lib && npm run build:cli",
         "build:clean": "rm -rf dist && rm -f bin/parser-lr.js bin/parser-lr.js.map",
-        "build:lib": "tsc -p tsconfig.lib.json && cp src/lib/grammar/grammar.json dist/lib/grammar/",
+        "build:lib": "node scripts/build-lib.mjs",
         "build:cli": "rollup -c rollup.cli.config.js && chmod +x bin/parser-lr.js",
         "cloc": "cloc src --exclude-dir=node_modules,dist",
+        "acceptance": "node scripts/acceptance-tarball.mjs",
         "test": "jest",
         "test:coverage": "jest --coverage",
         "prepack": "npm run build"