mcp-server-semgrep 1.0.0

package/semgrep-rules/solidity/security/compound-borrowfresh-reentrancy.sol

@@ -0,0 +1,3386 @@
+pragma solidity ^0.5.16;
+
+/**
+  * @title Compound's InterestRateModel Interface
+  * @author Compound
+  */
+contract InterestRateModel {
+    /// @notice Indicator that this is an InterestRateModel contract (for inspection)
+    bool public constant isInterestRateModel = true;
+
+    /**
+      * @notice Calculates the current borrow interest rate per block
+      * @param cash The total amount of cash the market has
+      * @param borrows The total amount of borrows the market has outstanding
+      * @param reserves The total amount of reserves the market has
+      * @return The borrow rate per block (as a percentage, and scaled by 1e18)
+      */
+    function getBorrowRate(uint cash, uint borrows, uint reserves) external view returns (uint);
+
+    /**
+      * @notice Calculates the current supply interest rate per block
+      * @param cash The total amount of cash the market has
+      * @param borrows The total amount of borrows the market has outstanding
+      * @param reserves The total amount of reserves the market has
+      * @param reserveFactorMantissa The current reserve factor the market has
+      * @return The supply rate per block (as a percentage, and scaled by 1e18)
+      */
+    function getSupplyRate(uint cash, uint borrows, uint reserves, uint reserveFactorMantissa) external view returns (uint);
+
+}
+
+
+
+
+
+
+
+
+
+
+
+
+contract ComptrollerErrorReporter {
+    enum Error {
+        NO_ERROR,
+        UNAUTHORIZED,
+        COMPTROLLER_MISMATCH,
+        INSUFFICIENT_SHORTFALL,
+        INSUFFICIENT_LIQUIDITY,
+        INVALID_CLOSE_FACTOR,
+        INVALID_COLLATERAL_FACTOR,
+        INVALID_LIQUIDATION_INCENTIVE,
+        MARKET_NOT_ENTERED, // no longer possible
+        MARKET_NOT_LISTED,
+        MARKET_ALREADY_LISTED,
+        MATH_ERROR,
+        NONZERO_BORROW_BALANCE,
+        PRICE_ERROR,
+        REJECTION,
+        SNAPSHOT_ERROR,
+        TOO_MANY_ASSETS,
+        TOO_MUCH_REPAY,
+
+        // OLA_ADDITIONS : All Enums from here
+        NOT_IN_MARKET,
+        TOO_LITTLE_BORROW,
+        IN_FRESH_LIQUIDATION_LIMITED_PERIOD,
+        INVALID_LIQUIDATION_FACTOR,
+        BORROWED_AGAINST_FAILED,
+        TOTAL_BORROWED_AGAINST_TOO_HIGH,
+        TOO_MUCH_COLLATERAL_ACTIVATION,
+
+        // V0.02
+        NOT_APPROVED_TO_MINT,
+        NOT_APPROVED_TO_BORROW
+    }
+
+    enum FailureInfo {
+        ACCEPT_ADMIN_PENDING_ADMIN_CHECK,
+        ACCEPT_PENDING_IMPLEMENTATION_ADDRESS_CHECK,
+        EXIT_MARKET_BALANCE_OWED,
+        EXIT_MARKET_REJECTION,
+        SET_CLOSE_FACTOR_OWNER_CHECK,
+        SET_CLOSE_FACTOR_VALIDATION,
+        SET_COLLATERAL_FACTOR_OWNER_CHECK,
+        SET_COLLATERAL_FACTOR_NO_EXISTS,
+        SET_COLLATERAL_FACTOR_VALIDATION,
+        SET_COLLATERAL_FACTOR_WITHOUT_PRICE,
+        SET_IMPLEMENTATION_OWNER_CHECK,
+        SET_LIQUIDATION_INCENTIVE_OWNER_CHECK,
+        SET_LIQUIDATION_INCENTIVE_VALIDATION,
+        SET_MAX_ASSETS_OWNER_CHECK,
+        SET_PENDING_ADMIN_OWNER_CHECK,
+        SET_PENDING_IMPLEMENTATION_OWNER_CHECK,
+        SET_PRICE_ORACLE_OWNER_CHECK,
+        SUPPORT_MARKET_EXISTS,
+        SUPPORT_MARKET_OWNER_CHECK,
+        SET_PAUSE_GUARDIAN_OWNER_CHECK,
+
+        // OLA_ADDITIONS : All Enums from here
+        SET_LIQUIDATION_INCENTIVE_NO_EXISTS,
+        SET_LIQUIDATION_INCENTIVE_WITHOUT_PRICE,
+        SET_LIQUIDATION_FACTOR_OWNER_CHECK,
+        SET_LIQUIDATION_FACTOR_NO_EXISTS,
+        SET_LIQUIDATION_FACTOR_VALIDATION,
+        SET_LIQUIDATION_FACTOR_WITHOUT_PRICE,
+        SET_LIQUIDATION_FACTOR_LOWER_THAN_COLLATERAL_FACTOR,
+        SET_LIQUIDATION_FACTOR_LOWER_THAN_EXISTING_FACTOR,
+        SET_COLLATERAL_FACTOR_HIGHER_THAN_LIQUIDATION_FACTOR,
+        SET_RAIN_MAKER_OWNER_CHECK,
+        ENTER_MARKET_NOT_ALLOWED,
+        UPDATE_LN_VERSION_ADMIN_OWNER_CHECK,
+        // V0.002
+        SET_BOUNCER_OWNER_CHECK,
+        SET_LIMIT_MINTING_OWNER_CHECK,
+        SET_LIMIT_BORROWING_OWNER_CHECK,
+        SET_MIN_BORROW_AMOUNT_USD_OWNER_CHECK,
+        SUPPORT_NEW_MARKET_OWNER_CHECK,
+        SUPPORT_NEW_MARKET_COMBINATION_CHECK
+    }
+
+    /**
+      * @dev `error` corresponds to enum Error; `info` corresponds to enum FailureInfo, and `detail` is an arbitrary
+      * contract-specific code that enables us to report opaque error codes from upgradeable contracts.
+      **/
+    event Failure(uint error, uint info, uint detail);
+
+    /**
+      * @dev use this when reporting a known error from the money market or a non-upgradeable collaborator
+      */
+    function fail(Error err, FailureInfo info) internal returns (uint) {
+        emit Failure(uint(err), uint(info), 0);
+
+        return uint(err);
+    }
+
+    /**
+      * @dev use this when reporting an opaque error from an upgradeable collaborator contract
+      */
+    function failOpaque(Error err, FailureInfo info, uint opaqueError) internal returns (uint) {
+        emit Failure(uint(err), uint(info), opaqueError);
+
+        return uint(err);
+    }
+}
+
+contract TokenErrorReporter {
+    enum Error {
+        NO_ERROR,
+        UNAUTHORIZED,
+        BAD_INPUT,
+        COMPTROLLER_REJECTION,
+        COMPTROLLER_CALCULATION_ERROR,
+        INTEREST_RATE_MODEL_ERROR,
+        INVALID_ACCOUNT_PAIR,
+        INVALID_CLOSE_AMOUNT_REQUESTED,
+        INVALID_COLLATERAL_FACTOR,
+        MATH_ERROR,
+        MARKET_NOT_FRESH,
+        MARKET_NOT_LISTED,
+        TOKEN_INSUFFICIENT_ALLOWANCE,
+        TOKEN_INSUFFICIENT_BALANCE,
+        TOKEN_INSUFFICIENT_CASH,
+        TOKEN_TRANSFER_IN_FAILED,
+        TOKEN_TRANSFER_OUT_FAILED,
+
+        // OLA_ADDITIONS : All Enums from here
+        BAD_SYSTEM_PARAMS
+    }
+
+    /*
+     * Notice: FailureInfo (but not Error) is kept in alphabetical order
+     *       This is because FailureInfo grows significantly faster, and
+     *       the order of Error has some meaning, while the order of FailureInfo
+     *       is entirely arbitrary.
+     */
+    enum FailureInfo {
+        ACCEPT_ADMIN_PENDING_ADMIN_CHECK,
+        ACCRUE_INTEREST_ACCUMULATED_INTEREST_CALCULATION_FAILED,
+        ACCRUE_INTEREST_BORROW_RATE_CALCULATION_FAILED,
+        ACCRUE_INTEREST_NEW_BORROW_INDEX_CALCULATION_FAILED,
+        ACCRUE_INTEREST_NEW_TOTAL_BORROWS_CALCULATION_FAILED,
+        ACCRUE_INTEREST_NEW_TOTAL_RESERVES_CALCULATION_FAILED,
+        ACCRUE_INTEREST_SIMPLE_INTEREST_FACTOR_CALCULATION_FAILED,
+        BORROW_ACCUMULATED_BALANCE_CALCULATION_FAILED,
+        BORROW_ACCRUE_INTEREST_FAILED,
+        BORROW_CASH_NOT_AVAILABLE,
+        BORROW_FRESHNESS_CHECK,
+        BORROW_NEW_TOTAL_BALANCE_CALCULATION_FAILED,
+        BORROW_NEW_ACCOUNT_BORROW_BALANCE_CALCULATION_FAILED,
+        BORROW_MARKET_NOT_LISTED,
+        BORROW_COMPTROLLER_REJECTION,
+        LIQUIDATE_ACCRUE_BORROW_INTEREST_FAILED,
+        LIQUIDATE_ACCRUE_COLLATERAL_INTEREST_FAILED,
+        LIQUIDATE_COLLATERAL_FRESHNESS_CHECK,
+        LIQUIDATE_COMPTROLLER_REJECTION,
+        LIQUIDATE_COMPTROLLER_CALCULATE_AMOUNT_SEIZE_FAILED,
+        LIQUIDATE_CLOSE_AMOUNT_IS_UINT_MAX,
+        LIQUIDATE_CLOSE_AMOUNT_IS_ZERO,
+        LIQUIDATE_FRESHNESS_CHECK,
+        LIQUIDATE_LIQUIDATOR_IS_BORROWER,
+        LIQUIDATE_REPAY_BORROW_FRESH_FAILED,
+        LIQUIDATE_SEIZE_BALANCE_INCREMENT_FAILED,
+        LIQUIDATE_SEIZE_BALANCE_DECREMENT_FAILED,
+        LIQUIDATE_SEIZE_COMPTROLLER_REJECTION,
+        LIQUIDATE_SEIZE_LIQUIDATOR_IS_BORROWER,
+        LIQUIDATE_SEIZE_TOO_MUCH,
+        MINT_ACCRUE_INTEREST_FAILED,
+        MINT_COMPTROLLER_REJECTION,
+        MINT_EXCHANGE_CALCULATION_FAILED,
+        MINT_EXCHANGE_RATE_READ_FAILED,
+        MINT_FRESHNESS_CHECK,
+        MINT_NEW_ACCOUNT_BALANCE_CALCULATION_FAILED,
+        MINT_NEW_TOTAL_SUPPLY_CALCULATION_FAILED,
+        MINT_TRANSFER_IN_FAILED,
+        MINT_TRANSFER_IN_NOT_POSSIBLE,
+        REDEEM_ACCRUE_INTEREST_FAILED,
+        REDEEM_COMPTROLLER_REJECTION,
+        REDEEM_EXCHANGE_TOKENS_CALCULATION_FAILED,
+        REDEEM_EXCHANGE_AMOUNT_CALCULATION_FAILED,
+        REDEEM_EXCHANGE_RATE_READ_FAILED,
+        REDEEM_FRESHNESS_CHECK,
+        REDEEM_NEW_ACCOUNT_BALANCE_CALCULATION_FAILED,
+        REDEEM_NEW_TOTAL_SUPPLY_CALCULATION_FAILED,
+        REDEEM_TRANSFER_OUT_NOT_POSSIBLE,
+        REDUCE_RESERVES_ACCRUE_INTEREST_FAILED,
+        REDUCE_RESERVES_ADMIN_CHECK,
+        REDUCE_RESERVES_CASH_NOT_AVAILABLE,
+        REDUCE_RESERVES_FRESH_CHECK,
+        REDUCE_RESERVES_VALIDATION,
+        REPAY_BEHALF_ACCRUE_INTEREST_FAILED,
+        REPAY_BORROW_ACCRUE_INTEREST_FAILED,
+        REPAY_BORROW_ACCUMULATED_BALANCE_CALCULATION_FAILED,
+        REPAY_BORROW_COMPTROLLER_REJECTION,
+        REPAY_BORROW_FRESHNESS_CHECK,
+        REPAY_BORROW_NEW_ACCOUNT_BORROW_BALANCE_CALCULATION_FAILED,
+        REPAY_BORROW_NEW_TOTAL_BALANCE_CALCULATION_FAILED,
+        REPAY_BORROW_TRANSFER_IN_NOT_POSSIBLE,
+        SET_COLLATERAL_FACTOR_OWNER_CHECK,
+        SET_COLLATERAL_FACTOR_VALIDATION,
+        SET_COMPTROLLER_OWNER_CHECK,
+        SET_INTEREST_RATE_MODEL_ACCRUE_INTEREST_FAILED,
+        SET_INTEREST_RATE_MODEL_FRESH_CHECK,
+        SET_INTEREST_RATE_MODEL_OWNER_CHECK,
+        SET_MAX_ASSETS_OWNER_CHECK,
+        SET_ORACLE_MARKET_NOT_LISTED,
+        SET_PENDING_ADMIN_OWNER_CHECK,
+        SET_RESERVE_FACTOR_ACCRUE_INTEREST_FAILED,
+        SET_RESERVE_FACTOR_ADMIN_CHECK,
+        SET_RESERVE_FACTOR_FRESH_CHECK,
+        SET_RESERVE_FACTOR_BOUNDS_CHECK,
+        TRANSFER_COMPTROLLER_REJECTION,
+        TRANSFER_NOT_ALLOWED,
+        TRANSFER_NOT_ENOUGH,
+        TRANSFER_TOO_MUCH,
+        ADD_RESERVES_ACCRUE_INTEREST_FAILED,
+        ADD_RESERVES_FRESH_CHECK,
+        ADD_RESERVES_TRANSFER_IN_NOT_POSSIBLE,
+
+        // OLA_ADDITIONS : All Enums from here
+        REDUCE_RESERVES_OLA_PART_CALCULATION_FAILED
+    }
+
+    /**
+      * @dev `error` corresponds to enum Error; `info` corresponds to enum FailureInfo, and `detail` is an arbitrary
+      * contract-specific code that enables us to report opaque error codes from upgradeable contracts.
+      **/
+    event Failure(uint error, uint info, uint detail);
+
+    /**
+      * @dev use this when reporting a known error from the money market or a non-upgradeable collaborator
+      */
+    function fail(Error err, FailureInfo info) internal returns (uint) {
+        emit Failure(uint(err), uint(info), 0);
+
+        return uint(err);
+    }
+
+    /**
+      * @dev use this when reporting an opaque error from an upgradeable collaborator contract
+      */
+    function failOpaque(Error err, FailureInfo info, uint opaqueError) internal returns (uint) {
+        emit Failure(uint(err), uint(info), opaqueError);
+
+        return uint(err);
+    }
+}
+
+
+
+
+/**
+  * @title Careful Math
+  * @author Compound
+  * @notice Derived from OpenZeppelin's SafeMath library
+  *         https://github.com/OpenZeppelin/openzeppelin-solidity/blob/master/contracts/math/SafeMath.sol
+  */
+contract CarefulMath {
+
+    /**
+     * @dev Possible error codes that we can return
+     */
+    enum MathError {
+        NO_ERROR,
+        DIVISION_BY_ZERO,
+        INTEGER_OVERFLOW,
+        INTEGER_UNDERFLOW
+    }
+
+    /**
+    * @dev Multiplies two numbers, returns an error on overflow.
+    */
+    function mulUInt(uint a, uint b) internal pure returns (MathError, uint) {
+        if (a == 0) {
+            return (MathError.NO_ERROR, 0);
+        }
+
+        uint c = a * b;
+
+        if (c / a != b) {
+            return (MathError.INTEGER_OVERFLOW, 0);
+        } else {
+            return (MathError.NO_ERROR, c);
+        }
+    }
+
+    /**
+    * @dev Integer division of two numbers, truncating the quotient.
+    */
+    function divUInt(uint a, uint b) internal pure returns (MathError, uint) {
+        if (b == 0) {
+            return (MathError.DIVISION_BY_ZERO, 0);
+        }
+
+        return (MathError.NO_ERROR, a / b);
+    }
+
+    /**
+    * @dev Subtracts two numbers, returns an error on overflow (i.e. if subtrahend is greater than minuend).
+    */
+    function subUInt(uint a, uint b) internal pure returns (MathError, uint) {
+        if (b <= a) {
+            return (MathError.NO_ERROR, a - b);
+        } else {
+            return (MathError.INTEGER_UNDERFLOW, 0);
+        }
+    }
+
+    /**
+    * @dev Adds two numbers, returns an error on overflow.
+    */
+    function addUInt(uint a, uint b) internal pure returns (MathError, uint) {
+        uint c = a + b;
+
+        if (c >= a) {
+            return (MathError.NO_ERROR, c);
+        } else {
+            return (MathError.INTEGER_OVERFLOW, 0);
+        }
+    }
+
+    /**
+    * @dev add a and b and then subtract c
+    */
+    function addThenSubUInt(uint a, uint b, uint c) internal pure returns (MathError, uint) {
+        (MathError err0, uint sum) = addUInt(a, b);
+
+        if (err0 != MathError.NO_ERROR) {
+            return (err0, 0);
+        }
+
+        return subUInt(sum, c);
+    }
+}
+
+
+/**
+ * @title Exponential module for storing fixed-precision decimals
+ * @author Compound
+ * @notice Exp is a struct which stores decimals with a fixed precision of 18 decimal places.
+ *         Thus, if we wanted to store the 5.1, mantissa would store 5.1e18. That is:
+ *         `Exp({mantissa: 5100000000000000000})`.
+ */
+contract ExponentialNoError {
+    uint constant expScale = 1e18;
+    uint constant doubleScale = 1e36;
+    uint constant halfExpScale = expScale/2;
+    uint constant mantissaOne = expScale;
+
+    struct Exp {
+        uint mantissa;
+    }
+
+    struct Double {
+        uint mantissa;
+    }
+
+    /**
+     * @dev Truncates the given exp to a whole number value.
+     *      For example, truncate(Exp{mantissa: 15 * expScale}) = 15
+     */
+    function truncate(Exp memory exp) pure internal returns (uint) {
+        // Note: We are not using careful Math here as we're performing a division that cannot fail
+        return exp.mantissa / expScale;
+    }
+
+    /**
+     * @dev Multiply an Exp by a scalar, then truncate to return an unsigned integer.
+     */
+    function mul_ScalarTruncate(Exp memory a, uint scalar) pure internal returns (uint) {
+        Exp memory product = mul_(a, scalar);
+        return truncate(product);
+    }
+
+    /**
+     * @dev Multiply an Exp by a scalar, truncate, then add an to an unsigned integer, returning an unsigned integer.
+     */
+    function mul_ScalarTruncateAddUInt(Exp memory a, uint scalar, uint addend) pure internal returns (uint) {
+        Exp memory product = mul_(a, scalar);
+        return add_(truncate(product), addend);
+    }
+
+    /**
+     * @dev Checks if first Exp is less than second Exp.
+     */
+    function lessThanExp(Exp memory left, Exp memory right) pure internal returns (bool) {
+        return left.mantissa < right.mantissa;
+    }
+
+    /**
+     * @dev Checks if left Exp <= right Exp.
+     */
+    function lessThanOrEqualExp(Exp memory left, Exp memory right) pure internal returns (bool) {
+        return left.mantissa <= right.mantissa;
+    }
+
+    /**
+     * @dev Checks if left Exp > right Exp.
+     */
+    function greaterThanExp(Exp memory left, Exp memory right) pure internal returns (bool) {
+        return left.mantissa > right.mantissa;
+    }
+
+    /**
+     * @dev returns true if Exp is exactly zero
+     */
+    function isZeroExp(Exp memory value) pure internal returns (bool) {
+        return value.mantissa == 0;
+    }
+
+    function safe224(uint n, string memory errorMessage) pure internal returns (uint224) {
+        require(n < 2**224, errorMessage);
+        return uint224(n);
+    }
+
+    function safe32(uint n, string memory errorMessage) pure internal returns (uint32) {
+        require(n < 2**32, errorMessage);
+        return uint32(n);
+    }
+
+    function add_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
+        return Exp({mantissa: add_(a.mantissa, b.mantissa)});
+    }
+
+    function add_(Double memory a, Double memory b) pure internal returns (Double memory) {
+        return Double({mantissa: add_(a.mantissa, b.mantissa)});
+    }
+
+    function add_(uint a, uint b) pure internal returns (uint) {
+        return add_(a, b, "addition overflow");
+    }
+
+    function add_(uint a, uint b, string memory errorMessage) pure internal returns (uint) {
+        uint c = a + b;
+        require(c >= a, errorMessage);
+        return c;
+    }
+
+    function sub_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
+        return Exp({mantissa: sub_(a.mantissa, b.mantissa)});
+    }
+
+    function sub_(Double memory a, Double memory b) pure internal returns (Double memory) {
+        return Double({mantissa: sub_(a.mantissa, b.mantissa)});
+    }
+
+    function sub_(uint a, uint b) pure internal returns (uint) {
+        return sub_(a, b, "subtraction underflow");
+    }
+
+    function sub_(uint a, uint b, string memory errorMessage) pure internal returns (uint) {
+        require(b <= a, errorMessage);
+        return a - b;
+    }
+
+    function mul_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
+        return Exp({mantissa: mul_(a.mantissa, b.mantissa) / expScale});
+    }
+
+    function mul_(Exp memory a, uint b) pure internal returns (Exp memory) {
+        return Exp({mantissa: mul_(a.mantissa, b)});
+    }
+
+    function mul_(uint a, Exp memory b) pure internal returns (uint) {
+        return mul_(a, b.mantissa) / expScale;
+    }
+
+    function mul_(Double memory a, Double memory b) pure internal returns (Double memory) {
+        return Double({mantissa: mul_(a.mantissa, b.mantissa) / doubleScale});
+    }
+
+    function mul_(Double memory a, uint b) pure internal returns (Double memory) {
+        return Double({mantissa: mul_(a.mantissa, b)});
+    }
+
+    function mul_(uint a, Double memory b) pure internal returns (uint) {
+        return mul_(a, b.mantissa) / doubleScale;
+    }
+
+    function mul_(uint a, uint b) pure internal returns (uint) {
+        return mul_(a, b, "multiplication overflow");
+    }
+
+    function mul_(uint a, uint b, string memory errorMessage) pure internal returns (uint) {
+        if (a == 0 || b == 0) {
+            return 0;
+        }
+        uint c = a * b;
+        require(c / a == b, errorMessage);
+        return c;
+    }
+
+    function div_(Exp memory a, Exp memory b) pure internal returns (Exp memory) {
+        return Exp({mantissa: div_(mul_(a.mantissa, expScale), b.mantissa)});
+    }
+
+    function div_(Exp memory a, uint b) pure internal returns (Exp memory) {
+        return Exp({mantissa: div_(a.mantissa, b)});
+    }
+
+    function div_(uint a, Exp memory b) pure internal returns (uint) {
+        return div_(mul_(a, expScale), b.mantissa);
+    }
+
+    function div_(Double memory a, Double memory b) pure internal returns (Double memory) {
+        return Double({mantissa: div_(mul_(a.mantissa, doubleScale), b.mantissa)});
+    }
+
+    function div_(Double memory a, uint b) pure internal returns (Double memory) {
+        return Double({mantissa: div_(a.mantissa, b)});
+    }
+
+    function div_(uint a, Double memory b) pure internal returns (uint) {
+        return div_(mul_(a, doubleScale), b.mantissa);
+    }
+
+    function div_(uint a, uint b) pure internal returns (uint) {
+        return div_(a, b, "divide by zero");
+    }
+
+    function div_(uint a, uint b, string memory errorMessage) pure internal returns (uint) {
+        require(b > 0, errorMessage);
+        return a / b;
+    }
+
+    function fraction(uint a, uint b) pure internal returns (Double memory) {
+        return Double({mantissa: div_(mul_(a, doubleScale), b)});
+    }
+}
+
+
+/**
+ * @title Exponential module for storing fixed-precision decimals
+ * @author Compound
+ * @dev Legacy contract for compatibility reasons with existing contracts that still use MathError
+ * @notice Exp is a struct which stores decimals with a fixed precision of 18 decimal places.
+ *         Thus, if we wanted to store the 5.1, mantissa would store 5.1e18. That is:
+ *         `Exp({mantissa: 5100000000000000000})`.
+ */
+contract Exponential is CarefulMath, ExponentialNoError {
+    /**
+     * @dev Creates an exponential from numerator and denominator values.
+     *      Note: Returns an error if (`num` * 10e18) > MAX_INT,
+     *            or if `denom` is zero.
+     */
+    function getExp(uint num, uint denom) pure internal returns (MathError, Exp memory) {
+        (MathError err0, uint scaledNumerator) = mulUInt(num, expScale);
+        if (err0 != MathError.NO_ERROR) {
+            return (err0, Exp({mantissa: 0}));
+        }
+
+        (MathError err1, uint rational) = divUInt(scaledNumerator, denom);
+        if (err1 != MathError.NO_ERROR) {
+            return (err1, Exp({mantissa: 0}));
+        }
+
+        return (MathError.NO_ERROR, Exp({mantissa: rational}));
+    }
+
+    /**
+     * @dev Adds two exponentials, returning a new exponential.
+     */
+    function addExp(Exp memory a, Exp memory b) pure internal returns (MathError, Exp memory) {
+        (MathError error, uint result) = addUInt(a.mantissa, b.mantissa);
+
+        return (error, Exp({mantissa: result}));
+    }
+
+    /**
+     * @dev Subtracts two exponentials, returning a new exponential.
+     */
+    function subExp(Exp memory a, Exp memory b) pure internal returns (MathError, Exp memory) {
+        (MathError error, uint result) = subUInt(a.mantissa, b.mantissa);
+
+        return (error, Exp({mantissa: result}));
+    }
+
+    /**
+     * @dev Multiply an Exp by a scalar, returning a new Exp.
+     */
+    function mulScalar(Exp memory a, uint scalar) pure internal returns (MathError, Exp memory) {
+        (MathError err0, uint scaledMantissa) = mulUInt(a.mantissa, scalar);
+        if (err0 != MathError.NO_ERROR) {
+            return (err0, Exp({mantissa: 0}));
+        }
+
+        return (MathError.NO_ERROR, Exp({mantissa: scaledMantissa}));
+    }
+
+    /**
+     * @dev Multiply an Exp by a scalar, then truncate to return an unsigned integer.
+     */
+    function mulScalarTruncate(Exp memory a, uint scalar) pure internal returns (MathError, uint) {
+        (MathError err, Exp memory product) = mulScalar(a, scalar);
+        if (err != MathError.NO_ERROR) {
+            return (err, 0);
+        }
+
+        return (MathError.NO_ERROR, truncate(product));
+    }
+
+    /**
+     * @dev Multiply an Exp by a scalar, truncate, then add an to an unsigned integer, returning an unsigned integer.
+     */
+    function mulScalarTruncateAddUInt(Exp memory a, uint scalar, uint addend) pure internal returns (MathError, uint) {
+        (MathError err, Exp memory product) = mulScalar(a, scalar);
+        if (err != MathError.NO_ERROR) {
+            return (err, 0);
+        }
+
+        return addUInt(truncate(product), addend);
+    }
+
+    /**
+     * @dev Divide an Exp by a scalar, returning a new Exp.
+     */
+    function divScalar(Exp memory a, uint scalar) pure internal returns (MathError, Exp memory) {
+        (MathError err0, uint descaledMantissa) = divUInt(a.mantissa, scalar);
+        if (err0 != MathError.NO_ERROR) {
+            return (err0, Exp({mantissa: 0}));
+        }
+
+        return (MathError.NO_ERROR, Exp({mantissa: descaledMantissa}));
+    }
+
+    /**
+     * @dev Divide a scalar by an Exp, returning a new Exp.
+     */
+    function divScalarByExp(uint scalar, Exp memory divisor) pure internal returns (MathError, Exp memory) {
+        /*
+          We are doing this as:
+          getExp(mulUInt(expScale, scalar), divisor.mantissa)
+
+          How it works:
+          Exp = a / b;
+          Scalar = s;
+          `s / (a / b)` = `b * s / a` and since for an Exp `a = mantissa, b = expScale`
+        */
+        (MathError err0, uint numerator) = mulUInt(expScale, scalar);
+        if (err0 != MathError.NO_ERROR) {
+            return (err0, Exp({mantissa: 0}));
+        }
+        return getExp(numerator, divisor.mantissa);
+    }
+
+    /**
+     * @dev Divide a scalar by an Exp, then truncate to return an unsigned integer.
+     */
+    function divScalarByExpTruncate(uint scalar, Exp memory divisor) pure internal returns (MathError, uint) {
+        (MathError err, Exp memory fraction) = divScalarByExp(scalar, divisor);
+        if (err != MathError.NO_ERROR) {
+            return (err, 0);
+        }
+
+        return (MathError.NO_ERROR, truncate(fraction));
+    }
+
+    /**
+     * @dev Multiplies two exponentials, returning a new exponential.
+     */
+    function mulExp(Exp memory a, Exp memory b) pure internal returns (MathError, Exp memory) {
+
+        (MathError err0, uint doubleScaledProduct) = mulUInt(a.mantissa, b.mantissa);
+        if (err0 != MathError.NO_ERROR) {
+            return (err0, Exp({mantissa: 0}));
+        }
+
+        // We add half the scale before dividing so that we get rounding instead of truncation.
+        //  See "Listing 6" and text above it at https://accu.org/index.php/journals/1717
+        // Without this change, a result like 6.6...e-19 will be truncated to 0 instead of being rounded to 1e-18.
+        (MathError err1, uint doubleScaledProductWithHalfScale) = addUInt(halfExpScale, doubleScaledProduct);
+        if (err1 != MathError.NO_ERROR) {
+            return (err1, Exp({mantissa: 0}));
+        }
+
+        (MathError err2, uint product) = divUInt(doubleScaledProductWithHalfScale, expScale);
+        // The only error `div` can return is MathError.DIVISION_BY_ZERO but we control `expScale` and it is not zero.
+        assert(err2 == MathError.NO_ERROR);
+
+        return (MathError.NO_ERROR, Exp({mantissa: product}));
+    }
+
+    /**
+     * @dev Multiplies two exponentials given their mantissas, returning a new exponential.
+     */
+    function mulExp(uint a, uint b) pure internal returns (MathError, Exp memory) {
+        return mulExp(Exp({mantissa: a}), Exp({mantissa: b}));
+    }
+
+    /**
+     * @dev Multiplies three exponentials, returning a new exponential.
+     */
+    function mulExp3(Exp memory a, Exp memory b, Exp memory c) pure internal returns (MathError, Exp memory) {
+        (MathError err, Exp memory ab) = mulExp(a, b);
+        if (err != MathError.NO_ERROR) {
+            return (err, ab);
+        }
+        return mulExp(ab, c);
+    }
+
+    /**
+     * @dev Divides two exponentials, returning a new exponential.
+     *     (a/scale) / (b/scale) = (a/scale) * (scale/b) = a/b,
+     *  which we can scale as an Exp by calling getExp(a.mantissa, b.mantissa)
+     */
+    function divExp(Exp memory a, Exp memory b) pure internal returns (MathError, Exp memory) {
+        return getExp(a.mantissa, b.mantissa);
+    }
+}
+
+
+
+/**
+ * @title ERC 20 Token Standard Interface
+ *  https://eips.ethereum.org/EIPS/eip-20
+ */
+interface EIP20Interface {
+    function name() external view returns (string memory);
+    function symbol() external view returns (string memory);
+    function decimals() external view returns (uint8);
+
+    /**
+      * @notice Get the total number of tokens in circulation
+      * @return The supply of tokens
+      */
+    function totalSupply() external view returns (uint256);
+
+    /**
+     * @notice Gets the balance of the specified address
+     * @param owner The address from which the balance will be retrieved
+     * @return The balance
+     */
+    function balanceOf(address owner) external view returns (uint256 balance);
+
+    /**
+      * @notice Transfer `amount` tokens from `msg.sender` to `dst`
+      * @param dst The address of the destination account
+      * @param amount The number of tokens to transfer
+      * @return Whether or not the transfer succeeded
+      */
+    function transfer(address dst, uint256 amount) external returns (bool success);
+
+    /**
+      * @notice Transfer `amount` tokens from `src` to `dst`
+      * @param src The address of the source account
+      * @param dst The address of the destination account
+      * @param amount The number of tokens to transfer
+      * @return Whether or not the transfer succeeded
+      */
+    function transferFrom(address src, address dst, uint256 amount) external returns (bool success);
+
+    /**
+      * @notice Approve `spender` to transfer up to `amount` from `src`
+      * @dev This will overwrite the approval amount for `spender`
+      *  and is subject to issues noted [here](https://eips.ethereum.org/EIPS/eip-20#approve)
+      * @param spender The address of the account which may transfer tokens
+      * @param amount The number of tokens that are approved (-1 means infinite)
+      * @return Whether or not the approval succeeded
+      */
+    function approve(address spender, uint256 amount) external returns (bool success);
+
+    /**
+      * @notice Get the current allowance from `owner` for `spender`
+      * @param owner The address of the account which owns the tokens to be spent
+      * @param spender The address of the account which may transfer tokens
+      * @return The number of tokens allowed to be spent (-1 means infinite)
+      */
+    function allowance(address owner, address spender) external view returns (uint256 remaining);
+
+    event Transfer(address indexed from, address indexed to, uint256 amount);
+    event Approval(address indexed owner, address indexed spender, uint256 amount);
+}
+
+
+
+interface RegistryForOToken {
+    function isSupportedInterestRateModel(address interestRateModel) external returns (bool);
+    function olaBankAddress() external view returns (address payable);
+    function blocksBased() external view returns (bool);
+}
+
+interface ComptrollerForOToken {
+    function adminBankAddress() external view returns (address payable);
+}
+
+/**
+ * View functions that are not used by the core contracts.
+ */
+contract CTokenViewInterface {
+    /*** View Interface ***/
+    function borrowRatePerBlock() external view returns (uint);
+    function supplyRatePerBlock() external view returns (uint);
+    function totalBorrowsCurrent() external returns (uint);
+
+    /**
+     * @notice Used by the Maximilion
+     */
+    function borrowBalanceCurrent(address account) external returns (uint);
+    function exchangeRateCurrent() public returns (uint);
+    function getCash() external view returns (uint);
+}
+
+
+contract CTokenInterface {
+    // OLA_ADDITIONS : "Underlying field"
+    address constant public nativeCoinUnderlying = address(0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE);
+
+    /**
+     * OLA_ADDITIONS : This field
+     * @notice This value is hard coded to 0.5 (50% for the Ola ecosystem and the LeN owner each)
+     */
+    uint constant public olaReserveFactorMantissa = 0.5e18;
+
+    /**
+     * @notice Indicator that this is a CToken contract (for inspection)
+     */
+    bool public constant isCToken = true;
+
+    /**
+     * @notice Maximum borrow rate that can ever be applied (.0005% / block)
+     */
+    uint internal constant borrowRateMaxMantissa = 0.0005e16;
+
+    /**
+     * @notice Maximum fraction of interest that can be set aside for reserves
+     */
+    uint internal constant reserveFactorMaxMantissa = 0.3e18;
+
+    /**
+     * OLA_ADDITIONS : This value
+     * @notice Minimum fraction of interest that can be set aside for reserves
+     */
+    uint internal constant reserveFactorMinMantissa = 0.05e18;
+
+    /*** Market Events ***/
+
+    /**
+     * @notice Event emitted when interest is accrued
+     */
+    event AccrueInterest(uint cashPrior, uint interestAccumulated, uint borrowIndex, uint totalBorrows);
+
+    /**
+     * @notice Event emitted when tokens are minted
+     */
+    event Mint(address minter, uint mintAmount, uint mintTokens);
+
+    /**
+     * @notice Event emitted when tokens are redeemed
+     */
+    event Redeem(address redeemer, uint redeemAmount, uint redeemTokens);
+
+    /**
+     * @notice Event emitted when underlying is borrowed
+     */
+    event Borrow(address borrower, uint borrowAmount, uint accountBorrows, uint totalBorrows);
+
+    /**
+     * @notice Event emitted when a borrow is repaid
+     */
+    event RepayBorrow(address payer, address borrower, uint repayAmount, uint accountBorrows, uint totalBorrows);
+
+    /**
+     * @notice Event emitted when a borrow is liquidated
+     */
+    event LiquidateBorrow(address liquidator, address borrower, uint repayAmount, address cTokenCollateral, uint seizeTokens);
+
+
+    /*** Admin Events ***/
+
+    /**
+     * @notice Event emitted when pendingAdmin is changed
+     */
+    event NewPendingAdmin(address oldPendingAdmin, address newPendingAdmin);
+
+    /**
+     * @notice Event emitted when pendingAdmin is accepted, which means admin is updated
+     */
+    event NewAdmin(address oldAdmin, address newAdmin);
+
+    /**
+     * @notice Event emitted when Comptroller is changed
+     */
+    event NewComptroller(ComptrollerInterface oldComptroller, ComptrollerInterface newComptroller);
+
+    /**
+     * @notice Event emitted when interestRateModel is changed
+     */
+    event NewMarketInterestRateModel(InterestRateModel oldInterestRateModel, InterestRateModel newInterestRateModel);
+
+    /**
+     * @notice Event emitted when the reserve factor is changed
+     */
+    event NewReserveFactor(uint oldReserveFactorMantissa, uint newReserveFactorMantissa);
+
+    /**
+     * @notice Event emitted when the reserves are reduced
+     */
+    event ReservesReduced(address admin, uint adminPart, address olaBank, uint olaPart, uint newTotalReserves);
+
+    /**
+     * @notice EIP20 Transfer event
+     */
+    event Transfer(address indexed from, address indexed to, uint amount);
+
+    /**
+     * @notice EIP20 Approval event
+     */
+    event Approval(address indexed owner, address indexed spender, uint amount);
+
+    /**
+     * @notice Failure event
+     */
+    event Failure(uint error, uint info, uint detail);
+
+    /*** User Interface ***/
+
+    function transfer(address dst, uint amount) external returns (bool);
+    function transferFrom(address src, address dst, uint amount) external returns (bool);
+    function approve(address spender, uint amount) external returns (bool);
+    function allowance(address owner, address spender) external view returns (uint);
+    function balanceOf(address owner) external view returns (uint);
+    function balanceOfUnderlying(address owner) external returns (uint);
+    function getAccountSnapshot(address account) external view returns (uint, uint, uint, uint);
+    function borrowBalanceStored(address account) public view returns (uint);
+    function exchangeRateStored() public view returns (uint);
+    function getAccrualBlockNumber() external view returns (uint);
+    function accrueInterest() public returns (uint);
+    function seize(address liquidator, address borrower, uint seizeTokens) external returns (uint);
+
+    /*** Admin Functions ***/
+
+    function _setPendingAdmin(address payable newPendingAdmin) external returns (uint);
+    function _acceptAdmin() external returns (uint);
+    function _setReserveFactor(uint newReserveFactorMantissa) external returns (uint);
+    function _reduceReserves(uint reduceAmount) external returns (uint);
+    function _setInterestRateModel(InterestRateModel newInterestRateModel) public returns (uint);
+}
+
+
+/**
+ * OLA_ADDITIONS : This base admin storage.
+ */
+contract CTokenAdminStorage {
+    /**
+     * @notice Administrator for this contract
+     */
+    address payable public admin;
+
+    /**
+     * @notice Pending administrator for this contract
+     */
+    address payable public pendingAdmin;
+
+    /**
+     * @notice Contract which oversees inter-cToken operations
+     */
+    ComptrollerInterface public comptroller;
+
+    /**
+     * @notice Implementation address for this contract
+     */
+    address public implementation;
+
+    // OLA_ADDITIONS : Contract hash name
+    bytes32 public contractNameHash;
+}
+
+/**
+ * @notice DO NOT ADD ANY MORE STORAGE VARIABLES HERE (add them to their respective type storage)
+ */
+contract CTokenStorage is CTokenAdminStorage {
+    /**
+     * @dev Guard variable for re-entrancy checks
+     */
+    bool internal _notEntered;
+
+    /**
+     * @notice EIP-20 token name for this token
+     */
+    string public name;
+
+    /**
+     * @notice EIP-20 token symbol for this token
+     */
+    string public symbol;
+
+    /**
+     * @notice EIP-20 token decimals for this token
+     */
+    uint8 public decimals;
+
+    /**
+     * @notice Underlying asset for this CToken
+     */
+    address public underlying;
+
+    // @notice Indicates if the calculations should be blocks or time based
+    bool public blocksBased;
+
+    /**
+     * @notice Model which tells what the current interest rate should be
+     */
+    InterestRateModel public interestRateModel;
+
+    /**
+     * @notice Initial exchange rate used when minting the first CTokens (used when totalSupply = 0)
+     */
+    uint internal initialExchangeRateMantissa;
+
+    /**
+     * @notice Fraction of interest currently set aside for reserves
+     */
+    uint public reserveFactorMantissa;
+
+    /**
+     * @notice Block number that interest was last accrued at
+     */
+    uint public accrualBlockNumber;
+
+    /**
+     * @notice Block number that interest was last accrued at
+     */
+    uint public accrualBlockTimestamp;
+
+    /**
+     * @notice Accumulator of the total earned interest rate since the opening of the market
+     */
+    uint public borrowIndex;
+
+    /**
+     * @notice Total amount of outstanding borrows of the underlying in this market
+     */
+    uint public totalBorrows;
+
+    /**
+     * OLA_ADDITIONS : Removed option to 'add reserves' as it makes no sense when reducing reserves
+     *                 sends a part to Ola Bank.
+     * @notice Total amount of reserves of the underlying held in this market
+     */
+    uint public totalReserves;
+
+    /**
+     * @notice Total number of tokens in circulation
+     */
+    uint public totalSupply;
+
+    /**
+     * @notice Official record of token balances for each account
+     */
+    mapping (address => uint) internal accountTokens;
+
+    /**
+     * @notice Approved token transfer amounts on behalf of others
+     */
+    mapping (address => mapping (address => uint)) internal transferAllowances;
+
+    /**
+     * @notice Container for borrow balance information
+     * @member principal Total balance (with accrued interest), after applying the most recent balance-changing action
+     * @member interestIndex Global borrowIndex as of the most recent balance-changing action
+     */
+    struct BorrowSnapshot {
+        uint principal;
+        uint interestIndex;
+    }
+
+    /**
+     * @notice Mapping of account addresses to outstanding borrow balances
+     */
+    mapping(address => BorrowSnapshot) internal accountBorrows;
+
+    // IMPORTANT : DO NOT ADD ANY MORE STORAGE VARIABLES HERE (add them to their respective type storage)
+}
+
+/**
+ * @title Compound's CToken Contract
+ * @notice Abstract base for CTokens
+ * @author Compound
+ */
+contract CToken is CTokenStorage, CTokenInterface, CTokenViewInterface, Exponential, TokenErrorReporter {
+    /**
+     * @notice Initialize the money market
+     * @param comptroller_ The address of the Comptroller
+     * @param interestRateModel_ The address of the interest rate model
+     * @param initialExchangeRateMantissa_ The initial exchange rate, scaled by 1e18
+     * @param name_ EIP-20 name of this token
+     * @param symbol_ EIP-20 symbol of this token
+     * @param decimals_ EIP-20 decimal precision of this token
+     */
+    function initialize(ComptrollerInterface comptroller_,
+                        InterestRateModel interestRateModel_,
+                        uint initialExchangeRateMantissa_,
+                        string memory name_,
+                        string memory symbol_,
+                        uint8 decimals_) public {
+        require(msg.sender == admin, "only admin may initialize the market");
+        require(accrualBlockNumber == 0 && borrowIndex == 0, "market may only be initialized once");
+
+        // Set initial exchange rate
+        initialExchangeRateMantissa = initialExchangeRateMantissa_;
+        require(initialExchangeRateMantissa > 0, "initial exchange rate must be greater than zero.");
+
+        // Set the Comptroller
+        uint err = _setComptroller(comptroller_);
+        require(err == uint(Error.NO_ERROR), "setting comptroller failed");
+
+        // Initialize block number and borrow index (block number mocks depend on Comptroller being set)
+        accrualBlockNumber = getBlockNumber();
+        accrualBlockTimestamp = getBlockTimestamp();
+        borrowIndex = mantissaOne;
+
+        // Set the calculation based flag from the ministry
+        RegistryForOToken ministry = RegistryForOToken(comptroller.getRegistry());
+        blocksBased = ministry.blocksBased();
+
+        // Set the interest rate model (depends on block number / borrow index)
+        err = _setInterestRateModelFresh(interestRateModel_);
+        require(err == uint(Error.NO_ERROR), "setting interest rate model failed");
+
+        name = name_;
+        symbol = symbol_;
+        decimals = decimals_;
+
+        // The counter starts true to prevent changing it from zero to non-zero (i.e. smaller cost/refund)
+        _notEntered = true;
+    }
+
+    /**
+     * @notice Transfer `tokens` tokens from `src` to `dst` by `spender`
+     * @dev Called by both `transfer` and `transferFrom` internally
+     * @param spender The address of the account performing the transfer
+     * @param src The address of the source account
+     * @param dst The address of the destination account
+     * @param tokens The number of tokens to transfer
+     * @return Whether or not the transfer succeeded
+     */
+    function transferTokens(address spender, address src, address dst, uint tokens) internal returns (uint) {
+        /* Fail if transfer not allowed */
+        uint allowed = comptroller.transferAllowed(address(this), src, dst, tokens);
+        if (allowed != 0) {
+            return failOpaque(Error.COMPTROLLER_REJECTION, FailureInfo.TRANSFER_COMPTROLLER_REJECTION, allowed);
+        }
+
+        /* Do not allow self-transfers */
+        if (src == dst) {
+            return fail(Error.BAD_INPUT, FailureInfo.TRANSFER_NOT_ALLOWED);
+        }
+
+        /* Get the allowance, infinite for the account owner */
+        uint startingAllowance = 0;
+        if (spender == src) {
+            startingAllowance = uint(-1);
+        } else {
+            startingAllowance = transferAllowances[src][spender];
+        }
+
+        /* Do the calculations, checking for {under,over}flow */
+        MathError mathErr;
+        uint allowanceNew;
+        uint srcTokensNew;
+        uint dstTokensNew;
+
+        (mathErr, allowanceNew) = subUInt(startingAllowance, tokens);
+        if (mathErr != MathError.NO_ERROR) {
+            return fail(Error.MATH_ERROR, FailureInfo.TRANSFER_NOT_ALLOWED);
+        }
+
+        (mathErr, srcTokensNew) = subUInt(accountTokens[src], tokens);
+        if (mathErr != MathError.NO_ERROR) {
+            return fail(Error.MATH_ERROR, FailureInfo.TRANSFER_NOT_ENOUGH);
+        }
+
+        (mathErr, dstTokensNew) = addUInt(accountTokens[dst], tokens);
+        if (mathErr != MathError.NO_ERROR) {
+            return fail(Error.MATH_ERROR, FailureInfo.TRANSFER_TOO_MUCH);
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        accountTokens[src] = srcTokensNew;
+        accountTokens[dst] = dstTokensNew;
+
+        /* Eat some of the allowance (if necessary) */
+        if (startingAllowance != uint(-1)) {
+            transferAllowances[src][spender] = allowanceNew;
+        }
+
+        /* We emit a Transfer event */
+        emit Transfer(src, dst, tokens);
+
+        // unused function
+         comptroller.transferVerify(address(this), src, dst, tokens);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+     * @notice Transfer `amount` tokens from `msg.sender` to `dst`
+     * @param dst The address of the destination account
+     * @param amount The number of tokens to transfer
+     * @return Whether or not the transfer succeeded
+     */
+    function transfer(address dst, uint256 amount) external nonReentrant returns (bool) {
+        return transferTokens(msg.sender, msg.sender, dst, amount) == uint(Error.NO_ERROR);
+    }
+
+    /**
+     * @notice Transfer `amount` tokens from `src` to `dst`
+     * @param src The address of the source account
+     * @param dst The address of the destination account
+     * @param amount The number of tokens to transfer
+     * @return Whether or not the transfer succeeded
+     */
+    function transferFrom(address src, address dst, uint256 amount) external nonReentrant returns (bool) {
+        return transferTokens(msg.sender, src, dst, amount) == uint(Error.NO_ERROR);
+    }
+
+    /**
+     * @notice Approve `spender` to transfer up to `amount` from `src`
+     * @dev This will overwrite the approval amount for `spender`
+     *  and is subject to issues noted [here](https://eips.ethereum.org/EIPS/eip-20#approve)
+     * @param spender The address of the account which may transfer tokens
+     * @param amount The number of tokens that are approved (-1 means infinite)
+     * @return Whether or not the approval succeeded
+     */
+    function approve(address spender, uint256 amount) external returns (bool) {
+        address src = msg.sender;
+        transferAllowances[src][spender] = amount;
+        emit Approval(src, spender, amount);
+        return true;
+    }
+
+    /**
+     * @notice Get the current allowance from `owner` for `spender`
+     * @param owner The address of the account which owns the tokens to be spent
+     * @param spender The address of the account which may transfer tokens
+     * @return The number of tokens allowed to be spent (-1 means infinite)
+     */
+    function allowance(address owner, address spender) external view returns (uint256) {
+        return transferAllowances[owner][spender];
+    }
+
+    /**
+     * @notice Get the token balance of the `owner`
+     * @param owner The address of the account to query
+     * @return The number of tokens owned by `owner`
+     */
+    function balanceOf(address owner) external view returns (uint256) {
+        return accountTokens[owner];
+    }
+
+    /**
+     * @notice Get the underlying balance of the `owner`
+     * @dev This also accrues interest in a transaction
+     * @param owner The address of the account to query
+     * @return The amount of underlying owned by `owner`
+     */
+    function balanceOfUnderlying(address owner) external returns (uint) {
+        Exp memory exchangeRate = Exp({mantissa: exchangeRateCurrent()});
+        (MathError mErr, uint balance) = mulScalarTruncate(exchangeRate, accountTokens[owner]);
+        require(mErr == MathError.NO_ERROR, "balance could not be calculated");
+        return balance;
+    }
+
+    /**
+     * @notice Get a snapshot of the account's balances, and the cached exchange rate
+     * @dev This is used by Comptroller to more efficiently perform liquidity checks.
+     * @param account Address of the account to snapshot
+     * @return (possible error, token balance, borrow balance, exchange rate mantissa)
+     */
+    function getAccountSnapshot(address account) external view returns (uint, uint, uint, uint) {
+        uint cTokenBalance = accountTokens[account];
+        uint borrowBalance;
+        uint exchangeRateMantissa;
+
+        MathError mErr;
+
+        (mErr, borrowBalance) = borrowBalanceStoredInternal(account);
+        if (mErr != MathError.NO_ERROR) {
+            return (uint(Error.MATH_ERROR), 0, 0, 0);
+        }
+
+        (mErr, exchangeRateMantissa) = exchangeRateStoredInternal();
+        if (mErr != MathError.NO_ERROR) {
+            return (uint(Error.MATH_ERROR), 0, 0, 0);
+        }
+
+        return (uint(Error.NO_ERROR), cTokenBalance, borrowBalance, exchangeRateMantissa);
+    }
+
+    /**
+     * @dev Function to simply retrieve block number
+     *  This exists mainly for inheriting test contracts to stub this result.
+     */
+    function getBlockNumber() internal view returns (uint) {
+        return block.number;
+    }
+
+    /**
+     * @dev Function to simply retrieve block timestamp
+     *  This exists mainly for inheriting test contracts to stub this result.
+     */
+    function getBlockTimestamp() internal view returns (uint) {
+        return block.timestamp;
+    }
+
+    /**
+     * @notice Returns the current per-block borrow interest rate for this cToken
+     * @return The borrow interest rate per block, scaled by 1e18
+     */
+    function borrowRatePerBlock() external view returns (uint) {
+        return interestRateModel.getBorrowRate(getCashPrior(), totalBorrows, totalReserves);
+    }
+
+    /**
+     * @notice Returns the current per-block supply interest rate for this cToken
+     * @return The supply interest rate per block, scaled by 1e18
+     */
+    function supplyRatePerBlock() external view returns (uint) {
+        return interestRateModel.getSupplyRate(getCashPrior(), totalBorrows, totalReserves, reserveFactorMantissa);
+    }
+
+    /**
+     * @notice Returns the current total borrows plus accrued interest
+     * @return The total borrows with interest
+     */
+    function totalBorrowsCurrent() external nonReentrant returns (uint) {
+        require(accrueInterest() == uint(Error.NO_ERROR), "accrue interest failed");
+        return totalBorrows;
+    }
+
+    /**
+     * @notice Accrue interest to updated borrowIndex and then calculate account's borrow balance using the updated borrowIndex
+     * @param account The address whose balance should be calculated after updating borrowIndex
+     * @return The calculated balance
+     */
+    function borrowBalanceCurrent(address account) external nonReentrant returns (uint) {
+        require(accrueInterest() == uint(Error.NO_ERROR), "accrue interest failed");
+        return borrowBalanceStored(account);
+    }
+
+    /**
+     * @notice Return the borrow balance of account based on stored data
+     * @param account The address whose balance should be calculated
+     * @return The calculated balance
+     */
+    function borrowBalanceStored(address account) public view returns (uint) {
+        (MathError err, uint result) = borrowBalanceStoredInternal(account);
+        require(err == MathError.NO_ERROR, "borrowBalanceStored: borrowBalanceStoredInternal failed");
+        return result;
+    }
+
+    /**
+     * @notice Return the borrow balance of account based on stored data
+     * @param account The address whose balance should be calculated
+     * @return (error code, the calculated balance or 0 if error code is non-zero)
+     */
+    function borrowBalanceStoredInternal(address account) internal view returns (MathError, uint) {
+        /* Note: we do not assert that the market is up to date */
+        MathError mathErr;
+        uint principalTimesIndex;
+        uint result;
+
+        /* Get borrowBalance and borrowIndex */
+        BorrowSnapshot storage borrowSnapshot = accountBorrows[account];
+
+        /* If borrowBalance = 0 then borrowIndex is likely also 0.
+         * Rather than failing the calculation with a division by 0, we immediately return 0 in this case.
+         */
+        if (borrowSnapshot.principal == 0) {
+            return (MathError.NO_ERROR, 0);
+        }
+
+        /* Calculate new borrow balance using the interest index:
+         *  recentBorrowBalance = borrower.borrowBalance * market.borrowIndex / borrower.borrowIndex
+         */
+        (mathErr, principalTimesIndex) = mulUInt(borrowSnapshot.principal, borrowIndex);
+        if (mathErr != MathError.NO_ERROR) {
+            return (mathErr, 0);
+        }
+
+        (mathErr, result) = divUInt(principalTimesIndex, borrowSnapshot.interestIndex);
+        if (mathErr != MathError.NO_ERROR) {
+            return (mathErr, 0);
+        }
+
+        return (MathError.NO_ERROR, result);
+    }
+
+    /**
+     * @notice Accrue interest then return the up-to-date exchange rate
+     * @return Calculated exchange rate scaled by 1e18
+     */
+    function exchangeRateCurrent() public nonReentrant returns (uint) {
+        require(accrueInterest() == uint(Error.NO_ERROR), "accrue interest failed");
+        return exchangeRateStored();
+    }
+
+    /**
+     * @notice Calculates the exchange rate from the underlying to the CToken
+     * @dev This function does not accrue interest before calculating the exchange rate
+     * @return Calculated exchange rate scaled by 1e18
+     */
+    function exchangeRateStored() public view returns (uint) {
+        (MathError err, uint result) = exchangeRateStoredInternal();
+        require(err == MathError.NO_ERROR, "exchangeRateStored: exchangeRateStoredInternal failed");
+        return result;
+    }
+
+    /**
+     * @notice Calculates the exchange rate from the underlying to the CToken
+     * @dev This function does not accrue interest before calculating the exchange rate
+     * @return (error code, calculated exchange rate scaled by 1e18)
+     */
+    function exchangeRateStoredInternal() internal view returns (MathError, uint) {
+        uint _totalSupply = totalSupply;
+        if (_totalSupply == 0) {
+            /*
+             * If there are no tokens minted:
+             *  exchangeRate = initialExchangeRate
+             */
+            return (MathError.NO_ERROR, initialExchangeRateMantissa);
+        } else {
+            /*
+             * Otherwise:
+             *  exchangeRate = (totalCash + totalBorrows - totalReserves) / totalSupply
+             */
+            uint totalCash = getCashPrior();
+            uint cashPlusBorrowsMinusReserves;
+            Exp memory exchangeRate;
+            MathError mathErr;
+
+            (mathErr, cashPlusBorrowsMinusReserves) = addThenSubUInt(totalCash, totalBorrows, totalReserves);
+            if (mathErr != MathError.NO_ERROR) {
+                return (mathErr, 0);
+            }
+
+            (mathErr, exchangeRate) = getExp(cashPlusBorrowsMinusReserves, _totalSupply);
+            if (mathErr != MathError.NO_ERROR) {
+                return (mathErr, 0);
+            }
+
+            return (MathError.NO_ERROR, exchangeRate.mantissa);
+        }
+    }
+
+    /**
+     * @notice Get cash balance of this cToken in the underlying asset
+     * @return The quantity of underlying asset owned by this contract
+     */
+    function getCash() external view returns (uint) {
+        return getCashPrior();
+    }
+
+    /**
+     * @notice Get the accrual block number of this cToken
+     * @return The accrual block number
+     */
+    function getAccrualBlockNumber() external view returns (uint) {
+        return accrualBlockNumber;
+    }
+
+    /**
+     * @notice Applies accrued interest to total borrows and reserves
+     * @dev This calculates interest accrued from the last checkpointed block
+     *   up to the current block and writes new checkpoint to storage.
+     */
+    function accrueInterest() public returns (uint) {
+        /* Remember the initial block number */
+        uint currentBlockNumber = getBlockNumber();
+        uint accrualBlockNumberPrior = accrualBlockNumber;
+        uint currentBlockTimestamp = getBlockTimestamp();
+
+        /* Short-circuit accumulating 0 interest */
+        if (accrualBlockNumberPrior == currentBlockNumber) {
+            return uint(Error.NO_ERROR);
+        }
+
+        // OLA_ADDITIONS : Distinction between time and block based calculations
+        /* Calculate the number of blocks elapsed since the last accrual */
+        MathError mathErr;
+        uint delta;
+
+        if (blocksBased) {
+            (mathErr, delta) = subUInt(currentBlockNumber, accrualBlockNumberPrior);
+        } else {
+            // This variable is defined here due to solidity limits
+            uint accrualBlockTimestampPrior = accrualBlockTimestamp;
+
+            /* Short-circuit accumulating 0 interest on time based chains + extra safety for weird timestamps */
+            if (currentBlockTimestamp <= accrualBlockTimestampPrior) {
+                return uint(Error.NO_ERROR);
+            }
+
+            (mathErr, delta) = subUInt(currentBlockTimestamp, accrualBlockTimestampPrior);
+        }
+        require(mathErr == MathError.NO_ERROR, "could not calculate delta");
+
+        /* Read the previous values out of storage */
+        uint cashPrior = getCashPrior();
+        uint borrowsPrior = totalBorrows;
+        uint reservesPrior = totalReserves;
+        uint borrowIndexPrior = borrowIndex;
+
+        /* Calculate the current borrow interest rate */
+        uint borrowRateMantissa = interestRateModel.getBorrowRate(cashPrior, borrowsPrior, reservesPrior);
+        require(borrowRateMantissa <= borrowRateMaxMantissa, "borrow rate is absurdly high");
+
+        /*
+         * Calculate the interest accumulated into borrows and reserves and the new index:
+         *  simpleInterestFactor = borrowRate * delta
+         *  interestAccumulated = simpleInterestFactor * totalBorrows
+         *  totalBorrowsNew = interestAccumulated + totalBorrows
+         *  totalReservesNew = interestAccumulated * reserveFactor + totalReserves
+         *  borrowIndexNew = simpleInterestFactor * borrowIndex + borrowIndex
+         */
+
+        Exp memory simpleInterestFactor;
+        uint interestAccumulated;
+        uint totalBorrowsNew;
+        uint totalReservesNew;
+        uint borrowIndexNew;
+
+        (mathErr, simpleInterestFactor) = mulScalar(Exp({mantissa: borrowRateMantissa}), delta);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.ACCRUE_INTEREST_SIMPLE_INTEREST_FACTOR_CALCULATION_FAILED, uint(mathErr));
+        }
+
+        (mathErr, interestAccumulated) = mulScalarTruncate(simpleInterestFactor, borrowsPrior);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.ACCRUE_INTEREST_ACCUMULATED_INTEREST_CALCULATION_FAILED, uint(mathErr));
+        }
+
+        (mathErr, totalBorrowsNew) = addUInt(interestAccumulated, borrowsPrior);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.ACCRUE_INTEREST_NEW_TOTAL_BORROWS_CALCULATION_FAILED, uint(mathErr));
+        }
+
+        (mathErr, totalReservesNew) = mulScalarTruncateAddUInt(Exp({mantissa: reserveFactorMantissa}), interestAccumulated, reservesPrior);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.ACCRUE_INTEREST_NEW_TOTAL_RESERVES_CALCULATION_FAILED, uint(mathErr));
+        }
+
+        (mathErr, borrowIndexNew) = mulScalarTruncateAddUInt(simpleInterestFactor, borrowIndexPrior, borrowIndexPrior);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.ACCRUE_INTEREST_NEW_BORROW_INDEX_CALCULATION_FAILED, uint(mathErr));
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        /* We write the previously calculated values into storage */
+        accrualBlockNumber = currentBlockNumber;
+        accrualBlockTimestamp = currentBlockTimestamp;
+        borrowIndex = borrowIndexNew;
+        totalBorrows = totalBorrowsNew;
+        totalReserves = totalReservesNew;
+
+        /* We emit an AccrueInterest event */
+        emit AccrueInterest(cashPrior, interestAccumulated, borrowIndexNew, totalBorrowsNew);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+     * @notice Sender supplies assets into the market and receives cTokens in exchange
+     * @dev Accrues interest whether or not the operation succeeds, unless reverted
+     * @param mintAmount The amount of the underlying asset to supply
+     * @return (uint, uint) An error code (0=success, otherwise a failure, see ErrorReporter.sol), and the actual mint amount.
+     */
+    function mintInternal(uint mintAmount) internal nonReentrant returns (uint, uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted borrow failed
+            return (fail(Error(error), FailureInfo.MINT_ACCRUE_INTEREST_FAILED), 0);
+        }
+        // mintFresh emits the actual Mint event if successful and logs on errors, so we don't need to
+        return mintFresh(msg.sender, mintAmount);
+    }
+
+    struct MintLocalVars {
+        Error err;
+        MathError mathErr;
+        uint exchangeRateMantissa;
+        uint mintTokens;
+        uint totalSupplyNew;
+        uint accountTokensNew;
+        uint actualMintAmount;
+    }
+
+    /**
+     * @notice User supplies assets into the market and receives cTokens in exchange
+     * @dev Assumes interest has already been accrued up to the current block
+     * @param minter The address of the account which is supplying the assets
+     * @param mintAmount The amount of the underlying asset to supply
+     * @return (uint, uint) An error code (0=success, otherwise a failure, see ErrorReporter.sol), and the actual mint amount.
+     */
+    function mintFresh(address minter, uint mintAmount) internal returns (uint, uint) {
+        /* Fail if mint not allowed */
+        uint allowed = comptroller.mintAllowed(address(this), minter, mintAmount);
+        if (allowed != 0) {
+            return (failOpaque(Error.COMPTROLLER_REJECTION, FailureInfo.MINT_COMPTROLLER_REJECTION, allowed), 0);
+        }
+
+        /* Verify market's block number equals current block number */
+        if (accrualBlockNumber != getBlockNumber()) {
+            return (fail(Error.MARKET_NOT_FRESH, FailureInfo.MINT_FRESHNESS_CHECK), 0);
+        }
+
+        MintLocalVars memory vars;
+
+        (vars.mathErr, vars.exchangeRateMantissa) = exchangeRateStoredInternal();
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return (failOpaque(Error.MATH_ERROR, FailureInfo.MINT_EXCHANGE_RATE_READ_FAILED, uint(vars.mathErr)), 0);
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        /*
+         *  We call `doTransferIn` for the minter and the mintAmount.
+         *  Note: The cToken must handle variations between ERC-20 and ETH underlying.
+         *  `doTransferIn` reverts if anything goes wrong, since we can't be sure if
+         *  side-effects occurred. The function returns the amount actually transferred,
+         *  in case of a fee. On success, the cToken holds an additional `actualMintAmount`
+         *  of cash.
+         */
+        vars.actualMintAmount = doTransferIn(minter, mintAmount);
+
+        /*
+         * We get the current exchange rate and calculate the number of cTokens to be minted:
+         *  mintTokens = actualMintAmount / exchangeRate
+         */
+
+        (vars.mathErr, vars.mintTokens) = divScalarByExpTruncate(vars.actualMintAmount, Exp({mantissa: vars.exchangeRateMantissa}));
+        require(vars.mathErr == MathError.NO_ERROR, "MINT_EXCHANGE_CALCULATION_FAILED");
+
+        /*
+         * We calculate the new total supply of cTokens and minter token balance, checking for overflow:
+         *  totalSupplyNew = totalSupply + mintTokens
+         *  accountTokensNew = accountTokens[minter] + mintTokens
+         */
+        (vars.mathErr, vars.totalSupplyNew) = addUInt(totalSupply, vars.mintTokens);
+        require(vars.mathErr == MathError.NO_ERROR, "MINT_NEW_TOTAL_SUPPLY_CALCULATION_FAILED");
+
+        (vars.mathErr, vars.accountTokensNew) = addUInt(accountTokens[minter], vars.mintTokens);
+        require(vars.mathErr == MathError.NO_ERROR, "MINT_NEW_ACCOUNT_BALANCE_CALCULATION_FAILED");
+
+        /* We write previously calculated values into storage */
+        totalSupply = vars.totalSupplyNew;
+        accountTokens[minter] = vars.accountTokensNew;
+
+        /* We emit a Mint event, and a Transfer event */
+        emit Mint(minter, vars.actualMintAmount, vars.mintTokens);
+        emit Transfer(address(this), minter, vars.mintTokens);
+
+        /* We call the defense hook */
+        // unused function
+        comptroller.mintVerify(address(this), minter, vars.actualMintAmount, vars.mintTokens);
+
+        return (uint(Error.NO_ERROR), vars.actualMintAmount);
+    }
+
+    /**
+     * @notice Sender redeems cTokens in exchange for the underlying asset
+     * @dev Accrues interest whether or not the operation succeeds, unless reverted
+     * @param redeemTokens The number of cTokens to redeem into underlying
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function redeemInternal(uint redeemTokens) internal nonReentrant returns (uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted redeem failed
+            return fail(Error(error), FailureInfo.REDEEM_ACCRUE_INTEREST_FAILED);
+        }
+        // redeemFresh emits redeem-specific logs on errors, so we don't need to
+        return redeemFresh(msg.sender, redeemTokens, 0);
+    }
+
+    /**
+     * @notice Sender redeems cTokens in exchange for a specified amount of underlying asset
+     * @dev Accrues interest whether or not the operation succeeds, unless reverted
+     * @param redeemAmount The amount of underlying to receive from redeeming cTokens
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function redeemUnderlyingInternal(uint redeemAmount) internal nonReentrant returns (uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted redeem failed
+            return fail(Error(error), FailureInfo.REDEEM_ACCRUE_INTEREST_FAILED);
+        }
+        // redeemFresh emits redeem-specific logs on errors, so we don't need to
+        return redeemFresh(msg.sender, 0, redeemAmount);
+    }
+
+    struct RedeemLocalVars {
+        Error err;
+        MathError mathErr;
+        uint exchangeRateMantissa;
+        uint redeemTokens;
+        uint redeemAmount;
+        uint totalSupplyNew;
+        uint accountTokensNew;
+    }
+
+    /**
+     * @notice User redeems cTokens in exchange for the underlying asset
+     * @dev Assumes interest has already been accrued up to the current block
+     * @param redeemer The address of the account which is redeeming the tokens
+     * @param redeemTokensIn The number of cTokens to redeem into underlying (only one of redeemTokensIn or redeemAmountIn may be non-zero)
+     * @param redeemAmountIn The number of underlying tokens to receive from redeeming cTokens (only one of redeemTokensIn or redeemAmountIn may be non-zero)
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function redeemFresh(address payable redeemer, uint redeemTokensIn, uint redeemAmountIn) internal returns (uint) {
+        require(redeemTokensIn == 0 || redeemAmountIn == 0, "one of redeemTokensIn or redeemAmountIn must be zero");
+
+        RedeemLocalVars memory vars;
+
+        /* exchangeRate = invoke Exchange Rate Stored() */
+        (vars.mathErr, vars.exchangeRateMantissa) = exchangeRateStoredInternal();
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.REDEEM_EXCHANGE_RATE_READ_FAILED, uint(vars.mathErr));
+        }
+
+        /* If redeemTokensIn > 0: */
+        if (redeemTokensIn > 0) {
+            /*
+             * We calculate the exchange rate and the amount of underlying to be redeemed:
+             *  redeemTokens = redeemTokensIn
+             *  redeemAmount = redeemTokensIn x exchangeRateCurrent
+             */
+            vars.redeemTokens = redeemTokensIn;
+
+            (vars.mathErr, vars.redeemAmount) = mulScalarTruncate(Exp({mantissa: vars.exchangeRateMantissa}), redeemTokensIn);
+            if (vars.mathErr != MathError.NO_ERROR) {
+                return failOpaque(Error.MATH_ERROR, FailureInfo.REDEEM_EXCHANGE_TOKENS_CALCULATION_FAILED, uint(vars.mathErr));
+            }
+        } else {
+            /*
+             * We get the current exchange rate and calculate the amount to be redeemed:
+             *  redeemTokens = redeemAmountIn / exchangeRate
+             *  redeemAmount = redeemAmountIn
+             */
+
+            (vars.mathErr, vars.redeemTokens) = divScalarByExpTruncate(redeemAmountIn, Exp({mantissa: vars.exchangeRateMantissa}));
+            if (vars.mathErr != MathError.NO_ERROR) {
+                return failOpaque(Error.MATH_ERROR, FailureInfo.REDEEM_EXCHANGE_AMOUNT_CALCULATION_FAILED, uint(vars.mathErr));
+            }
+
+            vars.redeemAmount = redeemAmountIn;
+        }
+
+        /* Fail if redeem not allowed */
+        uint allowed = comptroller.redeemAllowed(address(this), redeemer, vars.redeemTokens);
+        if (allowed != 0) {
+            return failOpaque(Error.COMPTROLLER_REJECTION, FailureInfo.REDEEM_COMPTROLLER_REJECTION, allowed);
+        }
+
+        /* Verify market's block number equals current block number */
+        if (accrualBlockNumber != getBlockNumber()) {
+            return fail(Error.MARKET_NOT_FRESH, FailureInfo.REDEEM_FRESHNESS_CHECK);
+        }
+
+        /*
+         * We calculate the new total supply and redeemer balance, checking for underflow:
+         *  totalSupplyNew = totalSupply - redeemTokens
+         *  accountTokensNew = accountTokens[redeemer] - redeemTokens
+         */
+        (vars.mathErr, vars.totalSupplyNew) = subUInt(totalSupply, vars.redeemTokens);
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.REDEEM_NEW_TOTAL_SUPPLY_CALCULATION_FAILED, uint(vars.mathErr));
+        }
+
+        (vars.mathErr, vars.accountTokensNew) = subUInt(accountTokens[redeemer], vars.redeemTokens);
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.REDEEM_NEW_ACCOUNT_BALANCE_CALCULATION_FAILED, uint(vars.mathErr));
+        }
+
+        /* Fail gracefully if protocol has insufficient cash */
+        if (getCashPrior() < vars.redeemAmount) {
+            return fail(Error.TOKEN_INSUFFICIENT_CASH, FailureInfo.REDEEM_TRANSFER_OUT_NOT_POSSIBLE);
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        /*
+         * We invoke doTransferOut for the redeemer and the redeemAmount.
+         *  Note: The cToken must handle variations between ERC-20 and ETH underlying.
+         *  On success, the cToken has redeemAmount less of cash.
+         *  doTransferOut reverts if anything goes wrong, since we can't be sure if side effects occurred.
+         */
+        doTransferOut(redeemer, vars.redeemAmount);
+
+        /* We write previously calculated values into storage */
+        totalSupply = vars.totalSupplyNew;
+        accountTokens[redeemer] = vars.accountTokensNew;
+
+        /* We emit a Transfer event, and a Redeem event */
+        emit Transfer(redeemer, address(this), vars.redeemTokens);
+        emit Redeem(redeemer, vars.redeemAmount, vars.redeemTokens);
+
+        /* We call the defense hook */
+        comptroller.redeemVerify(address(this), redeemer, vars.redeemAmount, vars.redeemTokens);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+      * @notice Sender borrows assets from the protocol to their own address
+      * @param borrowAmount The amount of the underlying asset to borrow
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function borrowInternal(uint borrowAmount) internal nonReentrant returns (uint) {
+        uint error = accrueInterest();
+
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted borrow failed
+            return fail(Error(error), FailureInfo.BORROW_ACCRUE_INTEREST_FAILED);
+        }
+        // borrowFresh emits borrow-specific logs on errors, so we don't need to
+        return borrowFresh(msg.sender, borrowAmount);
+    }
+
+    struct BorrowLocalVars {
+        MathError mathErr;
+        uint accountBorrows;
+        uint accountBorrowsNew;
+        uint totalBorrowsNew;
+    }
+
+    /**
+      * @notice Users borrow assets from the protocol to their own address
+      * @param borrowAmount The amount of the underlying asset to borrow
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function borrowFresh(address payable borrower, uint borrowAmount) internal returns (uint) {
+        /* Fail if borrow not allowed */
+        uint allowed = comptroller.borrowAllowed(address(this), borrower, borrowAmount);
+
+        if (allowed != 0) {
+            return failOpaque(Error.COMPTROLLER_REJECTION, FailureInfo.BORROW_COMPTROLLER_REJECTION, allowed);
+        }
+
+
+        /* Verify market's block number equals current block number */
+        if (accrualBlockNumber != getBlockNumber()) {
+            return fail(Error.MARKET_NOT_FRESH, FailureInfo.BORROW_FRESHNESS_CHECK);
+        }
+
+        /* Fail gracefully if protocol has insufficient underlying cash */
+        if (getCashPrior() < borrowAmount) {
+            return fail(Error.TOKEN_INSUFFICIENT_CASH, FailureInfo.BORROW_CASH_NOT_AVAILABLE);
+        }
+
+        BorrowLocalVars memory vars;
+
+        /*
+         * We calculate the new borrower and total borrow balances, failing on overflow:
+         *  accountBorrowsNew = accountBorrows + borrowAmount
+         *  totalBorrowsNew = totalBorrows + borrowAmount
+         */
+        (vars.mathErr, vars.accountBorrows) = borrowBalanceStoredInternal(borrower);
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.BORROW_ACCUMULATED_BALANCE_CALCULATION_FAILED, uint(vars.mathErr));
+        }
+
+        (vars.mathErr, vars.accountBorrowsNew) = addUInt(vars.accountBorrows, borrowAmount);
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.BORROW_NEW_ACCOUNT_BORROW_BALANCE_CALCULATION_FAILED, uint(vars.mathErr));
+        }
+
+        (vars.mathErr, vars.totalBorrowsNew) = addUInt(totalBorrows, borrowAmount);
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.BORROW_NEW_TOTAL_BALANCE_CALCULATION_FAILED, uint(vars.mathErr));
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        /*
+         * We invoke doTransferOut for the borrower and the borrowAmount.
+         *  Note: The cToken must handle variations between ERC-20 and ETH underlying.
+         *  On success, the cToken borrowAmount less of cash.
+         *  doTransferOut reverts if anything goes wrong, since we can't be sure if side effects occurred.
+         */
+        // ruleid: compound-borrowfresh-reentrancy
+        doTransferOut(borrower, borrowAmount);
+
+        /* We write the previously calculated values into storage */
+        accountBorrows[borrower].principal = vars.accountBorrowsNew;
+        accountBorrows[borrower].interestIndex = borrowIndex;
+        totalBorrows = vars.totalBorrowsNew;
+
+        /* We emit a Borrow event */
+        emit Borrow(borrower, borrowAmount, vars.accountBorrowsNew, vars.totalBorrowsNew);
+
+        /* We call the defense hook */
+        // unused function
+        // Comptroller.borrowVerify(address(this), borrower, borrowAmount);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+     * @notice Sender repays their own borrow
+     * @param repayAmount The amount to repay
+     * @return (uint, uint) An error code (0=success, otherwise a failure, see ErrorReporter.sol), and the actual repayment amount.
+     */
+    function repayBorrowInternal(uint repayAmount) internal nonReentrant returns (uint, uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted borrow failed
+            return (fail(Error(error), FailureInfo.REPAY_BORROW_ACCRUE_INTEREST_FAILED), 0);
+        }
+        // repayBorrowFresh emits repay-borrow-specific logs on errors, so we don't need to
+        return repayBorrowFresh(msg.sender, msg.sender, repayAmount);
+    }
+
+    /**
+     * @notice Sender repays a borrow belonging to borrower
+     * @param borrower the account with the debt being payed off
+     * @param repayAmount The amount to repay
+     * @return (uint, uint) An error code (0=success, otherwise a failure, see ErrorReporter.sol), and the actual repayment amount.
+     */
+    function repayBorrowBehalfInternal(address borrower, uint repayAmount) internal nonReentrant returns (uint, uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted borrow failed
+            return (fail(Error(error), FailureInfo.REPAY_BEHALF_ACCRUE_INTEREST_FAILED), 0);
+        }
+        // repayBorrowFresh emits repay-borrow-specific logs on errors, so we don't need to
+        return repayBorrowFresh(msg.sender, borrower, repayAmount);
+    }
+
+    struct RepayBorrowLocalVars {
+        Error err;
+        MathError mathErr;
+        uint repayAmount;
+        uint borrowerIndex;
+        uint accountBorrows;
+        uint accountBorrowsNew;
+        uint totalBorrowsNew;
+        uint actualRepayAmount;
+    }
+
+    /**
+     * @notice Borrows are repaid by another user (possibly the borrower).
+     * @param payer the account paying off the borrow
+     * @param borrower the account with the debt being payed off
+     * @param repayAmount the amount of undelrying tokens being returned
+     * @return (uint, uint) An error code (0=success, otherwise a failure, see ErrorReporter.sol), and the actual repayment amount.
+     */
+    function repayBorrowFresh(address payer, address borrower, uint repayAmount) internal returns (uint, uint) {
+        /* Fail if repayBorrow not allowed */
+        uint allowed = comptroller.repayBorrowAllowed(address(this), payer, borrower, repayAmount);
+        if (allowed != 0) {
+            return (failOpaque(Error.COMPTROLLER_REJECTION, FailureInfo.REPAY_BORROW_COMPTROLLER_REJECTION, allowed), 0);
+        }
+
+        /* Verify market's block number equals current block number */
+        if (accrualBlockNumber != getBlockNumber()) {
+            return (fail(Error.MARKET_NOT_FRESH, FailureInfo.REPAY_BORROW_FRESHNESS_CHECK), 0);
+        }
+
+        RepayBorrowLocalVars memory vars;
+
+        /* We remember the original borrowerIndex for verification purposes */
+        vars.borrowerIndex = accountBorrows[borrower].interestIndex;
+
+        /* We fetch the amount the borrower owes, with accumulated interest */
+        (vars.mathErr, vars.accountBorrows) = borrowBalanceStoredInternal(borrower);
+        if (vars.mathErr != MathError.NO_ERROR) {
+            return (failOpaque(Error.MATH_ERROR, FailureInfo.REPAY_BORROW_ACCUMULATED_BALANCE_CALCULATION_FAILED, uint(vars.mathErr)), 0);
+        }
+
+        /* If repayAmount == -1, repayAmount = accountBorrows */
+        if (repayAmount == uint(-1)) {
+            vars.repayAmount = vars.accountBorrows;
+        } else {
+            vars.repayAmount = repayAmount;
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        /*
+         * We call doTransferIn for the payer and the repayAmount
+         *  Note: The cToken must handle variations between ERC-20 and ETH underlying.
+         *  On success, the cToken holds an additional repayAmount of cash.
+         *  doTransferIn reverts if anything goes wrong, since we can't be sure if side effects occurred.
+         *   it returns the amount actually transferred, in case of a fee.
+         */
+        vars.actualRepayAmount = doTransferIn(payer, vars.repayAmount);
+
+        /*
+         * We calculate the new borrower and total borrow balances, failing on underflow:
+         *  accountBorrowsNew = accountBorrows - actualRepayAmount
+         *  totalBorrowsNew = totalBorrows - actualRepayAmount
+         */
+        (vars.mathErr, vars.accountBorrowsNew) = subUInt(vars.accountBorrows, vars.actualRepayAmount);
+        require(vars.mathErr == MathError.NO_ERROR, "REPAY_BORROW_NEW_ACCOUNT_BORROW_BALANCE_CALCULATION_FAILED");
+
+        (vars.mathErr, vars.totalBorrowsNew) = subUInt(totalBorrows, vars.actualRepayAmount);
+        require(vars.mathErr == MathError.NO_ERROR, "REPAY_BORROW_NEW_TOTAL_BALANCE_CALCULATION_FAILED");
+
+        /* We write the previously calculated values into storage */
+        accountBorrows[borrower].principal = vars.accountBorrowsNew;
+        accountBorrows[borrower].interestIndex = borrowIndex;
+        totalBorrows = vars.totalBorrowsNew;
+
+        /* We emit a RepayBorrow event */
+        emit RepayBorrow(payer, borrower, vars.actualRepayAmount, vars.accountBorrowsNew, vars.totalBorrowsNew);
+
+        /* We call the defense hook */
+        // unused function
+        // Comptroller.repayBorrowVerify(address(this), payer, borrower, vars.actualRepayAmount, vars.borrowerIndex);
+
+        return (uint(Error.NO_ERROR), vars.actualRepayAmount);
+    }
+
+    /**
+     * @notice The sender liquidates the borrowers collateral.
+     *  The collateral seized is transferred to the liquidator.
+     * @param borrower The borrower of this cToken to be liquidated
+     * @param cTokenCollateral The market in which to seize collateral from the borrower
+     * @param repayAmount The amount of the underlying borrowed asset to repay
+     * @return (uint, uint) An error code (0=success, otherwise a failure, see ErrorReporter.sol), and the actual repayment amount.
+     */
+    function liquidateBorrowInternal(address borrower, uint repayAmount, CTokenInterface cTokenCollateral) internal nonReentrant returns (uint, uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted liquidation failed
+            return (fail(Error(error), FailureInfo.LIQUIDATE_ACCRUE_BORROW_INTEREST_FAILED), 0);
+        }
+
+        error = cTokenCollateral.accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but we still want to log the fact that an attempted liquidation failed
+            return (fail(Error(error), FailureInfo.LIQUIDATE_ACCRUE_COLLATERAL_INTEREST_FAILED), 0);
+        }
+
+        // liquidateBorrowFresh emits borrow-specific logs on errors, so we don't need to
+        return liquidateBorrowFresh(msg.sender, borrower, repayAmount, cTokenCollateral);
+    }
+
+    /**
+     * @notice The liquidator liquidates the borrowers collateral.
+     *  The collateral seized is transferred to the liquidator.
+     * @param borrower The borrower of this cToken to be liquidated
+     * @param liquidator The address repaying the borrow and seizing collateral
+     * @param cTokenCollateral The market in which to seize collateral from the borrower
+     * @param repayAmount The amount of the underlying borrowed asset to repay
+     * @return (uint, uint) An error code (0=success, otherwise a failure, see ErrorReporter.sol), and the actual repayment amount.
+     */
+    function liquidateBorrowFresh(address liquidator, address borrower, uint repayAmount, CTokenInterface cTokenCollateral) internal returns (uint, uint) {
+        /* Fail if liquidate not allowed */
+        uint allowed = comptroller.liquidateBorrowAllowed(address(this), address(cTokenCollateral), liquidator, borrower, repayAmount);
+        if (allowed != 0) {
+            return (failOpaque(Error.COMPTROLLER_REJECTION, FailureInfo.LIQUIDATE_COMPTROLLER_REJECTION, allowed), 0);
+        }
+
+        /* Verify market's block number equals current block number */
+        if (accrualBlockNumber != getBlockNumber()) {
+            return (fail(Error.MARKET_NOT_FRESH, FailureInfo.LIQUIDATE_FRESHNESS_CHECK), 0);
+        }
+
+        /* Verify cTokenCollateral market's block number equals current block number */
+        if (cTokenCollateral.getAccrualBlockNumber() != getBlockNumber()) {
+            return (fail(Error.MARKET_NOT_FRESH, FailureInfo.LIQUIDATE_COLLATERAL_FRESHNESS_CHECK), 0);
+        }
+
+        /* Fail if borrower = liquidator */
+        if (borrower == liquidator) {
+            return (fail(Error.INVALID_ACCOUNT_PAIR, FailureInfo.LIQUIDATE_LIQUIDATOR_IS_BORROWER), 0);
+        }
+
+        /* Fail if repayAmount = 0 */
+        if (repayAmount == 0) {
+            return (fail(Error.INVALID_CLOSE_AMOUNT_REQUESTED, FailureInfo.LIQUIDATE_CLOSE_AMOUNT_IS_ZERO), 0);
+        }
+
+        /* Fail if repayAmount = -1 */
+        if (repayAmount == uint(-1)) {
+            return (fail(Error.INVALID_CLOSE_AMOUNT_REQUESTED, FailureInfo.LIQUIDATE_CLOSE_AMOUNT_IS_UINT_MAX), 0);
+        }
+
+
+        /* Fail if repayBorrow fails */
+        (uint repayBorrowError, uint actualRepayAmount) = repayBorrowFresh(liquidator, borrower, repayAmount);
+        if (repayBorrowError != uint(Error.NO_ERROR)) {
+            return (fail(Error(repayBorrowError), FailureInfo.LIQUIDATE_REPAY_BORROW_FRESH_FAILED), 0);
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        /* We calculate the number of collateral tokens that will be seized */
+        (uint amountSeizeError, uint seizeTokens) = comptroller.liquidateCalculateSeizeTokens(address(this), address(cTokenCollateral), actualRepayAmount);
+        require(amountSeizeError == uint(Error.NO_ERROR), "LIQUIDATE_COMPTROLLER_CALCULATE_AMOUNT_SEIZE_FAILED");
+
+        /* Revert if borrower collateral token balance < seizeTokens */
+        require(cTokenCollateral.balanceOf(borrower) >= seizeTokens, "LIQUIDATE_SEIZE_TOO_MUCH");
+
+        // If this is also the collateral, run seizeInternal to avoid re-entrancy, otherwise make an external call
+        uint seizeError;
+        if (address(cTokenCollateral) == address(this)) {
+            seizeError = seizeInternal(address(this), liquidator, borrower, seizeTokens);
+        } else {
+            seizeError = cTokenCollateral.seize(liquidator, borrower, seizeTokens);
+        }
+
+        /* Revert if seize tokens fails (since we cannot be sure of side effects) */
+        require(seizeError == uint(Error.NO_ERROR), "token seizure failed");
+
+        /* We emit a LiquidateBorrow event */
+        emit LiquidateBorrow(liquidator, borrower, actualRepayAmount, address(cTokenCollateral), seizeTokens);
+
+        /* We call the defense hook */
+        // unused function
+        // Comptroller.liquidateBorrowVerify(address(this), address(cTokenCollateral), liquidator, borrower, actualRepayAmount, seizeTokens);
+
+        return (uint(Error.NO_ERROR), actualRepayAmount);
+    }
+
+    /**
+     * @notice Transfers collateral tokens (this market) to the liquidator.
+     * @dev Will fail unless called by another cToken during the process of liquidation.
+     *  Its absolutely critical to use msg.sender as the borrowed cToken and not a parameter.
+     * @param liquidator The account receiving seized collateral
+     * @param borrower The account having collateral seized
+     * @param seizeTokens The number of cTokens to seize
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function seize(address liquidator, address borrower, uint seizeTokens) external nonReentrant returns (uint) {
+        return seizeInternal(msg.sender, liquidator, borrower, seizeTokens);
+    }
+
+    /**
+     * @notice Transfers collateral tokens (this market) to the liquidator.
+     * @dev Called only during an in-kind liquidation, or by liquidateBorrow during the liquidation of another CToken.
+     *  Its absolutely critical to use msg.sender as the seizer cToken and not a parameter.
+     * @param seizerToken The contract seizing the collateral (i.e. borrowed cToken)
+     * @param liquidator The account receiving seized collateral
+     * @param borrower The account having collateral seized
+     * @param seizeTokens The number of cTokens to seize
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function seizeInternal(address seizerToken, address liquidator, address borrower, uint seizeTokens) internal returns (uint) {
+        /* Fail if seize not allowed */
+        uint allowed = comptroller.seizeAllowed(address(this), seizerToken, liquidator, borrower, seizeTokens);
+        if (allowed != 0) {
+            return failOpaque(Error.COMPTROLLER_REJECTION, FailureInfo.LIQUIDATE_SEIZE_COMPTROLLER_REJECTION, allowed);
+        }
+
+        /* Fail if borrower = liquidator */
+        if (borrower == liquidator) {
+            return fail(Error.INVALID_ACCOUNT_PAIR, FailureInfo.LIQUIDATE_SEIZE_LIQUIDATOR_IS_BORROWER);
+        }
+
+        MathError mathErr;
+        uint borrowerTokensNew;
+        uint liquidatorTokensNew;
+
+        /*
+         * We calculate the new borrower and liquidator token balances, failing on underflow/overflow:
+         *  borrowerTokensNew = accountTokens[borrower] - seizeTokens
+         *  liquidatorTokensNew = accountTokens[liquidator] + seizeTokens
+         */
+        (mathErr, borrowerTokensNew) = subUInt(accountTokens[borrower], seizeTokens);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.LIQUIDATE_SEIZE_BALANCE_DECREMENT_FAILED, uint(mathErr));
+        }
+
+        (mathErr, liquidatorTokensNew) = addUInt(accountTokens[liquidator], seizeTokens);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.LIQUIDATE_SEIZE_BALANCE_INCREMENT_FAILED, uint(mathErr));
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        /* We write the previously calculated values into storage */
+        accountTokens[borrower] = borrowerTokensNew;
+        accountTokens[liquidator] = liquidatorTokensNew;
+
+        /* Emit a Transfer event */
+        emit Transfer(borrower, liquidator, seizeTokens);
+
+        /* We call the defense hook */
+        // Transfer verify is required here due to tokens being transferred, and have to keep the
+        // ACC accounting in check
+        // This works, because the 'borrower' has to be in this market. and so, the active collateral usage can either remain unchanged
+        // (if the liquidator is also in the market) or reduce (if the liquidator is not in the market)
+        comptroller.transferVerify(address(this), borrower, liquidator, seizeTokens);
+
+        /* We call the defense hook */
+        // unused function
+        // Comptroller.seizeVerify(address(this), seizerToken, liquidator, borrower, seizeTokens);
+
+        return uint(Error.NO_ERROR);
+    }
+
+
+    /*** Admin Functions ***/
+
+    /**
+      * @notice Begins transfer of admin rights. The newPendingAdmin must call `_acceptAdmin` to finalize the transfer.
+      * @dev Admin function to begin change of admin. The newPendingAdmin must call `_acceptAdmin` to finalize the transfer.
+      * @param newPendingAdmin New pending admin.
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _setPendingAdmin(address payable newPendingAdmin) external returns (uint) {
+        // Check caller = admin
+        if (msg.sender != admin) {
+            return fail(Error.UNAUTHORIZED, FailureInfo.SET_PENDING_ADMIN_OWNER_CHECK);
+        }
+
+        // Save current value, if any, for inclusion in log
+        address oldPendingAdmin = pendingAdmin;
+
+        // Store pendingAdmin with value newPendingAdmin
+        pendingAdmin = newPendingAdmin;
+
+        // Emit NewPendingAdmin(oldPendingAdmin, newPendingAdmin)
+        emit NewPendingAdmin(oldPendingAdmin, newPendingAdmin);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+      * @notice Accepts transfer of admin rights. msg.sender must be pendingAdmin
+      * @dev Admin function for pending admin to accept role and update admin
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _acceptAdmin() external returns (uint) {
+        // Check caller is pendingAdmin and pendingAdmin ≠ address(0)
+        if (msg.sender != pendingAdmin || msg.sender == address(0)) {
+            return fail(Error.UNAUTHORIZED, FailureInfo.ACCEPT_ADMIN_PENDING_ADMIN_CHECK);
+        }
+
+        // Save current values for inclusion in log
+        address oldAdmin = admin;
+        address oldPendingAdmin = pendingAdmin;
+
+        // Store admin with value pendingAdmin
+        admin = pendingAdmin;
+
+        // Clear the pending value
+        pendingAdmin = address(0);
+
+        emit NewAdmin(oldAdmin, admin);
+        emit NewPendingAdmin(oldPendingAdmin, pendingAdmin);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+      * OLA_ADDITIONS : Made internal and removes Admin check.
+      * @notice Sets a new Comptroller for the market
+      * @dev Admin function to set a new Comptroller
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _setComptroller(ComptrollerInterface newComptroller) internal returns (uint) {
+        ComptrollerInterface oldComptroller = comptroller;
+        // Ensure invoke Comptroller.isComptroller() returns true
+        require(newComptroller.isComptroller(), "marker method returned false");
+
+        // Set market's Comptroller to newComptroller
+        comptroller = newComptroller;
+
+        // Emit NewComptroller(oldComptroller, newComptroller)
+        emit NewComptroller(oldComptroller, newComptroller);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+      * @notice accrues interest and sets a new reserve factor for the protocol using _setReserveFactorFresh
+      * @dev Admin function to accrue interest and set a new reserve factor
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _setReserveFactor(uint newReserveFactorMantissa) external nonReentrant returns (uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but on top of that we want to log the fact that an attempted reserve factor change failed.
+            return fail(Error(error), FailureInfo.SET_RESERVE_FACTOR_ACCRUE_INTEREST_FAILED);
+        }
+        // _setReserveFactorFresh emits reserve-factor-specific logs on errors, so we don't need to.
+        return _setReserveFactorFresh(newReserveFactorMantissa);
+    }
+
+    /**
+      * @notice Sets a new reserve factor for the protocol (*requires fresh interest accrual)
+      * @dev Admin function to set a new reserve factor
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _setReserveFactorFresh(uint newReserveFactorMantissa) internal returns (uint) {
+        // Check caller is admin
+        if (msg.sender != admin) {
+            return fail(Error.UNAUTHORIZED, FailureInfo.SET_RESERVE_FACTOR_ADMIN_CHECK);
+        }
+
+        // Verify market's block number equals current block number
+        if (accrualBlockNumber != getBlockNumber()) {
+            return fail(Error.MARKET_NOT_FRESH, FailureInfo.SET_RESERVE_FACTOR_FRESH_CHECK);
+        }
+
+        // Check newReserveFactor ≤ maxReserveFactor
+        if (newReserveFactorMantissa > reserveFactorMaxMantissa) {
+            return fail(Error.BAD_INPUT, FailureInfo.SET_RESERVE_FACTOR_BOUNDS_CHECK);
+        }
+
+        // OLA_ADDITIONS :This constraint
+        // Check newReserveFactor >= minReserveFactor
+        if (newReserveFactorMantissa < reserveFactorMinMantissa) {
+            return fail(Error.BAD_INPUT, FailureInfo.SET_RESERVE_FACTOR_BOUNDS_CHECK);
+        }
+
+        uint oldReserveFactorMantissa = reserveFactorMantissa;
+        reserveFactorMantissa = newReserveFactorMantissa;
+
+        emit NewReserveFactor(oldReserveFactorMantissa, newReserveFactorMantissa);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+     * @notice Accrues interest and reduces reserves by transferring to admin
+     * @param reduceAmount Amount of reduction to reserves
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function _reduceReserves(uint reduceAmount) external nonReentrant returns (uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but on top of that we want to log the fact that an attempted reduce reserves failed.
+            return fail(Error(error), FailureInfo.REDUCE_RESERVES_ACCRUE_INTEREST_FAILED);
+        }
+
+
+
+        // _reduceReservesFresh emits reserve-reduction-specific logs on errors, so we don't need to.
+        return _reduceReservesFresh(reduceAmount);
+    }
+
+    /**
+     * @notice Reduces reserves by transferring to the LeN admin and to Ola bank their respective shares
+     * @dev Requires fresh interest accrual
+     * @param reduceAmount Amount of reduction to reserves
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function _reduceReservesFresh(uint reduceAmount) internal returns (uint) {
+        // totalReserves - reduceAmount
+        uint totalReservesNew;
+
+        // OLA_ADDITIONS : Allowing anyone to reduce reserves
+        // Check caller is admin
+        // if (msg.sender != admin) {
+        //     return fail(Error.UNAUTHORIZED, FailureInfo.REDUCE_RESERVES_ADMIN_CHECK);
+        // }
+
+        // We fail gracefully unless market's block number equals current block number
+        if (accrualBlockNumber != getBlockNumber()) {
+            return fail(Error.MARKET_NOT_FRESH, FailureInfo.REDUCE_RESERVES_FRESH_CHECK);
+        }
+
+        // Fail gracefully if protocol has insufficient underlying cash
+        if (getCashPrior() < reduceAmount) {
+            return fail(Error.TOKEN_INSUFFICIENT_CASH, FailureInfo.REDUCE_RESERVES_CASH_NOT_AVAILABLE);
+        }
+
+        // Check reduceAmount ≤ reserves[n] (totalReserves)
+        if (reduceAmount > totalReserves) {
+            return fail(Error.BAD_INPUT, FailureInfo.REDUCE_RESERVES_VALIDATION);
+        }
+
+        // OLA_ADDITIONS : Dividing the reduced amount between the Admin and Ola (+validations)
+        //                 Important to notice that we have added Math calculations to this function.
+        //                 Where as before, it only used pre-calculated numbers.
+        MathError mathErr;
+        uint adminPart;
+        uint olaPart;
+        uint olaReserveFactorMantissa = fetchOlaReserveFactorMantissa();
+        address payable olaBankAddress = fetchOlaBankAddress();
+        address payable adminBankAddress = fetchAdminBankAddress();
+
+        // Calculate olaPart
+        (mathErr, olaPart) = mulScalarTruncate(Exp({mantissa: olaReserveFactorMantissa}), reduceAmount);
+        if (mathErr != MathError.NO_ERROR) {
+            return failOpaque(Error.MATH_ERROR, FailureInfo.REDUCE_RESERVES_OLA_PART_CALCULATION_FAILED, uint(mathErr));
+        }
+
+        // Sanity check, should never be a problem in a well parameterized system
+        if (olaPart >= reduceAmount) {
+            return fail(Error.BAD_SYSTEM_PARAMS, FailureInfo.REDUCE_RESERVES_OLA_PART_CALCULATION_FAILED);
+        }
+
+        /////////////////////////
+        // EFFECTS & INTERACTIONS
+        // (No safe failures beyond this point)
+
+        // Calculate admin part
+        adminPart = reduceAmount - olaPart;
+        // We checked olaPart < reduceAmount above, so this should never revert.
+        require(adminPart < reduceAmount, "reduce reserves unexpected adminPart underflow");
+
+        totalReservesNew = totalReserves - reduceAmount;
+        // We checked reduceAmount <= totalReserves above, so this should never revert.
+        require(totalReservesNew <= totalReserves, "reduce reserves unexpected underflow");
+
+        // Store reserves[n+1] = reserves[n] - reduceAmount
+        totalReserves = totalReservesNew;
+
+        // OLA_ADDITIONS : Transfer reserves to both admin and Ola bank addresses
+        // doTransferOut reverts if anything goes wrong, since we can't be sure if side effects occurred.
+        doTransferOut(adminBankAddress, adminPart);
+        doTransferOut(olaBankAddress, olaPart);
+
+        emit ReservesReduced(adminBankAddress, adminPart, olaBankAddress, olaPart, totalReservesNew);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /**
+     * @notice accrues interest and updates the interest rate model using _setInterestRateModelFresh
+     * @dev Admin function to accrue interest and update the interest rate model
+     * @param newInterestRateModel the new interest rate model to use
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function _setInterestRateModel(InterestRateModel newInterestRateModel) public returns (uint) {
+        uint error = accrueInterest();
+        if (error != uint(Error.NO_ERROR)) {
+            // accrueInterest emits logs on errors, but on top of that we want to log the fact that an attempted change of interest rate model failed
+            return fail(Error(error), FailureInfo.SET_INTEREST_RATE_MODEL_ACCRUE_INTEREST_FAILED);
+        }
+        // _setInterestRateModelFresh emits interest-rate-model-update-specific logs on errors, so we don't need to.
+        return _setInterestRateModelFresh(newInterestRateModel);
+    }
+
+    /**
+     * @notice updates the interest rate model (*requires fresh interest accrual)
+     * @dev Admin function to update the interest rate model
+     * @param newInterestRateModel the new interest rate model to use
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function _setInterestRateModelFresh(InterestRateModel newInterestRateModel) internal returns (uint) {
+
+        // Used to store old model for use in the event that is emitted on success
+        InterestRateModel oldInterestRateModel;
+
+        // Check caller is admin
+        if (msg.sender != admin) {
+            return fail(Error.UNAUTHORIZED, FailureInfo.SET_INTEREST_RATE_MODEL_OWNER_CHECK);
+        }
+
+        // We fail gracefully unless market's block number equals current block number
+        if (accrualBlockNumber != getBlockNumber()) {
+            return fail(Error.MARKET_NOT_FRESH, FailureInfo.SET_INTEREST_RATE_MODEL_FRESH_CHECK);
+        }
+
+        // Ensure interest rate model is an approved contracts
+        RegistryForOToken registry = RegistryForOToken(comptroller.getRegistry());
+
+        require(registry.isSupportedInterestRateModel(address(newInterestRateModel)), "Unapproved interest rate model");
+
+        // Track the market's current interest rate model
+        oldInterestRateModel = interestRateModel;
+
+        // Ensure invoke newInterestRateModel.isInterestRateModel() returns true
+        require(newInterestRateModel.isInterestRateModel(), "marker method returned false");
+
+        // Set the interest rate model to newInterestRateModel
+        interestRateModel = newInterestRateModel;
+
+        // Emit NewMarketInterestRateModel(oldInterestRateModel, newInterestRateModel)
+        emit NewMarketInterestRateModel(oldInterestRateModel, newInterestRateModel);
+
+        return uint(Error.NO_ERROR);
+    }
+
+    /*** Safe Token ***/
+
+    /**
+     * @notice Gets balance of this contract in terms of the underlying
+     * @dev This excludes the value of the current message, if any
+     * @return The quantity of underlying owned by this contract
+     */
+    function getCashPrior() internal view returns (uint);
+
+    /**
+     * @dev Performs a transfer in, reverting upon failure. Returns the amount actually transferred to the protocol, in case of a fee.
+     *  This may revert due to insufficient balance or insufficient allowance.
+     */
+    function doTransferIn(address from, uint amount) internal returns (uint);
+
+    /**
+     * @dev Performs a transfer out, ideally returning an explanatory error code upon failure tather than reverting.
+     *  If caller has not called checked protocol's balance, may revert due to insufficient cash held in the contract.
+     *  If caller has checked protocol's balance, and verified it is >= amount, this should not revert in normal conditions.
+     */
+    function doTransferOut(address payable to, uint amount) internal;
+
+    /**
+     * OLA_ADDITIONS: This function
+     * @dev Returns the ola reserves factor.
+     */
+    function fetchOlaReserveFactorMantissa() internal pure returns (uint) {
+        return olaReserveFactorMantissa;
+    }
+
+    /**
+     * OLA_ADDITIONS: This function
+     * @dev Fetches the ola bank address.
+     */
+    function fetchOlaBankAddress() internal returns (address payable) {
+        return RegistryForOToken(comptroller.getRegistry()).olaBankAddress();
+    }
+
+    /**
+     * OLA_ADDITIONS: This function
+     * @dev Fetches the admin bank address.
+     */
+    function fetchAdminBankAddress() internal view returns (address payable) {
+        return ComptrollerForOToken(address(comptroller)).adminBankAddress();
+    }
+
+    /*** Reentrancy Guard ***/
+
+    /**
+     * @dev Prevents a contract from calling itself, directly or indirectly.
+     */
+    modifier nonReentrant() {
+        require(_notEntered, "re-entered");
+        _notEntered = false;
+        _;
+        _notEntered = true; // get a gas-refund post-Istanbul
+    }
+}
+
+
+contract ComptrollerInterface {
+    /// @notice Indicator that this is a Comptroller contract (for inspection)
+    bool public constant isComptroller = true;
+
+    /*** OLA_ADDITIONS : registry getter ***/
+    /*** Registry ***/
+    function getRegistry() external view returns (address);
+
+    /*** Assets supported by the Comptroller ***/
+    function getAllMarkets() public view returns (CToken[] memory);
+
+    /*** OLA_ADDITIONS : peripheral checkers ***/
+    /*** Peripherals ***/
+    function hasRainMaker() view public returns (bool);
+    function hasBouncer() view public returns (bool);
+
+    /*** Assets You Are In ***/
+
+    function enterMarkets(address[] calldata cTokens) external returns (uint[] memory);
+    function exitMarket(address cToken) external returns (uint);
+
+    /*** Policy Hooks ***/
+
+    function mintAllowed(address cToken, address minter, uint mintAmount) external returns (uint);
+    function mintVerify(address cToken, address minter, uint mintAmount, uint mintTokens) external;
+
+    function redeemAllowed(address cToken, address redeemer, uint redeemTokens) external returns (uint);
+    function redeemVerify(address cToken, address redeemer, uint redeemAmount, uint redeemTokens) external;
+
+    function borrowAllowed(address cToken, address borrower, uint borrowAmount) external returns (uint);
+    function borrowVerify(address cToken, address borrower, uint borrowAmount) external;
+
+    function repayBorrowAllowed(
+        address cToken,
+        address payer,
+        address borrower,
+        uint repayAmount) external returns (uint);
+    function repayBorrowVerify(
+        address cToken,
+        address payer,
+        address borrower,
+        uint repayAmount,
+        uint borrowerIndex) external;
+
+    function liquidateBorrowAllowed(
+        address cTokenBorrowed,
+        address cTokenCollateral,
+        address liquidator,
+        address borrower,
+        uint repayAmount) external returns (uint);
+    function liquidateBorrowVerify(
+        address cTokenBorrowed,
+        address cTokenCollateral,
+        address liquidator,
+        address borrower,
+        uint repayAmount,
+        uint seizeTokens) external;
+
+    function seizeAllowed(
+        address cTokenCollateral,
+        address cTokenBorrowed,
+        address liquidator,
+        address borrower,
+        uint seizeTokens) external returns (uint);
+    function seizeVerify(
+        address cTokenCollateral,
+        address cTokenBorrowed,
+        address liquidator,
+        address borrower,
+        uint seizeTokens) external;
+
+    function transferAllowed(address cToken, address src, address dst, uint transferTokens) external returns (uint);
+    function transferVerify(address cToken, address src, address dst, uint transferTokens) external;
+
+    /*** Liquidity/Liquidation Calculations ***/
+
+    function liquidateCalculateSeizeTokens(
+        address cTokenBorrowed,
+        address cTokenCollateral,
+        uint repayAmount) external view returns (uint, uint);
+}
+
+
+
+
+/**
+ * @title EIP20NonStandardInterface
+ * @dev Version of ERC20 with no return values for `transfer` and `transferFrom`
+ *  See https://medium.com/coinmonks/missing-return-value-bug-at-least-130-tokens-affected-d67bf08521ca
+ */
+interface EIP20NonStandardInterface {
+
+    /**
+     * @notice Get the total number of tokens in circulation
+     * @return The supply of tokens
+     */
+    function totalSupply() external view returns (uint256);
+
+    /**
+     * @notice Gets the balance of the specified address
+     * @param owner The address from which the balance will be retrieved
+     * @return The balance
+     */
+    function balanceOf(address owner) external view returns (uint256 balance);
+
+    ///
+    /// !!!!!!!!!!!!!!
+    /// !!! NOTICE !!! `transfer` does not return a value, in violation of the ERC-20 specification
+    /// !!!!!!!!!!!!!!
+    ///
+
+    /**
+      * @notice Transfer `amount` tokens from `msg.sender` to `dst`
+      * @param dst The address of the destination account
+      * @param amount The number of tokens to transfer
+      */
+    function transfer(address dst, uint256 amount) external;
+
+    ///
+    /// !!!!!!!!!!!!!!
+    /// !!! NOTICE !!! `transferFrom` does not return a value, in violation of the ERC-20 specification
+    /// !!!!!!!!!!!!!!
+    ///
+
+    /**
+      * @notice Transfer `amount` tokens from `src` to `dst`
+      * @param src The address of the source account
+      * @param dst The address of the destination account
+      * @param amount The number of tokens to transfer
+      */
+    function transferFrom(address src, address dst, uint256 amount) external;
+
+    /**
+      * @notice Approve `spender` to transfer up to `amount` from `src`
+      * @dev This will overwrite the approval amount for `spender`
+      *  and is subject to issues noted [here](https://eips.ethereum.org/EIPS/eip-20#approve)
+      * @param spender The address of the account which may transfer tokens
+      * @param amount The number of tokens that are approved
+      * @return Whether or not the approval succeeded
+      */
+    function approve(address spender, uint256 amount) external returns (bool success);
+
+    /**
+      * @notice Get the current allowance from `owner` for `spender`
+      * @param owner The address of the account which owns the tokens to be spent
+      * @param spender The address of the account which may transfer tokens
+      * @return The number of tokens allowed to be spent
+      */
+    function allowance(address owner, address spender) external view returns (uint256 remaining);
+
+    event Transfer(address indexed from, address indexed to, uint256 amount);
+    event Approval(address indexed owner, address indexed spender, uint256 amount);
+}
+
+
+contract CTokenDelegatorInterface {
+
+    /*** Implementation Events ***/
+
+    /**
+     * @notice Emitted when implementation is changed
+     */
+    event NewImplementation(address indexed oldImplementation, address indexed newImplementation);
+
+    /**
+     * @notice Emitted when implementation is not changed under a system version update
+     */
+    event ImplementationDidNotChange(address indexed implementation);
+
+
+    /*** Implementation functions ***/
+
+    // OLA_ADDITIONS : Update implementation from the Registry
+    function updateImplementationFromRegistry(bool allowResign, bytes calldata becomeImplementationData) external returns (bool);
+}
+
+
+
+
+
+contract CErc20Interface {
+    /*** User Interface ***/
+
+    function mint(uint mintAmount) external returns (uint);
+    function redeem(uint redeemTokens) external returns (uint);
+    function redeemUnderlying(uint redeemAmount) external returns (uint);
+    function borrow(uint borrowAmount) external returns (uint);
+    function repayBorrow(uint repayAmount) external returns (uint);
+    function repayBorrowBehalf(address borrower, uint repayAmount) external returns (uint);
+    function liquidateBorrow(address borrower, uint repayAmount, CTokenInterface cTokenCollateral) external returns (uint);
+    function sweepToken(EIP20NonStandardInterface token) external;
+}
+
+contract CErc20StorageV0_01 {}
+
+contract CErc20StorageV0_02 is CErc20StorageV0_01 {}
+
+contract ONativeInterface {
+    /*** User Interface ***/
+
+    function mint() external payable;
+    function redeem(uint redeemTokens) external returns (uint);
+    function redeemUnderlying(uint redeemAmount) external returns (uint);
+    function borrow(uint borrowAmount) external returns (uint);
+    function repayBorrow() external payable;
+    function repayBorrowBehalf(address borrower) external payable;
+    function liquidateBorrow(address borrower, CTokenInterface cTokenCollateral) external payable;
+    function sweepToken(EIP20NonStandardInterface token) external;
+}
+
+contract CEtherStorageV0_01 {}
+
+contract CEtherStorageV0_02 is CEtherStorageV0_01 {}
+
+contract CDelegateInterface {
+    /**
+     * @notice Called by the delegator on a delegate to initialize it for duty
+     * @dev Should revert if any issues arise which make it unfit for delegation
+     * @param data The encoded bytes data for any initialization
+     */
+    function _becomeImplementation(bytes memory data) public;
+
+    /**
+     * @notice Called by the delegator on a delegate to forfeit its responsibility
+     */
+    function _resignImplementation() public;
+}
+
+
+
+
+
+
+interface RegistryForODelegator {
+    function getImplementationForLn(address lnUnitroller, bytes32 contractNameHash) external returns (address);
+}
+
+/**
+ * @title Ola's ODelegator Contract
+ * @notice OTokens which delegate to an implementation
+ * @author Ola
+ */
+contract ODelegator is CTokenAdminStorage, CTokenDelegatorInterface {
+
+    /**
+     * @notice Called by the Comptroller (most of the time) or by the admin (only via the constructor) to update the
+     *         implementation of the delegator
+     * @param implementation_ The address of the new implementation for delegation
+     * @param allowResign Flag to indicate whether to call _resignImplementation on the old implementation
+     * @param becomeImplementationData The encoded bytes data to be passed to _becomeImplementation
+     */
+    function _setImplementation(address implementation_, bool allowResign, bytes memory becomeImplementationData) internal {
+        if (allowResign) {
+            delegateToImplementation(abi.encodeWithSignature("_resignImplementation()"));
+        }
+
+        // Basic sanity
+        require(CToken(implementation_).isCToken(), "Not CTokens");
+
+        address oldImplementation = implementation;
+        implementation = implementation_;
+
+
+        delegateToImplementation(abi.encodeWithSignature("_becomeImplementation(bytes)", becomeImplementationData));
+
+        emit NewImplementation(oldImplementation, implementation);
+    }
+
+    /**
+     * @notice Internal method to delegate execution to another contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     * @param callee The contract to delegatecall
+     * @param data The raw data to delegatecall
+     * @return The returned bytes from the delegatecall
+     */
+    function delegateTo(address callee, bytes memory data) internal returns (bytes memory) {
+        (bool success, bytes memory returnData) = callee.delegatecall(data);
+        assembly {
+            if eq(success, 0) {
+                revert(add(returnData, 0x20), returndatasize)
+            }
+        }
+        return returnData;
+    }
+
+    /**
+     * @notice Delegates execution to the implementation contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     * @param data The raw data to delegatecall
+     * @return The returned bytes from the delegatecall
+     */
+    function delegateToImplementation(bytes memory data) public returns (bytes memory) {
+        return delegateTo(implementation, data);
+    }
+
+    /**
+     * @notice Delegates execution to an implementation contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     *  There are an additional 2 prefix uints from the wrapper returndata, which we ignore since we make an extra hop.
+     * @param data The raw data to delegatecall
+     * @return The returned bytes from the delegatecall
+     */
+    function delegateToViewImplementation(bytes memory data) public view returns (bytes memory) {
+        (bool success, bytes memory returnData) = address(this).staticcall(abi.encodeWithSignature("delegateToImplementation(bytes)", data));
+        assembly {
+            if eq(success, 0) {
+                revert(add(returnData, 0x20), returndatasize)
+            }
+        }
+        return abi.decode(returnData, (bytes));
+    }
+
+    function updateImplementationFromRegistry(bool allowResign, bytes calldata becomeImplementationData) external returns (bool) {
+        require(msg.sender == address(comptroller), "Not comptroller");
+        address implementationToSet = RegistryForODelegator(comptroller.getRegistry()).getImplementationForLn(address(comptroller), contractNameHash);
+        require(implementationToSet != address(0), "No implementation");
+
+        if (implementationToSet != implementation) {
+            // New implementations always get set via the setter (post-initialize)
+            _setImplementation(implementationToSet, allowResign, becomeImplementationData);
+        } else {
+            emit ImplementationDidNotChange(implementation);
+        }
+
+        return true;
+    }
+
+    /**
+     * @notice Delegates execution to an implementation contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     */
+    function () external payable {
+        require(msg.value == 0,"ODelegator:fallback: cannot send value to fallback");
+
+        // delegate all other functions to current implementation
+        (bool success, ) = implementation.delegatecall(msg.data);
+
+        assembly {
+            let free_mem_ptr := mload(0x40)
+            returndatacopy(free_mem_ptr, 0, returndatasize)
+
+            switch success
+            case 0 { revert(free_mem_ptr, returndatasize) }
+            default { return(free_mem_ptr, returndatasize) }
+        }
+    }
+}
+
+/**
+ * @title Compound's CErc20Delegator Contract
+ * @notice CTokens which wrap an EIP-20 underlying and delegate to an implementation
+ * @author Compound
+ */
+contract CErc20Delegator is ODelegator, CTokenInterface, CErc20Interface {
+    // OLA_ADDITIONS : This contract name hash
+    bytes32 constant public CErc20DelegatorContractHash = keccak256("CErc20Delegator");
+
+    /**
+     * @notice Construct a new money market
+     * @param underlying_ The address of the underlying asset
+     * @param comptroller_ The address of the Comptroller
+     * @param interestRateModel_ The address of the interest rate model
+     * @param initialExchangeRateMantissa_ The initial exchange rate, scaled by 1e18
+     * @param name_ ERC-20 name of this token
+     * @param symbol_ ERC-20 symbol of this token
+     * @param decimals_ ERC-20 decimal precision of this token
+     * @param admin_ Address of the administrator of this token
+     * @param becomeImplementationData The encoded args for becomeImplementation
+     */
+    constructor(address underlying_,
+                ComptrollerInterface comptroller_,
+                InterestRateModel interestRateModel_,
+                uint initialExchangeRateMantissa_,
+                string memory name_,
+                string memory symbol_,
+                uint8 decimals_,
+                address payable admin_,
+                bytes memory becomeImplementationData) public {
+        // Creator of the contract is admin during initialization
+        admin = msg.sender;
+
+        // Initialize name hash
+        contractNameHash = CErc20DelegatorContractHash;
+
+        address cErc20Implementation = RegistryForODelegator(comptroller_.getRegistry()).getImplementationForLn(address(comptroller_), CErc20DelegatorContractHash);
+
+        // First delegate gets to initialize the delegator (i.e. storage contract)
+        delegateTo(cErc20Implementation, abi.encodeWithSignature("initialize(address,address,address,uint256,string,string,uint8)",
+                                                            underlying_,
+                                                            comptroller_,
+                                                            interestRateModel_,
+                                                            initialExchangeRateMantissa_,
+                                                            name_,
+                                                            symbol_,
+                                                            decimals_));
+
+        // New implementations always get set via the setter (post-initialize)
+        _setImplementation(cErc20Implementation, false, becomeImplementationData);
+
+        // Set the proper admin now that initialization is done
+        admin = admin_;
+    }
+
+    /**
+     * @notice Sender supplies assets into the market and receives cTokens in exchange
+     * @dev Accrues interest whether or not the operation succeeds, unless reverted
+     * @param mintAmount The amount of the underlying asset to supply
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function mint(uint mintAmount) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("mint(uint256)", mintAmount));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Sender redeems cTokens in exchange for the underlying asset
+     * @dev Accrues interest whether or not the operation succeeds, unless reverted
+     * @param redeemTokens The number of cTokens to redeem into underlying
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function redeem(uint redeemTokens) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("redeem(uint256)", redeemTokens));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Sender redeems cTokens in exchange for a specified amount of underlying asset
+     * @dev Accrues interest whether or not the operation succeeds, unless reverted
+     * @param redeemAmount The amount of underlying to redeem
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function redeemUnderlying(uint redeemAmount) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("redeemUnderlying(uint256)", redeemAmount));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+      * @notice Sender borrows assets from the protocol to their own address
+      * @param borrowAmount The amount of the underlying asset to borrow
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function borrow(uint borrowAmount) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("borrow(uint256)", borrowAmount));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Sender repays their own borrow
+     * @param repayAmount The amount to repay
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function repayBorrow(uint repayAmount) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("repayBorrow(uint256)", repayAmount));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Sender repays a borrow belonging to borrower
+     * @param borrower the account with the debt being payed off
+     * @param repayAmount The amount to repay
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function repayBorrowBehalf(address borrower, uint repayAmount) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("repayBorrowBehalf(address,uint256)", borrower, repayAmount));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice The sender liquidates the borrowers collateral.
+     *  The collateral seized is transferred to the liquidator.
+     * @param borrower The borrower of this cToken to be liquidated
+     * @param cTokenCollateral The market in which to seize collateral from the borrower
+     * @param repayAmount The amount of the underlying borrowed asset to repay
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function liquidateBorrow(address borrower, uint repayAmount, CTokenInterface cTokenCollateral) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("liquidateBorrow(address,uint256,address)", borrower, repayAmount, cTokenCollateral));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Transfer `amount` tokens from `msg.sender` to `dst`
+     * @param dst The address of the destination account
+     * @param amount The number of tokens to transfer
+     * @return Whether or not the transfer succeeded
+     */
+    function transfer(address dst, uint amount) external returns (bool) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("transfer(address,uint256)", dst, amount));
+        return abi.decode(data, (bool));
+    }
+
+    /**
+     * @notice Transfer `amount` tokens from `src` to `dst`
+     * @param src The address of the source account
+     * @param dst The address of the destination account
+     * @param amount The number of tokens to transfer
+     * @return Whether or not the transfer succeeded
+     */
+    function transferFrom(address src, address dst, uint256 amount) external returns (bool) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("transferFrom(address,address,uint256)", src, dst, amount));
+        return abi.decode(data, (bool));
+    }
+
+    /**
+     * @notice Approve `spender` to transfer up to `amount` from `src`
+     * @dev This will overwrite the approval amount for `spender`
+     *  and is subject to issues noted [here](https://eips.ethereum.org/EIPS/eip-20#approve)
+     * @param spender The address of the account which may transfer tokens
+     * @param amount The number of tokens that are approved (-1 means infinite)
+     * @return Whether or not the approval succeeded
+     */
+    function approve(address spender, uint256 amount) external returns (bool) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("approve(address,uint256)", spender, amount));
+        return abi.decode(data, (bool));
+    }
+
+    /**
+     * @notice Get the current allowance from `owner` for `spender`
+     * @param owner The address of the account which owns the tokens to be spent
+     * @param spender The address of the account which may transfer tokens
+     * @return The number of tokens allowed to be spent (-1 means infinite)
+     */
+    function allowance(address owner, address spender) external view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("allowance(address,address)", owner, spender));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Get the token balance of the `owner`
+     * @param owner The address of the account to query
+     * @return The number of tokens owned by `owner`
+     */
+    function balanceOf(address owner) external view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("balanceOf(address)", owner));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Get the underlying balance of the `owner`
+     * @dev This also accrues interest in a transaction
+     * @param owner The address of the account to query
+     * @return The amount of underlying owned by `owner`
+     */
+    function balanceOfUnderlying(address owner) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("balanceOfUnderlying(address)", owner));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Get a snapshot of the account's balances, and the cached exchange rate
+     * @dev This is used by Comptroller to more efficiently perform liquidity checks.
+     * @param account Address of the account to snapshot
+     * @return (possible error, token balance, borrow balance, exchange rate mantissa)
+     */
+    function getAccountSnapshot(address account) external view returns (uint, uint, uint, uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("getAccountSnapshot(address)", account));
+        return abi.decode(data, (uint, uint, uint, uint));
+    }
+
+    /**
+     * @notice Returns the current per-block borrow interest rate for this cToken
+     * @return The borrow interest rate per block, scaled by 1e18
+     */
+    function borrowRatePerBlock() external view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("borrowRatePerBlock()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Returns the current per-block supply interest rate for this cToken
+     * @return The supply interest rate per block, scaled by 1e18
+     */
+    function supplyRatePerBlock() external view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("supplyRatePerBlock()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Returns the current total borrows plus accrued interest
+     * @return The total borrows with interest
+     */
+    function totalBorrowsCurrent() external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("totalBorrowsCurrent()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Accrue interest to updated borrowIndex and then calculate account's borrow balance using the updated borrowIndex
+     * @param account The address whose balance should be calculated after updating borrowIndex
+     * @return The calculated balance
+     */
+    function borrowBalanceCurrent(address account) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("borrowBalanceCurrent(address)", account));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Return the borrow balance of account based on stored data
+     * @param account The address whose balance should be calculated
+     * @return The calculated balance
+     */
+    function borrowBalanceStored(address account) public view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("borrowBalanceStored(address)", account));
+        return abi.decode(data, (uint));
+    }
+
+   /**
+     * @notice Accrue interest then return the up-to-date exchange rate
+     * @return Calculated exchange rate scaled by 1e18
+     */
+    function exchangeRateCurrent() public returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("exchangeRateCurrent()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Calculates the exchange rate from the underlying to the CToken
+     * @dev This function does not accrue interest before calculating the exchange rate
+     * @return Calculated exchange rate scaled by 1e18
+     */
+    function exchangeRateStored() public view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("exchangeRateStored()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Get cash balance of this cToken in the underlying asset
+     * @return The quantity of underlying asset owned by this contract
+     */
+    function getCash() external view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("getCash()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Get the accrual block number of this cToken
+     * @return The accrual block number
+     */
+    function getAccrualBlockNumber() external view returns (uint) {
+        bytes memory data = delegateToViewImplementation(abi.encodeWithSignature("getAccrualBlockNumber()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+      * @notice Applies accrued interest to total borrows and reserves.
+      * @dev This calculates interest accrued from the last checkpointed block
+      *      up to the current block and writes new checkpoint to storage.
+      */
+    function accrueInterest() public returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("accrueInterest()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Transfers collateral tokens (this market) to the liquidator.
+     * @dev Will fail unless called by another cToken during the process of liquidation.
+     *  Its absolutely critical to use msg.sender as the borrowed cToken and not a parameter.
+     * @param liquidator The account receiving seized collateral
+     * @param borrower The account having collateral seized
+     * @param seizeTokens The number of cTokens to seize
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function seize(address liquidator, address borrower, uint seizeTokens) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("seize(address,address,uint256)", liquidator, borrower, seizeTokens));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice A public function to sweep accidental ERC-20 transfers to this contract. Tokens are sent to admin (Timelock)
+     * @param token The address of the ERC-20 token to sweep
+     */
+    function sweepToken(EIP20NonStandardInterface token) external {
+        delegateToImplementation(abi.encodeWithSignature("sweepToken(address)", token));
+    }
+
+
+    /*** Admin Functions ***/
+
+    /**
+      * @notice Begins transfer of admin rights. The newPendingAdmin must call `_acceptAdmin` to finalize the transfer.
+      * @dev Admin function to begin change of admin. The newPendingAdmin must call `_acceptAdmin` to finalize the transfer.
+      * @param newPendingAdmin New pending admin.
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _setPendingAdmin(address payable newPendingAdmin) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("_setPendingAdmin(address)", newPendingAdmin));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+      * @notice accrues interest and sets a new reserve factor for the protocol using _setReserveFactorFresh
+      * @dev Admin function to accrue interest and set a new reserve factor
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _setReserveFactor(uint newReserveFactorMantissa) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("_setReserveFactor(uint256)", newReserveFactorMantissa));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+      * @notice Accepts transfer of admin rights. msg.sender must be pendingAdmin
+      * @dev Admin function for pending admin to accept role and update admin
+      * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+      */
+    function _acceptAdmin() external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("_acceptAdmin()"));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Accrues interest and reduces reserves by transferring to admin
+     * @param reduceAmount Amount of reduction to reserves
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function _reduceReserves(uint reduceAmount) external returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("_reduceReserves(uint256)", reduceAmount));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Accrues interest and updates the interest rate model using _setInterestRateModelFresh
+     * @dev Admin function to accrue interest and update the interest rate model
+     * @param newInterestRateModel the new interest rate model to use
+     * @return uint 0=success, otherwise a failure (see ErrorReporter.sol for details)
+     */
+    function _setInterestRateModel(InterestRateModel newInterestRateModel) public returns (uint) {
+        bytes memory data = delegateToImplementation(abi.encodeWithSignature("_setInterestRateModel(address)", newInterestRateModel));
+        return abi.decode(data, (uint));
+    }
+
+    /**
+     * @notice Internal method to delegate execution to another contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     * @param callee The contract to delegatecall
+     * @param data The raw data to delegatecall
+     * @return The returned bytes from the delegatecall
+     */
+    function delegateTo(address callee, bytes memory data) internal returns (bytes memory) {
+        (bool success, bytes memory returnData) = callee.delegatecall(data);
+        assembly {
+            if eq(success, 0) {
+                revert(add(returnData, 0x20), returndatasize)
+            }
+        }
+        return returnData;
+    }
+
+    /**
+     * @notice Delegates execution to the implementation contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     * @param data The raw data to delegatecall
+     * @return The returned bytes from the delegatecall
+     */
+    function delegateToImplementation(bytes memory data) public returns (bytes memory) {
+        return delegateTo(implementation, data);
+    }
+
+    /**
+     * @notice Delegates execution to an implementation contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     *  There are an additional 2 prefix uints from the wrapper returndata, which we ignore since we make an extra hop.
+     * @param data The raw data to delegatecall
+     * @return The returned bytes from the delegatecall
+     */
+    function delegateToViewImplementation(bytes memory data) public view returns (bytes memory) {
+        (bool success, bytes memory returnData) = address(this).staticcall(abi.encodeWithSignature("delegateToImplementation(bytes)", data));
+        assembly {
+            if eq(success, 0) {
+                revert(add(returnData, 0x20), returndatasize)
+            }
+        }
+        return abi.decode(returnData, (bytes));
+    }
+
+    /**
+     * @notice Delegates execution to an implementation contract
+     * @dev It returns to the external caller whatever the implementation returns or forwards reverts
+     */
+    function () external payable {
+        require(msg.value == 0,"CErc20Delegator:fallback: cannot send value to fallback");
+
+        // delegate all other functions to current implementation
+        (bool success, ) = implementation.delegatecall(msg.data);
+
+        assembly {
+            let free_mem_ptr := mload(0x40)
+            returndatacopy(free_mem_ptr, 0, returndatasize)
+
+            switch success
+            case 0 { revert(free_mem_ptr, returndatasize) }
+            default { return(free_mem_ptr, returndatasize) }
+        }
+    }
+}
+
+
+