exiftool-vendored.pl 12.76.0 → 12.78.0

package/bin/lib/Image/ExifTool/Geolocation.pm

@@ -0,0 +1,237 @@
+#------------------------------------------------------------------------------
+# File:         Geolocation.pm
+#
+# Description:  Look up geolocation information based on a GPS position
+#
+# Revisions:    2024-03-03 - P. Harvey Created
+#
+# References:   https://download.geonames.org/export/
+#
+# Notes:        Set $Image::ExifTool::Geolocation::databaseFile to override
+#               default database file (lib/Image/ExifTool/Geolocation.dat)
+#
+#               Based on data from geonames.org Creative Commons databases,
+#               reformatted as follows in the Geolocation.dat file:
+#
+#   Header: GeolocationV.VV\tNNNN\n - V.VV=version, NNNN=num city entries
+#
+#   NNNN City entries:
+#       1. int16u[2] - longitude.latitude (converted to 0-64k range)
+#       2. int8u - low byte of time zone number
+#       3. int8u - 100's=time zone high bit, population: 10's=num zeros, 1's=sig digit
+#       4. UTF8 City name, terminated by tab
+#       5. 2-character country code
+#       6. Region code, terminated by newline
+#   End of section marker - "\0\0\0\0\x01"
+#   Country entries:
+#       1. 2-character country code
+#       2. Country name, terminated by newline
+#   End of section marker - "\0\0\0\0\x02"
+#   Region entries:
+#       1. 2-character country code
+#       2. Region code, terminated by tab
+#       3. Region name, terminated by newline
+#   End of section marker - "\0\0\0\0\x03"
+#   Time zone entries:
+#       1. Time zone name, terminated by newline
+#   End of file marker - "\0\0\0\0\0"
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::Geolocation;
+
+use strict;
+use vars qw($VERSION $databaseFile);
+
+$VERSION = '1.00';
+
+my (@cityLookup, %countryLookup, %adminLookup, @timezoneLookup);
+
+# get path name for database file from lib/Image/ExifTool/Geolocation.dat by default,
+# or according to $Image::ExifTool::Geolocation::databaseFile if specified
+my $datfile = $databaseFile;
+unless ($datfile) {
+    $datfile = $INC{'Image/ExifTool/Geolocation.pm'};
+    $datfile or $datfile = 'Geolocation.pm', warn("Error getting Geolocation directory\n");
+    $datfile =~ s/\.pm$/\.dat/;
+}
+
+# open geolocation database and verify header
+open DATFILE, "<$datfile" or warn("Error reading $datfile\n"), return 0;
+binmode DATFILE;
+my $line = <DATFILE>;
+unless ($line =~ /^Geolocation(\d+\.\d+)\t(\d+)/) {
+    warn("Bad format Geolocation database\n");
+    close(DATFILE);
+    return 0;
+}
+my $ncity = $2;
+
+# read city database
+for (;;) {
+    $line = <DATFILE>;
+    last if length($line) == 6 and $line =~ /\0\0\0\0/;
+    $line .= <DATFILE> while length($line) < 7;
+    chomp $line;
+    push @cityLookup, $line;
+}
+@cityLookup == $ncity or warn("Bad number of entries in Geolocation database\n"), return 0;
+# read countries
+for (;;) {
+    $line = <DATFILE>;
+    last if length($line) == 6 and $line =~ /\0\0\0\0/;
+    chomp $line;
+    $countryLookup{substr($line,0,2)} = substr($line,2);
+}
+# read regions
+for (;;) {
+    $line = <DATFILE>;
+    last if length($line) == 6 and $line =~ /\0\0\0\0/;
+    chomp $line;
+    my ($code, $region) = split /\t/, $line;
+    $adminLookup{$code} = $region;
+}
+# read time zones
+for (;;) {
+    $line = <DATFILE>;
+    last if length($line) == 6 and $line =~ /\0\0\0\0/;
+    chomp $line;
+    push @timezoneLookup, $line;
+}
+close DATFILE;
+
+#------------------------------------------------------------------------------
+# Look up lat/lon in geolocation database
+# Inputs: 0) Latitude, 1) longitude, 2) optional min population,
+#         3) optional max distance (km)
+# Returns: 0) UTF8 city name (or undef if geolocation is unsuccessful),
+#          1) UTF8 state, province or region (or undef),
+#          2) country code, 3) country name (undef is possible),
+#          4) time zone name (empty string possible), 5) approx population,
+#          6) approx distance (km), 7) approximate compass bearing (or undef),
+#          8/9) approx lat/lon
+sub Geolocate($$;$$)
+{
+    my ($lat, $lon, $pop, $km) = @_;
+    my ($minPop, $maxDist2);
+    my $earthCirc = 40000;  # earth circumference in km
+
+    if ($pop) {
+        # convert population minimum to a 2-digit code
+        my $dig = substr($pop, 0, 1);
+        my $zer = length($pop) - 1;
+        # round up if necessary
+        if (length($pop) > 1 and substr($pop, 1, 1) >= 5) {
+            ++$dig > 9 and $dig = 1, ++$zer;
+        }
+        $minPop = $zer.$dig;
+    }
+    if ($km) {
+        # convert max distance to reduced coordinate units
+        my $tmp = $km * 2 * 65536 / $earthCirc;
+        $maxDist2 = $tmp * $tmp;
+    }
+    my $cos = cos($lat * 3.14159 / 180); # cosine factor for longitude distances
+    # reduce lat/lon to the range 0-65536
+    $lat = int(($lat + 90)  / 180 * 65536 + 0.5) & 0xffff;
+    $lon = int(($lon + 180) / 360 * 65536 + 0.5) & 0xffff;
+    my $coord = pack('n2',$lon,$lat);   # pack for comparison with binary database values
+    # binary search to find closest longitude
+    my ($n0, $n1) = (0, scalar(@cityLookup)-1);
+    while ($n1 - $n0 > 1) {
+        my $n = int(($n0 + $n1) / 2);
+        if ($coord lt $cityLookup[$n]) {
+            $n1 = $n;
+        } else {
+            $n0 = $n;
+        }
+    }
+    # step backward then forward through database to find nearest city
+    my ($minDist2, $minN, @dxy);
+    my ($inc, $end, $n) = (-1, -1, $n0+1);
+    for (;;) {
+        if (($n += $inc) == $end) {
+            last if $inc == 1;
+            ($inc, $end, $n) = (1, scalar(@cityLookup), $n1);
+        }
+        my ($x,$y) = unpack('n2', $cityLookup[$n]);
+        my ($dy,$dx) = ($y-$lat, $x-$lon);
+        $dx += 65536 if $dx < -32768;       # measure the short way around the world
+        $dx -= 65536 if $dx > 32768;
+        $dx = 2 * $cos * $dx;               # adjust for longitude spacing
+        my $dx2 = $dx * $dx;
+        my $dist2 = $dy * $dy + $dx2;
+        if (defined $minDist2) {
+            # searched far enough if longitude alone is further than best distance
+            $dx2 > $minDist2 and $n = $end - $inc, next;
+        } elsif (defined $maxDist2) {
+            $dx2 > $maxDist2 and $n = $end - $inc, next;
+            next if $dist2 > $maxDist2;   # ignore if distance is too great
+        }
+        # ignore if population is below threshold
+        next if $minPop and $minPop > unpack('x5C', $cityLookup[$n]) % 100;
+        if (not defined $minDist2 or $minDist2 > $dist2) {
+            $minDist2 = $dist2;
+            @dxy = ($dx, $dy);
+            $minN = $n;
+        }
+    }
+    return () unless defined $minN;
+
+    my ($ln,$lt,$tn,$pc) = unpack('n2C2', $cityLookup[$minN]);
+    my ($city, $code) = split /\t/, substr($cityLookup[$minN],6);
+    my $ctry = substr($code,0,2);
+    my $rgn = $adminLookup{$code};
+    my $po2 = substr($pc, -1) . (length($pc) > 1 ? '0' x substr($pc, -2, 1) : '');
+    $tn += 256 if $pc > 99;
+    my $be; # calculate bearing to geolocated city
+    if ($dxy[0] or $dxy[1]) {
+        $be = atan2($dxy[0],$dxy[1]) * 180 / 3.14159;
+        $be += 360 if $be < 0;
+        $be = int($be + 0.5);
+    }
+    $lt = sprintf('%.3f', $lt * 180 / 65536 - 90);
+    $ln = sprintf('%.3f', $ln * 360 / 65536 - 180);
+    $km = sprintf('%.1f', sqrt($minDist2) * $earthCirc / (2 * 65536));
+
+    return($city,$rgn,$ctry,$countryLookup{$ctry},$timezoneLookup[$tn],$po2,$km,$be,$lt,$ln);
+}
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::Geolocation - Look up geolocation based on GPS position
+
+=head1 SYNOPSIS
+
+This module is used by the Image::ExifTool Geolocation feature.
+
+=head1 DESCRIPTION
+
+This module contains the code to convert GPS coordinates to city, region,
+country, time zone, etc.  It uses a database derived from geonames.org,
+modified to reduce the size as much as possible.
+
+=head1 AUTHOR
+
+Copyright 2003-2024, Phil Harvey (philharvey66 at gmail.com)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.  Geolocation.dat is based on data
+from geonames.org with a Creative Commons license.
+
+=head1 REFERENCES
+
+=over 4
+
+=item L<https://download.geonames.org/export/>
+
+=back
+
+=head1 SEE ALSO
+
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut
+
+1; #end

package/bin/lib/Image/ExifTool/Geotag.pm

@@ -1109,7 +1109,7 @@ sub SetGeoValues($$;$)
                     $iExt = $i1;
                 }
                 if (abs($time - $tn) > $geoMaxExtSecs) {
-                    $err or $err = 'Time is too far from nearest GPS fix'.' '.abs($time-$tn).' '.$geoMaxExtSecs;
+                    $err or $err = 'Time is too far from nearest GPS fix'.' '.abs($time-$tn).' > '.$geoMaxExtSecs;
                     $et->VPrint(2, '  Nearest fix:     ', PrintFixTime($tn), "\n") if $verbose > 2;
                     $fix = { } if $$geotag{DateTimeOnly};
                 } else {

package/bin/lib/Image/ExifTool/HtmlDump.pm

@@ -13,7 +13,7 @@ use vars qw($VERSION);
 use Image::ExifTool;    # only for FinishTiffDump()
 use Image::ExifTool::HTML qw(EscapeHTML);
 
-$VERSION = '1.41';
+$VERSION = '1.42';
 
 sub DumpTable($$$;$$$$$$);
 sub Open($$$;@);
@@ -769,6 +769,7 @@ sub FinishTiffDump($$$)
         PreviewImageStart => 'PreviewImageLength',
         JpgFromRawStart   => 'JpgFromRawLength',
         OtherImageStart   => 'OtherImageLength',
+        PreviewJXLStart   => 'PreviewJXLLength',
         ImageOffset       => 'ImageByteCount',
         AlphaOffset       => 'AlphaByteCount',
         MPImageStart      => 'MPImageLength',

package/bin/lib/Image/ExifTool/Import.pm

@@ -12,7 +12,7 @@ require Exporter;
 
 use vars qw($VERSION @ISA @EXPORT_OK);
 
-$VERSION = '1.11';
+$VERSION = '1.12';
 @ISA = qw(Exporter);
 @EXPORT_OK = qw(ReadCSV ReadJSON);
 
@@ -238,7 +238,7 @@ Tok: for (;;) {
 
 #------------------------------------------------------------------------------
 # Read JSON file
-# Inputs: 0) JSON file name, file ref or RAF ref, 1) database hash ref,
+# Inputs: 0) JSON file name, file ref, RAF ref or SCALAR ref, 1) database hash ref,
 #         2) flag to delete "-" tags, 3) character set
 # Returns: undef on success, or error string
 sub ReadJSON($$;$$)
@@ -255,6 +255,9 @@ sub ReadJSON($$;$$)
     } elsif (ref $file eq 'GLOB') {
         $raf = File::RandomAccess->new($file);
         $file = 'JSON file';
+    } elsif (ref $file eq 'SCALAR') {
+        $raf = File::RandomAccess->new($file);
+        $file = 'in memory';
     } else {
         open JSONFILE, $file or return "Error opening JSON file '${file}'";
         binmode JSONFILE;

package/bin/lib/Image/ExifTool/JSON.pm

@@ -60,15 +60,15 @@ sub FoundTag($$$$%)
     # avoid conflict with special table entries
     $tag .= '!' if $Image::ExifTool::specialTags{$tag};
 
-    # use underline instead of colon if necessary in tag name
-    $tag =~ s/([A-Z]):([A-Z]{2})/${1}_$2/g;
-
-    AddTagToTable($tagTablePtr, $tag, {
-        Name => Image::ExifTool::MakeTagName($tag),
-        %flags,
-        Temporary => 1,
-    }) unless $$tagTablePtr{$tag};
-
+    unless ($$tagTablePtr{$tag}) {
+        my $name = $tag;
+        $name =~ tr/:/_/; # use underlines in place of colons in tag name
+        AddTagToTable($tagTablePtr, $tag, {
+            Name => Image::ExifTool::MakeTagName($name),
+            %flags,
+            Temporary => 1,
+        });
+    }
     $et->HandleTag($tagTablePtr, $tag, $val);
 }
 

package/bin/lib/Image/ExifTool/MWG.pm

@@ -441,6 +441,7 @@ my %sRegionStruct = (
         Writable => 'real',
         Notes => 'not part of MWG 2.0 spec',
     },
+    # Title - seen in sample XMP of MWG 2.0 specification, but not in spec itself
     seeAlso => { Namespace => 'rdfs', Resource => 1 },
 );
 my %sKeywordStruct;

package/bin/lib/Image/ExifTool/MacOS.pm

@@ -12,7 +12,7 @@ use strict;
 use vars qw($VERSION);
 use Image::ExifTool qw(:DataAccess :Utils);
 
-$VERSION = '1.12';
+$VERSION = '1.13';
 
 sub MDItemLocalTime($);
 sub ProcessATTR($$$);
@@ -22,6 +22,11 @@ my %mdDateInfo = (
     PrintConv => '$self->ConvertDateTime($val)',
 );
 
+my %delXAttr = (
+    XAttrQuarantine => 'com.apple.quarantine',
+    XAttrMDItemWhereFroms => 'com.apple.metadata:kMDItemWhereFroms',
+);
+
 # Information decoded from Mac OS sidecar files
 %Image::ExifTool::MacOS::Main = (
     GROUPS => { 0 => 'File', 1 => 'MacOS' },
@@ -320,7 +325,17 @@ my %mdDateInfo = (
         Groups => { 2 => 'Time' },
     },
     'com.apple.metadata:kMDItemFinderComment'  => { Name => 'XAttrMDItemFinderComment' },
-    'com.apple.metadata:kMDItemWhereFroms'     => { Name => 'XAttrMDItemWhereFroms' },
+    'com.apple.metadata:kMDItemWhereFroms' => {
+        Name => 'XAttrMDItemWhereFroms',
+        Writable => 1,
+        WritePseudo => 1,
+        WriteCheck => '"May only delete this tag"',
+        Protected => 1,
+        Notes => q{
+            information about where the file came from.  May only be deleted when
+            writing
+        },
+    },
     'com.apple.metadata:kMDLabel'              => { Name => 'XAttrMDLabel', Binary => 1 },
     'com.apple.ResourceFork'                   => { Name => 'XAttrResourceFork', Binary => 1 },
     'com.apple.lastuseddate#PS'                => {
@@ -407,9 +422,9 @@ sub SetMacOSTags($$$)
                 $et->VPrint(1,"    - $tag = (all)\n") if $overwrite > 0;
                 undef $val if $val eq '';
             }
-        } elsif ($tag eq 'XAttrQuarantine') {
+        } elsif ($delXAttr{$tag}) {
             ($f = $file) =~ s/'/'\\''/g;
-            $cmd = "/usr/bin/xattr -d com.apple.quarantine '${f}'";
+            $cmd = "/usr/bin/xattr -d $delXAttr{$tag} '${f}'";
             $silentErr = 256;   # (will get this error if attribute doesn't exist)
         } else {
             ($f = $file) =~ s/(["\\])/\\$1/g;   # escape necessary characters for script

package/bin/lib/Image/ExifTool/Nikon.pm

@@ -703,8 +703,8 @@ sub GetAFPointGrid($$;$);
 #
     '00 54 56 56 30 30 00 00' => 'Coastal Optical Systems 60mm 1:4 UV-VIS-IR Macro Apo',
 #
-    'BF 4E 26 26 1E 1E 01 04' => 'Irix 15mm f/2.4 Firefly', #30
-    'BF 3C 1B 1B 30 30 01 04' => 'Irix 11mm f/4 Firefly', #30
+    'BF 4E 26 26 1E 1E 01 04' => 'Irix 15mm f/2.4 Firefly', #30 (guessing the Blackstone version may be the same ID - PH)
+    'BF 3C 1B 1B 30 30 01 04' => 'Irix 11mm f/4 Firefly', #30 (guessing the Blackstone version may be the same ID - PH)
 #
     '4A 40 11 11 2C 0C 4D 02' => 'Samyang 8mm f/3.5 Fish-Eye CS',
     '4A 48 24 24 24 0C 4D 02.1' => 'Samyang 10mm f/2.8 ED AS NCS CS',

package/bin/lib/Image/ExifTool/Ogg.pm

@@ -17,7 +17,7 @@ use strict;
 use vars qw($VERSION);
 use Image::ExifTool qw(:DataAccess :Utils);
 
-$VERSION = '1.03';
+$VERSION = '1.04';
 
 my $MAX_PACKETS = 2;    # maximum packets to scan from each stream at start of file
 
@@ -145,6 +145,7 @@ sub ProcessOGG($$)
         # calculate total data length
         my $dataLen = Get8u(\$buff, 27);
         if ($nseg) {
+            last unless $raf;
             $raf->Read($buff, $nseg-1) == $nseg-1 or last;
             my @segs = unpack('C*', $buff);
             # could check that all these (but the last) are 255...
@@ -160,7 +161,7 @@ sub ProcessOGG($$)
             }
         }
         # read page data
-        $raf->Read($buff, $dataLen) == $dataLen or last;
+        last unless $raf and $raf->Read($buff, $dataLen) == $dataLen;
         if ($verbose > 1) {
             printf $out "Page %d, stream 0x%x, flag 0x%x (%d bytes)\n",
                    $pageNum, $stream, $flag, $dataLen;

package/bin/lib/Image/ExifTool/Olympus.pm

@@ -40,7 +40,7 @@ use Image::ExifTool qw(:DataAccess :Utils);
 use Image::ExifTool::Exif;
 use Image::ExifTool::APP12;
 
-$VERSION = '2.82';
+$VERSION = '2.83';
 
 sub PrintLensInfo($$$);
 
@@ -117,6 +117,7 @@ my %olympusLensTypes = (
     '0 36 10' => 'Olympus M.Zuiko Digital ED 8-25mm F4 Pro', #IB
     '0 37 10' => 'Olympus M.Zuiko Digital ED 40-150mm F4.0 Pro', #forum3833
     '0 39 10' => 'Olympus M.Zuiko Digital ED 90mm F3.5 Macro IS Pro', #forum3833
+    '0 40 10' => 'Olympus M.Zuiko Digital ED 150-600mm F5.0-6.3', #forum15652
     # Sigma lenses
     '1 01 00' => 'Sigma 18-50mm F3.5-5.6 DC', #8
     '1 01 10' => 'Sigma 30mm F2.8 EX DN', #NJ
@@ -442,6 +443,7 @@ my %olympusCameraTypes = (
     S0093 => 'E-P7', #IB
     S0095 => 'OM-1', #IB
     S0101 => 'OM-5', #IB
+    S0121 => 'OM-1MarkII', #forum15652
     SR45 => 'D220',
     SR55 => 'D320L',
     SR83 => 'D340L',

package/bin/lib/Image/ExifTool/PDF.pm

@@ -114,11 +114,11 @@ my %supportedFilter = (
         Notes => q{
             stored as a string but treated as a comma- or semicolon-separated list of
             items when reading if the string contains commas or semicolons, whichever is
-            more numerous, otherwise it is treated a space-separated list of items.
-            Written as a comma-separated list.  The list behaviour may be defeated by
-            setting the API NoPDFList option.  Note that the corresponding
-            XMP-pdf:Keywords tag is not treated as a list, so the NoPDFList option
-            should be used when copying between these two.
+            more numerous, otherwise it is treated a space-separated list of items.  The
+            list behaviour may be defeated by setting the API NoPDFList option.  Written
+            as a comma-separated string.  Note that the corresponding XMP-pdf:Keywords
+            tag is not treated as a list, so the NoPDFList option should be used when
+            copying between these two.
         },
     },
     Creator     => { },

package/bin/lib/Image/ExifTool/Pentax.pm

@@ -177,7 +177,7 @@ sub DecodeAFPoints($$$$;$);
     '4 6' => 'smc PENTAX-FA 35-80mm F4-5.6',
     '4 7' => 'Irix 45mm F1.4', #27
     '4 8' => 'Irix 150mm F2.8 Macro', #exiv2 issue 1084
-    '4 9' => 'Irix 11mm F4 Firefly', #27
+    '4 9' => 'Irix 11mm F4 Firefly', #27 (guessing the Blackstone version may be the same ID - PH)
     '4 10' => 'Irix 15mm F2.4', #27
     '4 12' => 'smc PENTAX-FA 50mm F1.4', #17
     '4 15' => 'smc PENTAX-FA 28-105mm F4-5.6 [IF]',