cloudx-react-native 2.0.0-beta.1

package/ios/RNCloudXBannerView.mm

@@ -0,0 +1,633 @@
+//
+//  RNCloudXBannerView.mm
+//  cloudx-react-native
+//
+
+#import "RNCloudXBannerView.h"
+#import <React/RCTLog.h>
+#import <CloudXCore/CLXError.h>
+
+#ifdef RCT_NEW_ARCH_ENABLED
+#import <react/renderer/components/RNCloudXSpec/ComponentDescriptors.h>
+#import <react/renderer/components/RNCloudXSpec/EventEmitters.h>
+#import <react/renderer/components/RNCloudXSpec/Props.h>
+#import <react/renderer/components/RNCloudXSpec/RCTComponentViewHelpers.h>
+#import <React/RCTConversions.h>
+#import "RCTFabricComponentsPlugins.h"
+using namespace facebook::react;
+#endif
+
+#ifdef RCT_NEW_ARCH_ENABLED
+@interface RNCloudXBannerView () <RCTCloudXAdViewViewProtocol>
+#else
+@interface RNCloudXBannerView ()
+#endif
+@property (nonatomic, strong) CLXBannerAdView *bannerAdView;
+@property (nonatomic, assign) BOOL hasCreatedAd;
+@property (nonatomic, assign) BOOL isUsingWindowPositioning;
+@end
+
+@implementation RNCloudXBannerView
+
+#ifdef RCT_NEW_ARCH_ENABLED
+
++ (ComponentDescriptorProvider)componentDescriptorProvider
+{
+    return concreteComponentDescriptorProvider<CloudXAdViewComponentDescriptor>();
+}
+
+- (instancetype)initWithFrame:(CGRect)frame
+{
+    self = [super initWithFrame:frame];
+    if (self) {
+        static const auto defaultProps = std::make_shared<const CloudXAdViewProps>();
+        _props = defaultProps;
+
+        const auto &initProps = *std::static_pointer_cast<CloudXAdViewProps const>(_props);
+        _hasCreatedAd = NO;
+        _isUsingWindowPositioning = NO;
+        _autoRefresh = initProps.autoRefresh;
+        _shouldLoad = initProps.loadOnMount;
+        self.backgroundColor = [UIColor clearColor];
+
+        [self setupEventHandlers];
+    }
+    return self;
+}
+
+- (void)setupEventHandlers
+{
+    self.onAdLoaded = [self](NSDictionary *event) {
+        if (_eventEmitter) {
+            auto emitter = std::static_pointer_cast<CloudXAdViewEventEmitter const>(_eventEmitter);
+            CloudXAdViewEventEmitter::OnAdLoaded result = {
+                .adUnitId = std::string([event[@"adUnitId"] ?: @"" UTF8String]),
+                .adFormat = std::string([event[@"adFormat"] ?: @"" UTF8String]),
+                .networkName = std::string([event[@"networkName"] ?: @"" UTF8String]),
+                .networkPlacement = std::string([event[@"networkPlacement"] ?: @"" UTF8String]),
+                .placement = std::string([event[@"placement"] ?: @"" UTF8String]),
+                .revenue = [event[@"revenue"] doubleValue],
+            };
+            emitter->onAdLoaded(result);
+        }
+    };
+
+    self.onAdLoadFailed = [self](NSDictionary *event) {
+        if (_eventEmitter) {
+            auto emitter = std::static_pointer_cast<CloudXAdViewEventEmitter const>(_eventEmitter);
+            CloudXAdViewEventEmitter::OnAdLoadFailed result = {
+                .adUnitId = std::string([event[@"adUnitId"] ?: @"" UTF8String]),
+                .code = [event[@"code"] intValue],
+                .message = std::string([event[@"message"] ?: @"" UTF8String]),
+            };
+            emitter->onAdLoadFailed(result);
+        }
+    };
+
+    self.onAdClicked = [self](NSDictionary *event) {
+        if (_eventEmitter) {
+            auto emitter = std::static_pointer_cast<CloudXAdViewEventEmitter const>(_eventEmitter);
+            CloudXAdViewEventEmitter::OnAdClicked result = {
+                .adUnitId = std::string([event[@"adUnitId"] ?: @"" UTF8String]),
+                .adFormat = std::string([event[@"adFormat"] ?: @"" UTF8String]),
+                .networkName = std::string([event[@"networkName"] ?: @"" UTF8String]),
+                .networkPlacement = std::string([event[@"networkPlacement"] ?: @"" UTF8String]),
+                .placement = std::string([event[@"placement"] ?: @"" UTF8String]),
+                .revenue = [event[@"revenue"] doubleValue],
+            };
+            emitter->onAdClicked(result);
+        }
+    };
+
+    self.onAdExpanded = [self](NSDictionary *event) {
+        if (_eventEmitter) {
+            auto emitter = std::static_pointer_cast<CloudXAdViewEventEmitter const>(_eventEmitter);
+            CloudXAdViewEventEmitter::OnAdExpanded result = {
+                .adUnitId = std::string([event[@"adUnitId"] ?: @"" UTF8String]),
+                .adFormat = std::string([event[@"adFormat"] ?: @"" UTF8String]),
+                .networkName = std::string([event[@"networkName"] ?: @"" UTF8String]),
+                .networkPlacement = std::string([event[@"networkPlacement"] ?: @"" UTF8String]),
+                .placement = std::string([event[@"placement"] ?: @"" UTF8String]),
+                .revenue = [event[@"revenue"] doubleValue],
+            };
+            emitter->onAdExpanded(result);
+        }
+    };
+
+    self.onAdCollapsed = [self](NSDictionary *event) {
+        if (_eventEmitter) {
+            auto emitter = std::static_pointer_cast<CloudXAdViewEventEmitter const>(_eventEmitter);
+            CloudXAdViewEventEmitter::OnAdCollapsed result = {
+                .adUnitId = std::string([event[@"adUnitId"] ?: @"" UTF8String]),
+                .adFormat = std::string([event[@"adFormat"] ?: @"" UTF8String]),
+                .networkName = std::string([event[@"networkName"] ?: @"" UTF8String]),
+                .networkPlacement = std::string([event[@"networkPlacement"] ?: @"" UTF8String]),
+                .placement = std::string([event[@"placement"] ?: @"" UTF8String]),
+                .revenue = [event[@"revenue"] doubleValue],
+            };
+            emitter->onAdCollapsed(result);
+        }
+    };
+
+    self.onAdRevenuePaid = [self](NSDictionary *event) {
+        if (_eventEmitter) {
+            auto emitter = std::static_pointer_cast<CloudXAdViewEventEmitter const>(_eventEmitter);
+            CloudXAdViewEventEmitter::OnAdRevenuePaid result = {
+                .adUnitId = std::string([event[@"adUnitId"] ?: @"" UTF8String]),
+                .adFormat = std::string([event[@"adFormat"] ?: @"" UTF8String]),
+                .networkName = std::string([event[@"networkName"] ?: @"" UTF8String]),
+                .networkPlacement = std::string([event[@"networkPlacement"] ?: @"" UTF8String]),
+                .placement = std::string([event[@"placement"] ?: @"" UTF8String]),
+                .revenue = [event[@"revenue"] doubleValue],
+            };
+            emitter->onAdRevenuePaid(result);
+        }
+    };
+}
+
+- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps
+{
+    const auto &oldViewProps = *std::static_pointer_cast<CloudXAdViewProps const>(_props);
+    const auto &newViewProps = *std::static_pointer_cast<CloudXAdViewProps const>(props);
+
+    BOOL adUnitIdChanged = NO;
+
+    if (oldViewProps.adUnitId != newViewProps.adUnitId) {
+        [self setAdId:RCTNSStringFromString(newViewProps.adUnitId)];
+        adUnitIdChanged = YES;
+    }
+
+    if (oldViewProps.adFormat != newViewProps.adFormat) {
+        [self setBannerSize:RCTNSStringFromString(newViewProps.adFormat)];
+    }
+
+    if (oldViewProps.placement != newViewProps.placement) {
+        [self setPlacement:RCTNSStringFromString(newViewProps.placement)];
+    }
+
+    if (oldViewProps.customData != newViewProps.customData) {
+        [self setCustomData:RCTNSStringFromString(newViewProps.customData)];
+    }
+
+    if (oldViewProps.autoRefresh != newViewProps.autoRefresh) {
+        [self setAutoRefresh:newViewProps.autoRefresh];
+    }
+
+    if (oldViewProps.loadOnMount != newViewProps.loadOnMount) {
+        [self setShouldLoad:newViewProps.loadOnMount];
+    }
+
+    if (oldViewProps.adPosition != newViewProps.adPosition) {
+        [self setAdPosition:RCTNSStringFromString(newViewProps.adPosition)];
+    }
+
+    if (adUnitIdChanged) {
+        [self attemptLoadIfReady];
+    }
+
+    [super updateProps:props oldProps:oldProps];
+}
+
+- (void)handleCommand:(const NSString *)commandName args:(const NSArray *)args
+{
+    if ([commandName isEqualToString:@"loadAd"]) {
+        [self loadAd];
+    } else if ([commandName isEqualToString:@"destroy"]) {
+        [self destroyAd];
+    }
+}
+
+- (void)prepareForRecycle
+{
+    [super prepareForRecycle];
+
+    static const auto defaultProps = std::make_shared<const CloudXAdViewProps>();
+    _props = defaultProps;
+
+    [self destroyAd];
+
+    _adId = nil;
+    _bannerSize = nil;
+    _adPosition = nil;
+    _placement = nil;
+    _customData = nil;
+    _hasCreatedAd = NO;
+    _isUsingWindowPositioning = NO;
+    _autoRefresh = NO;
+    _shouldLoad = NO;
+}
+
+#else
+
+- (instancetype)init {
+    if (self = [super init]) {
+        _hasCreatedAd = NO;
+        _isUsingWindowPositioning = NO;
+        _autoRefresh = YES;
+        self.backgroundColor = [UIColor clearColor];
+    }
+    return self;
+}
+
+#endif
+
+// Dispatch to main queue -- dealloc may run on arbitrary threads
+- (void)dealloc {
+    CLXBannerAdView *adView = _bannerAdView;
+    BOOL needsWindowRemoval = _isUsingWindowPositioning;
+    if (adView) {
+        dispatch_async(dispatch_get_main_queue(), ^{
+            adView.delegate = nil;
+            adView.revenueDelegate = nil;
+            [adView stopAutoRefresh];
+            if (needsWindowRemoval) [adView removeFromSuperview];
+            [adView destroy];
+        });
+    }
+}
+
+#pragma mark - Position Helpers
+
+- (RNCloudXAdViewPosition)positionFromString:(NSString *)positionString {
+    if (!positionString || positionString.length == 0) {
+        return RNCloudXAdViewPositionNone;
+    }
+    
+    NSDictionary *positionMap = @{
+        @"TOP_LEFT": @(RNCloudXAdViewPositionTopLeft),
+        @"TOP_CENTER": @(RNCloudXAdViewPositionTopCenter),
+        @"TOP_RIGHT": @(RNCloudXAdViewPositionTopRight),
+        @"CENTER_LEFT": @(RNCloudXAdViewPositionCenterLeft),
+        @"CENTERED": @(RNCloudXAdViewPositionCentered),
+        @"CENTER_RIGHT": @(RNCloudXAdViewPositionCenterRight),
+        @"BOTTOM_LEFT": @(RNCloudXAdViewPositionBottomLeft),
+        @"BOTTOM_CENTER": @(RNCloudXAdViewPositionBottomCenter),
+        @"BOTTOM_RIGHT": @(RNCloudXAdViewPositionBottomRight),
+    };
+    
+    NSNumber *position = positionMap[positionString.uppercaseString];
+    return position ? (RNCloudXAdViewPosition)position.integerValue : RNCloudXAdViewPositionNone;
+}
+
+- (void)setShouldLoad:(BOOL)shouldLoad {
+    _shouldLoad = shouldLoad;
+    [self attemptLoadIfReady];
+}
+
+- (void)setAdId:(NSString *)adId {
+    _adId = adId;
+    [self attemptLoadIfReady];
+}
+
+- (void)setPlacement:(NSString *)placement {
+    _placement = placement;
+    if (self.bannerAdView) {
+        self.bannerAdView.placement = placement;
+    }
+    [self attemptLoadIfReady];
+}
+
+- (void)setCustomData:(NSString *)customData {
+    _customData = customData;
+    if (self.bannerAdView) {
+        self.bannerAdView.customData = customData;
+    }
+}
+
+// Destroy and recreate if format changed on an already-mounted ad,
+// since banner and MREC use different native SDK creation methods.
+- (void)setBannerSize:(NSString *)bannerSize {
+    NSString *oldSize = _bannerSize;
+    _bannerSize = [bannerSize copy];
+    if (self.hasCreatedAd && oldSize != nil && ![oldSize isEqualToString:bannerSize]) {
+        [self destroyAd];
+        [self attemptLoadIfReady];
+    }
+}
+
+- (void)setAutoRefresh:(BOOL)autoRefresh {
+    _autoRefresh = autoRefresh;
+    if (self.bannerAdView) {
+        if (autoRefresh) {
+            [self.bannerAdView startAutoRefresh];
+        } else {
+            [self.bannerAdView stopAutoRefresh];
+        }
+    }
+}
+
+- (void)didSetProps:(NSArray<NSString *> *)changedProps {
+    [self attemptLoadIfReady];
+}
+
+- (void)attemptLoadIfReady {
+    if (self.shouldLoad && !self.hasCreatedAd && self.adId) {
+        dispatch_async(dispatch_get_main_queue(), ^{
+            if (!self.hasCreatedAd) {
+                [self createAndLoadBanner];
+            }
+        });
+    }
+}
+
+- (void)loadAd {
+    if (self.bannerAdView) {
+        [self.bannerAdView load];
+    }
+}
+
+- (void)destroyAd {
+    if (self.bannerAdView) {
+        self.bannerAdView.delegate = nil;
+        self.bannerAdView.revenueDelegate = nil;
+        [self.bannerAdView stopAutoRefresh];
+        if (self.isUsingWindowPositioning) {
+            [self.bannerAdView removeFromSuperview];
+        }
+        [self.bannerAdView destroy];
+        self.bannerAdView = nil;
+        self.hasCreatedAd = NO;
+    }
+}
+
+- (void)createAndLoadBanner {
+    if (self.hasCreatedAd) {
+        return;
+    }
+    
+    UIViewController *viewController = [self reactViewController];
+    if (!viewController) {
+        RCTLogError(@"[CloudXBannerView] No view controller found");
+        if (self.onAdLoadFailed) {
+            self.onAdLoadFailed(@{
+                @"adUnitId": self.adId ?: @"",
+                @"code": @(-1),
+                @"message": @"No view controller"
+            });
+        }
+        return;
+    }
+    
+    // Determine if this is a banner or MREC
+    BOOL isMREC = [self.bannerSize isEqualToString:@"MREC"];
+    
+    NSString *adUnitId = self.adId;
+    if (isMREC) {
+        self.bannerAdView = [[CloudXCore shared] createMRECWithAdUnitId:adUnitId
+                                                         viewController:viewController];
+    } else {
+        self.bannerAdView = [[CloudXCore shared] createBannerWithAdUnitId:adUnitId
+                                                           viewController:viewController];
+    }
+    if (self.bannerAdView) {
+        self.bannerAdView.delegate = self;
+        self.bannerAdView.revenueDelegate = self;
+        if (self.placement) {
+            self.bannerAdView.placement = self.placement;
+        }
+        if (self.customData) {
+            self.bannerAdView.customData = self.customData;
+        }
+        if (!self.autoRefresh) {
+            [self.bannerAdView stopAutoRefresh];
+        }
+
+        self.hasCreatedAd = YES;
+        
+        // Check if we should use programmatic window positioning
+        RNCloudXAdViewPosition adViewPosition = [self positionFromString:self.adPosition];
+        
+        if (adViewPosition != RNCloudXAdViewPositionNone) {
+            [self addBannerToWindowWithPosition:adViewPosition isMREC:isMREC];
+        } else {
+            [self addBannerAsSubview];
+        }
+        
+        [self.bannerAdView load];
+    } else {
+        RCTLogError(@"[CloudXBannerView] Failed to create banner");
+        if (self.onAdLoadFailed) {
+            self.onAdLoadFailed(@{
+                @"adUnitId": self.adId ?: @"",
+                @"code": @(-1),
+                @"message": @"Failed to create banner"
+            });
+        }
+    }
+}
+
+- (void)addBannerAsSubview {
+    self.isUsingWindowPositioning = NO;
+    self.bannerAdView.translatesAutoresizingMaskIntoConstraints = NO;
+    [self addSubview:self.bannerAdView];
+    
+    // Setup constraints to fill container
+    [NSLayoutConstraint activateConstraints:@[
+        [self.bannerAdView.topAnchor constraintEqualToAnchor:self.topAnchor],
+        [self.bannerAdView.leftAnchor constraintEqualToAnchor:self.leftAnchor],
+        [self.bannerAdView.rightAnchor constraintEqualToAnchor:self.rightAnchor],
+        [self.bannerAdView.bottomAnchor constraintEqualToAnchor:self.bottomAnchor]
+    ]];
+}
+
+- (void)addBannerToWindowWithPosition:(RNCloudXAdViewPosition)position isMREC:(BOOL)isMREC {
+    self.isUsingWindowPositioning = YES;
+    
+    UIWindow *keyWindow = [self keyWindow];
+    if (!keyWindow) {
+        RCTLogError(@"[CloudXBannerView] No key window found for positioning");
+        [self addBannerAsSubview]; // Fallback to React Native layout
+        return;
+    }
+    
+    self.bannerAdView.translatesAutoresizingMaskIntoConstraints = NO;
+    [keyWindow addSubview:self.bannerAdView];
+    
+    // Banner dimensions
+    BOOL isTablet = (UIDevice.currentDevice.userInterfaceIdiom == UIUserInterfaceIdiomPad);
+    CGFloat bannerWidth = isMREC ? 300 : (isTablet ? 728 : 320);
+    CGFloat bannerHeight = isMREC ? 250 : (isTablet ? 90 : 50);
+    
+    // Get safe area insets
+    UIEdgeInsets safeArea = UIEdgeInsetsZero;
+    if (@available(iOS 11.0, *)) {
+        safeArea = keyWindow.safeAreaInsets;
+    }
+    
+    // Size constraints
+    [NSLayoutConstraint activateConstraints:@[
+        [self.bannerAdView.widthAnchor constraintEqualToConstant:bannerWidth],
+        [self.bannerAdView.heightAnchor constraintEqualToConstant:bannerHeight]
+    ]];
+    
+    // Position constraints based on specified position
+    switch (position) {
+        case RNCloudXAdViewPositionTopLeft:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.topAnchor constraintEqualToAnchor:keyWindow.topAnchor constant:safeArea.top],
+                [self.bannerAdView.leftAnchor constraintEqualToAnchor:keyWindow.leftAnchor constant:safeArea.left]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionTopCenter:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.topAnchor constraintEqualToAnchor:keyWindow.topAnchor constant:safeArea.top],
+                [self.bannerAdView.centerXAnchor constraintEqualToAnchor:keyWindow.centerXAnchor]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionTopRight:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.topAnchor constraintEqualToAnchor:keyWindow.topAnchor constant:safeArea.top],
+                [self.bannerAdView.rightAnchor constraintEqualToAnchor:keyWindow.rightAnchor constant:-safeArea.right]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionCenterLeft:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.centerYAnchor constraintEqualToAnchor:keyWindow.centerYAnchor],
+                [self.bannerAdView.leftAnchor constraintEqualToAnchor:keyWindow.leftAnchor constant:safeArea.left]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionCentered:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.centerXAnchor constraintEqualToAnchor:keyWindow.centerXAnchor],
+                [self.bannerAdView.centerYAnchor constraintEqualToAnchor:keyWindow.centerYAnchor]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionCenterRight:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.centerYAnchor constraintEqualToAnchor:keyWindow.centerYAnchor],
+                [self.bannerAdView.rightAnchor constraintEqualToAnchor:keyWindow.rightAnchor constant:-safeArea.right]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionBottomLeft:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.bottomAnchor constraintEqualToAnchor:keyWindow.bottomAnchor constant:-safeArea.bottom],
+                [self.bannerAdView.leftAnchor constraintEqualToAnchor:keyWindow.leftAnchor constant:safeArea.left]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionBottomCenter:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.bottomAnchor constraintEqualToAnchor:keyWindow.bottomAnchor constant:-safeArea.bottom],
+                [self.bannerAdView.centerXAnchor constraintEqualToAnchor:keyWindow.centerXAnchor]
+            ]];
+            break;
+            
+        case RNCloudXAdViewPositionBottomRight:
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.bottomAnchor constraintEqualToAnchor:keyWindow.bottomAnchor constant:-safeArea.bottom],
+                [self.bannerAdView.rightAnchor constraintEqualToAnchor:keyWindow.rightAnchor constant:-safeArea.right]
+            ]];
+            break;
+            
+        default:
+            // Should not reach here, but fallback to bottom center
+            [NSLayoutConstraint activateConstraints:@[
+                [self.bannerAdView.bottomAnchor constraintEqualToAnchor:keyWindow.bottomAnchor constant:-safeArea.bottom],
+                [self.bannerAdView.centerXAnchor constraintEqualToAnchor:keyWindow.centerXAnchor]
+            ]];
+            break;
+    }
+}
+
+- (UIWindow *)keyWindow {
+    if (@available(iOS 13.0, *)) {
+        for (UIWindowScene *scene in UIApplication.sharedApplication.connectedScenes) {
+            if (scene.activationState == UISceneActivationStateForegroundActive) {
+                for (UIWindow *window in scene.windows) {
+                    if (window.isKeyWindow) {
+                        return window;
+                    }
+                }
+            }
+        }
+    }
+    
+    // Fallback for iOS 12 and earlier
+#pragma clang diagnostic push
+#pragma clang diagnostic ignored "-Wdeprecated-declarations"
+    return UIApplication.sharedApplication.keyWindow;
+#pragma clang diagnostic pop
+}
+
+#pragma mark - Helper
+
+- (UIViewController *)reactViewController {
+    UIResponder *responder = self;
+    while (responder) {
+        if ([responder isKindOfClass:[UIViewController class]]) {
+            return (UIViewController *)responder;
+        }
+        responder = [responder nextResponder];
+    }
+    return nil;
+}
+
+#pragma mark - CLXBannerDelegate
+
+- (void)didLoadAd:(CLXAd *)ad {
+    NSDictionary *event = [self serializeAdEvent:ad];
+    if (self.onAdLoaded) {
+        self.onAdLoaded(event);
+    }
+}
+
+- (void)didFailToLoadAd:(NSString *)adUnitId error:(CLXError *)error {
+    RCTLogError(@"[CloudXBannerView] Banner failed to load: %@", error.localizedDescription);
+    NSDictionary *event = @{
+        @"adUnitId": adUnitId ?: self.adId ?: @"",
+        @"code": @(error.code),
+        @"message": error.localizedDescription ?: @"Unknown error"
+    };
+    if (self.onAdLoadFailed) {
+        self.onAdLoadFailed(event);
+    }
+}
+
+- (void)didClickAd:(CLXAd *)ad {
+    NSDictionary *event = [self serializeAdEvent:ad];
+    if (self.onAdClicked) {
+        self.onAdClicked(event);
+    }
+}
+
+- (void)didPayRevenueForAd:(CLXAd *)ad {
+    NSDictionary *event = [self serializeAdEvent:ad];
+    if (self.onAdRevenuePaid) {
+        self.onAdRevenuePaid(event);
+    }
+}
+
+- (void)didExpandAd:(CLXAd *)ad {
+    NSDictionary *event = [self serializeAdEvent:ad];
+    if (self.onAdExpanded) {
+        self.onAdExpanded(event);
+    }
+}
+
+- (void)didCollapseAd:(CLXAd *)ad {
+    NSDictionary *event = [self serializeAdEvent:ad];
+    if (self.onAdCollapsed) {
+        self.onAdCollapsed(event);
+    }
+}
+
+#pragma mark - Serialization Helper
+
+- (NSDictionary *)serializeAdEvent:(CLXAd *)ad {
+    NSMutableDictionary *eventData = [NSMutableDictionary dictionary];
+    eventData[@"adUnitId"] = ad.adUnitId ?: self.adId ?: @"";
+    eventData[@"adFormat"] = [self.bannerSize isEqualToString:@"MREC"] ? @"MREC" : @"BANNER";
+    eventData[@"networkName"] = ad.networkName ?: @"";
+    eventData[@"networkPlacement"] = ad.networkPlacement ?: @"";
+    eventData[@"placement"] = ad.placement ?: self.placement ?: @"";
+    eventData[@"revenue"] = ad.revenue ? @([ad.revenue doubleValue]) : @(0);
+    return eventData;
+}
+
+@end

package/ios/RNCloudXBannerViewManager.h

@@ -0,0 +1,11 @@
+//
+//  RNCloudXBannerViewManager.h
+//  cloudx-react-native
+//
+
+#import <React/RCTViewManager.h>
+
+@interface RNCloudXBannerViewManager : RCTViewManager
+
+@end
+

package/ios/RNCloudXBannerViewManager.mm

@@ -0,0 +1,60 @@
+//
+//  RNCloudXBannerViewManager.m
+//  cloudx-react-native
+//
+
+#import "RNCloudXBannerViewManager.h"
+#import "RNCloudXBannerView.h"
+#import <React/RCTUIManager.h>
+
+@implementation RNCloudXBannerViewManager
+
+RCT_EXPORT_MODULE(CloudXAdView)
+
+- (UIView *)view {
+    return [[RNCloudXBannerView alloc] init];
+}
+
+// Props matching the codegen spec (CloudXAdViewNativeComponent.ts)
+// Remap JS prop names to native ObjC property names where they differ
+RCT_REMAP_VIEW_PROPERTY(adUnitId, adId, NSString)
+RCT_REMAP_VIEW_PROPERTY(adFormat, bannerSize, NSString)
+RCT_REMAP_VIEW_PROPERTY(loadOnMount, shouldLoad, BOOL)
+RCT_EXPORT_VIEW_PROPERTY(placement, NSString)
+RCT_EXPORT_VIEW_PROPERTY(customData, NSString)
+RCT_EXPORT_VIEW_PROPERTY(autoRefresh, BOOL)
+RCT_EXPORT_VIEW_PROPERTY(adPosition, NSString)
+RCT_EXPORT_VIEW_PROPERTY(onAdLoaded, RCTDirectEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onAdLoadFailed, RCTDirectEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onAdClicked, RCTDirectEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onAdExpanded, RCTDirectEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onAdCollapsed, RCTDirectEventBlock)
+RCT_EXPORT_VIEW_PROPERTY(onAdRevenuePaid, RCTDirectEventBlock)
+
++ (BOOL)requiresMainQueueSetup {
+    return YES;
+}
+
+#pragma mark - Native Commands
+
+- (void)receiveCommand:(UIView *)view commandName:(NSString *)commandName args:(NSArray *)args {
+    RNCloudXBannerView *bannerView = (RNCloudXBannerView *)view;
+    if ([commandName isEqualToString:@"loadAd"]) {
+        [bannerView loadAd];
+    } else if ([commandName isEqualToString:@"destroy"]) {
+        [bannerView destroyAd];
+    }
+}
+
+@end
+
+#ifdef RCT_NEW_ARCH_ENABLED
+#import <React/RCTComponentViewProtocol.h>
+#import "RNCloudXBannerView.h"
+
+extern "C" Class<RCTComponentViewProtocol> CloudXAdViewCls(void)
+{
+    return [RNCloudXBannerView class];
+}
+#endif
+