mparticle-roku-sdk 2.1.16

package/mParticleTask.brs

@@ -0,0 +1,78 @@
+'*************************************************************
+' mParticle Roku SDK - mParticle Task Node for Scene Graph
+' Copyright 2019 mParticle, Inc.
+'*************************************************************
+
+sub init()
+    m.port = createObject("roMessagePort")
+    m.top.observeField("mParticleApiCall", m.port)
+    m.top.functionName = "setupRunLoop"
+    m.top.control = "RUN"
+end sub
+
+sub setupRunLoop()
+    options = m.global.mparticleOptions
+    options.addReplace("batchUploads", true)
+    mParticleStart(options, m.port)
+    m.mparticle = mparticle()
+    m.top[mParticleConstants().SCENEGRAPH_NODES.CURRENT_USER_NODE] = m.mparticle.identity.getCurrentUser()
+    while true
+        msg = wait(15 * 1000, m.port)
+        if (msg = invalid) then
+            m.mparticle._internal.sessionManager.updateLastEventTime(m.mparticle._internal.utils.unixTimeMillis())
+            m.mparticle._internal.networking.queueUpload()
+            m.mparticle._internal.networking.processUploads()
+        else
+            mt = type(msg)
+
+            if mt = "roSGNodeEvent"
+                if msg.getField() = mParticleConstants().SCENEGRAPH_NODES.API_CALL_NODE
+                    executeApiCall(msg.getData())
+                end if
+            else if (mt = "roUrlEvent")
+                if m.mparticle.isMparticleEvent(msg.getSourceIdentity())
+                    identityResult = m.mparticle.onUrlEvent(msg)
+                    if (identityResult <> invalid) then
+                        m.top[mParticleConstants().SCENEGRAPH_NODES.IDENTITY_RESULT_NODE] = identityResult
+                        if (identityResult.httpcode = 200) then
+                            m.top[mParticleConstants().SCENEGRAPH_NODES.CURRENT_USER_NODE] = m.mparticle.identity.getCurrentUser()
+                        end if
+                    end if
+                end if
+            else
+                print "Error: unrecognized event type '"; mt ; "'"
+            end if
+        end if
+    end while
+end sub
+
+function executeApiCall(apiCall as object)
+    args = apiCall.args
+    length = args.count()
+    if (apiCall.methodName.Instr("identity/") = 0) then
+        target = m.mparticle.identity
+        methodName = apiCall.methodName.Replace("identity/", "")
+    else if (apiCall.methodName.Instr("media/") = 0) then
+        target = m.mparticle.media
+        methodName = apiCall.methodName.Replace("media/", "")
+    else
+        target = m.mparticle
+        methodName = apiCall.methodName
+    end if
+
+    if (length = 0) then
+        target[methodName]()
+    else if (length = 1) then
+        target[methodName](args[0])
+    else if (length = 2) then
+        target[methodName](args[0], args[1])
+    else if (length = 3) then
+        target[methodName](args[0], args[1], args[2])
+    else if (length = 4) then
+        target[methodName](args[0], args[1], args[2], args[3])
+    else if (length = 5) then
+        target[methodName](args[0], args[1], args[2], args[3], args[4])
+    else if (length = 6) then
+        target[methodName](args[0], args[1], args[2], args[3], args[4], args[5])
+    end if
+end function

package/mParticleTask.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="utf-8" ?>
+<component name="mParticleTask" extends="Task">
+  <interface>
+  	<field id="mParticleApiCall" type="assocarray"/>
+  	<field id="mParticleIdentityResult" type="assocarray"/>
+  	<field id="mParticleCurrentUser" type="assocarray"/>
+  </interface>
+  <!-- Replace with correct path if necessary -->
+  <script type="text/brightscript" uri="pkg:/components/mParticleTask.brs"/>
+  <!-- Replace with correct path if necessary -->
+  <script type="text/brightscript" uri="pkg:/source/mparticle/mParticleCore.brs"/>
+</component>

package/package.json

@@ -0,0 +1,5 @@
+{
+    "name": "mparticle-roku-sdk",
+    "description": "mParticle SDK for Roku Streaming devices",
+    "version": "2.1.16"
+}

package/testing/tests/Test__mParticle.brs

@@ -0,0 +1,88 @@
+function TestSuite__mParticle() as object
+    this = BaseTestSuite()
+    this.Name = "mParticleTestSuite"
+    this.addTest("TestCase__mParticle_CheckConfiguration", TestCase__mParticle_CheckConfiguration)
+    this.addTest("TestCase__mParticle_CheckDefaultEnvironment", TestCase__mParticle_CheckDefaultEnvironment)
+    this.addTest("TestCase__mParticle_CheckSetEnvironment", TestCase__mParticle_CheckSetEnvironment)
+    this.addTest("TestCase__mParticle_TestSetUserIdentity", TestCase__mParticle_TestSetUserIdentity)
+
+    this.SetUp = mParticleTestSuite__SetUp
+    this.TearDown = mParticleTestSuite__TearDown
+    return this
+end function
+
+sub mParticleTestSuite__SetUp()
+end sub
+
+sub mParticleTestSuite__TearDown()
+end sub
+
+function reset()
+    getGlobalAA().mparticleInstance = invalid
+end function
+
+function TestCase__mParticle_CheckConfiguration() as string
+    reset()
+    options = {}
+    options.logLevel = mparticleConstants().LOG_LEVEL.DEBUG
+    options.apiKey = "fookey"
+    options.apiSecret = "foosecret"
+    option.dataPlanId = "fooId"
+    options.dataPlanVersion = 1
+    options.isscenegraph = true
+    mparticlestart(options)
+    msgs = []
+    msgs.push(m.assertEqual(mparticle()._internal.configuration.apiKey, "fookey"))
+    msgs.push(m.assertEqual(mparticle()._internal.configuration.apiSecret, "foosecret"))
+    msgs.push(m.assertEqual(mparticle()._internal.configuration.dataPlanId, "fooId"))
+    msgs.push(m.assertEqual(mparticle()._internal.configuration.dataPlanVersion, 1))
+    msgs.push(m.assertEqual(mparticle()._internal.configuration.logLevel, mparticleConstants().LOG_LEVEL.DEBUG))
+    msgs.push(m.assertTrue(mparticle()._internal.configuration.isscenegraph))
+    return testResult(msgs)
+end function
+
+function TestCase__mParticle_CheckDefaultEnvironment() as string
+    reset()
+    options = {}
+    mparticlestart(options)
+    msgs = []
+    msgs.push(m.assertTrue(mparticle()._internal.configuration.development))
+    return testResult(msgs)
+end function
+
+function TestCase__mParticle_CheckSetEnvironment() as string
+    reset()
+    options = {}
+    options.environment = mParticleConstants().ENVIRONMENT.FORCE_DEVELOPMENT
+    mparticlestart(options)
+    msgs = []
+    msgs.push(m.assertTrue(mparticle()._internal.configuration.development))
+    return testResult(msgs)
+end function
+
+function TestCase__mParticle_TestSetUserIdentity() as string
+    reset()
+    options = {}
+    mparticlestart({})
+    mp = mparticle()
+    mp._internal.storage.clear()
+    mp.setuseridentity(mparticleConstants().IDENTITY_TYPE.CUSTOMER_ID, "foo-customer-id")
+    identity = mparticle()._internal.storage.getUserIdentities().lookup(mparticleConstants().IDENTITY_TYPE.CUSTOMER_ID)
+    msgs = []
+    msgs.push(m.assertEqual(identity.n, mparticleConstants().IDENTITY_TYPE.CUSTOMER_ID))
+    msgs.push(m.assertEqual(identity.i, "foo-customer-id"))
+    return testResult(msgs)
+end function
+
+function testResult(msgs as object) as string
+    endMessage = []
+    for each msg in msgs
+        if (len(msg) > 0)
+            endMessage.push(msg)
+        end if
+    end for
+    if (endMessage.count() > 0)
+        return formatjson(endmessage)
+    end if
+    return ""
+end function