expo-modules-core 0.6.1 → 0.7.0

package/ios/JSI/JavaScriptObject.mm

@@ -0,0 +1,93 @@
+// Copyright 2022-present 650 Industries. All rights reserved.
+
+#import <ExpoModulesCore/JSIConversions.h>
+#import <ExpoModulesCore/JavaScriptObject.h>
+#import <ExpoModulesCore/JavaScriptRuntime.h>
+#import <ExpoModulesCore/ExpoModulesProxySpec.h>
+
+@implementation JavaScriptObject {
+  /**
+   Pointer to the `JavaScriptRuntime` wrapper.
+
+   \note It must be weak because only then the original runtime can be safely deallocated
+   when the JS engine wants to without unsetting it on each created object.
+   */
+  __weak JavaScriptRuntime *_runtime;
+
+  /**
+   Shared pointer to the original JSI object that is being wrapped by `JavaScriptObject` class.
+   */
+  std::shared_ptr<jsi::Object> _jsObjectPtr;
+}
+
+- (nonnull instancetype)initWith:(std::shared_ptr<jsi::Object>)jsObjectPtr
+                         runtime:(nonnull JavaScriptRuntime *)runtime
+{
+  if (self = [super init]) {
+    _runtime = runtime;
+    _jsObjectPtr = jsObjectPtr;
+  }
+  return self;
+}
+
+- (nonnull jsi::Object *)get
+{
+  return _jsObjectPtr.get();
+}
+
+#pragma mark - Subscripting
+
+- (nullable id)objectForKeyedSubscript:(nonnull NSString *)key
+{
+  auto runtime = [_runtime get];
+  auto callInvoker = [_runtime callInvoker];
+
+  if (runtime && callInvoker) {
+    auto value = _jsObjectPtr->getProperty(*runtime, [key UTF8String]);
+    return expo::convertJSIValueToObjCObject(*runtime, value, callInvoker);
+  }
+  return nil;
+}
+
+- (void)setObject:(nullable id)obj forKeyedSubscript:(nonnull NSString *)key
+{
+  auto runtime = [_runtime get];
+
+  if (!runtime) {
+    NSLog(@"Cannot set '%@' property when the JavaScript runtime is no longer available.", key);
+    return;
+  }
+  if ([obj isKindOfClass:[JavaScriptObject class]]) {
+    _jsObjectPtr->setProperty(*runtime, [key UTF8String], *[obj get]);
+  } else {
+    _jsObjectPtr->setProperty(*runtime, [key UTF8String], expo::convertObjCObjectToJSIValue(*runtime, obj));
+  }
+}
+
+#pragma mark - Functions
+
+- (void)setAsyncFunction:(nonnull NSString *)name
+               argsCount:(NSInteger)argsCount
+                   block:(nonnull JSAsyncFunctionBlock)block
+{
+  if (!_runtime) {
+    NSLog(@"Cannot set '%@' async function when the JavaScript runtime is no longer available.", name);
+    return;
+  }
+  jsi::Function function = [_runtime createAsyncFunction:name argsCount:argsCount block:block];
+  _jsObjectPtr->setProperty(*[_runtime get], [name UTF8String], function);
+}
+
+- (void)setSyncFunction:(nonnull NSString *)name
+              argsCount:(NSInteger)argsCount
+                  block:(nonnull JSSyncFunctionBlock)block
+{
+  if (!_runtime) {
+    NSLog(@"Cannot set '%@' sync function when the JavaScript runtime is no longer available.", name);
+    return;
+  }
+  jsi::Function function = [_runtime createSyncFunction:name argsCount:argsCount block:block];
+  _jsObjectPtr->setProperty(*[_runtime get], [name UTF8String], function);
+}
+
+@end

package/ios/JSI/JavaScriptRuntime.h

@@ -0,0 +1,54 @@
+// Copyright 2018-present 650 Industries. All rights reserved.
+
+#import <ExpoModulesCore/JavaScriptObject.h>
+
+#ifdef __cplusplus
+#import <ReactCommon/CallInvoker.h>
+
+namespace jsi = facebook::jsi;
+namespace react = facebook::react;
+#endif // __cplusplus
+
+@interface JavaScriptRuntime : NSObject
+
+#ifdef __cplusplus
+typedef jsi::Value (^JSHostFunctionBlock)(jsi::Runtime &runtime, std::shared_ptr<react::CallInvoker> callInvoker, NSArray * _Nonnull arguments);
+
+- (nonnull instancetype)initWithRuntime:(jsi::Runtime &)runtime
+                            callInvoker:(std::shared_ptr<react::CallInvoker>)callInvoker;
+
+/**
+ Returns the underlying runtime object.
+ */
+- (nonnull jsi::Runtime *)get;
+
+/**
+ Returns the call invoker the runtime was initialized with.
+ */
+- (std::shared_ptr<react::CallInvoker>)callInvoker;
+
+/**
+ Wraps given host object to `JavaScriptObject`.
+ */
+- (nonnull JavaScriptObject *)createHostObject:(std::shared_ptr<jsi::HostObject>)jsiHostObjectPtr;
+
+- (jsi::Function)createSyncFunction:(nonnull NSString *)name
+                          argsCount:(NSInteger)argsCount
+                              block:(nonnull JSSyncFunctionBlock)block;
+
+- (jsi::Function)createAsyncFunction:(nonnull NSString *)name
+                           argsCount:(NSInteger)argsCount
+                               block:(nonnull JSAsyncFunctionBlock)block;
+#endif // __cplusplus
+
+/**
+ Returns the runtime global object for use in Swift.
+ */
+- (nonnull JavaScriptObject *)global;
+
+/**
+ Creates a new object for use in Swift.
+ */
+- (nonnull JavaScriptObject *)createObject;
+
+@end

package/ios/JSI/JavaScriptRuntime.mm

@@ -0,0 +1,102 @@
+// Copyright 2018-present 650 Industries. All rights reserved.
+
+#import <jsi/jsi.h>
+
+#import <ExpoModulesCore/JavaScriptRuntime.h>
+#import <ExpoModulesCore/ExpoModulesHostObject.h>
+#import <ExpoModulesCore/Swift.h>
+
+using namespace facebook;
+
+@implementation JavaScriptRuntime {
+  jsi::Runtime *_runtime;
+  std::shared_ptr<react::CallInvoker> _jsCallInvoker;
+
+  JavaScriptObject *_global;
+}
+
+- (nonnull instancetype)initWithRuntime:(jsi::Runtime &)runtime callInvoker:(std::shared_ptr<react::CallInvoker>)callInvoker
+{
+  if (self = [super init]) {
+    _runtime = &runtime;
+    _jsCallInvoker = callInvoker;
+
+    auto jsGlobalPtr = std::make_shared<jsi::Object>(_runtime->global());
+    _global = [[JavaScriptObject alloc] initWith:jsGlobalPtr runtime:self];
+  }
+  return self;
+}
+
+- (nonnull jsi::Runtime *)get
+{
+  return _runtime;
+}
+
+- (std::shared_ptr<react::CallInvoker>)callInvoker
+{
+  return _jsCallInvoker;
+}
+
+- (nonnull JavaScriptObject *)createObject
+{
+  auto jsObjectPtr = std::make_shared<jsi::Object>(*_runtime);
+  return [[JavaScriptObject alloc] initWith:jsObjectPtr runtime:self];
+}
+
+- (nonnull JavaScriptObject *)createHostObject:(std::shared_ptr<jsi::HostObject>)jsiHostObjectPtr
+{
+  auto jsObjectPtr = std::make_shared<jsi::Object>(jsi::Object::createFromHostObject(*_runtime, jsiHostObjectPtr));
+  return [[JavaScriptObject alloc] initWith:jsObjectPtr runtime:self];
+}
+
+- (nonnull JavaScriptObject *)global
+{
+  return _global;
+}
+
+- (jsi::Function)createSyncFunction:(nonnull NSString *)name
+                          argsCount:(NSInteger)argsCount
+                              block:(nonnull JSSyncFunctionBlock)block
+{
+  return [self createHostFunction:name argsCount:argsCount block:^jsi::Value(jsi::Runtime &runtime, std::shared_ptr<react::CallInvoker> callInvoker, NSArray * _Nonnull arguments) {
+    return expo::convertObjCObjectToJSIValue(runtime, block(arguments));
+  }];
+}
+
+- (jsi::Function)createAsyncFunction:(nonnull NSString *)name
+                           argsCount:(NSInteger)argsCount
+                               block:(nonnull JSAsyncFunctionBlock)block
+{
+  return [self createHostFunction:name argsCount:argsCount block:^jsi::Value(jsi::Runtime &runtime, std::shared_ptr<react::CallInvoker> callInvoker, NSArray *arguments) {
+    // The function that is invoked as a setup of the JavaScript `Promise`.
+    auto promiseSetup = [callInvoker, block, arguments](jsi::Runtime &runtime, std::shared_ptr<Promise> promise) {
+      expo::callPromiseSetupWithBlock(runtime, callInvoker, promise, ^(RCTPromiseResolveBlock resolver, RCTPromiseRejectBlock rejecter) {
+        block(arguments, resolver, rejecter);
+      });
+    };
+    return createPromiseAsJSIValue(runtime, promiseSetup);
+  }];
+}
+
+#pragma mark - Private
+
+typedef jsi::Value (^JSHostFunctionBlock)(jsi::Runtime &runtime, std::shared_ptr<react::CallInvoker> callInvoker, NSArray * _Nonnull arguments);
+
+- (jsi::Function)createHostFunction:(nonnull NSString *)name
+                          argsCount:(NSInteger)argsCount
+                              block:(nonnull JSHostFunctionBlock)block
+{
+  jsi::PropNameID propNameId = jsi::PropNameID::forAscii(*_runtime, [name UTF8String], [name length]);
+  std::weak_ptr<react::CallInvoker> weakCallInvoker = _jsCallInvoker;
+  jsi::HostFunctionType function = [weakCallInvoker, block](jsi::Runtime &runtime, const jsi::Value &thisVal, const jsi::Value *args, size_t count) -> jsi::Value {
+    if (auto callInvoker = weakCallInvoker.lock()) {
+      NSArray *arguments = expo::convertJSIValuesToNSArray(runtime, args, count, callInvoker);
+      return block(runtime, callInvoker, arguments);
+    }
+    // TODO: We should throw some kind of error.
+    return jsi::Value::undefined();
+  };
+  return jsi::Function::createFromHostFunction(*_runtime, propNameId, (unsigned int)argsCount, function);
+}
+
+@end

package/ios/ModuleRegistryAdapter/EXModuleRegistryAdapter.m

@@ -55,18 +55,9 @@
   EXReactNativeEventEmitter *eventEmitter = [EXReactNativeEventEmitter new];
   [moduleRegistry registerInternalModule:eventEmitter];
 
-  NSMutableSet *exportedSwiftViewModuleNames = [NSMutableSet new];
-
-  for (ViewModuleWrapper *swiftViewModule in [nativeModulesProxy.swiftInteropBridge getViewManagers]) {
-    Class wrappedViewModuleClass = [ViewModuleWrapper createViewModuleWrapperClassWithModule:swiftViewModule];
-    [extraModules addObject:[[wrappedViewModuleClass alloc] init]];
-    [exportedSwiftViewModuleNames addObject:swiftViewModule.name];
-  }
   for (EXViewManager *viewManager in [moduleRegistry getAllViewManagers]) {
-    if (![exportedSwiftViewModuleNames containsObject:viewManager.viewName]) {
-      Class viewManagerAdapterClass = [EXViewManagerAdapterClassesRegistry createViewManagerAdapterClassForViewManager:viewManager];
-      [extraModules addObject:[[viewManagerAdapterClass alloc] init]];
-    }
+    Class viewManagerAdapterClass = [EXViewManagerAdapterClassesRegistry createViewManagerAdapterClassForViewManager:viewManager];
+    [extraModules addObject:[[viewManagerAdapterClass alloc] init]];
   }
 
   // Silence React Native warning `Base module "%s" does not exist`
@@ -75,7 +66,6 @@
   // subclass EXViewManagerAdapter, so RN expects to find EXViewManagerAdapter
   // exported.
   [extraModules addObject:[[EXViewManagerAdapter alloc] init]];
-  [extraModules addObject:[[ViewModuleWrapper alloc] initWithDummy:nil]];
 
   // It is possible that among internal modules there are some RCTBridgeModules --
   // let's add them to extraModules here.

package/ios/NativeModulesProxy/EXComponentDataCompatibleWrapper.h

@@ -0,0 +1,16 @@
+// Copyright 2018-present 650 Industries. All rights reserved.
+
+#import <React/RCTComponentData.h>
+
+/**
+ * A compatible wrapper for `RCTComponentData` which has different designated initializers between different react-native versions.
+ * This class unifies the interface to make react-native <= 0.64 backward compatible.
+ * Remove when we drop support for SDK 44
+ */
+@interface EXComponentDataCompatibleWrapper : RCTComponentData
+
+- (instancetype)initWithManagerClass:(Class)managerClass
+                              bridge:(RCTBridge *)bridge
+                     eventDispatcher:(id<RCTEventDispatcherProtocol>)eventDispatcher NS_DESIGNATED_INITIALIZER;
+
+@end

package/ios/NativeModulesProxy/EXComponentDataCompatibleWrapper.m

@@ -0,0 +1,28 @@
+// Copyright 2018-present 650 Industries. All rights reserved.
+
+#import <ExpoModulesCore/EXComponentDataCompatibleWrapper.h>
+
+@interface RCTComponentData (EXComponentDataCompatibleWrapper)
+
+// available in RN 0.65+
+- (instancetype)initWithManagerClass:(Class)managerClass
+                              bridge:(RCTBridge *)bridge
+                     eventDispatcher:(id<RCTEventDispatcherProtocol>) eventDispatcher;
+
+- (instancetype)initWithManagerClass:(Class)managerClass bridge:(RCTBridge *)bridge;
+
+@end
+
+@implementation EXComponentDataCompatibleWrapper
+
+- (instancetype)initWithManagerClass:(Class)managerClass
+                              bridge:(RCTBridge *)bridge
+                     eventDispatcher:(id<RCTEventDispatcherProtocol>)eventDispatcher
+{
+  if ([self respondsToSelector:@selector(initWithManagerClass:bridge:)]) {
+    return [super initWithManagerClass:managerClass bridge:bridge];
+  }
+  return [super initWithManagerClass:managerClass bridge:bridge eventDispatcher:eventDispatcher];
+}
+
+@end

package/ios/NativeModulesProxy/EXNativeModulesProxy.mm

@@ -10,6 +10,7 @@
 
 #import <jsi/jsi.h>
 
+#import <ExpoModulesCore/EXComponentDataCompatibleWrapper.h>
 #import <ExpoModulesCore/EXNativeModulesProxy.h>
 #import <ExpoModulesCore/EXEventEmitter.h>
 #import <ExpoModulesCore/EXViewManager.h>
@@ -41,13 +42,6 @@ static const NSString *methodInfoArgumentsCountKey = @"argumentsCount";
 
 @end
 
-@interface RCTComponentData (EXNativeModulesProxy)
-
-- (instancetype)initWithManagerClass:(Class)managerClass bridge:(RCTBridge *)bridge eventDispatcher:(id<RCTEventDispatcherProtocol>) eventDispatcher; // available in RN 0.65+
-- (instancetype)initWithManagerClass:(Class)managerClass bridge:(RCTBridge *)bridge;
-
-@end
-
 @interface EXNativeModulesProxy ()
 
 @property (nonatomic, strong) NSRegularExpression *regexp;
@@ -150,8 +144,18 @@ RCT_EXPORT_MODULE(NativeUnimoduleProxy)
 - (void)setBridge:(RCTBridge *)bridge
 {
   if (!_bridge) {
-    [self registerExpoModulesInBridge:bridge];
+    // The `setBridge` can be called during module setup or after. Registering more modules
+    // during setup causes a crash due to mutating `_moduleDataByID` while it's being enumerated.
+    // In that case we register them asynchronously.
+    if ([[bridge valueForKey:@"_moduleSetupComplete"] boolValue]) {
+      [self registerExpoModulesInBridge:bridge];
+    } else {
+      dispatch_async(dispatch_get_main_queue(), ^{
+        [self registerExpoModulesInBridge:bridge];
+      });
+    }
   }
+  [_swiftInteropBridge setReactBridge:bridge];
   _bridge = bridge;
 }
 
@@ -233,45 +237,49 @@ RCT_EXPORT_METHOD(callMethod:(NSString *)moduleName methodNameOrKey:(id)methodNa
 
 - (void)registerExpoModulesInBridge:(RCTBridge *)bridge
 {
-  // Registering expo modules in bridge is needed only when the proxy module owns the registry
-  // (was autoinitialized by React Native). Otherwise they're registered by the registry adapter.
-  if (!_ownsModuleRegistry || [bridge moduleIsInitialized:[EXReactNativeEventEmitter class]]) {
-    return;
-  }
+  // Registering expo modules (excluding Swifty view managers!) in bridge is needed only when the proxy module owns
+  // the registry (was autoinitialized by React Native). Otherwise they're registered by the registry adapter.
+  BOOL ownsModuleRegistry = _ownsModuleRegistry && ![bridge moduleIsInitialized:[EXReactNativeEventEmitter class]];
 
   // An array of `RCTBridgeModule` classes to register.
   NSMutableArray<Class<RCTBridgeModule>> *additionalModuleClasses = [NSMutableArray new];
   NSMutableSet *visitedSweetModules = [NSMutableSet new];
 
-  // Event emitter is a bridge module, however it's also needed by expo modules,
-  // so later we'll register an instance created by React Native as expo module.
-  [additionalModuleClasses addObject:[EXReactNativeEventEmitter class]];
-
   // Add dynamic wrappers for view modules written in Sweet API.
   for (ViewModuleWrapper *swiftViewModule in [_swiftInteropBridge getViewManagers]) {
-    Class wrappedViewModuleClass = [ViewModuleWrapper createViewModuleWrapperClassWithModule:swiftViewModule];
+    Class wrappedViewModuleClass = [self registerComponentData:swiftViewModule inBridge:bridge];
     [additionalModuleClasses addObject:wrappedViewModuleClass];
     [visitedSweetModules addObject:swiftViewModule.name];
   }
 
-  // Add dynamic wrappers for the classic view managers.
-  for (EXViewManager *viewManager in [_exModuleRegistry getAllViewManagers]) {
-    if (![visitedSweetModules containsObject:viewManager.viewName]) {
-      Class viewManagerWrapperClass = [EXViewManagerAdapterClassesRegistry createViewManagerAdapterClassForViewManager:viewManager];
-      [additionalModuleClasses addObject:viewManagerWrapperClass];
+  [additionalModuleClasses addObject:[ViewModuleWrapper class]];
+  [self registerLegacyComponentData:[ViewModuleWrapper class] inBridge:bridge];
+
+  // Add modules from legacy module registry only when the NativeModulesProxy owns the registry.
+  if (ownsModuleRegistry) {
+    // Event emitter is a bridge module, however it's also needed by expo modules,
+    // so later we'll register an instance created by React Native as expo module.
+    [additionalModuleClasses addObject:[EXReactNativeEventEmitter class]];
+
+    // Add dynamic wrappers for the classic view managers.
+    for (EXViewManager *viewManager in [_exModuleRegistry getAllViewManagers]) {
+      if (![visitedSweetModules containsObject:viewManager.viewName]) {
+        Class viewManagerWrapperClass = [EXViewManagerAdapterClassesRegistry createViewManagerAdapterClassForViewManager:viewManager];
+        [additionalModuleClasses addObject:viewManagerWrapperClass];
+        [self registerLegacyComponentData:viewManagerWrapperClass inBridge:bridge];
+      }
     }
-  }
 
-  // View manager wrappers don't have their own prop configs, so we must register
-  // their base view managers that provides common props such as `proxiedProperties`.
-  // Otherwise, React Native may treat these props as invalid in subclassing views.
-  [additionalModuleClasses addObject:[EXViewManagerAdapter class]];
-  [additionalModuleClasses addObject:[ViewModuleWrapper class]];
+    // View manager wrappers don't have their own prop configs, so we must register
+    // their base view managers that provides common props such as `proxiedProperties`.
+    // Otherwise, React Native may treat these props as invalid in subclassing views.
+    [additionalModuleClasses addObject:[EXViewManagerAdapter class]];
 
-  // Some modules might need access to the bridge.
-  for (id module in [_exModuleRegistry getAllInternalModules]) {
-    if ([module conformsToProtocol:@protocol(RCTBridgeModule)]) {
-      [module setValue:bridge forKey:@"bridge"];
+    // Some modules might need access to the bridge.
+    for (id module in [_exModuleRegistry getAllInternalModules]) {
+      if ([module conformsToProtocol:@protocol(RCTBridgeModule)]) {
+        [module setValue:bridge forKey:@"bridge"];
+      }
     }
   }
 
@@ -283,19 +291,19 @@ RCT_EXPORT_METHOD(callMethod:(NSString *)moduleName methodNameOrKey:(id)methodNa
   // Register the view managers as additional modules.
   [self registerAdditionalModuleClasses:additionalModuleClasses inBridge:bridge];
 
-  // Bridge's `registerAdditionalModuleClasses:` method doesn't register
-  // components in UIManager — we need to register them on our own.
-  [self registerComponentDataForModuleClasses:additionalModuleClasses inBridge:bridge];
-
-  // Get the newly created instance of `EXReactEventEmitter` bridge module,
-  // pass event names supported by Swift modules and register it in legacy modules registry.
-  EXReactNativeEventEmitter *eventEmitter = [bridge moduleForClass:[EXReactNativeEventEmitter class]];
-  [eventEmitter setSwiftInteropBridge:_swiftInteropBridge];
-  [_exModuleRegistry registerInternalModule:eventEmitter];
-
-  // Let the modules consume the registry :)
-  // It calls `setModuleRegistry:` on all `EXModuleRegistryConsumer`s.
-  [_exModuleRegistry initialize];
+  // As the last step, when the registry is owned,
+  // register the event emitter and initialize the registry.
+  if (ownsModuleRegistry) {
+    // Get the newly created instance of `EXReactEventEmitter` bridge module,
+    // pass event names supported by Swift modules and register it in legacy modules registry.
+    EXReactNativeEventEmitter *eventEmitter = [bridge moduleForClass:[EXReactNativeEventEmitter class]];
+    [eventEmitter setSwiftInteropBridge:_swiftInteropBridge];
+    [_exModuleRegistry registerInternalModule:eventEmitter];
+
+    // Let the modules consume the registry :)
+    // It calls `setModuleRegistry:` on all `EXModuleRegistryConsumer`s.
+    [_exModuleRegistry initialize];
+  }
 }
 
 - (void)registerAdditionalModuleClasses:(NSArray<Class> *)moduleClasses inBridge:(RCTBridge *)bridge
@@ -324,27 +332,38 @@ RCT_EXPORT_METHOD(callMethod:(NSString *)moduleName methodNameOrKey:(id)methodNa
   [bridge registerAdditionalModuleClasses:moduleClasses];
 }
 
-- (void)registerComponentDataForModuleClasses:(NSArray<Class> *)moduleClasses inBridge:(RCTBridge *)bridge
+- (Class)registerComponentData:(ViewModuleWrapper *)viewModule inBridge:(RCTBridge *)bridge
 {
   // Hacky way to get a dictionary with `RCTComponentData` from UIManager.
   NSMutableDictionary<NSString *, RCTComponentData *> *componentDataByName = [bridge.uiManager valueForKey:@"_componentDataByName"];
+  Class wrappedViewModuleClass = [ViewModuleWrapper createViewModuleWrapperClassWithModule:viewModule];
+  NSString *className = NSStringFromClass(wrappedViewModuleClass);
 
-  // Register missing components data for all view managers.
-  for (Class moduleClass in moduleClasses) {
-    NSString *className = NSStringFromClass(moduleClass);
-
-    if ([moduleClass isSubclassOfClass:[RCTViewManager class]] && !componentDataByName[className]) {
-      RCTComponentData *componentData = [RCTComponentData alloc];
-      if ([componentData respondsToSelector:@selector(initWithManagerClass:bridge:eventDispatcher:)]) {
-        // Init method was changed in RN 0.65
-        [componentData initWithManagerClass:moduleClass bridge:bridge eventDispatcher:bridge.eventDispatcher];
-      } else {
-        // fallback for older RNs
-        [componentData initWithManagerClass:moduleClass bridge:bridge];
-      }
-      
-      componentDataByName[className] = componentData;
-    }
+  if (componentDataByName[className]) {
+    // Just in case the component was already registered, let's leave a log that we're overriding it.
+    NSLog(@"Overriding ComponentData for view %@", className);
+  }
+
+  EXComponentData *componentData = [[EXComponentData alloc] initWithViewModule:viewModule
+                                                                  managerClass:wrappedViewModuleClass
+                                                                        bridge:bridge];
+  componentDataByName[className] = componentData;
+  return wrappedViewModuleClass;
+}
+
+/**
+ Bridge's `registerAdditionalModuleClasses:` method doesn't register
+ components in UIManager — we need to register them on our own.
+ */
+- (void)registerLegacyComponentData:(Class)moduleClass inBridge:(RCTBridge *)bridge
+{
+  // Hacky way to get a dictionary with `RCTComponentData` from UIManager.
+  NSMutableDictionary<NSString *, RCTComponentData *> *componentDataByName = [bridge.uiManager valueForKey:@"_componentDataByName"];
+  NSString *className = NSStringFromClass(moduleClass);
+
+  if ([moduleClass isSubclassOfClass:[RCTViewManager class]] && !componentDataByName[className]) {
+    RCTComponentData *componentData = [[EXComponentDataCompatibleWrapper alloc] initWithManagerClass:moduleClass bridge:bridge eventDispatcher:bridge.eventDispatcher];
+    componentDataByName[className] = componentData;
   }
 }
 
@@ -384,10 +403,15 @@ RCT_EXPORT_METHOD(callMethod:(NSString *)moduleName methodNameOrKey:(id)methodNa
  */
 - (void)installExpoTurboModules
 {
-  facebook::jsi::Runtime *runtime = [_bridge respondsToSelector:@selector(runtime)] ? reinterpret_cast<facebook::jsi::Runtime *>(_bridge.runtime) : NULL;
+  facebook::jsi::Runtime *jsiRuntime = [_bridge respondsToSelector:@selector(runtime)] ? reinterpret_cast<facebook::jsi::Runtime *>(_bridge.runtime) : nullptr;
+
+  if (jsiRuntime) {
+    JavaScriptRuntime *runtime = [[JavaScriptRuntime alloc] initWithRuntime:*jsiRuntime callInvoker:_bridge.jsCallInvoker];
+
+    [JavaScriptRuntimeManager installExpoModulesToRuntime:runtime withSwiftInterop:_swiftInteropBridge];
+    [_swiftInteropBridge setRuntime:runtime];
 
-  if (runtime) {
-    expo::installRuntimeObjects(*runtime, _bridge.jsCallInvoker, self);
+    expo::installRuntimeObjects(*jsiRuntime, _bridge.jsCallInvoker, self);
   }
 }
 

package/ios/RCTComponentData+Privates.h

@@ -0,0 +1,12 @@
+// Copyright 2021-present 650 Industries. All rights reserved.
+
+#import <React/RCTComponent.h>
+#import <React/RCTComponentData.h>
+
+typedef void (^RCTPropBlockAlias)(id<RCTComponent> _Nonnull view, id _Nullable json);
+
+@interface RCTComponentData (Privates)
+
+- (nonnull RCTPropBlockAlias)createPropBlock:(nonnull NSString *)name isShadowView:(BOOL)isShadowView;
+
+@end

package/ios/ReactDelegates/ExpoReactDelegate.swift

@@ -12,7 +12,7 @@ public class ExpoReactDelegate: NSObject {
   }
 
   @objc
-  public func createBridge(delegate: RCTBridgeDelegate, launchOptions: [AnyHashable : Any]?) -> RCTBridge {
+  public func createBridge(delegate: RCTBridgeDelegate, launchOptions: [AnyHashable: Any]?) -> RCTBridge {
     self.handlers.forEach { $0.bridgeWillCreate() }
     let result = self.handlers.lazy
       .compactMap { $0.createBridge(reactDelegate: self, bridgeDelegate: delegate, launchOptions: launchOptions) }
@@ -22,7 +22,7 @@ public class ExpoReactDelegate: NSObject {
   }
 
   @objc
-  public func createRootView(bridge: RCTBridge, moduleName: String, initialProperties: [AnyHashable : Any]?) -> RCTRootView {
+  public func createRootView(bridge: RCTBridge, moduleName: String, initialProperties: [AnyHashable: Any]?) -> RCTRootView {
     return self.handlers.lazy
       .compactMap { $0.createRootView(reactDelegate: self, bridge: bridge, moduleName: moduleName, initialProperties: initialProperties) }
       .first(where: { _ in true }) ?? RCTRootView(bridge: bridge, moduleName: moduleName, initialProperties: initialProperties)

package/ios/ReactDelegates/ExpoReactDelegateHandler.swift

@@ -14,7 +14,7 @@ open class ExpoReactDelegateHandler: NSObject {
    Otherwise return nil.
    */
   @objc
-  open func createBridge(reactDelegate: ExpoReactDelegate, bridgeDelegate: RCTBridgeDelegate, launchOptions: [AnyHashable : Any]?) -> RCTBridge? {
+  open func createBridge(reactDelegate: ExpoReactDelegate, bridgeDelegate: RCTBridgeDelegate, launchOptions: [AnyHashable: Any]?) -> RCTBridge? {
     return nil
   }
 
@@ -23,7 +23,7 @@ open class ExpoReactDelegateHandler: NSObject {
    Otherwise return nil.
    */
   @objc
-  open func createRootView(reactDelegate: ExpoReactDelegate, bridge: RCTBridge, moduleName: String, initialProperties: [AnyHashable : Any]?) -> RCTRootView? {
+  open func createRootView(reactDelegate: ExpoReactDelegate, bridge: RCTBridge, moduleName: String, initialProperties: [AnyHashable: Any]?) -> RCTRootView? {
     return nil
   }
 
@@ -36,7 +36,7 @@ open class ExpoReactDelegateHandler: NSObject {
     return nil
   }
 
-  // MARK - event callbacks
+  // MARK: - event callbacks
 
   /**
    Callback before bridge creation

package/ios/ReactDelegates/ModulePriorities.swift

@@ -11,7 +11,7 @@ internal struct ModulePriorities {
     // key: node package name
     // value: priority value, the higher value takes precedence
     "expo-screen-orientation": 10,
-    "expo-updates": 5,
+    "expo-updates": 5
   ]
 
   static func get(_ packageName: String) -> Int {