datahike-browser-tests 1.0.0

package/test/datahike/test/query_interop_test.cljc

@@ -0,0 +1,47 @@
+(ns datahike.test.query-interop-test
+  (:require
+   #?(:cljs [cljs.test    :as t :refer-macros [is are deftest]]
+      :clj  [clojure.test :as t :refer        [is are deftest]])
+   [datahike.api :as d]
+   [datahike.db :as db]))
+
+#?(:cljs (def Exception js/Error))
+
+(def test-db
+  (d/db-with
+   (db/empty-db)
+   [[:db/add 1 :name "Vlad"]
+    [:db/add 2 :name "Ivan"]
+    [:db/add 3 :name "Sergey"]]))
+
+(deftest test-filter
+  (are [q expected] (= (d/q q test-db) expected)
+    '[:find ?v
+      :where [_ :name ?v]
+      [(.startsWith ?v "Ser")]]
+    #{["Sergey"]}
+
+    '[:find ?v
+      :where [_ :name ?v]
+      [(.contains ?v "a")]]
+    #{["Vlad"] ["Ivan"]}
+
+    '[:find ?v
+      :where [_ :name ?v]
+      [(.matches ?v ".+rg.+")]]
+    #{["Sergey"]}))
+
+(deftest test-bind
+  (are [q expected] (= (d/q q test-db) expected)
+    '[:find ?V
+      :where
+      [?e :name ?v]
+      [(.toLowerCase ?v) ?V]]
+    #{["vlad"] ["ivan"] ["sergey"]}))
+
+(deftest test-method-not-found
+  (is (thrown? Exception (d/q '[:find ?v
+                                :where
+                                [?e :name ?v]
+                                [(.thisMethodDoesNotExist ?v 1)]]
+                              test-db))))

package/test/datahike/test/query_not_test.cljc

@@ -0,0 +1,189 @@
+(ns datahike.test.query-not-test
+  (:require
+   #?(:cljs [cljs.test    :as t :refer-macros [are deftest]]
+      :clj  [clojure.test :as t :refer        [are deftest]])
+   [datahike.api :as d]
+   #?(:cljs [datahike.cljs :refer [Throwable]])
+   [datahike.db :as db]
+   [datahike.test.core-test]))
+
+(def test-db
+  (delay
+    (d/db-with (db/empty-db)
+               [{:db/id 1 :name "Ivan" :age 10}
+                {:db/id 2 :name "Ivan" :age 20}
+                {:db/id 3 :name "Oleg" :age 10}
+                {:db/id 4 :name "Oleg" :age 20}
+                {:db/id 5 :name "Ivan" :age 10}
+                {:db/id 6 :name "Ivan" :age 20}])))
+
+(deftest test-not
+  (are [q res] (= (set (d/q (into '[:find [?e ...] :where] (quote q)) @test-db))
+                  res)
+    [[?e :name]
+     (not [?e :name "Ivan"])]
+    #{3 4}
+
+    [[?e :name]
+     (not
+      [?e :name "Ivan"]
+      [?e :age  10])]
+    #{2 3 4 6}
+
+    [[?e :name]
+     (not [?e :name "Ivan"])
+     (not [?e :age 10])]
+    #{4}
+
+    ;; full exclude
+    [[?e :name]
+     (not [?e :age])]
+    #{}
+
+    ;; not-intersecting rels
+    [[?e :name "Ivan"]
+     (not [?e :name "Oleg"])]
+    #{1 2 5 6}
+
+    ;; exclude empty set
+    [[?e :name]
+     (not [?e :name "Ivan"]
+          [?e :name "Oleg"])]
+    #{1 2 3 4 5 6}
+
+    ;; nested excludes
+    [[?e :name]
+     (not [?e :name "Ivan"]
+          (not [?e :age 10]))]
+    #{1 3 4 5}
+
+    ;; extra binding in not
+    [[?e :name ?a]
+     (not [?e :age ?f]
+          [?e :age 10])]
+    #{2 4 6}))
+
+(deftest test-not-join
+  (are [q res] (= (d/q (into '[:find ?e ?a :where] (quote q)) @test-db)
+                  res)
+    [[?e :name]
+     [?e :age  ?a]
+     (not-join [?e]
+               [?e :name "Oleg"]
+               [?e :age ?a])]
+    #{[1 10] [2 20] [5 10] [6 20]}
+
+    [[?e :age  ?a]
+     [?e :age  10]
+     (not-join [?e]
+               [?e :name "Oleg"]
+               [?e :age  ?a]
+               [?e :age  10])]
+    #{[1 10] [5 10]}))
+
+(deftest test-default-source
+  (let [db1 (d/db-with (db/empty-db)
+                       [[:db/add 1 :name "Ivan"]
+                        [:db/add 2 :name "Oleg"]])
+        db2 (d/db-with (db/empty-db)
+                       [[:db/add 1 :age 10]
+                        [:db/add 2 :age 20]])]
+    (are [q res] (= (set (d/q (into '[:find [?e ...]
+                                      :in   $ $2
+                                      :where]
+                                    (quote q))
+                              db1 db2))
+                    res)
+      ;; NOT inherits default source
+      [[?e :name]
+       (not [?e :name "Ivan"])]
+      #{2}
+
+      ;; NOT can reference any source
+      [[?e :name]
+       (not [$2 ?e :age 10])]
+      #{2}
+
+      ;; NOT can change default source
+      [[?e :name]
+       ($2 not [?e :age 10])]
+      #{2}
+
+      ;; even with another default source, it can reference any other source explicitly
+      [[?e :name]
+       ($2 not [$ ?e :name "Ivan"])]
+      #{2}
+
+      ;; nested NOT keeps the default source
+      [[?e :name]
+       ($2 not (not [?e :age 10]))]
+      #{1}
+
+      ;; can override nested NOT source
+      [[?e :name]
+       ($2 not ($ not [?e :name "Ivan"]))]
+      #{1})))
+
+(deftest test-impl-edge-cases
+  (are [q res] (= (d/q (quote q) @test-db)
+                  res)
+    ;; const \ empty
+    [:find ?e
+     :where [?e :name "Oleg"]
+     [?e :age  10]
+     (not [?e :age 20])]
+    #{[3]}
+
+    ;; const \ const
+    [:find ?e
+     :where [?e :name "Oleg"]
+     [?e :age  10]
+     (not [?e :age 10])]
+    #{}
+
+    ;; rel \ const
+    [:find ?e
+     :where [?e :name "Oleg"]
+     (not [?e :age 10])]
+    #{[4]}
+
+    ;; 2 rels \ 2 rels
+    [:find ?e ?e2
+     :where [?e  :name "Ivan"]
+     [?e2 :name "Ivan"]
+     (not [?e :age 10]
+          [?e2 :age 20])]
+    #{[2 1] [6 5] [1 1] [2 2] [5 5] [6 6] [2 5] [1 5] [2 6] [6 1] [5 1] [6 2]}
+
+    ;; 2 rels \ rel + const
+    [:find ?e ?e2
+     :where [?e  :name "Ivan"]
+     [?e2 :name "Oleg"]
+     (not [?e :age 10]
+          [?e2 :age 20])]
+    #{[2 3] [1 3] [2 4] [6 3] [5 3] [6 4]}
+
+    ;; 2 rels \ 2 consts
+    [:find ?e ?e2
+     :where [?e  :name "Oleg"]
+     [?e2 :name "Oleg"]
+     (not [?e :age 10]
+          [?e2 :age 20])]
+    #{[4 3] [3 3] [4 4]}))
+
+(deftest test-insufficient-bindings
+  (are [q msg] (thrown-with-msg? Throwable msg
+                                 (d/q (into '[:find ?e :where] (quote q)) @test-db))
+    [(not [?e :name "Ivan"])
+     [?e :name]]
+    #"Insufficient bindings: none of #\{\?e\} is bound"
+
+    [[?e :name]
+     (not-join [?e]
+               (not [1 :age ?a])
+               [?e :age ?a])]
+    #"Insufficient bindings: none of #\{\?a\} is bound"
+
+    [[?e :name]
+     (not [?a :name "Ivan"])]
+    #"Insufficient bindings: none of #\{\?a\} is bound"))

package/test/datahike/test/query_or_test.cljc

@@ -0,0 +1,158 @@
+(ns datahike.test.query-or-test
+  (:require
+   #?(:cljs [cljs.test    :as t :refer-macros [is are deftest]]
+      :clj  [clojure.test :as t :refer        [is are deftest]])
+   [datahike.api :as d]
+   #?(:cljs [datahike.cljs :refer [Throwable]])
+   [datahike.db :as db]
+   [datahike.test.core-test]))
+
+(def test-db
+  (delay
+    (d/db-with (db/empty-db)
+               [{:db/id 1 :name "Ivan" :age 10}
+                {:db/id 2 :name "Ivan" :age 20}
+                {:db/id 3 :name "Oleg" :age 10}
+                {:db/id 4 :name "Oleg" :age 20}
+                {:db/id 5 :name "Ivan" :age 10}
+                {:db/id 6 :name "Ivan" :age 20}])))
+
+(deftest test-or
+  (are [q res] (= (d/q (into '[:find ?e :where] (quote q)) @test-db)
+                  (into #{} (map vector) res))
+
+    ;; intersecting results
+    [(or [?e :name "Oleg"]
+         [?e :age 10])]
+    #{1 3 4 5}
+
+    ;; one branch empty
+    [(or [?e :name "Oleg"]
+         [?e :age 30])]
+    #{3 4}
+
+    ;; both empty
+    [(or [?e :name "Petr"]
+         [?e :age 30])]
+    #{}
+
+    ;; join with 1 var
+    [[?e :name "Ivan"]
+     (or [?e :name "Oleg"]
+         [?e :age 10])]
+    #{1 5}
+
+    ;; join with 2 vars
+    [[?e :age ?a]
+     (or (and [?e :name "Ivan"]
+              [1  :age  ?a])
+         (and [?e :name "Oleg"]
+              [2  :age  ?a]))]
+    #{1 5 4}
+
+    ;; OR introduces vars
+    [(or (and [?e :name "Ivan"]
+              [1  :age  ?a])
+         (and [?e :name "Oleg"]
+              [2  :age  ?a]))
+     [?e :age ?a]]
+    #{1 5 4}
+
+    ;; OR introduces vars in different order
+    [(or (and [?e :name "Ivan"]
+              [1  :age  ?a])
+         (and [2  :age  ?a]
+              [?e :name "Oleg"]))
+     [?e :age ?a]]
+    #{1 5 4}))
+
+(deftest test-or-join
+  (are [q res] (= (d/q (into '[:find ?e :where] (quote q)) @test-db)
+                  (into #{} (map vector) res))
+    [(or-join [?e]
+              [?e :name ?n]
+              (and [?e :age ?a]
+                   [?e :name ?n]))]
+    #{1 2 3 4 5 6}
+
+    [[?e  :name ?a]
+     [?e2 :name ?a]
+     (or-join [?e]
+              (and [?e  :age ?a]
+                   [?e2 :age ?a]))]
+    #{1 2 3 4 5 6})
+
+  (is (= #{[:a1 :b1 :c1]
+           [:a2 :b2 :c2]}
+         (d/q '[:find ?a ?b ?c
+                :in $xs $ys
+                :where [$xs ?a ?b ?c] ;; check join by ?a, ignoring ?b, dropping ?c ?d
+                (or-join [?a]
+                         [$ys ?a ?b ?d])]
+              [[:a1 :b1 :c1]
+               [:a2 :b2 :c2]
+               [:a3 :b3 :c3]]
+              [[:a1 :b1  :d1] ;; same ?a, same ?b
+               [:a2 :b2* :d2] ;; same ?a, different ?b. Should still be joined
+               [:a4 :b4 :c4]]))) ;; different ?a, should be dropped
+
+  (is (= #{[:a1 :c1] [:a2 :c2]}
+         (d/q '[:find ?a ?c
+                :in $xs $ys
+                :where (or-join [?a ?c]
+                                [$xs ?a ?b ?c] ; rel with hole (?b gets dropped, leaving {?a 0 ?c 2} and 3-element tuples)
+                                [$ys ?a ?c])]
+              [[:a1 :b1 :c1]]
+              [[:a2 :c2]]))))
+
+(deftest test-default-source
+  (let [db1 (d/db-with (db/empty-db)
+                       [[:db/add 1 :name "Ivan"]
+                        [:db/add 2 :name "Oleg"]])
+        db2 (d/db-with (db/empty-db)
+                       [[:db/add 1 :age 10]
+                        [:db/add 2 :age 20]])]
+    (are [q res] (= (d/q (into '[:find ?e :in $ $2 :where] (quote q)) db1 db2)
+                    (into #{} (map vector) res))
+      ;; OR inherits default source
+      [[?e :name]
+       (or [?e :name "Ivan"])]
+      #{1}
+
+      ;; OR can reference any source
+      [[?e :name]
+       (or [$2 ?e :age 10])]
+      #{1}
+
+      ;; OR can change default source
+      [[?e :name]
+       ($2 or [?e :age 10])]
+      #{1}
+
+      ;; even with another default source, it can reference any other source explicitly
+      [[?e :name]
+       ($2 or [$ ?e :name "Ivan"])]
+      #{1}
+
+      ;; nested OR keeps the default source
+      [[?e :name]
+       ($2 or (or [?e :age 10]))]
+      #{1}
+
+      ;; can override nested OR source
+      [[?e :name]
+       ($2 or ($ or [?e :name "Ivan"]))]
+      #{1})))
+
+(deftest test-errors
+  (is (thrown-with-msg? Throwable #"Join variable not declared inside clauses"
+                        (d/q '[:find ?e
+                               :where (or [?e :name _]
+                                          [?e :age ?a])]
+                             @test-db)))
+
+  (is (thrown-with-msg? Throwable #"Insufficient bindings: #\{\?e\} not bound"
+                        (d/q '[:find ?e
+                               :where (or-join [[?e]]
+                                               [?e :name "Ivan"])]
+                             @test-db))))

package/test/datahike/test/query_pull_test.cljc

@@ -0,0 +1,147 @@
+(ns datahike.test.query-pull-test
+  (:require
+   #?(:cljs [cljs.test    :as t :refer-macros [is are deftest testing]]
+      :clj  [clojure.test :as t :refer        [is are deftest testing]])
+   [datahike.api :as d]
+   [datahike.db :as db]))
+
+(def test-db (d/db-with (db/empty-db)
+                        [{:db/id 1 :name "Petr" :age 44}
+                         {:db/id 2 :name "Ivan" :age 25}
+                         {:db/id 3 :name "Oleg" :age 11}]))
+
+(deftest test-basics
+  (are [find res] (= (set (d/q {:find find
+                                :where '[[?e :age ?a]
+                                         [(>= ?a 18)]]}
+                               test-db))
+                     res)
+    '[(pull ?e [:name])]
+    #{[{:name "Ivan"}] [{:name "Petr"}]}
+
+    '[(pull ?e [*])]
+    #{[{:db/id 2 :age 25 :name "Ivan"}] [{:db/id 1 :age 44 :name "Petr"}]}
+
+    '[?e (pull ?e [:name])]
+    #{[2 {:name "Ivan"}] [1 {:name "Petr"}]}
+
+    '[?e ?a (pull ?e [:name])]
+    #{[2 25 {:name "Ivan"}] [1 44 {:name "Petr"}]}
+
+    '[?e ?a (pull ?e #{:name})]
+    #{[2 25 {:name "Ivan"}] [1 44 {:name "Petr"}]}
+
+    '[?e (pull ?e [:name]) ?a]
+    #{[2 {:name "Ivan"} 25] [1 {:name "Petr"} 44]}))
+
+(deftest test-var-pattern
+  (are [find pattern res] (= (set (d/q {:find find
+                                        :in   '[$ ?pattern]
+                                        :where '[[?e :age ?a]
+                                                 [(>= ?a 18)]]}
+                                       test-db pattern))
+                             res)
+    '[(pull ?e ?pattern)] [:name]
+    #{[{:name "Ivan"}] [{:name "Petr"}]}
+
+    '[(pull ?e ?pattern)] #{:name}
+    #{[{:name "Ivan"}] [{:name "Petr"}]}
+
+    '[?e ?a ?pattern (pull ?e ?pattern)] [:name]
+    #{[2 25 [:name] {:name "Ivan"}] [1 44 [:name] {:name "Petr"}]}))
+
+;; not supported
+#_(deftest test-multi-pattern
+    (is (= (set (d/q '[:find ?e ?p (pull ?e ?p)
+                       :in $ [?p ...]
+                       :where [?e :age ?a]
+                       [>= ?a 18]]
+                     test-db [[:name] [:age]]))
+           #{[2 [:name] {:name "Ivan"}]
+             [2 [:age]  {:age 25}]
+             [1 [:name] {:name "Petr"}]
+             [1 [:age]  {:age 44}]})))
+
+(deftest test-multiple-sources
+  (let [db1 (d/db-with (db/empty-db) [{:db/id 1 :name "Ivan" :age 25}])
+        db2 (d/db-with (db/empty-db) [{:db/id 1 :name "Petr" :age 25}])]
+    (is (= (set (d/q '[:find ?e (pull $1 ?e [:name])
+                       :in $1 $2
+                       :where [$1 ?e :age 25]]
+                     db1 db2))
+           #{[1 {:name "Ivan"}]}))
+
+    (is (= (set (d/q '[:find ?e (pull $2 ?e [:name])
+                       :in $1 $2
+                       :where [$2 ?e :age 25]]
+                     db1 db2))
+           #{[1 {:name "Petr"}]}))
+
+    (testing "$ is default source"
+      (is (= (set (d/q '[:find ?e (pull ?e [:name])
+                         :in $1 $
+                         :where [$ ?e :age 25]]
+                       db1 db2))
+             #{[1 {:name "Petr"}]})))))
+
+(deftest test-find-spec
+  (is (= (d/q '[:find (pull ?e [:name]) .
+                :where [?e :age 25]]
+              test-db)
+         {:name "Ivan"}))
+  (is (= (d/q '[:find (pull ?e #{:name}) .
+                :where [?e :age 25]]
+              test-db)
+         {:name "Ivan"}))
+
+  (is (= (set (d/q '[:find [(pull ?e [:name]) ...]
+                     :where [?e :age ?a]]
+                   test-db))
+         #{{:name "Ivan"} {:name "Petr"} {:name "Oleg"}}))
+
+  (is (= (d/q '[:find [?e (pull ?e [:name])]
+                :where [?e :age 25]]
+              test-db)
+         [2 {:name "Ivan"}])))
+
+(deftest test-find-spec-input
+  (is (= (d/q '[:find (pull ?e ?p) .
+                :in $ ?p
+                :where [(ground 2) ?e]]
+              test-db [:name])
+         {:name "Ivan"}))
+  (is (= (d/q '[:find (pull ?e ?p) .
+                :in $ ?p
+                :where [(ground 2) ?e]]
+              test-db #{:name})
+         {:name "Ivan"}))
+  (is (= (d/q '[:find (pull ?e p) .
+                :in $ p
+                :where [(ground 2) ?e]]
+              test-db [:name])
+         {:name "Ivan"})))
+
+(deftest test-aggregates
+  (let [db (d/db-with (db/empty-db {:value {:db/cardinality :db.cardinality/many}})
+                      [{:db/id 1 :name "Petr" :value [10 20 30 40]}
+                       {:db/id 2 :name "Ivan" :value [14 16]}
+                       {:db/id 3 :name "Oleg" :value 1}])]
+    (is (= (set (d/q '[:find ?e (pull ?e [:name]) (min ?v) (max ?v)
+                       :where [?e :value ?v]]
+                     db))
+           #{[1 {:name "Petr"} 10 40]
+             [2 {:name "Ivan"} 14 16]
+             [3 {:name "Oleg"} 1 1]}))))
+
+(deftest test-lookup-refs
+  (let [db (d/db-with (db/empty-db {:name {:db/unique :db.unique/identity}})
+                      [{:db/id 1 :name "Petr" :age 44}
+                       {:db/id 2 :name "Ivan" :age 25}
+                       {:db/id 3 :name "Oleg" :age 11}])]
+    (is (= (set (d/q '[:find ?ref ?a (pull ?ref [:db/id :name])
+                       :in   $ [?ref ...]
+                       :where [?ref :age ?a]
+                       [(>= ?a 18)]]
+                     db [[:name "Ivan"] [:name "Oleg"] [:name "Petr"]]))
+           #{[[:name "Petr"] 44 {:db/id 1 :name "Petr"}]
+             [[:name "Ivan"] 25 {:db/id 2 :name "Ivan"}]}))))