cgraphx 2.0.2 → 2.0.6

package/dist/core/code/engine/core/ingestion/languages/cpp/query.js

@@ -0,0 +1,763 @@
+"use strict";
+var __importDefault = (this && this.__importDefault) || function (mod) {
+    return (mod && mod.__esModule) ? mod : { "default": mod };
+};
+Object.defineProperty(exports, "__esModule", { value: true });
+exports.getCppParser = getCppParser;
+exports.getCppScopeQuery = getCppScopeQuery;
+const tree_sitter_1 = __importDefault(require("tree-sitter"));
+const node_module_1 = require("node:module");
+// 懒加载(spec §7/§13):tree-sitter-cpp 移至 devDependencies,生产 --omit=dev 不装。
+// 首次用到时按需 require + 缓存;失败 → null,该语言降级为结构层收录,不阻断 analyze。
+const _require = (0, node_module_1.createRequire)(__filename);
+let _cppGrammar;
+const loadCppGrammar = () => {
+    if (_cppGrammar !== undefined)
+        return _cppGrammar;
+    try {
+        _cppGrammar = _require('tree-sitter-cpp');
+    }
+    catch {
+        _cppGrammar = null;
+    }
+    return _cppGrammar;
+};
+const CPP_SCOPE_QUERY = `
+;; ─── Scopes ──────────────────────────────────────────────────────────
+(translation_unit) @scope.module
+(namespace_definition) @scope.namespace
+(class_specifier) @scope.class
+(struct_specifier) @scope.class
+(function_definition) @scope.function
+(lambda_expression) @scope.function
+(compound_statement) @scope.block
+(if_statement) @scope.block
+(for_statement) @scope.block
+(for_range_loop) @scope.block
+(while_statement) @scope.block
+(do_statement) @scope.block
+(switch_statement) @scope.block
+(case_statement) @scope.block
+(try_statement) @scope.block
+(catch_clause) @scope.block
+
+;; ─── Declarations — namespace ────────────────────────────────────────
+(namespace_definition
+  name: (namespace_identifier) @declaration.name) @declaration.namespace
+
+;; Anonymous namespace (no name child) — captured as scope only, names
+;; inside are marked file-local by captures.ts.
+
+;; ─── Declarations — class / struct (named) ───────────────────────────
+(class_specifier
+  name: (type_identifier) @declaration.name
+  body: (field_declaration_list)) @declaration.class
+
+(class_specifier
+  name: (template_type
+    (type_identifier) @declaration.name
+    (template_argument_list) @declaration.template-arguments)
+  body: (field_declaration_list)) @declaration.class
+
+(struct_specifier
+  name: (type_identifier) @declaration.name
+  body: (field_declaration_list)) @declaration.struct
+
+(struct_specifier
+  name: (template_type
+    (type_identifier) @declaration.name
+    (template_argument_list) @declaration.template-arguments)
+  body: (field_declaration_list)) @declaration.struct
+
+;; Declarations — struct (typedef struct { ... } Name)
+(type_definition
+  type: (struct_specifier
+    body: (field_declaration_list))
+  declarator: (type_identifier) @declaration.name) @declaration.struct
+
+;; ─── Declarations — class / struct inside template_declaration ───────
+;; \`parameters:\` is the DECLARED parameter list (\`template <class T>\`), which
+;; lives on the template_declaration and not on the specifier — the opposite
+;; nesting from \`@declaration.template-arguments\` above, which is part of the
+;; specifier's own NAME. A partial specialization carries both, and that pairing
+;; is the only thing separating it from a full specialization written against
+;; the identical arguments.
+;;
+;; These four patterns are TWINS of the four standalone specifier patterns
+;; above: a templated struct matches both, minting two defs with one id, and
+;; only this half can see the parameter list. The duplicate-declaration backfill
+;; in scope-extractor.ts is what stops match order from deciding which twin
+;; keeps the parameters.
+(template_declaration
+  parameters: (template_parameter_list) @declaration.type-parameters
+  (class_specifier
+    name: (type_identifier) @declaration.name
+    body: (field_declaration_list)) @declaration.class)
+
+(template_declaration
+  parameters: (template_parameter_list) @declaration.type-parameters
+  (class_specifier
+    name: (template_type
+      (type_identifier) @declaration.name
+      (template_argument_list) @declaration.template-arguments)
+    body: (field_declaration_list)) @declaration.class)
+
+(template_declaration
+  parameters: (template_parameter_list) @declaration.type-parameters
+  (struct_specifier
+    name: (type_identifier) @declaration.name
+    body: (field_declaration_list)) @declaration.struct)
+
+(template_declaration
+  parameters: (template_parameter_list) @declaration.type-parameters
+  (struct_specifier
+    name: (template_type
+      (type_identifier) @declaration.name
+      (template_argument_list) @declaration.template-arguments)
+    body: (field_declaration_list)) @declaration.struct)
+
+;; ─── Declarations — enum ─────────────────────────────────────────────
+(enum_specifier
+  name: (type_identifier) @declaration.name) @declaration.enum
+
+;; ─── Declarations — enum (typedef enum { ... } Name) ─────────────────
+(type_definition
+  type: (enum_specifier
+    body: (enumerator_list))
+  declarator: (type_identifier) @declaration.name) @declaration.enum
+
+;; ─── Declarations — enum constants ───────────────────────────────────
+(enumerator
+  name: (identifier) @declaration.name) @declaration.const
+
+;; ─── Declarations — function definition (plain identifier) ──────────
+(function_definition
+  declarator: (function_declarator
+    declarator: (identifier) @declaration.name)) @declaration.function
+
+;; Lambda bindings (\`auto f = [](int x){ … };\`). The \`@declaration.function\`
+;; anchor sits on the INNER lambda_expression so its range aligns with
+;; \`(lambda_expression) @scope.function\` above; otherwise the def is owned by
+;; the enclosing scope and calls inside the lambda lose caller attribution.
+;; Mirrors the TypeScript arrow patterns (#2687).
+(declaration
+  declarator: (init_declarator
+    declarator: (identifier) @declaration.name
+    value: (lambda_expression) @declaration.function))
+
+;; ─── Declarations — function definition with pointer return ─────────
+(function_definition
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (identifier) @declaration.name))) @declaration.function
+
+;; ─── Declarations — out-of-class method (qualified_identifier) ──────
+(function_definition
+  declarator: (function_declarator
+    declarator: (qualified_identifier
+      name: (identifier) @declaration.name))) @declaration.method
+
+;; Out-of-class operator method: Point::operator+(...)
+(function_definition
+  declarator: (function_declarator
+    declarator: (qualified_identifier
+      name: (operator_name) @declaration.name))) @declaration.method
+
+;; ─── Declarations — out-of-class method with pointer return ─────────
+(function_definition
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (qualified_identifier
+        name: (identifier) @declaration.name)))) @declaration.method
+
+;; ─── Declarations — out-of-class method (destructor_name) ───────────
+(function_definition
+  declarator: (function_declarator
+    declarator: (qualified_identifier
+      name: (destructor_name) @declaration.name))) @declaration.method
+
+;; ─── Declarations — template function definition ────────────────────
+(template_declaration
+  (function_definition
+    declarator: (function_declarator
+      declarator: (identifier) @declaration.name)) @declaration.function)
+
+;; ─── Declarations — template method (qualified) ─────────────────────
+(template_declaration
+  (function_definition
+    declarator: (function_declarator
+      declarator: (qualified_identifier
+        name: (identifier) @declaration.name))) @declaration.method)
+
+;; ─── Declarations — inline method in class body (field_identifier) ──
+;; tree-sitter-cpp uses field_identifier for names inside class bodies
+(function_definition
+  declarator: (function_declarator
+    declarator: (field_identifier) @declaration.name)) @declaration.method
+
+;; Inline operator method in class body: Point operator+(Point) const { ... }
+(function_definition
+  declarator: (function_declarator
+    declarator: (operator_name) @declaration.name)) @declaration.method
+
+;; ─── Declarations — inline method with pointer return (field_identifier) ──
+;; Covers: User* lookup(int id) { ... } inside a class body
+;; AST: function_definition > pointer_declarator > function_declarator > field_identifier
+(function_definition
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (field_identifier) @declaration.name))) @declaration.method
+
+;; ─── Declarations — inline method with reference return (field_identifier) ──
+;; Covers: User& getRef() { ... } inside a class body
+(function_definition
+  declarator: (reference_declarator
+    (function_declarator
+      declarator: (field_identifier) @declaration.name))) @declaration.method
+
+;; Inline operator method with reference return: Point& operator+=(Point) { ... }
+(field_declaration_list
+  (function_definition
+    declarator: (reference_declarator
+      (function_declarator
+        declarator: (operator_name) @declaration.name))) @declaration.method)
+
+;; Free operator definition with reference return: std::ostream& operator<<(...) { ... }
+(translation_unit
+  (function_definition
+    declarator: (reference_declarator
+      (function_declarator
+        declarator: (operator_name) @declaration.name))) @declaration.function)
+
+(namespace_definition
+  body: (declaration_list
+    (function_definition
+      declarator: (reference_declarator
+        (function_declarator
+          declarator: (operator_name) @declaration.name))) @declaration.function))
+
+;; ─── Declarations — function prototype (forward declaration) ────────
+(declaration
+  declarator: (function_declarator
+    declarator: (identifier) @declaration.name)) @declaration.function
+
+;; tree-sitter-cpp 0.23 represents a deleted free function as an
+;; init_declarator whose value is a delete_expression.
+(declaration
+  declarator: (init_declarator
+    declarator: (function_declarator
+      declarator: (identifier) @declaration.name)
+    value: (delete_expression))) @declaration.function
+
+;; Deleted free operator declaration.
+(declaration
+  declarator: (init_declarator
+    declarator: (function_declarator
+      declarator: (operator_name) @declaration.name)
+    value: (delete_expression))) @declaration.function
+
+;; Deleted free function with a pointer return type.
+(declaration
+  declarator: (init_declarator
+    declarator: (pointer_declarator
+      declarator: (function_declarator
+        declarator: (identifier) @declaration.name))
+    value: (delete_expression))) @declaration.function
+
+;; Free operator prototype: std::ostream& operator<<(std::ostream&, T)
+(declaration
+  declarator: (function_declarator
+    declarator: (operator_name) @declaration.name)) @declaration.function
+
+;; ─── Declarations — function prototype with pointer return ──────────
+(declaration
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (identifier) @declaration.name))) @declaration.function
+
+;; Free operator prototype with reference return.
+(declaration
+  declarator: (reference_declarator
+    (function_declarator
+      declarator: (operator_name) @declaration.name))) @declaration.function
+
+;; ─── Declarations — typedef ─────────────────────────────────────────
+(type_definition
+  declarator: (type_identifier) @declaration.name) @declaration.typedef
+
+;; ─── Declarations — type alias (using Name = Type) ──────────────────
+(alias_declaration
+  name: (type_identifier) @declaration.name) @declaration.typedef
+
+;; ─── Declarations — method prototype in class body (forward decl) ────
+;; Covers: class User { void save(); std::string getName(); };
+;; AST: field_declaration > function_declarator > field_identifier
+(field_declaration
+  declarator: (function_declarator
+    declarator: (field_identifier) @declaration.name)) @declaration.method
+
+;; Operator method prototype in class body: Point operator+(Point) const;
+(field_declaration
+  declarator: (function_declarator
+    declarator: (operator_name) @declaration.name)) @declaration.method
+
+;; Method prototype with pointer return: User* lookup(int id);
+(field_declaration
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (field_identifier) @declaration.name))) @declaration.method
+
+;; Constructor prototype in class body: User(int id);
+(field_declaration_list
+  (declaration
+    declarator: (function_declarator
+      declarator: (identifier) @declaration.name)) @declaration.method)
+
+;; Method prototype with reference return: User& getRef();
+(field_declaration
+  declarator: (reference_declarator
+    (function_declarator
+      declarator: (field_identifier) @declaration.name))) @declaration.method
+
+(field_declaration
+  declarator: (reference_declarator
+    (function_declarator
+      declarator: (operator_name) @declaration.name))) @declaration.method
+
+;; ─── Declarations — fields ──────────────────────────────────────────
+(field_declaration
+  declarator: (field_identifier) @declaration.name) @declaration.field
+
+;; Declarations — fields (pointer)
+(field_declaration
+  declarator: (pointer_declarator
+    declarator: (field_identifier) @declaration.name)) @declaration.field
+
+;; Declarations — fields (reference)
+(field_declaration
+  declarator: (reference_declarator
+    (field_identifier) @declaration.name)) @declaration.field
+
+;; ─── Declarations — variables (with initializer) ────────────────────
+(declaration
+  declarator: (init_declarator
+    declarator: (identifier) @declaration.name)) @declaration.variable
+
+;; ─── Declarations — variables (without initializer) ─────────────────
+;; Covers non-leading declarators in mixed declaration lists.
+(declaration
+  declarator: (identifier) @declaration.name) @declaration.variable
+
+(declaration
+  declarator: (pointer_declarator
+    declarator: (identifier) @declaration.name)) @declaration.variable
+
+;; ─── Declarations — macro definitions ───────────────────────────────
+(preproc_def
+  name: (identifier) @declaration.name) @declaration.macro
+
+(preproc_function_def
+  name: (identifier) @declaration.name) @declaration.macro
+
+;; ─── Imports — #include ─────────────────────────────────────────────
+(preproc_include) @import.statement
+
+;; ─── Imports — using declaration ─────────────────────────────────────
+;; Both "using namespace std;" and "using std::vector;" are
+;; using_declaration nodes in tree-sitter-cpp. The captures.ts
+;; differentiates between them by checking for a "namespace" anonymous
+;; child token.
+(using_declaration) @import.using-decl
+
+;; ─── Type bindings — parameter annotations ──────────────────────────
+(parameter_declaration
+  type: (_) @type-binding.type
+  declarator: (identifier) @type-binding.name) @type-binding.parameter
+
+;; Type bindings — reference parameter (const std::string& name)
+(parameter_declaration
+  type: (_) @type-binding.type
+  declarator: (reference_declarator
+    (identifier) @type-binding.name)) @type-binding.parameter
+
+;; Type bindings — pointer parameter (User* ptr)
+(parameter_declaration
+  type: (_) @type-binding.type
+  declarator: (pointer_declarator
+    declarator: (identifier) @type-binding.name)) @type-binding.parameter
+
+;; ─── Type bindings — variable with type (init_declarator) ───────────
+;; Covers: User user("alice"), User user = ..., int x = 0
+(declaration
+  type: (_) @type-binding.type
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name)) @type-binding.assignment
+
+;; ─── Type bindings — plain declaration (no initializer) ─────────────
+;; Covers: User user;
+(declaration
+  type: (type_identifier) @type-binding.type
+  declarator: (identifier) @type-binding.name) @type-binding.annotation
+
+;; Covers: List<User> users;
+(declaration
+  type: (template_type) @type-binding.type
+  declarator: (identifier) @type-binding.name) @type-binding.annotation
+
+;; ─── Type bindings — pointer variable declaration ───────────────────
+;; Covers: User* ptr = new User()
+(declaration
+  type: (type_identifier) @type-binding.type
+  declarator: (init_declarator
+    declarator: (pointer_declarator
+      declarator: (identifier) @type-binding.name))) @type-binding.annotation
+
+;; ─── Type bindings — auto + constructor call ────────────────────────
+;; Covers: auto user = User("alice")
+;; AST: declaration > placeholder_type_specifier/auto > init_declarator > identifier + call_expression > identifier
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (call_expression
+      function: (identifier) @type-binding.type))) @type-binding.constructor
+
+;; ─── Type bindings — auto + brace-init (compound_literal_expression) ─
+;; Covers: auto user = User{}, auto user = User{args}
+;; AST: declaration > placeholder_type_specifier/auto > init_declarator > identifier + compound_literal_expression > type_identifier
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (compound_literal_expression
+      type: (type_identifier) @type-binding.type))) @type-binding.constructor
+
+;; ─── Type bindings — auto + scoped brace-init (qualified) ───────────
+;; Covers: auto client = ns::HttpClient{}
+;; AST: compound_literal_expression > qualified_identifier > type_identifier
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (compound_literal_expression
+      type: (qualified_identifier
+        name: (type_identifier) @type-binding.type)))) @type-binding.constructor
+
+;; ─── Type bindings — auto + new expression ──────────────────────────
+;; Covers: auto user = new User(name)
+;; AST: declaration > placeholder_type_specifier/auto > init_declarator > identifier + new_expression > type_identifier
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (new_expression
+      type: (type_identifier) @type-binding.type))) @type-binding.constructor
+
+;; ─── Type bindings — auto + qualified template factory (std::make_shared<Dog>()) ─
+;; AST: declaration(1 > placeholder_type_specifier(2)2 > init_declarator(3 >
+;;   identifier(4)4 > call_expression(5 > qualified_identifier(6 >
+;;   template_function(7 > template_argument_list(8 > type_descriptor(9 >
+;;   type_identifier(10)10 )9 )8 )7 )6 )5 )3 )1
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (call_expression
+      function: (qualified_identifier
+        name: (template_function
+          arguments: (template_argument_list
+            (type_descriptor
+              type: (type_identifier) @type-binding.type))))))) @type-binding.constructor
+
+;; ─── Type bindings — auto + bare template factory (make_shared<Dog>()) ───────
+;; Same but without qualified_identifier wrapper — one fewer nesting level
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (call_expression
+      function: (template_function
+        arguments: (template_argument_list
+          (type_descriptor
+            type: (type_identifier) @type-binding.type)))))) @type-binding.constructor
+
+;; ─── Type bindings — auto alias assignment ──────────────────────────
+;; Covers: auto alias = existingVar (RHS is a plain identifier)
+;; AST: declaration > placeholder_type_specifier/auto > init_declarator > identifier + identifier
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (identifier) @type-binding.type)) @type-binding.alias
+
+;; ─── Type bindings — auto + member access (field_expression) ────────
+;; Covers: auto addr = user.address (RHS is obj.field)
+;; AST: declaration > placeholder_type_specifier > init_declarator > identifier + field_expression
+;; We capture the field name as @type-binding.type so the compound-receiver
+;; chain resolver can look it up on the receiver class scope.
+;; The full obj.field text is synthesized by interpret.ts into a dotted
+;; rawName for chain-follow resolution.
+(declaration
+  type: (placeholder_type_specifier)
+  declarator: (init_declarator
+    declarator: (identifier) @type-binding.name
+    value: (field_expression
+      argument: (_) @type-binding.member-access-receiver
+      field: (field_identifier) @type-binding.type))) @type-binding.member-access
+
+;; ─── Type bindings — function return type ───────────────────────────
+;; Covers: User getUser() { ... }
+;; AST: function_definition > type_identifier + function_declarator > identifier
+(function_definition
+  type: (type_identifier) @type-binding.type
+  declarator: (function_declarator
+    declarator: (identifier) @type-binding.name)) @type-binding.return
+
+;; Return type — out-of-class method: User Class::getUser() { ... }
+(function_definition
+  type: (type_identifier) @type-binding.type
+  declarator: (function_declarator
+    declarator: (qualified_identifier
+      name: (identifier) @type-binding.name))) @type-binding.return
+
+;; Return type — pointer return: User* getUser() { ... }
+(function_definition
+  type: (type_identifier) @type-binding.type
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (identifier) @type-binding.name))) @type-binding.return
+
+;; ─── Type bindings — inline method return type ──────────────────────
+;; Covers: class Foo { User getUser() { ... } };
+(function_definition
+  type: (type_identifier) @type-binding.type
+  declarator: (function_declarator
+    declarator: (field_identifier) @type-binding.name)) @type-binding.return
+
+;; Inline method pointer return type: class Foo { User* lookup(int) { ... } };
+(function_definition
+  type: (type_identifier) @type-binding.type
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (field_identifier) @type-binding.name))) @type-binding.return
+
+;; ─── Type bindings — method prototype return type in class body ──────
+;; Covers: class User { User* lookup(int); std::string getName(); };
+;; AST: field_declaration > function_declarator > field_identifier
+(field_declaration
+  type: (type_identifier) @type-binding.type
+  declarator: (function_declarator
+    declarator: (field_identifier) @type-binding.name)) @type-binding.return
+
+;; Method prototype pointer return type: User* lookup(int id);
+(field_declaration
+  type: (type_identifier) @type-binding.type
+  declarator: (pointer_declarator
+    declarator: (function_declarator
+      declarator: (field_identifier) @type-binding.name))) @type-binding.return
+
+;; ─── Type bindings — field type declarations (class members) ────────
+;; Covers: class User { Address address; };
+(field_declaration
+  type: (type_identifier) @type-binding.type
+  declarator: (field_identifier) @type-binding.name) @type-binding.field
+
+;; Field pointer type: Address* address;
+(field_declaration
+  type: (type_identifier) @type-binding.type
+  declarator: (pointer_declarator
+    declarator: (field_identifier) @type-binding.name)) @type-binding.field
+
+;; Field reference type: Address& address;
+(field_declaration
+  type: (type_identifier) @type-binding.type
+  declarator: (reference_declarator
+    (field_identifier) @type-binding.name)) @type-binding.field
+
+;; Generic field type: Repo<User> repo; (#2833)
+;; The three rules above all require type: (type_identifier), so a member whose
+;; type carries template arguments is a template_type and matched NONE of them —
+;; the field got no type binding at all, and every call through it lost its edge
+;; in BOTH spellings (repo.save() and this->repo.save()), while the same type in
+;; a LOCAL resolved fine because the local declaration rules gained their
+;; template_type variant long ago (see "Covers: List<User> users;" above).
+;; These three mirror the three above, one per declarator shape. Written as
+;; separate patterns rather than one alternation: a node-type alternation in a
+;; field position is the tree-sitter 0.21 hazard this repo has been bitten by
+;; before.
+(field_declaration
+  type: (template_type) @type-binding.type
+  declarator: (field_identifier) @type-binding.name) @type-binding.field
+
+;; Generic field, pointer: Repo<User>* repo;
+(field_declaration
+  type: (template_type) @type-binding.type
+  declarator: (pointer_declarator
+    declarator: (field_identifier) @type-binding.name)) @type-binding.field
+
+;; Generic field, reference: Repo<User>& repo;
+(field_declaration
+  type: (template_type) @type-binding.type
+  declarator: (reference_declarator
+    (field_identifier) @type-binding.name)) @type-binding.field
+
+;; ─── Field type, QUALIFIED: ns::Address addr; std::vector<Item> items; ─
+;; The six rules above require the type node to BE a type_identifier or a
+;; template_type, and a qualified member type is NEITHER: tree-sitter-cpp parses
+;; ns::Address as a qualified_identifier WRAPPING the type_identifier, and
+;; std::vector<Item> as one wrapping the template_type. So every qualified
+;; member — generic or not — matched none of the six and bound nothing, which
+;; covers the commonest member spellings in real C++ (std::string, std::mutex,
+;; std::vector<T>, ns::Config).
+;;
+;; ONE PATTERN PER DECLARATOR SHAPE, MATCHING THE OUTER qualified_identifier,
+;; and that is the whole design. A tree-sitter query cannot match a node at
+;; arbitrary nesting depth, and a::b::c::Repo<User> nests one
+;; qualified_identifier per qualifier — so enumerating the inner node instead
+;; costs 3 patterns per depth per genericity and STILL ends at whatever depth
+;; the last author enumerated (that boundary was real: depth 3 was uncaptured).
+;; Matching the outer node is depth-agnostic and genericity-agnostic, and it is
+;; a single node type in the field position, not an alternation — the
+;; tree-sitter 0.21 hazard this repo has been bitten by before.
+;;
+;; The QUALIFIER IS THEN DROPPED, by cppQualifiedTail in interpret.ts, not
+;; here — and dropping it was measured rather than assumed. Recording
+;; ns::Repo<User> resolves to NOTHING: findClassBindingInScope's dotted-tail
+;; fallback splits on "." and C++ writes "::", and resolveClassBindingForName's
+;; generic branch then looks up the base ns::Repo, which is not a key either
+;; because C++ emits no @declaration.qualified_name and indexes ns::Repo under
+;; Repo. Reducing to the tail lands on exactly the path the BARE spelling
+;; already takes — one class-like match or decline — so a qualified member field
+;; behaves like the bare one instead of like nothing. A tail that names no
+;; workspace class (std::string with no "class string" in the repo) binds
+;; nothing and emits nothing, which is why this is a miss-closing change rather
+;; than an edge-fabricating one.
+;;
+;; Like the six above, each requires the declarator to reach the field_identifier
+;; DIRECTLY, so a method whose return type is qualified (ns::Thing method();)
+;; still captures no field — a function_declarator sits in between and none of
+;; these match it. Same for a function-pointer member, a using/typedef alias, a
+;; friend declaration and an operator declaration.
+(field_declaration
+  type: (qualified_identifier) @type-binding.type
+  declarator: (field_identifier) @type-binding.name) @type-binding.field
+
+;; Qualified field, pointer: ns::Address* addr; std::unique_ptr<Repo>* repo;
+(field_declaration
+  type: (qualified_identifier) @type-binding.type
+  declarator: (pointer_declarator
+    declarator: (field_identifier) @type-binding.name)) @type-binding.field
+
+;; Qualified field, reference: ns::Address& addr; std::vector<Item>& items;
+(field_declaration
+  type: (qualified_identifier) @type-binding.type
+  declarator: (reference_declarator
+    (field_identifier) @type-binding.name)) @type-binding.field
+
+;; ─── References — constructor calls (new Foo()) ─────────────────────
+(new_expression
+  type: (type_identifier) @reference.name) @reference.call.constructor
+
+;; Constructor call with qualified type: new ns::Foo()
+(new_expression
+  type: (qualified_identifier
+    name: (type_identifier) @reference.name)) @reference.call.constructor
+
+;; ─── References — free calls ────────────────────────────────────────
+(call_expression
+  function: (identifier) @reference.name) @reference.call.free
+
+;; ─── References — qualified calls (Namespace func or Class method) ───
+;; Capture the LHS of scope-resolution as the explicit receiver so
+;; qualified static member calls route through receiver-bound-calls
+;; Case 2 (class-name receiver) path. Without the receiver capture,
+;; qualified calls have no explicit receiver and class methods cannot
+;; resolve through receiver-bound paths.
+(call_expression
+  function: (qualified_identifier
+    scope: (_) @reference.receiver
+    name: (identifier) @reference.name)) @reference.call.qualified
+
+;; Nested qualified receiver: outer::v1::Base<T>::f()
+;; tree-sitter-cpp nests this as qualified_identifier(name:
+;; qualified_identifier(scope: qualified_identifier(...), name: identifier)).
+;; Capturing the innermost receiver still gives isSuperReceiverInContext
+;; enough text to strip qualifiers/template args down to Base.
+(call_expression
+  function: (qualified_identifier
+    name: (qualified_identifier
+      scope: (_) @reference.receiver
+      name: (identifier) @reference.name))) @reference.call.qualified
+
+;; Double-nested qualified receiver: outer::v1::Base<T>::f()
+(call_expression
+  function: (qualified_identifier
+    name: (qualified_identifier
+      name: (qualified_identifier
+        scope: (_) @reference.receiver
+        name: (identifier) @reference.name)))) @reference.call.qualified
+
+;; ─── References — member calls (obj.method() / ptr->method()) ───────
+(call_expression
+  function: (field_expression
+    argument: (_) @reference.receiver
+    field: (field_identifier) @reference.name)) @reference.call.member
+
+;; Conservative operator-call support (#1636): model a + b as a
+;; member-style operator+ lookup, and lhs << rhs as a free
+;; operator<< lookup. Free operator+(T,T), member operator<<, and
+;; complex operand expressions remain false negatives for now.
+;; Built-in operators remain unresolved because no user-defined
+;; operator target exists.
+(binary_expression
+  left: (_) @reference.receiver
+  operator: "+" @reference.operator
+  right: (_)) @reference.call.member
+
+(binary_expression
+  left: (_)
+  operator: "<<" @reference.operator
+  right: (_)) @reference.call.free
+
+;; ─── References — template calls (func<T>()) ────────────────────────
+(call_expression
+  function: (template_function
+    name: (identifier) @reference.name)) @reference.call.free
+
+;; Note: Ns::func<T>() is parsed as qualified_identifier by tree-sitter-cpp,
+;; already captured by the qualified calls pattern above.
+
+;; ─── References — field reads ───────────────────────────────────────
+(field_expression
+  argument: (_) @reference.receiver
+  field: (field_identifier) @reference.name) @reference.read
+
+;; ─── References — field writes (assignment) ─────────────────────────
+(assignment_expression
+  left: (field_expression
+    argument: (_) @reference.receiver
+    field: (field_identifier) @reference.name)) @reference.write
+`;
+let _parser = null;
+let _query = null;
+function getCppParser() {
+    if (_parser === null) {
+        const grammar = loadCppGrammar();
+        if (grammar === null) {
+            throw new Error('tree-sitter-cpp grammar unavailable — install it (devDependency) or the language degrades to structure-layer capture.');
+        }
+        _parser = new tree_sitter_1.default();
+        _parser.setLanguage(grammar);
+    }
+    return _parser;
+}
+function getCppScopeQuery() {
+    if (_query === null) {
+        const grammar = loadCppGrammar();
+        if (grammar === null) {
+            throw new Error('tree-sitter-cpp grammar unavailable — install it (devDependency) or the language degrades to structure-layer capture.');
+        }
+        _query = new tree_sitter_1.default.Query(grammar, CPP_SCOPE_QUERY);
+    }
+    return _query;
+}