cobrowse-sdk-react-native 3.5.0 → 3.6.0

package/.github/workflows/lint.yaml

@@ -13,7 +13,7 @@ jobs:
       - uses: actions/setup-node@v4
         name: Install NodeJS
         with:
-          node-version: '22'
+          node-version: '24'
 
       - run: npm ci
 

package/android/build.gradle

@@ -45,7 +45,7 @@ android {
 
 dependencies {
     implementation 'com.facebook.react:react-native:+' // support react-native-v0.22-rc+
-    implementation 'io.cobrowse:cobrowse-sdk-android:3.13.0'
+    implementation 'io.cobrowse:cobrowse-sdk-android:3.13.2'
     implementation 'androidx.webkit:webkit:1.4.0'
     implementation 'androidx.activity:activity:1.6.0'
 }

package/cobrowse-sdk-react-native.podspec

@@ -11,7 +11,12 @@ Pod::Spec.new do |s|
   s.homepage      = package["homepage"]
   s.source        = { :git => 'https://github.com/cobrowseio/cobrowse-sdk-react-native.git' }
   s.platform      = :ios, '12.0'
-  s.dependency      'CobrowseIO/XCFramework', '3.13.5'
-  s.dependency      'React'
-  s.source_files =  'ios/*.{h,m}'
+  s.dependency      'CobrowseIO/XCFramework', '3.13.7'
+  s.source_files  = 'ios/**/*.{h,m,mm}'
+  
+  if defined?(install_modules_dependencies)
+    install_modules_dependencies(s)
+  else
+    s.dependency 'React'
+  end
 end

package/ios/RCTCobrowseIO.xcodeproj/project.pbxproj

@@ -11,6 +11,7 @@
 		A1368C9C237A2C7600728E42 /* CBIOCobrowseRedacted.m in Sources */ = {isa = PBXBuildFile; fileRef = A1368C9B237A2C7600728E42 /* CBIOCobrowseRedacted.m */; };
 		A1930DDD226FF9990011DF45 /* RCTTouchHandler+Touch.m in Sources */ = {isa = PBXBuildFile; fileRef = A1930DDC226FF9990011DF45 /* RCTTouchHandler+Touch.m */; };
 		A1BD99C6203105EA007F5AE5 /* RCTCobrowseIO.m in Sources */ = {isa = PBXBuildFile; fileRef = A1BD99C5203105E9007F5AE5 /* RCTCobrowseIO.m */; };
+		EFCB9C682F31677D003C9EEF /* RCTSurfaceTouchHandler+Touch.mm in Sources */ = {isa = PBXBuildFile; fileRef = EFCB9C672F31677D003C9EEF /* RCTSurfaceTouchHandler+Touch.mm */; };
 /* End PBXBuildFile section */
 
 /* Begin PBXCopyFilesBuildPhase section */
@@ -35,6 +36,8 @@
 		A1930DDC226FF9990011DF45 /* RCTTouchHandler+Touch.m */ = {isa = PBXFileReference; fileEncoding = 4; lastKnownFileType = sourcecode.c.objc; path = "RCTTouchHandler+Touch.m"; sourceTree = "<group>"; };
 		A19B6E3B2030F3FE00F6CF3B /* libRCTCobrowseIO.a */ = {isa = PBXFileReference; explicitFileType = archive.ar; includeInIndex = 0; path = libRCTCobrowseIO.a; sourceTree = BUILT_PRODUCTS_DIR; };
 		A1BD99C5203105E9007F5AE5 /* RCTCobrowseIO.m */ = {isa = PBXFileReference; fileEncoding = 4; lastKnownFileType = sourcecode.c.objc; path = RCTCobrowseIO.m; sourceTree = "<group>"; };
+		EFCB9C662F31677D003C9EEF /* RCTSurfaceTouchHandler+Touch.h */ = {isa = PBXFileReference; lastKnownFileType = sourcecode.c.h; path = "RCTSurfaceTouchHandler+Touch.h"; sourceTree = "<group>"; };
+		EFCB9C672F31677D003C9EEF /* RCTSurfaceTouchHandler+Touch.mm */ = {isa = PBXFileReference; lastKnownFileType = sourcecode.cpp.objcpp; path = "RCTSurfaceTouchHandler+Touch.mm"; sourceTree = "<group>"; };
 /* End PBXFileReference section */
 
 /* Begin PBXFrameworksBuildPhase section */
@@ -53,6 +56,8 @@
 			children = (
 				A1368C9E237A2C8E00728E42 /* RCTCobrowseIO.h */,
 				A1BD99C5203105E9007F5AE5 /* RCTCobrowseIO.m */,
+				EFCB9C662F31677D003C9EEF /* RCTSurfaceTouchHandler+Touch.h */,
+				EFCB9C672F31677D003C9EEF /* RCTSurfaceTouchHandler+Touch.mm */,
 				A1368C9D237A2C7F00728E42 /* CBIOCobrowseRedacted.h */,
 				A1368C9B237A2C7600728E42 /* CBIOCobrowseRedacted.m */,
 				A114D583203A2D1900B297FA /* CBIOSession+Bridging.h */,
@@ -130,6 +135,7 @@
 			files = (
 				A1930DDD226FF9990011DF45 /* RCTTouchHandler+Touch.m in Sources */,
 				A1BD99C6203105EA007F5AE5 /* RCTCobrowseIO.m in Sources */,
+				EFCB9C682F31677D003C9EEF /* RCTSurfaceTouchHandler+Touch.mm in Sources */,
 				A1368C9C237A2C7600728E42 /* CBIOCobrowseRedacted.m in Sources */,
 				A114D585203A2D1A00B297FA /* CBIOSession+Bridging.m in Sources */,
 			);

package/ios/RCTSurfaceTouchHandler+Touch.h

@@ -0,0 +1,20 @@
+#import <Foundation/Foundation.h>
+#import "CobrowseSDK/CBIOTouch.h"
+#import "CobrowseSDK/CBIOTouchEvent.h"
+
+#if __has_include("RCTSurfaceTouchHandler.h")
+  #import "RCTSurfaceTouchHandler.h"
+#elif __has_include(<React/RCTSurfaceTouchHandler.h>)
+  #import <React/RCTSurfaceTouchHandler.h>
+#elif __has_include(<React-RCTFabric/RCTSurfaceTouchHandler.h>)
+  #import <React-RCTFabric/RCTSurfaceTouchHandler.h>
+#else
+  #define CBIO_NO_SURFACE_TOUCH_HANDLER 1
+#endif
+
+#ifndef CBIO_NO_SURFACE_TOUCH_HANDLER
+
+@interface RCTSurfaceTouchHandler (Touch)
+@end
+
+#endif

package/ios/RCTSurfaceTouchHandler+Touch.mm

@@ -0,0 +1,258 @@
+#import <UIKit/UIKit.h>
+#import <UIKit/UIGestureRecognizerSubclass.h>
+#import <objc/runtime.h>
+#import "RCTSurfaceTouchHandler+Touch.h"
+
+// Check for RCTSurfaceTouchHandler availability
+#if __has_include("RCTSurfaceTouchHandler.h")
+  #import "RCTSurfaceTouchHandler.h"
+#elif __has_include(<React/RCTSurfaceTouchHandler.h>)
+  #import <React/RCTSurfaceTouchHandler.h>
+#elif __has_include(<React-RCTFabric/RCTSurfaceTouchHandler.h>)
+  #import <React-RCTFabric/RCTSurfaceTouchHandler.h>
+#else
+  #define CBIO_NO_SURFACE_TOUCH_HANDLER 1
+#endif
+
+#ifndef CBIO_NO_SURFACE_TOUCH_HANDLER
+
+// Check for Fabric C++ headers
+#if __has_include(<react/renderer/components/view/TouchEventEmitter.h>)
+  #import <react/renderer/components/view/TouchEventEmitter.h>
+#elif __has_include(<React-Fabric/react/renderer/components/view/TouchEventEmitter.h>)
+  #import <React-Fabric/react/renderer/components/view/TouchEventEmitter.h>
+#elif __has_include("react/renderer/components/view/TouchEventEmitter.h")
+  #import "react/renderer/components/view/TouchEventEmitter.h"
+#else
+  #define CBIO_NO_FABRIC_HEADERS 1
+#endif
+
+#ifndef CBIO_NO_FABRIC_HEADERS
+#include <exception>
+#endif
+
+#pragma mark - Logging
+
+static BOOL _supportWarningLogged = NO;
+
+static void logSupportWarning(NSString *issue) {
+    if (_supportWarningLogged) return;
+    _supportWarningLogged = YES;
+
+    NSLog(@"[Cobrowse WARNING] Fabric touch dispatch failed: %@. "
+          @"Please contact support@cobrowse.io with your React Native version.", issue);
+}
+
+#pragma mark - Helper Functions
+
+typedef NS_ENUM(NSInteger, CBIOFabricTouchPhase) {
+    CBIOFabricTouchPhaseStart,
+    CBIOFabricTouchPhaseMove,
+    CBIOFabricTouchPhaseEnd,
+    CBIOFabricTouchPhaseCancel
+};
+
+#ifndef CBIO_NO_FABRIC_HEADERS
+
+static SEL getEmitterSelector(void) {
+  static SEL sel;
+  static dispatch_once_t onceToken;
+  dispatch_once(&onceToken, ^{
+    sel = NSSelectorFromString(@"touchEventEmitterAtPoint:");
+  });
+  return sel;
+}
+
+// Walk up from the hit-tested view to find the nearest ancestor that
+// responds to touchEventEmitterAtPoint: (the "provider").
+//
+// In Fabric, touchEventEmitterAtPoint: is a simple getter that returns
+// the view's own _eventEmitter, so the provider IS the target — its tag
+// and coordinate space are used directly for the Touch struct.
+//
+// Simultaneously check whether we are inside a Fabric component subtree
+// at all, so we warn if the emitter API has been removed or renamed in 
+// a future RN version.
+static UIView * _Nullable findProvider(UIView *startView, BOOL *outSawFabric) {
+    SEL sel = getEmitterSelector();
+
+    static Protocol *componentViewProtocol = NSProtocolFromString(@"RCTComponentViewProtocol");
+
+    *outSawFabric = NO;
+
+    for (UIView *v = startView; v; v = v.superview) {
+        if (!*outSawFabric && componentViewProtocol && [v conformsToProtocol:componentViewProtocol]) *outSawFabric = YES;
+        if ([v respondsToSelector:sel]) {
+          return v;
+        }
+    }
+
+    return nil;
+}
+
+// Get the touch event emitter from a provider view.
+// In current Fabric, touchEventEmitterAtPoint: ignores the point
+// parameter and simply returns the view's own emitter. We still
+// pass the point for forward-compatibility.
+static facebook::react::SharedTouchEventEmitter getEventEmitter(UIView *provider, CGPoint screenPoint) {
+    SEL sel = getEmitterSelector();
+
+    CGPoint localPoint = [provider convertPoint:screenPoint fromView:nil];
+  
+    @try {
+        typedef facebook::react::SharedTouchEventEmitter (*GetEmitterIMP)(id, SEL, CGPoint);
+        GetEmitterIMP impl = (GetEmitterIMP)[provider methodForSelector:sel];
+
+        if (!impl) {
+            return nullptr;
+        }
+
+        return impl(provider, sel, localPoint);
+    } @catch (NSException *e) {
+        logSupportWarning([NSString stringWithFormat:@"Exception getting emitter: %@", e.reason]);
+        return nullptr;
+    }
+}
+
+static facebook::react::Touch createTouch(CGPoint screenPoint,
+                                           CGPoint localPoint,
+                                           NSInteger targetTag) {
+    facebook::react::Touch touch{};
+  
+    facebook::react::Point screen = {
+        static_cast<facebook::react::Float>(screenPoint.x),
+        static_cast<facebook::react::Float>(screenPoint.y)
+    };
+    touch.pagePoint = screen;
+    touch.screenPoint = screen;
+    touch.offsetPoint = {
+        static_cast<facebook::react::Float>(localPoint.x),
+        static_cast<facebook::react::Float>(localPoint.y)
+    };
+    
+    touch.identifier = 1;
+    touch.target = static_cast<facebook::react::Tag>(targetTag);
+
+    NSTimeInterval nowEpoch = [[NSDate date] timeIntervalSince1970];
+    NSTimeInterval nowUptime = [[NSProcessInfo processInfo] systemUptime];
+    touch.timestamp = (nowEpoch - nowUptime) + nowUptime;
+
+    touch.force = 1.0;
+
+    return touch;
+}
+
+#endif // !CBIO_NO_FABRIC_HEADERS
+
+#pragma mark - Category Implementation
+
+@implementation RCTSurfaceTouchHandler (Touch)
+
+- (BOOL)cobrowseDispatchEvent:(CBIOFabricTouchPhase)phase
+                  withTouches:(NSSet<CBIOTouch *> *)touches
+                    withEvent:(CBIOTouchEvent *)event {
+#ifndef CBIO_NO_FABRIC_HEADERS
+    // No multi-touch support yet
+    if (touches.count != 1) return NO;
+
+    CBIOTouch *touch = touches.anyObject;
+    UIView *hitView = touch.target;
+    CGPoint screenPoint = event.position;
+
+    BOOL sawFabric = NO;
+    UIView *provider = findProvider(hitView, &sawFabric);
+
+    if (!provider) {
+        if (sawFabric) {
+            logSupportWarning(@"Fabric component view detected, but no ancestor responds to touchEventEmitterAtPoint");
+        }
+        return NO;
+    }
+
+    // Get the emitter. ObjC messaging is wrapped in @try/@catch.
+    facebook::react::SharedTouchEventEmitter emitter = getEventEmitter(provider, screenPoint);
+    if (!emitter) return NO;
+  
+    NSInteger targetTag = provider.tag;
+    CGPoint localPoint = [provider convertPoint:screenPoint fromView:nil];
+
+    facebook::react::Touch t = createTouch(screenPoint, localPoint, targetTag);
+
+    facebook::react::TouchEvent touchEvent{};
+    facebook::react::Touches touchSet;
+    touchSet.insert(t);
+    facebook::react::Touches emptySet;
+
+    switch (phase) {
+        case CBIOFabricTouchPhaseStart:
+        case CBIOFabricTouchPhaseMove:
+            touchEvent.touches = touchSet;
+            touchEvent.changedTouches = touchSet;
+            touchEvent.targetTouches = touchSet;
+            break;
+
+        case CBIOFabricTouchPhaseEnd:
+        case CBIOFabricTouchPhaseCancel:
+            touchEvent.touches = emptySet;
+            touchEvent.changedTouches = touchSet;
+            touchEvent.targetTouches = emptySet;
+            break;
+
+        default:
+            return NO;
+    }
+
+#if defined(__cpp_exceptions)
+    try {
+#endif
+        switch (phase) {
+            case CBIOFabricTouchPhaseStart:  emitter->onTouchStart(touchEvent);  break;
+            case CBIOFabricTouchPhaseMove:   emitter->onTouchMove(touchEvent);   break;
+            case CBIOFabricTouchPhaseEnd:    emitter->onTouchEnd(touchEvent);    break;
+            case CBIOFabricTouchPhaseCancel: emitter->onTouchCancel(touchEvent); break;
+            default: return NO;
+        }
+        return YES;
+#if defined(__cpp_exceptions)
+    } catch (const std::exception &e) {
+        logSupportWarning([NSString stringWithFormat:
+            @"C++ exception dispatching touch: %s", e.what()]);
+        return NO;
+    } catch (...) {
+        logSupportWarning(@"Unknown C++ exception dispatching touch");
+        return NO;
+    }
+#endif
+
+#else
+    return NO;
+#endif
+}
+
+- (void)cobrowseTouchesBegan:(NSSet<CBIOTouch *> *)touches withEvent:(CBIOTouchEvent *)event {
+    if (![self cobrowseDispatchEvent:CBIOFabricTouchPhaseStart withTouches:touches withEvent:event]) return;
+
+    if (self.state == UIGestureRecognizerStatePossible) {
+        self.state = UIGestureRecognizerStateBegan;
+    }
+}
+
+- (void)cobrowseTouchesMoved:(NSSet<CBIOTouch *> *)touches withEvent:(CBIOTouchEvent *)event {
+    if (![self cobrowseDispatchEvent:CBIOFabricTouchPhaseMove withTouches:touches withEvent:event]) return;
+
+    self.state = UIGestureRecognizerStateChanged;
+}
+
+- (void)cobrowseTouchesEnded:(NSSet<CBIOTouch *> *)touches withEvent:(CBIOTouchEvent *)event {
+    [self cobrowseDispatchEvent:CBIOFabricTouchPhaseEnd withTouches:touches withEvent:event];
+    self.state = UIGestureRecognizerStateEnded;
+}
+
+- (void)cobrowseTouchesCancelled:(NSSet<CBIOTouch *> *)touches withEvent:(CBIOTouchEvent *)event {
+    [self cobrowseDispatchEvent:CBIOFabricTouchPhaseCancel withTouches:touches withEvent:event];
+    self.state = UIGestureRecognizerStateCancelled;
+}
+
+@end
+
+#endif // !CBIO_NO_SURFACE_TOUCH_HANDLER

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "cobrowse-sdk-react-native",
-  "version": "3.5.0",
+  "version": "3.6.0",
   "description": "Cobrowse SDK for React Native",
   "main": "lib/module/index",
   "module": "lib/module/index",