expo-modules-core 0.7.0 → 0.9.1

package/ios/JSI/JSIInstaller.mm

@@ -1,34 +0,0 @@
-// Copyright 2018-present 650 Industries. All rights reserved.
-
-#import <ExpoModulesCore/JSIInstaller.h>
-#import <ExpoModulesCore/ExpoModulesProxySpec.h>
-#import <ExpoModulesCore/ExpoModulesHostObject.h>
-#import <ExpoModulesCore/Swift.h>
-
-using namespace facebook;
-using namespace react;
-
-namespace expo {
-
-void installRuntimeObjects(jsi::Runtime &runtime, std::shared_ptr<CallInvoker> callInvoker, EXNativeModulesProxy *nativeModulesProxy)
-{
-  auto expoModulesProxyModule = std::make_shared<ExpoModulesProxySpec>(callInvoker, nativeModulesProxy);
-
-  runtime
-    .global()
-    .setProperty(runtime, "ExpoModulesProxy", jsi::Object::createFromHostObject(runtime, expoModulesProxyModule));
-}
-
-} // namespace expo
-
-@implementation JavaScriptRuntimeManager
-
-+ (void)installExpoModulesToRuntime:(nonnull JavaScriptRuntime *)runtime withSwiftInterop:(nonnull SwiftInteropBridge *)swiftInterop
-{
-  std::shared_ptr<expo::ExpoModulesHostObject> hostObjectPtr = std::make_shared<expo::ExpoModulesHostObject>(swiftInterop);
-  JavaScriptObject *global = [runtime global];
-
-  global[@"ExpoModules"] = [runtime createHostObject:hostObjectPtr];
-}
-
-@end

package/ios/JSI/JavaScriptObject.h

@@ -1,60 +0,0 @@
-// Copyright 2022-present 650 Industries. All rights reserved.
-
-#import <Foundation/Foundation.h>
-#import <React/RCTBridgeModule.h>
-
-#ifdef __cplusplus
-#import <jsi/jsi.h>
-#import <ReactCommon/CallInvoker.h>
-
-namespace jsi = facebook::jsi;
-#endif // __cplusplus
-
-typedef void (^JSAsyncFunctionBlock)(NSArray * _Nonnull, RCTPromiseResolveBlock _Nonnull, RCTPromiseRejectBlock _Nonnull);
-typedef id _Nullable (^JSSyncFunctionBlock)(NSArray * _Nonnull);
-
-@class JavaScriptRuntime;
-
-@interface JavaScriptObject : NSObject
-
-// Some parts of the interface must be hidden for Swift – it can't import any C++ code.
-#ifdef __cplusplus
-- (nonnull instancetype)initWith:(std::shared_ptr<jsi::Object>)jsObjectPtr
-                         runtime:(nonnull JavaScriptRuntime *)runtime;
-
-/**
- Returns the pointer to the underlying object.
- */
-- (nonnull jsi::Object *)get;
-#endif // __cplusplus
-
-#pragma mark - Subscripting
-
-/**
- Subscript getter. Supports only values convertible to Foundation types, otherwise `nil` is returned.
- */
-- (nullable id)objectForKeyedSubscript:(nonnull NSString *)key;
-
-/**
- Subscript setter. Only `JavaScriptObject` and Foundation object convertible to JSI values can be used as a value,
- otherwise the property is set to `undefined`.
- */
-- (void)setObject:(nullable id)obj forKeyedSubscript:(nonnull NSString *)key;
-
-#pragma mark - Functions
-
-/**
- Sets given function block on the object as a host function returning a promise.
- */
-- (void)setAsyncFunction:(nonnull NSString *)key
-               argsCount:(NSInteger)argsCount
-                   block:(nonnull JSAsyncFunctionBlock)block;
-
-/**
- Sets given synchronous function block as a host function on the object.
- */
-- (void)setSyncFunction:(nonnull NSString *)name
-              argsCount:(NSInteger)argsCount
-                  block:(nonnull JSSyncFunctionBlock)block;
-
-@end

package/ios/JSI/JavaScriptObject.mm

@@ -1,93 +0,0 @@
-// Copyright 2022-present 650 Industries. All rights reserved.
-
-#import <ExpoModulesCore/JSIConversions.h>
-#import <ExpoModulesCore/JavaScriptObject.h>
-#import <ExpoModulesCore/JavaScriptRuntime.h>
-#import <ExpoModulesCore/ExpoModulesProxySpec.h>
-
-@implementation JavaScriptObject {
-  /**
-   Pointer to the `JavaScriptRuntime` wrapper.
-
-   \note It must be weak because only then the original runtime can be safely deallocated
-   when the JS engine wants to without unsetting it on each created object.
-   */
-  __weak JavaScriptRuntime *_runtime;
-
-  /**
-   Shared pointer to the original JSI object that is being wrapped by `JavaScriptObject` class.
-   */
-  std::shared_ptr<jsi::Object> _jsObjectPtr;
-}
-
-- (nonnull instancetype)initWith:(std::shared_ptr<jsi::Object>)jsObjectPtr
-                         runtime:(nonnull JavaScriptRuntime *)runtime
-{
-  if (self = [super init]) {
-    _runtime = runtime;
-    _jsObjectPtr = jsObjectPtr;
-  }
-  return self;
-}
-
-- (nonnull jsi::Object *)get
-{
-  return _jsObjectPtr.get();
-}
-
-#pragma mark - Subscripting
-
-- (nullable id)objectForKeyedSubscript:(nonnull NSString *)key
-{
-  auto runtime = [_runtime get];
-  auto callInvoker = [_runtime callInvoker];
-
-  if (runtime && callInvoker) {
-    auto value = _jsObjectPtr->getProperty(*runtime, [key UTF8String]);
-    return expo::convertJSIValueToObjCObject(*runtime, value, callInvoker);
-  }
-  return nil;
-}
-
-- (void)setObject:(nullable id)obj forKeyedSubscript:(nonnull NSString *)key
-{
-  auto runtime = [_runtime get];
-
-  if (!runtime) {
-    NSLog(@"Cannot set '%@' property when the JavaScript runtime is no longer available.", key);
-    return;
-  }
-  if ([obj isKindOfClass:[JavaScriptObject class]]) {
-    _jsObjectPtr->setProperty(*runtime, [key UTF8String], *[obj get]);
-  } else {
-    _jsObjectPtr->setProperty(*runtime, [key UTF8String], expo::convertObjCObjectToJSIValue(*runtime, obj));
-  }
-}
-
-#pragma mark - Functions
-
-- (void)setAsyncFunction:(nonnull NSString *)name
-               argsCount:(NSInteger)argsCount
-                   block:(nonnull JSAsyncFunctionBlock)block
-{
-  if (!_runtime) {
-    NSLog(@"Cannot set '%@' async function when the JavaScript runtime is no longer available.", name);
-    return;
-  }
-  jsi::Function function = [_runtime createAsyncFunction:name argsCount:argsCount block:block];
-  _jsObjectPtr->setProperty(*[_runtime get], [name UTF8String], function);
-}
-
-- (void)setSyncFunction:(nonnull NSString *)name
-              argsCount:(NSInteger)argsCount
-                  block:(nonnull JSSyncFunctionBlock)block
-{
-  if (!_runtime) {
-    NSLog(@"Cannot set '%@' sync function when the JavaScript runtime is no longer available.", name);
-    return;
-  }
-  jsi::Function function = [_runtime createSyncFunction:name argsCount:argsCount block:block];
-  _jsObjectPtr->setProperty(*[_runtime get], [name UTF8String], function);
-}
-
-@end

package/ios/JSI/JavaScriptRuntime.mm

@@ -1,102 +0,0 @@
-// Copyright 2018-present 650 Industries. All rights reserved.
-
-#import <jsi/jsi.h>
-
-#import <ExpoModulesCore/JavaScriptRuntime.h>
-#import <ExpoModulesCore/ExpoModulesHostObject.h>
-#import <ExpoModulesCore/Swift.h>
-
-using namespace facebook;
-
-@implementation JavaScriptRuntime {
-  jsi::Runtime *_runtime;
-  std::shared_ptr<react::CallInvoker> _jsCallInvoker;
-
-  JavaScriptObject *_global;
-}
-
-- (nonnull instancetype)initWithRuntime:(jsi::Runtime &)runtime callInvoker:(std::shared_ptr<react::CallInvoker>)callInvoker
-{
-  if (self = [super init]) {
-    _runtime = &runtime;
-    _jsCallInvoker = callInvoker;
-
-    auto jsGlobalPtr = std::make_shared<jsi::Object>(_runtime->global());
-    _global = [[JavaScriptObject alloc] initWith:jsGlobalPtr runtime:self];
-  }
-  return self;
-}
-
-- (nonnull jsi::Runtime *)get
-{
-  return _runtime;
-}
-
-- (std::shared_ptr<react::CallInvoker>)callInvoker
-{
-  return _jsCallInvoker;
-}
-
-- (nonnull JavaScriptObject *)createObject
-{
-  auto jsObjectPtr = std::make_shared<jsi::Object>(*_runtime);
-  return [[JavaScriptObject alloc] initWith:jsObjectPtr runtime:self];
-}
-
-- (nonnull JavaScriptObject *)createHostObject:(std::shared_ptr<jsi::HostObject>)jsiHostObjectPtr
-{
-  auto jsObjectPtr = std::make_shared<jsi::Object>(jsi::Object::createFromHostObject(*_runtime, jsiHostObjectPtr));
-  return [[JavaScriptObject alloc] initWith:jsObjectPtr runtime:self];
-}
-
-- (nonnull JavaScriptObject *)global
-{
-  return _global;
-}
-
-- (jsi::Function)createSyncFunction:(nonnull NSString *)name
-                          argsCount:(NSInteger)argsCount
-                              block:(nonnull JSSyncFunctionBlock)block
-{
-  return [self createHostFunction:name argsCount:argsCount block:^jsi::Value(jsi::Runtime &runtime, std::shared_ptr<react::CallInvoker> callInvoker, NSArray * _Nonnull arguments) {
-    return expo::convertObjCObjectToJSIValue(runtime, block(arguments));
-  }];
-}
-
-- (jsi::Function)createAsyncFunction:(nonnull NSString *)name
-                           argsCount:(NSInteger)argsCount
-                               block:(nonnull JSAsyncFunctionBlock)block
-{
-  return [self createHostFunction:name argsCount:argsCount block:^jsi::Value(jsi::Runtime &runtime, std::shared_ptr<react::CallInvoker> callInvoker, NSArray *arguments) {
-    // The function that is invoked as a setup of the JavaScript `Promise`.
-    auto promiseSetup = [callInvoker, block, arguments](jsi::Runtime &runtime, std::shared_ptr<Promise> promise) {
-      expo::callPromiseSetupWithBlock(runtime, callInvoker, promise, ^(RCTPromiseResolveBlock resolver, RCTPromiseRejectBlock rejecter) {
-        block(arguments, resolver, rejecter);
-      });
-    };
-    return createPromiseAsJSIValue(runtime, promiseSetup);
-  }];
-}
-
-#pragma mark - Private
-
-typedef jsi::Value (^JSHostFunctionBlock)(jsi::Runtime &runtime, std::shared_ptr<react::CallInvoker> callInvoker, NSArray * _Nonnull arguments);
-
-- (jsi::Function)createHostFunction:(nonnull NSString *)name
-                          argsCount:(NSInteger)argsCount
-                              block:(nonnull JSHostFunctionBlock)block
-{
-  jsi::PropNameID propNameId = jsi::PropNameID::forAscii(*_runtime, [name UTF8String], [name length]);
-  std::weak_ptr<react::CallInvoker> weakCallInvoker = _jsCallInvoker;
-  jsi::HostFunctionType function = [weakCallInvoker, block](jsi::Runtime &runtime, const jsi::Value &thisVal, const jsi::Value *args, size_t count) -> jsi::Value {
-    if (auto callInvoker = weakCallInvoker.lock()) {
-      NSArray *arguments = expo::convertJSIValuesToNSArray(runtime, args, count, callInvoker);
-      return block(runtime, callInvoker, arguments);
-    }
-    // TODO: We should throw some kind of error.
-    return jsi::Value::undefined();
-  };
-  return jsi::Function::createFromHostFunction(*_runtime, propNameId, (unsigned int)argsCount, function);
-}
-
-@end

package/ios/NativeModulesProxy/EXComponentDataCompatibleWrapper.h

@@ -1,16 +0,0 @@
-// Copyright 2018-present 650 Industries. All rights reserved.
-
-#import <React/RCTComponentData.h>
-
-/**
- * A compatible wrapper for `RCTComponentData` which has different designated initializers between different react-native versions.
- * This class unifies the interface to make react-native <= 0.64 backward compatible.
- * Remove when we drop support for SDK 44
- */
-@interface EXComponentDataCompatibleWrapper : RCTComponentData
-
-- (instancetype)initWithManagerClass:(Class)managerClass
-                              bridge:(RCTBridge *)bridge
-                     eventDispatcher:(id<RCTEventDispatcherProtocol>)eventDispatcher NS_DESIGNATED_INITIALIZER;
-
-@end

package/ios/NativeModulesProxy/EXComponentDataCompatibleWrapper.m

@@ -1,28 +0,0 @@
-// Copyright 2018-present 650 Industries. All rights reserved.
-
-#import <ExpoModulesCore/EXComponentDataCompatibleWrapper.h>
-
-@interface RCTComponentData (EXComponentDataCompatibleWrapper)
-
-// available in RN 0.65+
-- (instancetype)initWithManagerClass:(Class)managerClass
-                              bridge:(RCTBridge *)bridge
-                     eventDispatcher:(id<RCTEventDispatcherProtocol>) eventDispatcher;
-
-- (instancetype)initWithManagerClass:(Class)managerClass bridge:(RCTBridge *)bridge;
-
-@end
-
-@implementation EXComponentDataCompatibleWrapper
-
-- (instancetype)initWithManagerClass:(Class)managerClass
-                              bridge:(RCTBridge *)bridge
-                     eventDispatcher:(id<RCTEventDispatcherProtocol>)eventDispatcher
-{
-  if ([self respondsToSelector:@selector(initWithManagerClass:bridge:)]) {
-    return [super initWithManagerClass:managerClass bridge:bridge];
-  }
-  return [super initWithManagerClass:managerClass bridge:bridge eventDispatcher:eventDispatcher];
-}
-
-@end