create-dubhe 0.1.13 → 1.2.0-pre.51

package/template/101/initia-template/contracts/counter/build/counter/sources/dependencies/InitiaStdlib/object_code_deployment.move

@@ -1,157 +0,0 @@
-/// This module allows users to deploy, upgrade and freeze modules deployed to objects on-chain.
-/// This enables users to deploy modules to an object with a unique address each time they are published.
-/// This modules provides an alternative method to publish code on-chain, where code is deployed to objects rather than accounts.
-/// This is encouraged as it abstracts the necessary resources needed for deploying modules,
-/// along with the required authorization to upgrade and freeze modules.
-///
-/// The functionalities of this module are as follows.
-///
-/// Publishing modules flow:
-/// 1. Create a new object with the address derived from the publisher address and the object seed.
-/// 2. Publish the module passed in the function via `metadata_serialized` and `code` to the newly created object.
-/// 3. Emits 'Publish' event with the address of the newly created object.
-/// 4. Create a `ManagingRefs` which stores the extend ref of the newly created object.
-/// Note: This is needed to upgrade the code as the signer must be generated to upgrade the existing code in an object.
-///
-/// Upgrading modules flow:
-/// 1. Assert the `code_object` passed in the function is owned by the `publisher`.
-/// 2. Assert the `code_object` passed in the function exists in global storage.
-/// 2. Retrieve the `ExtendRef` from the `code_object` and generate the signer from this.
-/// 3. Upgrade the module with the `metadata_serialized` and `code` passed in the function.
-/// 4. Emits 'Upgrade' event with the address of the object with the upgraded code.
-/// Note: If the modules were deployed as immutable when calling `publish`, the upgrade will fail.
-///
-/// Freezing modules flow:
-/// 1. Assert the `code_object` passed in the function exists in global storage.
-/// 2. Assert the `code_object` passed in the function is owned by the `publisher`.
-/// 3. Mark all the modules in the `code_object` as immutable.
-/// 4. Emits 'Freeze' event with the address of the object with the frozen code.
-/// Note: There is no unfreeze function as this gives no benefit if the user can freeze/unfreeze modules at will.
-///       Once modules are marked as immutable, they cannot be made mutable again.
-module initia_std::object_code_deployment {
-    use std::bcs;
-    use std::error;
-    use std::signer;
-    use std::vector;
-    use initia_std::account;
-    use initia_std::code::{Self, MetadataStore};
-    use initia_std::event;
-    use initia_std::object;
-    use initia_std::object::{ExtendRef, Object};
-    use initia_std::string::String;
-
-    /// Object code deployment feature not supported.
-    const EOBJECT_CODE_DEPLOYMENT_NOT_SUPPORTED: u64 = 1;
-    /// Not the owner of the `code_object`
-    const ENOT_CODE_OBJECT_OWNER: u64 = 2;
-    /// `code_object` does not exist.
-    const ECODE_OBJECT_DOES_NOT_EXIST: u64 = 3;
-
-    const OBJECT_CODE_DEPLOYMENT_DOMAIN_SEPARATOR: vector<u8> = b"initia_std::object_code_deployment";
-
-    /// Internal struct, attached to the object, that holds Refs we need to manage the code deployment (i.e. upgrades).
-    struct ManagingRefs has key {
-        /// We need to keep the extend ref to be able to generate the signer to upgrade existing code.
-        extend_ref: ExtendRef
-    }
-
-    #[event]
-    /// Event emitted when code is published to an object.
-    struct Publish has drop, store {
-        object_address: address
-    }
-
-    #[event]
-    /// Event emitted when code in an existing object is upgraded.
-    struct Upgrade has drop, store {
-        object_address: address
-    }
-
-    #[event]
-    /// Event emitted when code in an existing object is made immutable.
-    struct Freeze has drop, store {
-        object_address: address
-    }
-
-    #[deprecated]
-    /// Creates a new object with a unique address derived from the publisher address and the object seed.
-    /// Publishes the code passed in the function to the newly created object.
-    /// The caller must provide package metadata describing the package via `metadata_serialized` and
-    /// the code to be published via `code`. This contains a vector of modules to be deployed on-chain.
-    public entry fun publish(
-        publisher: &signer, _module_ids: vector<String>, code: vector<vector<u8>>
-    ) {
-        publish_v2(publisher, code);
-    }
-
-    /// Creates a new object with a unique address derived from the publisher address and the object seed.
-    /// Publishes the code passed in the function to the newly created object.
-    /// The caller must provide package metadata describing the package via `metadata_serialized` and
-    /// the code to be published via `code`. This contains a vector of modules to be deployed on-chain.
-    public entry fun publish_v2(
-        publisher: &signer, code: vector<vector<u8>>
-    ) {
-        let publisher_address = signer::address_of(publisher);
-        let object_seed = object_seed(publisher_address);
-        let constructor_ref = &object::create_named_object(publisher, object_seed);
-        let code_signer = &object::generate_signer(constructor_ref);
-        code::publish_v2(code_signer, code, 1);
-
-        event::emit(Publish { object_address: signer::address_of(code_signer) });
-
-        move_to(
-            code_signer,
-            ManagingRefs { extend_ref: object::generate_extend_ref(constructor_ref) }
-        );
-    }
-
-    inline fun object_seed(publisher: address): vector<u8> {
-        let sequence_number = account::get_sequence_number(publisher) + 1;
-        let seeds = vector[];
-        vector::append(
-            &mut seeds, bcs::to_bytes(&OBJECT_CODE_DEPLOYMENT_DOMAIN_SEPARATOR)
-        );
-        vector::append(&mut seeds, bcs::to_bytes(&sequence_number));
-        seeds
-    }
-
-    /// Upgrades the existing modules at the `code_object` address with the new modules passed in `code`,
-    /// along with the metadata `metadata_serialized`.
-    /// Note: If the modules were deployed as immutable when calling `publish`, the upgrade will fail.
-    /// Requires the publisher to be the owner of the `code_object`.
-    public entry fun upgrade(
-        publisher: &signer,
-        module_ids: vector<String>,
-        code: vector<vector<u8>>,
-        code_object: Object<MetadataStore>
-    ) acquires ManagingRefs {
-        let publisher_address = signer::address_of(publisher);
-        assert!(
-            object::is_owner(code_object, publisher_address),
-            error::permission_denied(ENOT_CODE_OBJECT_OWNER)
-        );
-
-        let code_object_address = object::object_address(&code_object);
-        assert!(
-            exists<ManagingRefs>(code_object_address),
-            error::not_found(ECODE_OBJECT_DOES_NOT_EXIST)
-        );
-
-        let extend_ref = &borrow_global<ManagingRefs>(code_object_address).extend_ref;
-        let code_signer = &object::generate_signer_for_extending(extend_ref);
-        code::publish(code_signer, module_ids, code, 1);
-
-        event::emit(Upgrade { object_address: signer::address_of(code_signer) });
-    }
-
-    /// Make an existing upgradable package immutable. Once this is called, the package cannot be made upgradable again.
-    /// Each `code_object` should only have one package, as one package is deployed per object in this module.
-    /// Requires the `publisher` to be the owner of the `code_object`.
-    public entry fun freeze_code_object(
-        publisher: &signer, code_object: Object<MetadataStore>
-    ) {
-        code::freeze_code_object(publisher, code_object);
-
-        event::emit(Freeze { object_address: object::object_address(&code_object) });
-    }
-}

package/template/101/initia-template/contracts/counter/build/counter/sources/dependencies/InitiaStdlib/oracle.move

@@ -1,71 +0,0 @@
-module initia_std::oracle {
-    use initia_std::string::{Self, String};
-
-    #[view]
-    public fun get_price(pair_id: String): (u256, u64, u64) {
-        get_price_internal(*string::bytes(&pair_id))
-    }
-
-    native fun get_price_internal(pair_id: vector<u8>): (u256, u64, u64);
-
-    #[test_only]
-    public fun set_price(
-        pair_id: &String,
-        price: u256,
-        updated_at: u64,
-        decimals: u64
-    ) {
-        set_price_internal(
-            *string::bytes(pair_id),
-            price,
-            updated_at,
-            decimals
-        )
-    }
-
-    #[test_only]
-    native fun set_price_internal(
-        pair_id: vector<u8>,
-        price: u256,
-        updated_at: u64,
-        decimals: u64
-    );
-
-    #[test]
-    public fun test_get_price() {
-        let btc_usd_pair_id = string::utf8(b"BITCOIN/USD");
-        let eth_usd_pair_id = string::utf8(b"ETHEREUM/USD");
-
-        let btc_price = 100_00000000_u256;
-        let eth_price = 10_000000000000000000_u256;
-
-        let btc_updated_at = 1000002;
-        let eth_updated_at = 1000001;
-
-        let btc_decimals = 8;
-        let eth_decimals = 18;
-
-        set_price(
-            &btc_usd_pair_id,
-            btc_price,
-            btc_updated_at,
-            btc_decimals
-        );
-        set_price(
-            &eth_usd_pair_id,
-            eth_price,
-            eth_updated_at,
-            eth_decimals
-        );
-
-        let (price, updated_at, decimals) = get_price(btc_usd_pair_id);
-        assert!(btc_price == price, 0);
-        assert!(btc_updated_at == updated_at, 0);
-        assert!(btc_decimals == decimals, 0);
-
-        let (price, updated_at, decimals) = get_price(eth_usd_pair_id);
-        assert!(eth_price == price, 0);
-        assert!(eth_updated_at == updated_at, 0);
-        assert!(eth_decimals == decimals, 0);
-    }
-}