occt-gltf-addon-linux-x64 0.1.1 → 0.1.2

package/resources/samples/tcl/bottle.tcl

@@ -0,0 +1,115 @@
+# Script reproducing creation of bottle model as described in OCCT Tutorial
+#Category: Modeling
+#Title: OCCT Tutorial bottle shape
+
+pload MODELING VISUALIZATION
+
+puts "Constructing bottle body..."
+
+# set basic dimensions
+dset height 70
+dset width 50
+dset thickness 30
+
+# construct base profile (half)
+vertex v1 -width/2 0 0
+vertex v2 -width/2 -thickness/4 0
+edge e1 v1 v2
+
+point p2 -width/2 -thickness/4 0
+point p3 0 -thickness/2 0
+point p4 width/2 -thickness/4 0
+catch {gcarc arc cir p2 p3 p4}
+mkedge e2 arc
+
+vertex v4 width/2 -thickness/4 0
+vertex v5 width/2 0 0
+edge e3 v4 v5
+
+wire w1 e1 e2 e3
+
+# complete profile by mirror and make a prism
+copy w1 w2
+tmirror w2 0 0 0 0 1 0
+
+wire w3 w1 w2
+mkplane f w3
+
+prism p f 0 0 height
+
+# fillet all edges
+explode p e
+blend b p thickness/12 p_1 thickness/12 p_2 thickness/12 p_3 thickness/12 p_4 thickness/12 p_5 thickness/12 p_6 thickness/12 p_7 thickness/12 p_8 thickness/12 p_9 thickness/12 p_10 thickness/12 p_11 thickness/12 p_12 thickness/12 p_13 thickness/12 p_14 thickness/12 p_15 thickness/12 p_16 thickness/12 p_17 thickness/12 p_18
+
+# neck dimensions
+dset neckradius thickness/4
+dset neckheight height/10
+
+# add neck
+pcylinder c neckradius neckheight
+ttranslate c 0 0 height
+
+bfuse f b c
+
+# make body hollow
+explode c f
+offsetshape body f -thickness/50 1.e-3 c_2
+
+puts "Constructing threading..."
+
+# make two cylinders
+cylinder c1 0 0 height 0 0 1 neckradius*0.99
+cylinder c2 0 0 height 0 0 1 neckradius*1.05
+
+# define threading dimensions in parametric space
+dset major 2*pi
+dset minor neckheight/10
+
+# make parametric curves for threading
+ellipse el1 2*pi neckheight/2 2*pi neckheight/4 major minor
+ellipse el2 2*pi neckheight/2 2*pi neckheight/4 major minor/4
+
+trim arc1 el1 0 pi
+trim arc2 el2 0 pi
+
+2dcvalue el1 0 x1 y1
+2dcvalue el1 pi x2 y2
+
+line l x1 y1 x2-x1 y2-y1
+parameters l x2 y2 1.e-9 U
+trim s l 0 U
+
+# construct 3d edges and wires
+mkedge E1OnS1 arc1 c1 0 pi
+mkedge E2OnS1 s c1 0 U
+mkedge E1OnS2 arc2 c2 0 pi
+mkedge E2OnS2 s c2 0 U
+
+wire tw1 E1OnS1 E2OnS1
+wire tw2 E1OnS2 E2OnS2
+mkedgecurve tw1 1.e-5
+mkedgecurve tw2 1.e-5
+
+# build threading as solid
+thrusections -N thread 1 0 tw1 tw2
+
+puts "Putting together and writing \"Open CASCADE\"..."
+
+# define text
+text2brep text2d OpenCASCADE -font Times-Roman -height 8 -aspect bold -composite off
+prism text text2d 0 0 2
+trotate    text 0 0 0 0 1 0 90
+ttranslate text 24.75 -2 65
+
+# cut operation
+bcut bodytext body text
+bop bodytext thread
+bopfuse bottle
+
+puts "Showing result..."
+
+# display result
+vdisplay bottle
+vfit
+vsetdispmode 1
+vaspects -isoontriangulation 1

package/resources/samples/tcl/cad.tcl

@@ -0,0 +1,63 @@
+# This script creates a model described at
+# http://www.caddd.org/2010/04/opencascade-challenge.html
+#Category: Modeling
+#Title: CAD shape
+
+pload MODELING VISUALIZATION
+
+# make base 
+box b0 0  0 0 12 7 6
+explode b0 e
+blend b01 b0 1 b0_8
+blend b02 b01 1 b0_6
+
+# make cut at bottom
+box b1 3 -1 0 2 9 1.5
+bcut b2 b02 b1
+explode b2 e
+blend b3 b2 1 b2_27
+blend b4 b3 1 b2_30
+
+# make central cut
+box h1 3 -1 2.5 2 9 0.5
+box h2 3 -1 3 2 9 2
+plane p 4 -1 3 0 1 0
+pcylinder c p 1 9
+bcommon h3 h2 c
+bcut b5 b4 h1
+bcut b6 b5 h3
+
+# make side cut
+box b7 9 -1 1 2 9 4
+explode b7 e
+blend b71 b7 1 b7_6
+blend b72 b71 1 b7_8
+bcut b8 b6 b72
+
+# make box for inner cylindrical cut
+box bc1 -1 0 2 9 1 4
+box bc2 2 -1 2 4 3 3
+bcut bc3 bc1 bc2
+explode bc3 e
+blend bc4 bc3 1 bc3_20
+blend bc5 bc4 1 bc3_23
+blend bc6 bc5 1.99 bc3_21
+blend bc7 bc6 1.99 bc3_22
+
+# make inner cylindrical cut
+explode bc7 f
+revol r bc7_1 -1 0 6 1 0 0 100
+bcut b9 b8 r
+
+# make outer cylindrical cut
+plane p2 -1 0 6 1 0 0
+pcylinder c2 p2 6 15
+bcommon res b9 c2
+
+# show result
+donly res
+trotate res 0 0 0 0 0 1 90
+vinit View1
+vdisplay -dispMode 1 res
+vaspects res -setFaceBoundaryDraw 1 -setFaceBoundaryColor WHITE -isoontriangulation 1
+vfit

package/resources/samples/tcl/cpu.tcl

@@ -0,0 +1,327 @@
+# Sample model of Intel i7-4790 CPU
+# Dimensions are taken from specs and photo found in Internet
+
+#Category: XDE
+#Title: Intel i7-4790 CPU
+
+pload MODELING VISUALIZATION XDE
+
+puts "Making board..."
+
+# board is rectangle 37.5 x 37.5 mm with semi-round holes on two sides;
+# assumed board thickness is 1 mm
+dset L 37.5
+dset t 1.
+polyline pboard 0 0 0 L 0 0 L L 0 0 L 0 0 0 0 
+mkplane fboard pboard
+circle cslot -0.2 32.2 0 1
+mkedge eslot cslot
+wire wslot eslot
+mkplane fslot wslot
+bcut fboard fboard fslot
+ttranslate fslot L+0.4 0 0
+bcut fboard fboard fslot
+prism board fboard 0 0 t
+
+# make faces representing dard-green parts of the board sides
+mkoffset dgbot fboard 1 -0.5
+mkplane dgbot dgbot_1
+tcopy dgbot dgtop
+ttranslate dgtop 0 0 0.5*t
+box aux 36.6 17.7 0 10 8.4 2*t
+bcut dgtop dgtop aux
+prism pbot dgbot 0 0 0.5*t
+prism ptop dgtop 0 0 0.5*t
+bfuse board board pbot
+bfuse board board ptop
+
+# add triangular faces indicating base corner of the plate
+polyline btri 0.5 0.5 0 1.5 0.5 0 0.5 1.5 0 0.5 0.5 0
+polyline ttri 0.5 0.5 t 2.5 0.5 t 0.5 2.5 t 0.5 0.5 t
+thrusections stri 1 1 btri ttri
+bfuse board board stri
+
+explode board so
+renamevar board_1 board
+
+puts "Making case..."
+
+# case is made of two filleted prisms, base and top
+polyline lbase 3.4 1.8 t L-3.4 1.8 t L-3.4 11.4 t L-1.8 11.4 t L-1.8 25.2 t \
+               L-3.4 25.2 t L-3.4 L-3 t 3.4 L-3 t 3.4 25.2 t \
+               1.8 25.2 t 1.8 11.4 t 3.4 11.4 t 3.4 1.8 t
+mkplane f lbase
+explode f e
+chfi2d fbase f f_1 f_2 F 1.3 f_2 f_3 F 0.7 f_3 f_4 F 0.7 f_4 f_5 F 0.7 \
+               f_5 f_6 F 0.7 f_6 f_7 F 1.3 f_7 f_8 F 1.3 f_8 f_9 F 0.7 \
+               f_9 f_10 F 0.7 f_10 f_11 F 0.7 f_11 f_12 F 0.7 f_12 f_1 F 1.3
+
+polyline ltop 4. 3.4 t L-4 3.4 t L-4 L-4.8 t 4 L-4.8 t 4. 3.4 t
+mkplane f ltop
+explode f e
+chfi2d ftop f f_1 f_2 F 1.6 f_2 f_3 F 1.6 f_3 f_4 F 1.6 f_4 f_1 F 1.6
+
+# make case, assume height of base 1 mm and top additional 2.5 mm
+prism pbase fbase 0 0 1
+prism ptop ftop 0 0 3.5
+bfuse case pbase ptop
+
+explode case so
+renamevar case_1 case
+
+# write text on top of the case
+# note that font is chosen by availability of Unicode symbols,
+# it is different from actual font found on processor
+set font "Arial Unicode MS"
+#set text "i\u24c2\u00a911\nINTEL\u00ae CORE\u2122 i7-4790\nSR1QF 3.60GHZ\nMALAY\nL411B540 \u24d4"
+#text2brep title $text "Arial Unicode MS" 1.7 x=10 y=24 z=4.51
+# alternative variant to work-around issue #25852
+set text "i\u20dd\u20dd11\nINTEL\u20dd CORE\u2122 i7-4790\nSR1QF 3.60GHZ\nMALAY\nL411B540 \u20dd"
+text2brep title0 $text -font $font -height 1.7 -pos 10 24 4.51 -valign topfirstline
+text2brep title1 "    M    C" -font $font -height 0.77 -pos 10 24.2 4.51
+text2brep title2 "R" -font $font -height 0.77 -pos 15.3 21.9 4.51
+text2brep title3 "e4" -font $font -height 0.7 -pos 18.6 15.1 4.51
+compound title0 title1 title2 title3 title
+
+puts "Adding contact pads..."
+
+# contact pads on top side (round); we need 42 with R=0.3 and 1 with R=0.6
+pcylinder rpad 0.27 0.1
+eval compound [lrepeat 42 rpad] cpad
+set lpad [explode cpad]
+for {set i 1} {$i <= 20} {incr i} {
+  ttranslate cpad_[expr 2*$i  ] [expr 4.5  + $i * 0.7] L-0.7 t
+  ttranslate cpad_[expr 2*$i-1] [expr 4.85 + $i * 0.7] L-1.3 t
+}
+ttranslate cpad_41 L-0.7 L-0.7 t
+ttranslate cpad_42 L-0.7   0.7 t
+pcylinder Rpad 0.5 0.1
+ttranslate Rpad 0.9 L-0.9 t
+eval compound $lpad Rpad rpads
+
+# contact pads at the bottom
+box pad -0.45 -0.27 -0.1 0.9 0.54 0.1
+trotate pad 0 0 0 0 0 1 60
+ellipse c 0 0 -0.1 0.5 0.4
+mkedge e c
+wire w e
+mkplane f w
+prism b f 0 0 0.1
+bcommon bpad pad b
+explode bpad so
+renamevar bpad_1 bpad
+#donly bpad; boundings bpad
+
+# pattern of presence of bottom pads, on XY plane (top view)
+set pattern [join {
+..ooooooooooooooo...ooooooooooooooooo... 
+.oooooooooooooooo...ooooooooooooooooooo. 
+.oooooooooooooooooooooooooooooooooooooo. 
+.oooooooooooooooooooooooooooooooooooooo. 
+.oooooooooooooooooooooooooooooooooooooo. 
+.oooooooooooooooooooooooooooooooooooooo. 
+.oooooooooooooooooooooooooooooooooooooo. 
+.oooooooooooooooooooooooooooooooooooooo. 
+.ooooooooooo................ooooooooooo. 
+.oooooooooo.................ooooooooooo. 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+..oooooooooo................oooooooooo.. 
+..oooooooooo................oooooooooo.. 
+..oooooooooo................oooooooooo.. 
+..oooooooooo................oooooooooo.. 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+oooooooooooo................oooooooooooo 
+.ooooooooooo.................ooooooooooo 
+.ooooooooooo................oooooooooooo 
+.ooooooooooooooooooooooooooooooooooooooo 
+oooooooooooooooooooooooooooooooooooooooo 
+oooooooooooooooooooooooooooooooooooooooo 
+oooooooooooooooooooooooooooooooooooooooo 
+oooooooooooooooooooooooooooooooooooooooo 
+.ooooooooooooooooooooooooooooooooooooooo 
+..oooooooooooooooo...oooooooooooooooooo. 
+...ooooooooooooooo...ooooooooooooooooo.. 
+} ""]                                 
+
+set nbpads 0
+for {set i 0} {$i < 1600} {incr i} { 
+  if { [string index $pattern $i] == "o" } { incr nbpads }
+}
+eval compound [lrepeat $nbpads bpad] cpad
+set lpad [explode cpad]
+for {set ipad 1; set iplace 0} {$ipad <= $nbpads && $iplace < 1600} {incr ipad; incr iplace} {
+  while { [string index $pattern $iplace] == "." } { incr iplace }
+  set icol [expr $iplace % 40]
+  set irow [expr $iplace / 40]
+  ttranslate cpad_$ipad [expr 1 + 0.91 * $icol] [expr [dval L] - 1 - 0.91 * $irow] 0
+}
+
+# round and square contact pads on top side
+# note re-use of rpad object used for bottom round pads
+eval compound [lrepeat 8 rpad] crpads
+set lrpad [explode crpads]
+ttranslate crpads_1 25.3  8.4  -0.1
+ttranslate crpads_2 12.2 29.2  -0.1
+ttranslate crpads_3 12.5 15.   -0.1
+ttranslate crpads_4 12.5 18.75 -0.1
+ttranslate crpads_5 12.5 19.5  -0.1
+ttranslate crpads_6 12.5 20.25 -0.1
+ttranslate crpads_7 12.5 21.   -0.1
+ttranslate crpads_8 12.5 22.5  -0.1
+box spad_1 12.21 13.75 -0.1 0.58 0.58 0.1
+box spad_2 12.21 23.2  -0.1 0.58 0.58 0.1
+
+# final compound for all bottom pads
+eval compound $lpad $lrpad spad_1 spad_2 bpads
+
+# resistor-like packages at the bottom
+box rpk1 -0.6 -0.25 -0.5 0.3 0.5 0.5
+box rpk2 -0.3 -0.25 -0.5 0.6 0.5 0.5
+box rpk3  0.3 -0.25 -0.5 0.3 0.5 0.5
+compound rpk1 rpk2 rpk3 rpk
+
+eval compound [lrepeat 47 rpk] crpk
+set lrpk [explode crpk]
+# rotate first 26 packages vertically
+for {set i 1} {$i <= 26} {incr i} {trotate crpk_$i 0 0 0 0 0 1 90}
+# first 9 are vertical column on the right side of the bottom view
+for {set i 1} {$i <=  9} {incr i} {
+  ttranslate crpk_$i 13.4 [expr 9.8 + 1.6 * $i] 0 
+}
+# next 8 are 2x4 grid in top left corner
+for {set i 1} {$i <=  4} {incr i} {
+  ttranslate crpk_[expr  9 + $i] 23. [expr 21.5 + 1.6 * $i] 0 
+  ttranslate crpk_[expr 13 + $i] 24. [expr 21.5 + 1.6 * $i] 0 
+}
+# others are translated individually, vertical first, bottom to top
+ttranslate crpk_18 21.5  9.4 0
+ttranslate crpk_19 21.5 11.0 0
+ttranslate crpk_20 21.5 12.6 0
+ttranslate crpk_21 22.5  9.8 0
+ttranslate crpk_22 20.0 12.2 0
+ttranslate crpk_23 24.0 13.6 0
+ttranslate crpk_24 24.0 15.2 0
+ttranslate crpk_25 19.5 16.0 0
+ttranslate crpk_26 20.5 16.0 0
+# now horizontal, bottom to top
+ttranslate crpk_27 23.7  9.5 0
+ttranslate crpk_28 23.7 10.5 0
+ttranslate crpk_29 22.8 11.5 0
+ttranslate crpk_30 22.8 12.5 0
+ttranslate crpk_31 22.7 14.3 0
+ttranslate crpk_32 22.7 16.0 0
+ttranslate crpk_33 22.8 17.0 0
+ttranslate crpk_34 22.8 19.1 0
+ttranslate crpk_35 22.7 20.0 0
+ttranslate crpk_36 23.0 20.9 0
+ttranslate crpk_37 23.3 21.8 0
+
+ttranslate crpk_38 19.8 21.6 0
+ttranslate crpk_39 19.8 22.6 0
+ttranslate crpk_40 19.8 23.6 0
+ttranslate crpk_41 21.6 22.2 0
+ttranslate crpk_42 21.6 23.2 0
+ttranslate crpk_43 21.6 24.2 0
+
+ttranslate crpk_44 18.0 24.6 0
+ttranslate crpk_45 18.0 25.6 0
+ttranslate crpk_46 18.0 26.6 0
+ttranslate crpk_47 18.0 27.6 0
+
+eval compound $lrpk brpk
+
+# show result in 3d viewer
+vinit View1
+vclear
+vsetdispmode 1
+vrenderparams -msaa 8
+vlight -clear
+vlight amblight -type AMBIENT
+vlight dirlight -type DIRECTIONAL -direction 1 -1 -2 -head 1
+if [info exists i7_show_3dview] {
+  vdisplay case
+  vsetcolor case GRAY70
+
+  vdisplay title
+  vsetcolor title GRAY10
+
+  # board is mostly yellow (edges, triangle markers)
+  foreach f [explode board f] { vdisplay $f; vsetcolor $f B3803D }
+  # top and bottom faces are light-green (outside) and dark-green (inside)
+  vsetcolor board_4  00998C
+  vsetcolor board_5  00998C
+  vsetcolor board_12 004D54
+  vsetcolor board_14 004D54
+
+  vdisplay rpads
+  vsetcolor rpads B39966
+
+  vdisplay bpads
+  vsetcolor bpads B39966
+
+  vdisplay brpk
+  vsetcolor brpk 80664D
+
+  donly board case rpads brpk; fit
+}
+
+# make XDE document
+catch {Close D}
+pload OCAF XDE
+
+NewDocument D MDTV-XCAF
+
+SetName D [XAddShape D board 0] "Board"
+foreach f [explode board f] { XSetColor D $f B3803D }
+XSetColor D board_4  00998C
+XSetColor D board_5  00998C
+XSetColor D board_12 004D54
+XSetColor D board_14 004D54
+
+SetName D [XAddShape D case 0] "Case"
+XSetColor D case GRAY70
+
+SetName D [XAddShape D title 0] "Case title"
+XSetColor D title GRAY10
+
+SetName D [XAddShape D rpads 1] "Top side contact pads"
+SetName D [XAddShape D bpads 1] "Bottom contact pads"
+SetName D [XFindShape D bpad] "Contact pad"
+SetName D [XFindShape D rpad] "Round pad"
+SetName D [XFindShape D Rpad] "Big round pad"
+SetName D [XFindShape D spad_1] "Square pad 1"
+SetName D [XFindShape D spad_2] "Square pad 2"
+XSetColor D rpad   B39966
+XSetColor D Rpad   B39966
+XSetColor D bpad   B39966
+XSetColor D spad_1 B39966
+XSetColor D spad_2 B39966
+
+SetName D [XAddShape D brpk 1] "Bottom packages"
+SetName D [XFindShape D rpk] "Bottom package"
+XSetColor D rpk1 GRAY70
+XSetColor D rpk2 80664D
+XSetColor D rpk3 GRAY70
+
+# display in 3D Viewer
+XDisplay -dispMode 1 D -explore
+vfit
+
+# save to STEP if variable i7_save_xde is defined (specifies file name)
+if [info exists i7_save_xde] {
+  param write.surfacecurve.mode 0
+  WriteStep D $i7_save_xde
+}

package/resources/samples/tcl/cutter.tcl

@@ -0,0 +1,91 @@
+# Sample: creation of milling cutter
+#Category: Modeling
+#Title: Milling cutter
+
+pload MODELING VISUALIZATION
+
+# parameters
+dset R  10.    ;# outer radius
+dset H  20.    ;# height of the spiral part
+dset a  0.5*pi ;# total angle of spiral rotation
+
+# make profile
+
+circle outer 0 0 0 0 0 1 R
+circle inner 0 0 0 0 0 1 R-2
+circle round 3 6 0 0 0 1 5
+polyline cut -2 0 0  -2 R+1 0  0.5 R+1 0  -1 0 0  -2 0 0
+
+proc _curvetoface {name} {
+  uplevel #0 mkedge $name $name
+  uplevel #0 wire $name $name
+  uplevel #0 mkface $name p0 $name
+}
+
+plane p0
+_curvetoface outer
+_curvetoface inner
+_curvetoface round
+mkface cut p0 cut
+
+bcommon teeth cut round
+bcommon teeth teeth outer
+
+tcopy inner profile
+set nbteeths 25
+for {set i 0} {$i < $nbteeths} {incr i} {
+  bfuse profile profile teeth
+  trotate teeth 0 0 0 0 0 1 360./$nbteeths
+}
+unifysamedom profile profile
+
+# sweep profile along curved shape
+
+polyline sp 0 0 0  0 0 H
+cylinder ss 0 0 0  0 0 1  1 0 0  R
+vertex v1 R 0 0
+vertex v2 R 0 H
+line ll 0 0 a H
+trim ll ll 0 sqrt(a*a+H*H)
+
+trotate v2 0 0 0 0 0 1 180.*a/pi
+mkedge ee ll ss v1 v2
+wire gg ee
+ 
+donly profile sp gg
+explode profile w
+tcopy profile_1 profile_2 
+tcopy profile_1 profile_3
+tscale profile_1  0 0 0  1./(R-2) 
+ttranslate profile_2 0 0 H/2
+tscale profile_2  0 0 H/2  4./(R-2) 
+ttranslate profile_3 0 0 H
+tscale profile_3  0 0 H  3./(R-2) 
+
+mksweep sp
+setsweep -G gg 0 0
+addsweep profile_1
+addsweep profile_2
+addsweep profile_3
+vclear
+
+buildsweep base -S
+
+# make a shank
+plane p1 0 0 H 0 0 1
+pcylinder shank p1 1.4 H
+plane p2 0 0 H+1 0 0 1
+pcylinder sh2 p2 1.5 H-1
+bfuse shank shank sh2
+bfuse cutter base shank
+
+# check result
+checkshape cutter
+
+# show result
+incmesh cutter 0.01
+vdisplay cutter
+vsetdispmode cutter 1
+vrenderparams -msaa 8
+incmesh profile_1 0.01; vdisplay profile_1
+vfit

package/resources/samples/tcl/dimensions.tcl

@@ -0,0 +1,83 @@
+# Dimensions demo
+#
+# It shows capability of OCC to create different kinds
+# of dimensions (linear and angular) with 2D or 3D text.
+
+#Category: Visualization
+#Title: Dimensions in 3d viewer
+
+set aTopLoc [locate_data_file occ/Top.brep]
+set aBotLoc [locate_data_file occ/Bottom.brep]
+set aHatch  [locate_data_file images/hatch_1.png]
+
+pload MODELING VISUALIZATION
+
+puts "Importing shapes..."
+restore $aTopLoc a
+restore $aBotLoc b
+
+vinit View1 w=768 h=768
+vclear
+vsetdispmode 0
+vbackground -color WHITE
+vbottom
+
+puts "Getting cut projection..."
+box bb -150 -250 0 150 250 100
+bsection bs b bb
+bsection as a bb
+vdisplay bs as
+vfit
+
+set anAEdges [explode as E]
+set aBEbges  [explode bs E]
+
+set anArrAngle [expr 3.14 * 12.0 / 180.0]
+
+# Form dimension names list to set parameters with vdimparam command
+set aList {rd_1 rd_2 ad_1 ad_2 ad_3}
+for {set i 1} {$i <= 10} {incr i} { lappend aList ld_$i }
+
+puts "Creating dimensions..."
+vdimension ld_1 -length -shapes bs_27 -plane xoy -color black -flyout -15
+vdimension ld_2 -length -shapes bs_14 -plane xoy -color black -flyout 15
+vdimension ld_3 -length -shapes bs_28 -plane xoy -color black -label right -flyout -27
+vdimension ld_4 -length -shapes as_7 -plane xoy -color black -flyout -20
+vdimension ld_5 -length -shapes as_28 -plane xoy -color black -flyout -15
+vdimension ld_6 -length -shapes as_18 -plane xoy -color black -flyout 30
+vdimension ld_7 -length -shapes bs_20 -plane xoy -color black -flyout -20
+vdimension ld_8 -length -shapes as_42 -plane xoy -color black -flyout 55 -label right
+vdimension ld_9 -length -shapes as_12 -plane xoy -color black -flyout 35 -label right
+vdimension ld_10 -length -shapes as_40 -plane xoy -color black -flyout 15
+
+vdimension rd_1 -radius -shapes bs_45 -color black -label right
+vdimension rd_2 -radius -shapes bs_63 -color black
+
+vdimension ad_1 -angle -shapes as_38 as_49 -color black
+vdimension ad_2 -angle -shapes bs_24 bs_25 -color black
+vdimension ad_3 -angle -shapes as_48 as_42 -color black
+
+puts "Changing text and arrow parameters of dimensions..."
+foreach i $aList {
+  vdimparam $i -text 3d sh 6 -arrowlength 4 -arrowangle $anArrAngle
+}
+
+vfit
+
+puts "Displaying exported shapes..."
+vdisplay -dispMode 1 a b
+vaspects a -setmaterial steel
+vaspects b -setmaterial bronze
+
+puts "Clipping shapes for better view..."
+
+vclipplane pa -set a -equation 0 0 1 0 -capping on -color GRAY90 -texName $aHatch -texScale 0.05 -0.05
+vclipplane pb -set b -equation 0 0 1 0 -capping on -color GOLD   -texName $aHatch -texScale 0.05 -0.05
+
+vbottom
+vrotate -0.3 -0.3 0
+vfit
+vzoom 1.2
+vrenderparams -msaa 8
+
+puts "Done."