javonet-nodejs-sdk 2.0.1 → 2.0.4

package/Binaries/Perl/Linux/X64/deps/lib/perl5/Module/Build/Tiny.pm

@@ -1,311 +0,0 @@
-package Module::Build::Tiny;
-$Module::Build::Tiny::VERSION = '0.039';
-use strict;
-use warnings;
-use Exporter 5.57 'import';
-our @EXPORT = qw/Build Build_PL/;
-
-use CPAN::Meta;
-use ExtUtils::Config 0.003;
-use ExtUtils::Helpers 0.020 qw/make_executable split_like_shell man1_pagename man3_pagename detildefy/;
-use ExtUtils::Install qw/pm_to_blib install/;
-use ExtUtils::InstallPaths 0.002;
-use File::Basename qw/basename dirname/;
-use File::Find ();
-use File::Path qw/mkpath rmtree/;
-use File::Spec::Functions qw/catfile catdir rel2abs abs2rel splitdir curdir/;
-use Getopt::Long 2.36 qw/GetOptionsFromArray/;
-use JSON::PP 2 qw/encode_json decode_json/;
-
-sub write_file {
-	my ($filename, $content) = @_;
-	open my $fh, '>', $filename or die "Could not open $filename: $!\n";
-	print $fh $content;
-}
-sub read_file {
-	my ($filename, $mode) = @_;
-	open my $fh, '<', $filename or die "Could not open $filename: $!\n";
-	return do { local $/; <$fh> };
-}
-
-sub get_meta {
-	my ($metafile) = grep { -e $_ } qw/META.json META.yml/ or die "No META information provided\n";
-	return CPAN::Meta->load_file($metafile);
-}
-
-sub manify {
-	my ($input_file, $output_file, $section, $opts) = @_;
-	return if -e $output_file && -M $input_file <= -M $output_file;
-	my $dirname = dirname($output_file);
-	mkpath($dirname, $opts->{verbose}) if not -d $dirname;
-	require Pod::Man;
-	Pod::Man->new(section => $section)->parse_from_file($input_file, $output_file);
-	print "Manifying $output_file\n" if $opts->{verbose} && $opts->{verbose} > 0;
-	return;
-}
-
-sub process_xs {
-	my ($source, $options) = @_;
-
-	die "Can't build xs files under --pureperl-only\n" if $options->{'pureperl-only'};
-	my (undef, @parts) = splitdir(dirname($source));
-	push @parts, my $file_base = basename($source, '.xs');
-	my $archdir = catdir(qw/blib arch auto/, @parts);
-	my $tempdir = 'temp';
-
-	my $c_file = catfile($tempdir, "$file_base.c");
-	require ExtUtils::ParseXS;
-	mkpath($tempdir, $options->{verbose}, oct '755');
-	ExtUtils::ParseXS::process_file(filename => $source, prototypes => 0, output => $c_file);
-
-	my $version = $options->{meta}->version;
-	require ExtUtils::CBuilder;
-	my $builder = ExtUtils::CBuilder->new(config => $options->{config}->values_set);
-	my $ob_file = $builder->compile(source => $c_file, defines => { VERSION => qq/"$version"/, XS_VERSION => qq/"$version"/ }, include_dirs => [ curdir, dirname($source) ]);
-
-	require DynaLoader;
-	my $mod2fname = defined &DynaLoader::mod2fname ? \&DynaLoader::mod2fname : sub { return $_[0][-1] };
-
-	mkpath($archdir, $options->{verbose}, oct '755') unless -d $archdir;
-	my $lib_file = catfile($archdir, $mod2fname->(\@parts) . '.' . $options->{config}->get('dlext'));
-	return $builder->link(objects => $ob_file, lib_file => $lib_file, module_name => join '::', @parts);
-}
-
-sub find {
-	my ($pattern, $dir) = @_;
-	my @ret;
-	File::Find::find(sub { push @ret, $File::Find::name if /$pattern/ && -f }, $dir) if -d $dir;
-	return @ret;
-}
-
-my %actions = (
-	build => sub {
-		my %opt = @_;
-		for my $pl_file (find(qr/\.PL$/, 'lib')) {
-                       (my $pm = $pl_file) =~ s/\.PL$//;
-			system $^X, $pl_file, $pm and die "$pl_file returned $?\n";
-		}
-		my %modules = map { $_ => catfile('blib', $_) } find(qr/\.p(?:m|od)$/, 'lib');
-		my %scripts = map { $_ => catfile('blib', $_) } find(qr//, 'script');
-		my %shared  = map { $_ => catfile(qw/blib lib auto share dist/, $opt{meta}->name, abs2rel($_, 'share')) } find(qr//, 'share');
-		pm_to_blib({ %modules, %scripts, %shared }, catdir(qw/blib lib auto/));
-		make_executable($_) for values %scripts;
-		mkpath(catdir(qw/blib arch/), $opt{verbose});
-		process_xs($_, \%opt) for find(qr/.xs$/, 'lib');
-
-		if ($opt{install_paths}->install_destination('bindoc') && $opt{install_paths}->is_default_installable('bindoc')) {
-			manify($_, catfile('blib', 'bindoc', man1_pagename($_)), $opt{config}->get('man1ext'), \%opt) for keys %scripts;
-		}
-		if ($opt{install_paths}->install_destination('libdoc') && $opt{install_paths}->is_default_installable('libdoc')) {
-			manify($_, catfile('blib', 'libdoc', man3_pagename($_)), $opt{config}->get('man3ext'), \%opt) for keys %modules;
-		}
-	},
-	test => sub {
-		my %opt = @_;
-		die "Must run `./Build build` first\n" if not -d 'blib';
-		require TAP::Harness::Env;
-		my %test_args = (
-			(verbosity => $opt{verbose}) x!! exists $opt{verbose},
-			(jobs => $opt{jobs}) x!! exists $opt{jobs},
-			(color => 1) x !!-t STDOUT,
-			lib => [ map { rel2abs(catdir(qw/blib/, $_)) } qw/arch lib/ ],
-		);
-		my $tester = TAP::Harness::Env->create(\%test_args);
-		$tester->runtests(sort +find(qr/\.t$/, 't'))->has_errors and exit 1;
-	},
-	install => sub {
-		my %opt = @_;
-		die "Must run `./Build build` first\n" if not -d 'blib';
-		install($opt{install_paths}->install_map, @opt{qw/verbose dry_run uninst/});
-	},
-	clean => sub {
-		my %opt = @_;
-		rmtree($_, $opt{verbose}) for qw/blib temp/;
-	},
-	realclean => sub {
-		my %opt = @_;
-		rmtree($_, $opt{verbose}) for qw/blib temp Build _build_params MYMETA.yml MYMETA.json/;
-	},
-);
-
-sub Build {
-	my $action = @ARGV && $ARGV[0] =~ /\A\w+\z/ ? shift @ARGV : 'build';
-	die "No such action '$action'\n" if not $actions{$action};
-	my($env, $bargv) = @{ decode_json(read_file('_build_params')) };
-	my %opt;
-	GetOptionsFromArray($_, \%opt, qw/install_base=s install_path=s% installdirs=s destdir=s prefix=s config=s% uninst:1 verbose:1 dry_run:1 pureperl-only:1 create_packlist=i jobs=i/) for ($env, $bargv, \@ARGV);
-	$_ = detildefy($_) for grep { defined } @opt{qw/install_base destdir prefix/}, values %{ $opt{install_path} };
-	@opt{ 'config', 'meta' } = (ExtUtils::Config->new($opt{config}), get_meta());
-	$actions{$action}->(%opt, install_paths => ExtUtils::InstallPaths->new(%opt, dist_name => $opt{meta}->name));
-}
-
-sub Build_PL {
-	my $meta = get_meta();
-	printf "Creating new 'Build' script for '%s' version '%s'\n", $meta->name, $meta->version;
-	my $dir = $meta->name eq 'Module-Build-Tiny' ? "use lib 'lib';" : '';
-	write_file('Build', "#!perl\n$dir\nuse Module::Build::Tiny;\nBuild();\n");
-	make_executable('Build');
-	my @env = defined $ENV{PERL_MB_OPT} ? split_like_shell($ENV{PERL_MB_OPT}) : ();
-	write_file('_build_params', encode_json([ \@env, \@ARGV ]));
-	$meta->save(@$_) for ['MYMETA.json'], [ 'MYMETA.yml' => { version => 1.4 } ];
-}
-
-1;
-
-#ABSTRACT: A tiny replacement for Module::Build
-
-
-# vi:et:sts=2:sw=2:ts=2
-
-__END__
-
-=pod
-
-=encoding UTF-8
-
-=head1 NAME
-
-Module::Build::Tiny - A tiny replacement for Module::Build
-
-=head1 VERSION
-
-version 0.039
-
-=head1 SYNOPSIS
-
- use Module::Build::Tiny;
- Build_PL();
-
-=head1 DESCRIPTION
-
-Many Perl distributions use a Build.PL file instead of a Makefile.PL file
-to drive distribution configuration, build, test and installation.
-Traditionally, Build.PL uses Module::Build as the underlying build system.
-This module provides a simple, lightweight, drop-in replacement.
-
-Whereas Module::Build has over 6,700 lines of code; this module has less
-than 120, yet supports the features needed by most distributions.
-
-=head2 Supported
-
-=over 4
-
-=item * Pure Perl distributions
-
-=item * Building XS or C
-
-=item * Recursive test files
-
-=item * MYMETA
-
-=item * Man page generation
-
-=item * Generated code from PL files
-
-=back
-
-=head2 Not Supported
-
-=over 4
-
-=item * Dynamic prerequisites
-
-=item * HTML documentation generation
-
-=item * Extending Module::Build::Tiny
-
-=item * Module sharedirs
-
-=back
-
-=head2 Directory structure
-
-Your .pm and .pod files must be in F<lib/>.  Any executables must be in
-F<script/>.  Test files must be in F<t/>. Dist sharedirs must be in F<share/>.
-
-=head1 USAGE
-
-These all work pretty much like their Module::Build equivalents.
-
-=head2 perl Build.PL
-
-=head2 Build [ build ] 
-
-=head2 Build test
-
-=head2 Build install
-
-This supports the following options:
-
-=over
-
-=item * verbose
-
-=item * install_base
-
-=item * installdirs
-
-=item * prefix
-
-=item * install_path
-
-=item * destdir
-
-=item * uninst
-
-=item * config
-
-=item * pure-perl
-
-=item * create_packlist
-
-=back
-
-=head1 AUTHORING
-
-This module doesn't support authoring. To develop modules using Module::Build::Tiny, usage of L<Dist::Zilla::Plugin::ModuleBuildTiny> or L<App::ModuleBuildTiny> is recommended.
-
-=head1 CONFIG FILE AND ENVIRONMENT
-
-Options can be provided in the C<PERL_MB_OPT> environment variable the same way they can with Module::Build. This should be done during the configuration stage.
-
-=head2 Incompatibilities
-
-=over 4
-
-=item * Argument parsing
-
-Module::Build has an extremely permissive way of argument handling, Module::Build::Tiny only supports a (sane) subset of that. In particular, C<./Build destdir=/foo> does not work, you will need to pass it as C<./Build --destdir=/foo>.
-
-=item * .modulebuildrc
-
-Module::Build::Tiny does not support .modulebuildrc files. In particular, this means that versions of local::lib older than 1.006008 may break with C<ERROR: Can't create /usr/local/somepath>. If the output of C<perl -Mlocal::lib> contains C<MODULEBUILDRC> but not C<PERL_MB_OPT >, you will need to upgrade it to resolve this issue.
-
-=back
-
-=head1 SEE ALSO
-
-L<Module::Build>
-
-=head1 AUTHORS
-
-=over 4
-
-=item *
-
-Leon Timmermans <leont@cpan.org>
-
-=item *
-
-David Golden <dagolden@cpan.org>
-
-=back
-
-=head1 COPYRIGHT AND LICENSE
-
-This software is copyright (c) 2011 by Leon Timmermans, David Golden.
-
-This is free software; you can redistribute it and/or modify it under
-the same terms as the Perl 5 programming language system itself.
-
-=cut

package/Binaries/Perl/Linux/X64/deps/lib/perl5/x86_64-linux-gnu-thread-multi/FFI/Build/File/Base.pm

@@ -1,366 +0,0 @@
-package FFI::Build::File::Base;
-
-use strict;
-use warnings;
-use 5.008004;
-use Carp ();
-use FFI::Temp;
-use File::Basename ();
-use FFI::Build::Platform;
-use FFI::Build::PluginData;
-use overload '""' => sub { $_[0]->path }, bool => sub { 1 }, fallback => 1;
-
-# ABSTRACT: Base class for File::Build files
-our $VERSION = '2.05'; # VERSION
-
-
-sub new
-{
-  my($class, $content, %config) = @_;
-
-  my $base     = $config{base} || 'ffi_build_';
-  my $dir      = $config{dir};
-  my $build    = $config{build};
-  my $platform = $config{platform} || FFI::Build::Platform->new;
-
-  my $self = bless {
-    platform => $platform,
-    build    => $build,
-  }, $class;
-
-  if(!defined $content)
-  {
-    Carp::croak("content is required");
-  }
-  elsif(ref($content) eq 'ARRAY')
-  {
-    $self->{path} = File::Spec->catfile(@$content);
-  }
-  elsif(ref($content) eq 'SCALAR')
-  {
-    my %args;
-    $args{TEMPLATE} = "${base}XXXXXX";
-    $args{DIR}      = $dir if $dir;
-    $args{SUFFIX}   = $self->default_suffix;
-    $args{UNLINK}   = 0;
-
-    my $fh = $self->{fh} = FFI::Temp->new(%args);
-
-    binmode( $fh, $self->default_encoding );
-    print $fh $$content;
-    close $fh;
-
-    $self->{path} = $fh->filename;
-    $self->{temp} = 1;
-  }
-  elsif(ref($content) eq '')
-  {
-    $self->{path} = $content;
-  }
-
-  if($self->platform->osname eq 'MSWin32')
-  {
-    $self->{native} = File::Spec->catfile($self->{path});
-    $self->{path} =~ s{\\}{/}g;
-  }
-
-  $self;
-}
-
-
-sub default_suffix    { die "must define a default extension in subclass" }
-sub default_encoding  { die "must define an encoding" }
-sub accept_suffix     { () }
-
-
-sub path      { shift->{path}                          }
-sub basename  { File::Basename::basename shift->{path} }
-sub dirname   { File::Basename::dirname  shift->{path} }
-sub is_temp   { shift->{temp}                          }
-sub platform  { shift->{platform}                      }
-sub build     { shift->{build}                         }
-
-
-sub native {
-  my($self) = @_;
-  $self->platform->osname eq 'MSWin32'
-    ? $self->{native}
-    : $self->{path};
-}
-
-
-sub slurp
-{
-  my($self) = @_;
-  my $fh;
-  open($fh, '<', $self->path) || Carp::croak "Error opening @{[ $self->path ]} for read $!";
-  binmode($fh, $self->default_encoding);
-  my $content = do { local $/; <$fh> };
-  close $fh;
-  $content;
-}
-
-
-sub keep
-{
-  delete shift->{temp};
-}
-
-
-sub build_item
-{
-  Carp::croak("Not implemented!");
-}
-
-
-sub needs_rebuild
-{
-  my($self, @source) = @_;
-  # if the target doesn't exist, then we definitely
-  # need a rebuild.
-  return 1 unless -f $self->path;
-  my $target_time = [stat $self->path]->[9];
-  foreach my $source (@source)
-  {
-    my $source_time = [stat "$source"]->[9];
-    return 1 if ! defined $source_time;
-    return 1 if $source_time > $target_time;
-  }
-  return 0;
-}
-
-
-sub ld
-{
-  return undef;
-}
-
-sub DESTROY
-{
-  my($self) = @_;
-
-  if($self->{temp})
-  {
-    unlink($self->path);
-  }
-}
-
-1;
-
-__END__
-
-=pod
-
-=encoding UTF-8
-
-=head1 NAME
-
-FFI::Build::File::Base - Base class for File::Build files
-
-=head1 VERSION
-
-version 2.05
-
-=head1 SYNOPSIS
-
-Create your own file class
-
- package FFI::Build::File::Foo;
- use parent qw( FFI::Build::File::Base );
- use constant default_suffix => '.foo';
- use constant default_encoding => ':utf8';
-
-Use it:
-
- # use an existing file in the filesystem
- my $file = FFI::Build::File::Foo->new('src/myfile.foo');
- 
- # generate a temp file with provided content
- # file will be deletd when $file falls out of scope.
- my $file = FFI::Build::File::Foo->new(\'content for a temp foo');
-
-=head1 DESCRIPTION
-
-This class is the base class for other C<FFI::Build::File::*> classes.
-
-=head1 CONSTRUCTOR
-
-=head2 new
-
- my $file = FFI::Build::File::Base->new(\$content, %options);
- my $file = FFI::Build::File::Base->new($filename, %options);
-
-Create a new instance of the file class.  You may provide either the
-content of the file as a scalar reference, or the path to an existing
-filename.  Options:
-
-=over 4
-
-=item base
-
-The base name for any temporary file C<ffi_build_> by default.
-
-=item build
-
-The L<FFI::Build> instance to use.
-
-=item dir
-
-The directory to store any temporary file.
-
-=item platform
-
-The L<FFI::Build::Platform> instance to use.
-
-=back
-
-=head1 METHODS
-
-=head2 default_suffix
-
- my $suffix = $file->default_suffix;
-
-B<MUST> be overridden in the subclass.  This is the standard extension for the file type.  C<.c> for a C file, C<.o> or C<.obj> for an object file depending on platform.  etc.
-
-=head2 default_encoding
-
- my $encoding = $file->default_encoding;
-
-B<MUST> be overridden in the subclass.  This is the passed to C<binmode> when the file is opened for reading or writing.
-
-=head2 accept_suffix
-
- my @suffix_list = $file->accept_suffix;
-
-Returns a list of regexes that recognize the file type.
-
-=head2 path
-
- my $path = $file->path;
-
-The full or relative path to the file.
-
-=head2 basename
-
- my $basename = $file->basename;
-
-The base filename part of the path.
-
-=head2 dirname
-
- my $dir = $file->dirname;
-
-The directory part of the path.
-
-=head2 is_temp
-
- my $bool = $file->is_temp;
-
-Returns true if the file is temporary, that is, it will be deleted when the file object falls out of scope.
-You can call C<keep>, to keep the file.
-
-=head2 platform
-
- my $platform = $file->platform;
-
-The L<FFI::Build::Platform> instance used for this file object.
-
-=head2 build
-
- my $build = $file->build;
-
-The L<FFI::Build> instance used for this file object, if any.
-
-=head2 native
-
- my $path = $file->native;
-
-Returns the operating system native version of the filename path.  On Windows, this means that forward slash C<\> is
-used instead of backslash C</>.
-
-=head2 slurp
-
- my $content = $file->slurp;
-
-Returns the content of the file.
-
-=head2 keep
-
- $file->keep;
-
-Turns off the temporary flag on the file object, meaning it will not automatically be deleted when the
-file object is deallocated or falls out of scope.
-
-=head2 build_item
-
- $file->build_item;
-
-Builds the file into its natural output type, usually an object file.  It returns a new file instance,
-or if the file is an object file then it returns empty list.
-
-=head2 build_all
-
- $file->build_all;
-
-If implemented the file in question can directly create a shared or dynamic library
-without needing a link step.  This is useful for languages that have their own build
-systems.
-
-=head2 needs_rebuild
-
- my $bool = $file->needs_rebuild
-
-=head2 ld
-
-=head1 AUTHOR
-
-Author: Graham Ollis E<lt>plicease@cpan.orgE<gt>
-
-Contributors:
-
-Bakkiaraj Murugesan (bakkiaraj)
-
-Dylan Cali (calid)
-
-pipcet
-
-Zaki Mughal (zmughal)
-
-Fitz Elliott (felliott)
-
-Vickenty Fesunov (vyf)
-
-Gregor Herrmann (gregoa)
-
-Shlomi Fish (shlomif)
-
-Damyan Ivanov
-
-Ilya Pavlov (Ilya33)
-
-Petr Písař (ppisar)
-
-Mohammad S Anwar (MANWAR)
-
-Håkon Hægland (hakonhagland, HAKONH)
-
-Meredith (merrilymeredith, MHOWARD)
-
-Diab Jerius (DJERIUS)
-
-Eric Brine (IKEGAMI)
-
-szTheory
-
-José Joaquín Atria (JJATRIA)
-
-Pete Houston (openstrike, HOUSTON)
-
-=head1 COPYRIGHT AND LICENSE
-
-This software is copyright (c) 2015-2022 by Graham Ollis.
-
-This is free software; you can redistribute it and/or modify it under
-the same terms as the Perl 5 programming language system itself.
-
-=cut