elm-pages 2.1.6 → 2.1.10

package/src/Pages/Internal/RoutePattern.elm

@@ -0,0 +1,122 @@
+module Pages.Internal.RoutePattern exposing (Ending(..), RoutePattern, Segment(..), codec, view)
+
+{-| Exposed for internal use only (used in generated code).
+
+@docs Ending, RoutePattern, Segment, codec, view
+
+-}
+
+import Codec exposing (Codec)
+import Html exposing (Html)
+
+
+{-| -}
+type alias RoutePattern =
+    { segments : List Segment
+    , ending : Maybe Ending
+    }
+
+
+{-| -}
+type Ending
+    = Optional String
+    | RequiredSplat
+    | OptionalSplat
+
+
+{-| -}
+type Segment
+    = StaticSegment String
+    | DynamicSegment String
+
+
+{-| -}
+codec : Codec RoutePattern
+codec =
+    Codec.object RoutePattern
+        |> Codec.field "segments" .segments (Codec.list segmentCodec)
+        |> Codec.field "ending" .ending (Codec.maybe endingCodec)
+        |> Codec.buildObject
+
+
+segmentCodec : Codec Segment
+segmentCodec =
+    Codec.custom
+        (\vStatic vDynamic value ->
+            case value of
+                StaticSegment string ->
+                    vStatic string
+
+                DynamicSegment string ->
+                    vDynamic string
+        )
+        |> Codec.variant1 "StaticSegment" StaticSegment Codec.string
+        |> Codec.variant1 "DynamicSegment" DynamicSegment Codec.string
+        |> Codec.buildCustom
+
+
+endingCodec : Codec Ending
+endingCodec =
+    Codec.custom
+        (\vOptional vRequiredSplat vOptionalSplat value ->
+            case value of
+                Optional string ->
+                    vOptional string
+
+                RequiredSplat ->
+                    vRequiredSplat
+
+                OptionalSplat ->
+                    vOptionalSplat
+        )
+        |> Codec.variant1 "Optional" Optional Codec.string
+        |> Codec.variant0 "RequiredSplat" RequiredSplat
+        |> Codec.variant0 "OptionalSplat" OptionalSplat
+        |> Codec.buildCustom
+
+
+segmentToString : Segment -> String
+segmentToString segment =
+    case segment of
+        StaticSegment string ->
+            string
+
+        DynamicSegment name ->
+            ":" ++ name
+
+
+{-| -}
+view : RoutePattern -> Html msg
+view routePattern =
+    Html.span []
+        (case routePattern.ending of
+            Nothing ->
+                [ Html.code [] [ Html.text <| toString_ routePattern.segments ] ]
+
+            Just (Optional optionalName) ->
+                [ Html.code []
+                    [ Html.text <| toString_ routePattern.segments ]
+                , Html.text " or "
+                , Html.code []
+                    [ Html.text <|
+                        toString_ routePattern.segments
+                            ++ "/:"
+                            ++ optionalName
+                    ]
+                ]
+
+            Just RequiredSplat ->
+                [ Html.code [] [ Html.text <| toString_ routePattern.segments ] ]
+
+            Just OptionalSplat ->
+                [ Html.code [] [ Html.text <| toString_ routePattern.segments ] ]
+        )
+
+
+toString_ : List Segment -> String
+toString_ segments =
+    "/"
+        ++ (segments
+                |> List.map segmentToString
+                |> String.join "/"
+           )

package/src/Pages/Internal/Router.elm

@@ -0,0 +1,116 @@
+module Pages.Internal.Router exposing (Matcher, firstMatch, fromOptionalSplat, maybeToList, nonEmptyToList, toNonEmpty)
+
+{-| Exposed for internal use only (used in generated code).
+
+@docs Matcher, firstMatch, fromOptionalSplat, maybeToList, nonEmptyToList, toNonEmpty
+
+-}
+
+import List.Extra
+import Regex
+
+
+{-| -}
+firstMatch : List (Matcher route) -> String -> Maybe route
+firstMatch matchers path =
+    List.Extra.findMap
+        (\matcher ->
+            if Regex.contains (matcher.pattern |> toRegex) (normalizePath path) then
+                tryMatch matcher path
+
+            else
+                Nothing
+        )
+        matchers
+
+
+toRegex : String -> Regex.Regex
+toRegex pattern =
+    Regex.fromString pattern
+        |> Maybe.withDefault Regex.never
+
+
+{-| -}
+nonEmptyToList : ( String, List String ) -> List String
+nonEmptyToList ( string, strings ) =
+    string :: strings
+
+
+{-| -}
+fromOptionalSplat : Maybe String -> List String
+fromOptionalSplat maybeMatch =
+    maybeMatch
+        |> Maybe.map (\match -> match |> String.split "/")
+        |> Maybe.map (List.filter (\item -> item /= ""))
+        |> Maybe.withDefault []
+
+
+{-| -}
+maybeToList : Maybe String -> List String
+maybeToList maybeString =
+    case maybeString of
+        Just string ->
+            [ string ]
+
+        Nothing ->
+            []
+
+
+{-| -}
+toNonEmpty : String -> ( String, List String )
+toNonEmpty string =
+    case string |> String.split "/" of
+        [] ->
+            ( "ERROR", [] )
+
+        first :: rest ->
+            ( first, rest )
+
+
+{-| -}
+type alias Matcher route =
+    { pattern : String, toRoute : List (Maybe String) -> Maybe route }
+
+
+{-| -}
+tryMatch : { pattern : String, toRoute : List (Maybe String) -> Maybe route } -> String -> Maybe route
+tryMatch { pattern, toRoute } path =
+    path
+        |> normalizePath
+        |> submatches pattern
+        |> toRoute
+
+
+submatches : String -> String -> List (Maybe String)
+submatches pattern path =
+    Regex.find
+        (Regex.fromString pattern
+            |> Maybe.withDefault Regex.never
+        )
+        path
+        |> List.concatMap .submatches
+
+
+normalizePath : String -> String
+normalizePath path =
+    path
+        |> ensureLeadingSlash
+        |> stripTrailingSlash
+
+
+ensureLeadingSlash : String -> String
+ensureLeadingSlash path =
+    if path |> String.startsWith "/" then
+        path
+
+    else
+        "/" ++ path
+
+
+stripTrailingSlash : String -> String
+stripTrailingSlash path =
+    if (path |> String.endsWith "/") && (String.length path > 1) then
+        String.dropRight 1 path
+
+    else
+        path

package/src/Pages/Internal/StaticHttpBody.elm

@@ -0,0 +1,54 @@
+module Pages.Internal.StaticHttpBody exposing (Body(..), codec, encode)
+
+import Codec exposing (Codec)
+import Json.Encode as Encode
+
+
+type Body
+    = EmptyBody
+    | StringBody String String
+    | JsonBody Encode.Value
+
+
+encode : Body -> Encode.Value
+encode body =
+    case body of
+        EmptyBody ->
+            encodeWithType "empty" []
+
+        StringBody _ content ->
+            encodeWithType "string"
+                [ ( "content", Encode.string content )
+                ]
+
+        JsonBody content ->
+            encodeWithType "json"
+                [ ( "content", content )
+                ]
+
+
+encodeWithType : String -> List ( String, Encode.Value ) -> Encode.Value
+encodeWithType typeName otherFields =
+    Encode.object <|
+        ( "type", Encode.string typeName )
+            :: otherFields
+
+
+codec : Codec Body
+codec =
+    Codec.custom
+        (\vEmpty vString vJson value ->
+            case value of
+                EmptyBody ->
+                    vEmpty
+
+                StringBody a b ->
+                    vString a b
+
+                JsonBody body ->
+                    vJson body
+        )
+        |> Codec.variant0 "EmptyBody" EmptyBody
+        |> Codec.variant2 "StringBody" StringBody Codec.string Codec.string
+        |> Codec.variant1 "JsonBody" JsonBody Codec.value
+        |> Codec.buildCustom

package/src/Pages/Internal/String.elm

@@ -0,0 +1,39 @@
+module Pages.Internal.String exposing (chopEnd, chopForwardSlashes, chopStart)
+
+{-| Remove a piece from the beginning of a string until it's not there anymore.
+
+    >>> chopStart "{" "{{{<-"
+    "<-"
+
+-}
+
+
+chopStart : String -> String -> String
+chopStart needle string =
+    if String.startsWith needle string then
+        chopStart needle (String.dropLeft (String.length needle) string)
+
+    else
+        string
+
+
+{-| Remove a piece from the end of a string until it's not there anymore.
+
+    >>> chopEnd "}" "->}}}"
+    "->"
+
+-}
+chopEnd : String -> String -> String
+chopEnd needle string =
+    if String.endsWith needle string then
+        chopEnd needle (String.dropRight (String.length needle) string)
+
+    else
+        string
+
+
+{-| Removes `/` characters from both ends of a string.
+-}
+chopForwardSlashes : String -> String
+chopForwardSlashes =
+    chopStart "/" >> chopEnd "/"

package/src/Pages/Manifest/Category.elm

@@ -0,0 +1,240 @@
+module Pages.Manifest.Category exposing
+    ( toString, Category
+    , books, business, education, entertainment, finance, fitness, food, games, government, health, kids, lifestyle, magazines, medical, music, navigation, news, personalization, photo, politics, productivity, security, shopping, social, sports, travel, utilities, weather
+    , custom
+    )
+
+{-| See <https://github.com/w3c/manifest/wiki/Categories> and
+<https://developer.mozilla.org/en-US/docs/Web/Manifest/categories>
+
+@docs toString, Category
+
+@docs books, business, education, entertainment, finance, fitness, food, games, government, health, kids, lifestyle, magazines, medical, music, navigation, news, personalization, photo, politics, productivity, security, shopping, social, sports, travel, utilities, weather
+
+
+## Custom categories
+
+@docs custom
+
+-}
+
+
+{-| Turn a category into its official String representation, as seen
+here: <https://github.com/w3c/manifest/wiki/Categories>.
+-}
+toString : Category -> String
+toString (Category raw) =
+    raw
+
+
+{-| Represents a known, valid category, as specified by
+<https://github.com/w3c/manifest/wiki/Categories>. If this document is updated
+and I don't add it, please open an issue or pull request to let me know!
+-}
+type Category
+    = Category String
+
+
+{-| It's best to use the pre-defined categories to ensure that clients (Android, iOS,
+Chrome, Windows app store, etc.) are aware of it and can handle it appropriately.
+But, if you're confident about using a custom one, you can do so with `Pages.Manifest.custom`.
+-}
+custom : String -> Category
+custom name =
+    Category name
+
+
+{-| Creates the described category.
+-}
+books : Category
+books =
+    Category "books"
+
+
+{-| Creates the described category.
+-}
+business : Category
+business =
+    Category "business"
+
+
+{-| Creates the described category.
+-}
+education : Category
+education =
+    Category "education"
+
+
+{-| Creates the described category.
+-}
+entertainment : Category
+entertainment =
+    Category "entertainment"
+
+
+{-| Creates the described category.
+-}
+finance : Category
+finance =
+    Category "finance"
+
+
+{-| Creates the described category.
+-}
+fitness : Category
+fitness =
+    Category "fitness"
+
+
+{-| Creates the described category.
+-}
+food : Category
+food =
+    Category "food"
+
+
+{-| Creates the described category.
+-}
+games : Category
+games =
+    Category "games"
+
+
+{-| Creates the described category.
+-}
+government : Category
+government =
+    Category "government"
+
+
+{-| Creates the described category.
+-}
+health : Category
+health =
+    Category "health"
+
+
+{-| Creates the described category.
+-}
+kids : Category
+kids =
+    Category "kids"
+
+
+{-| Creates the described category.
+-}
+lifestyle : Category
+lifestyle =
+    Category "lifestyle"
+
+
+{-| Creates the described category.
+-}
+magazines : Category
+magazines =
+    Category "magazines"
+
+
+{-| Creates the described category.
+-}
+medical : Category
+medical =
+    Category "medical"
+
+
+{-| Creates the described category.
+-}
+music : Category
+music =
+    Category "music"
+
+
+{-| Creates the described category.
+-}
+navigation : Category
+navigation =
+    Category "navigation"
+
+
+{-| Creates the described category.
+-}
+news : Category
+news =
+    Category "news"
+
+
+{-| Creates the described category.
+-}
+personalization : Category
+personalization =
+    Category "personalization"
+
+
+{-| Creates the described category.
+-}
+photo : Category
+photo =
+    Category "photo"
+
+
+{-| Creates the described category.
+-}
+politics : Category
+politics =
+    Category "politics"
+
+
+{-| Creates the described category.
+-}
+productivity : Category
+productivity =
+    Category "productivity"
+
+
+{-| Creates the described category.
+-}
+security : Category
+security =
+    Category "security"
+
+
+{-| Creates the described category.
+-}
+shopping : Category
+shopping =
+    Category "shopping"
+
+
+{-| Creates the described category.
+-}
+social : Category
+social =
+    Category "social"
+
+
+{-| Creates the described category.
+-}
+sports : Category
+sports =
+    Category "sports"
+
+
+{-| Creates the described category.
+-}
+travel : Category
+travel =
+    Category "travel"
+
+
+{-| Creates the described category.
+-}
+utilities : Category
+utilities =
+    Category "utilities"
+
+
+{-| Creates the described category.
+-}
+weather : Category
+weather =
+    Category "weather"