bare-ffmpeg 1.0.0-3 → 1.0.0-31

package/cmake/ports/ffmpeg/port.cmake

@@ -0,0 +1,514 @@
+include_guard(GLOBAL)
+
+set(libraries
+  avcodec
+  avdevice
+  avfilter
+  avformat
+  avutil
+  swresample
+  swscale
+)
+
+set(byproducts)
+
+foreach(name IN LISTS libraries)
+  add_library(${name} STATIC IMPORTED GLOBAL)
+
+  list(APPEND byproducts lib/lib${name}.a)
+endforeach()
+
+set(path)
+set(args
+  --disable-autodetect
+  --disable-doc
+  --disable-programs
+  --disable-network
+
+  --enable-pic
+  --enable-cross-compile
+)
+
+if(CMAKE_BUILD_TYPE MATCHES "Release")
+  list(APPEND args --disable-debug)
+elseif(CMAKE_BUILD_TYPE MATCHES "Debug")
+  list(APPEND args --disable-optimizations)
+elseif(CMAKE_BUILD_TYPE MATCHES "MinSizeRel")
+  list(APPEND args --disable-debug --enable-small)
+endif()
+
+if(APPLE AND CMAKE_OSX_ARCHITECTURES)
+  set(arch ${CMAKE_OSX_ARCHITECTURES})
+elseif(MSVC AND CMAKE_GENERATOR_PLATFORM)
+  set(arch ${CMAKE_GENERATOR_PLATFORM})
+elseif(ANDROID AND CMAKE_ANDROID_ARCH_ABI)
+  set(arch ${CMAKE_ANDROID_ARCH_ABI})
+elseif(CMAKE_SYSTEM_PROCESSOR)
+  set(arch ${CMAKE_SYSTEM_PROCESSOR})
+else()
+  set(arch ${CMAKE_HOST_SYSTEM_PROCESSOR})
+endif()
+
+string(TOLOWER "${arch}" arch)
+
+if(arch MATCHES "arm64|aarch64")
+  set(arch "aarch64")
+elseif(arch MATCHES "armv7-a|armeabi-v7a")
+  set(arch "arm")
+elseif(arch MATCHES "x64|x86_64|amd64")
+  set(arch "x64")
+elseif(arch MATCHES "x86|i386|i486|i586|i686")
+  set(arch "x86_32")
+else()
+  message(FATAL_ERROR "Unsupported architecture '${arch}'")
+endif()
+
+list(APPEND args --arch=${arch})
+
+if(APPLE)
+  list(APPEND args
+    --target-os=darwin
+
+    "--sysroot=${CMAKE_OSX_SYSROOT}"
+
+    --enable-avfoundation
+    --enable-videotoolbox
+  )
+
+  if(NOT IOS)
+    list(APPEND args
+      --enable-appkit
+      --enable-audiotoolbox
+    )
+  endif()
+elseif(LINUX)
+  list(APPEND args
+    --target-os=linux
+
+    "--sysroot=${CMAKE_SYSROOT}"
+
+    --enable-pthreads
+  )
+elseif(ANDROID)
+  list(APPEND args
+    --target-os=android
+
+    "--sysroot=${CMAKE_SYSROOT}"
+
+    --enable-jni
+    --enable-mediacodec
+  )
+
+  if(arch MATCHES "x86_32")
+    list(APPEND args --disable-asm)
+  endif()
+elseif(WIN32)
+  list(APPEND args
+    --target-os=win32
+
+    --enable-w32threads
+    --enable-d3d11va
+    --enable-d3d12va
+    --enable-dxva2
+    --enable-mediafoundation
+  )
+endif()
+
+set(env)
+
+if(CMAKE_C_COMPILER)
+  cmake_path(GET CMAKE_C_COMPILER PARENT_PATH CC_path)
+  cmake_path(GET CMAKE_C_COMPILER FILENAME CC_filename)
+
+  if(WIN32 AND CC_filename MATCHES "clang-cl.exe")
+    set(CC_filename "clang.exe")
+  endif()
+
+  list(APPEND path "${CC_path}")
+  list(APPEND args
+    "--cc=${CC_filename}"
+    "--host-cc=${CC_filename}"
+    "--extra-cflags=--target=${CMAKE_C_COMPILER_TARGET}"
+    "--ld=${CC_filename}"
+    "--host-ld=${CC_filename}"
+    "--extra-ldflags=--target=${CMAKE_C_COMPILER_TARGET}"
+  )
+
+  if(CMAKE_LINKER_TYPE MATCHES "LLD")
+    list(APPEND args --extra-ldflags=-fuse-ld=lld)
+  endif()
+endif()
+
+if(CMAKE_CXX_COMPILER)
+  cmake_path(GET CMAKE_CXX_COMPILER PARENT_PATH CXX_path)
+  cmake_path(GET CMAKE_CXX_COMPILER FILENAME CXX_filename)
+
+  if(WIN32 AND CXX_filename MATCHES "clang-cl.exe")
+    set(CXX_filename "clang.exe")
+  endif()
+
+  list(APPEND path "${CXX_path}")
+  list(APPEND args
+    "--cxx=${CXX_filename}"
+    "--extra-cxxflags=--target=${CMAKE_CXX_COMPILER_TARGET}"
+  )
+endif()
+
+if(CMAKE_OBJC_COMPILER)
+  cmake_path(GET CMAKE_OBJC_COMPILER PARENT_PATH OBJC_path)
+  cmake_path(GET CMAKE_OBJC_COMPILER FILENAME OBJC_filename)
+
+  list(APPEND path "${OBJC_path}")
+  list(APPEND args
+    "--objcc=${OBJC_filename}"
+    "--extra-objcflags=--target=${CMAKE_OBJC_COMPILER_TARGET}"
+  )
+endif()
+
+if(CMAKE_ASM_COMPILER)
+  cmake_path(GET CMAKE_ASM_COMPILER PARENT_PATH AS_path)
+  cmake_path(GET CMAKE_ASM_COMPILER FILENAME AS_filename)
+
+  if(WIN32 AND AS_filename MATCHES "clang-cl.exe")
+    set(AS_filename "clang.exe")
+  endif()
+
+  list(APPEND path "${AS_path}")
+  list(APPEND args "--as=${AS_filename}")
+endif()
+
+if(CMAKE_RC_COMPILER)
+  cmake_path(GET CMAKE_RC_COMPILER PARENT_PATH RC_path)
+  cmake_path(GET CMAKE_RC_COMPILER FILENAME RC_filename)
+
+  list(APPEND path "${RC_path}")
+  list(APPEND args "--windres=${RC_filename}")
+endif()
+
+if(CMAKE_AR)
+  cmake_path(GET CMAKE_AR PARENT_PATH AR_path)
+  cmake_path(GET CMAKE_AR FILENAME AR_filename)
+
+  if(WIN32 AND AR_filename MATCHES "llvm-lib.exe")
+    set(AR_filename "llvm-ar.exe")
+  endif()
+
+  list(APPEND path "${AR_path}")
+  list(APPEND args "--ar=${AR_filename}")
+endif()
+
+if(CMAKE_NM)
+  cmake_path(GET CMAKE_NM PARENT_PATH NM_path)
+  cmake_path(GET CMAKE_NM FILENAME NM_filename)
+
+  list(APPEND path "${NM_path}")
+  list(APPEND args "--nm=${NM_filename}")
+endif()
+
+if(CMAKE_RANLIB)
+  cmake_path(GET CMAKE_RANLIB PARENT_PATH RANLIB_path)
+  cmake_path(GET CMAKE_RANLIB FILENAME RANLIB_filename)
+
+  list(APPEND path "${RANLIB_path}")
+  list(APPEND args "--ranlib=${RANLIB_filename}")
+endif()
+
+if(CMAKE_STRIP)
+  cmake_path(GET CMAKE_STRIP PARENT_PATH STRIP_path)
+  cmake_path(GET CMAKE_STRIP FILENAME STRIP_filename)
+
+  list(APPEND path "${STRIP_path}")
+  list(APPEND args "--strip=${STRIP_filename}")
+endif()
+
+set(depends)
+set(pkg_config_path)
+
+if("gpl" IN_LIST features)
+  list(APPEND args --enable-gpl)
+
+  add_library(postproc STATIC IMPORTED GLOBAL)
+
+  list(APPEND libraries postproc)
+  list(APPEND byproducts lib/libpostproc.a)
+
+  target_link_libraries(postproc INTERFACE avutil)
+  target_link_libraries(avdevice INTERFACE postproc)
+  target_link_libraries(avfilter INTERFACE postproc)
+endif()
+
+if("zlib" IN_LIST features)
+  list(APPEND args --enable-zlib)
+endif()
+
+if("dav1d" IN_LIST features)
+  find_port(dav1d)
+
+  list(APPEND depends dav1d)
+  list(APPEND args --enable-libdav1d)
+  list(APPEND pkg_config_path "${dav1d_PREFIX}/lib/pkgconfig")
+
+  target_link_libraries(avcodec INTERFACE dav1d)
+endif()
+
+if("svt-av1" IN_LIST features)
+  find_port(svt-av1)
+
+  list(APPEND depends svt-av1)
+  list(APPEND args --enable-libsvtav1)
+  list(APPEND pkg_config_path "${svt-av1_PREFIX}/lib/pkgconfig")
+
+  target_link_libraries(avcodec INTERFACE svt-av1)
+endif()
+
+if("x264" IN_LIST features)
+  find_port(x264)
+
+  list(APPEND depends x264)
+  list(APPEND args --enable-libx264)
+  list(APPEND pkg_config_path "${x264_PREFIX}/lib/pkgconfig")
+
+  target_link_libraries(avcodec INTERFACE x264)
+endif()
+
+if("opus" IN_LIST features)
+  find_port(opus)
+
+  list(APPEND depends opus)
+  list(APPEND args --enable-libopus)
+  list(APPEND pkg_config_path "${opus_PREFIX}/lib/pkgconfig")
+
+  target_link_libraries(avcodec INTERFACE opus)
+endif()
+
+if(CMAKE_HOST_WIN32)
+  find_path(
+    msys2
+    NAMES msys2.exe
+    PATHS "C:/tools/msys64"
+    REQUIRED
+  )
+
+  find_program(
+    pkg-config
+    NAMES pkg-config
+    PATHS "${msys2}/usr/bin"
+    REQUIRED
+    NO_DEFAULT_PATH
+  )
+else()
+  find_program(
+    pkg-config
+    NAMES pkg-config
+    REQUIRED
+  )
+endif()
+
+foreach(part "$ENV{PATH}")
+  cmake_path(NORMAL_PATH part)
+
+  list(APPEND path "${part}")
+endforeach()
+
+list(APPEND args
+  "--pkg-config=${pkg-config}"
+  "--pkg-config-flags=--static"
+)
+
+list(REMOVE_DUPLICATES path)
+list(REMOVE_DUPLICATES pkg_config_path)
+
+if(CMAKE_HOST_WIN32)
+  list(TRANSFORM path REPLACE "([A-Z]):" "/\\1")
+  list(TRANSFORM pkg_config_path REPLACE "([A-Z]):" "/\\1")
+endif()
+
+list(JOIN path ":" path)
+list(JOIN pkg_config_path ":" pkg_config_path)
+
+list(APPEND env
+  "PATH=${path}"
+  "PKG_CONFIG_PATH=${pkg_config_path}"
+)
+
+declare_port(
+  "github:FFmpeg/FFmpeg#n8.0"
+  ffmpeg
+  AUTOTOOLS
+  DEPENDS ${depends}
+  BYPRODUCTS ${byproducts}
+  ARGS ${args}
+  ENV ${env}
+)
+
+file(MAKE_DIRECTORY "${ffmpeg_PREFIX}/include")
+
+foreach(name IN LISTS libraries)
+  add_dependencies(${name} ${ffmpeg})
+
+  set_target_properties(
+    ${name}
+    PROPERTIES
+    IMPORTED_LOCATION "${ffmpeg_PREFIX}/lib/lib${name}.a"
+  )
+
+  target_include_directories(
+    ${name}
+    INTERFACE "${ffmpeg_PREFIX}/include"
+  )
+
+  if(LINUX OR ANDROID)
+    target_link_options(
+      ${name}
+      INTERFACE
+        "-Wl,-Bsymbolic"
+    )
+  endif()
+endforeach()
+
+target_link_libraries(
+  avcodec
+  INTERFACE
+    avutil
+    swresample
+)
+
+target_link_libraries(
+  avdevice
+  INTERFACE
+    avcodec
+    avfilter
+    avformat
+    avutil
+    swresample
+    swscale
+)
+
+target_link_libraries(
+  avfilter
+  INTERFACE
+    avcodec
+    avformat
+    avutil
+    swresample
+    swscale
+)
+
+target_link_libraries(
+  avformat
+  INTERFACE
+    avcodec
+    avutil
+    swresample
+)
+
+target_link_libraries(
+  swresample
+  INTERFACE
+    avutil
+)
+
+target_link_libraries(
+  swscale
+  INTERFACE
+    avutil
+)
+
+if(APPLE)
+  target_link_libraries(
+    avcodec
+    INTERFACE
+      "-framework VideoToolbox"
+      "-framework CoreFoundation"
+      "-framework CoreMedia"
+      "-framework CoreVideo"
+      "-framework CoreServices"
+  )
+
+  target_link_libraries(
+    avdevice
+    INTERFACE
+      "-framework AVFoundation"
+      "-framework CoreAudio"
+      "-framework CoreGraphics"
+      "-framework CoreMedia"
+      "-framework CoreVideo"
+      "-framework Foundation"
+  )
+
+  target_link_libraries(
+    avutil
+    INTERFACE
+      "-framework VideoToolbox"
+      "-framework CoreFoundation"
+      "-framework CoreMedia"
+      "-framework CoreVideo"
+      "-framework CoreServices"
+  )
+
+  if(NOT IOS)
+    target_link_libraries(
+      avcodec
+      INTERFACE
+        "-framework AudioToolbox"
+    )
+
+    target_link_libraries(
+      avdevice
+      INTERFACE
+        "-framework AudioToolbox"
+    )
+  endif()
+elseif(ANDROID)
+  target_link_libraries(
+    avcodec
+    INTERFACE
+      android
+      mediandk
+  )
+
+  target_link_libraries(
+    avdevice
+    INTERFACE
+      android
+      camera2ndk
+      mediandk
+  )
+
+  target_link_libraries(
+    avutil
+    INTERFACE
+      android
+      mediandk
+  )
+elseif(WIN32)
+  target_link_libraries(
+    avcodec
+    INTERFACE
+      mfuuid
+      ole32
+      ole32
+      strmiids
+      user32
+  )
+
+  target_link_libraries(
+    avdevice
+    INTERFACE
+      gdi32
+      ole32
+      oleaut32
+      psapi
+      shlwapi
+      strmiids
+      uuid
+      vfw32
+  )
+
+  target_link_libraries(
+    avutil
+    INTERFACE
+      user32
+      bcrypt
+  )
+endif()

package/cmake/ports/opus/patches/01-windows-clang.patch

@@ -0,0 +1,52 @@
+From 7dba6a92ee0eb2d114495106367ddb327eca6428 Mon Sep 17 00:00:00 2001
+From: DoumanAsh <douman@gmx.se>
+Date: Sat, 11 May 2024 16:54:02 +0900
+Subject: [PATCH] Add sse4.1 flag when using clang-cl on MSVC targets
+
+---
+ CMakeLists.txt | 14 +++++++++++---
+ 1 file changed, 11 insertions(+), 3 deletions(-)
+
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 8535ad5f3..702a7ec82 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -14,6 +14,14 @@ include(GNUInstallDirs)
+ include(CMakeDependentOption)
+ include(FeatureSummary)
+ 
++# Detect clang-cl
++set(MSVC_CLANG_CL false BOOL)
++if (MSVC)
++    if("${CMAKE_C_COMPILER_ID}" MATCHES "Clang")
++        set(MSVC_CLANG_CL true BOOL)
++    endif()
++endif()
++
+ set(OPUS_BUILD_SHARED_LIBRARY_HELP_STR "build shared library.")
+ option(OPUS_BUILD_SHARED_LIBRARY ${OPUS_BUILD_SHARED_LIBRARY_HELP_STR} OFF)
+ if(OPUS_BUILD_SHARED_LIBRARY OR BUILD_SHARED_LIBS OR OPUS_BUILD_FRAMEWORK)
+@@ -484,20 +492,20 @@ if(NOT OPUS_DISABLE_INTRINSICS)
+         add_sources_group(opus lpcnet ${dnn_sources_sse4_1})
+       endif()
+       target_compile_definitions(opus PRIVATE OPUS_X86_MAY_HAVE_SSE4_1)
+-      if(NOT MSVC)
++      if(NOT MSVC OR MSVC_CLANG_CL)
+         set_source_files_properties(${celt_sources_sse4_1} ${silk_sources_sse4_1} ${dnn_sources_sse4_1} PROPERTIES COMPILE_FLAGS -msse4.1)
+       endif()
+ 
+       if(OPUS_FIXED_POINT)
+         add_sources_group(opus silk ${silk_sources_fixed_sse4_1})
+-        if(NOT MSVC)
++        if(NOT MSVC OR MSVC_CLANG_CL)
+           set_source_files_properties(${silk_sources_fixed_sse4_1} PROPERTIES COMPILE_FLAGS -msse4.1)
+         endif()
+       endif()
+     endif()
+     if(OPUS_X86_PRESUME_SSE4_1)
+       target_compile_definitions(opus PRIVATE OPUS_X86_PRESUME_SSE4_1)
+-      if(NOT MSVC)
++      if(NOT MSVC OR MSVC_CLANG_CL)
+         target_compile_options(opus PRIVATE -msse4.1)
+       endif()
+     endif()

package/cmake/ports/opus/port.cmake

@@ -0,0 +1,42 @@
+include_guard(GLOBAL)
+
+if(WIN32)
+  set(lib opus.lib)
+else()
+  set(lib libopus.a)
+endif()
+
+set(args
+  -DBUILD_SHARED_LIBS=OFF
+  -DBUILD_TESTING=OFF
+)
+
+if(WIN32)
+  list(APPEND args -DOPUS_DISABLE_INTRINSICS=ON)
+endif()
+
+declare_port(
+  "github:xiph/opus@v1.5.2"
+  opus
+  BYPRODUCTS lib/${lib}
+  ARGS ${args}
+  PATCHES
+    patches/01-windows-clang.patch
+)
+
+add_library(opus STATIC IMPORTED GLOBAL)
+
+add_dependencies(opus ${opus})
+
+set_target_properties(
+  opus
+  PROPERTIES
+  IMPORTED_LOCATION "${opus_PREFIX}/lib/${lib}"
+)
+
+file(MAKE_DIRECTORY "${opus_PREFIX}/include")
+
+target_include_directories(
+  opus
+  INTERFACE "${opus_PREFIX}/include"
+)

package/cmake/ports/svt-av1/port.cmake

@@ -0,0 +1,42 @@
+include_guard(GLOBAL)
+
+if(WIN32)
+  set(lib SvtAv1Enc.lib)
+else()
+  set(lib libSvtAv1Enc.a)
+endif()
+
+set(args
+  -DCMAKE_POLICY_VERSION_MINIMUM=3.5
+  -DBUILD_SHARED_LIBS=OFF
+  -DBUILD_TESTING=OFF
+  -DBUILD_APPS=OFF
+)
+
+if(WIN32)
+  list(APPEND args -DCOMPILE_C_ONLY=ON)
+endif()
+
+declare_port(
+  "gitlab:AOMediaCodec/SVT-AV1@2.3.0"
+  svt-av1
+  BYPRODUCTS lib/${lib}
+  ARGS ${args}
+)
+
+add_library(svt-av1 STATIC IMPORTED GLOBAL)
+
+add_dependencies(svt-av1 ${svt-av1})
+
+set_target_properties(
+  svt-av1
+  PROPERTIES
+  IMPORTED_LOCATION "${svt-av1_PREFIX}/lib/${lib}"
+)
+
+file(MAKE_DIRECTORY "${svt-av1_PREFIX}/include")
+
+target_include_directories(
+  svt-av1
+  INTERFACE "${svt-av1_PREFIX}/include"
+)

package/cmake/ports/x264/patches/01-windows-clang.patch

@@ -0,0 +1,33 @@
+diff --git a/configure b/configure
+index e242e73..28b4bfe 100755
+--- a/configure
++++ b/configure
+@@ -606,7 +606,7 @@ if [[ $host_os = mingw* || $host_os = msys* || $host_os = cygwin* ]]; then
+         if cc_check '' -Qdiag-error:10006,10157 ; then
+             CHECK_CFLAGS="$CHECK_CFLAGS -Qdiag-error:10006,10157"
+         fi
+-    elif [[ "$cc_base" = cl || "$cc_base" = cl[\ .]* ]]; then
++    elif [[ "$cc_base" = cl || "$cc_base" = cl[\ .]* || "$cc_base" = clang-cl || "$cc_base" = clang-cl[\ .]* ]]; then
+         # Standard Microsoft Visual Studio
+         compiler=CL
+         compiler_style=MS
+@@ -1458,8 +1458,8 @@ fi
+ DEPMM="${QPRE}MM"
+ DEPMT="${QPRE}MT"
+ if [ $compiler_style = MS ]; then
+-    AR="lib.exe -nologo -out:"
+-    LD="link.exe -out:"
++    AR="${AR-lib.exe} -nologo -out:"
++    LD="${LD-link.exe} -out:"
+     if [ $compiler = ICL ]; then
+         AR="xi$AR"
+         LD="xi$LD"
+@@ -1470,7 +1470,7 @@ if [ $compiler_style = MS ]; then
+     HAVE_GETOPT_LONG=0
+     LDFLAGS="-nologo -incremental:no $(cl_ldflags $LDFLAGS)"
+     LDFLAGSCLI="$(cl_ldflags $LDFLAGSCLI)"
+-    LIBX264=libx264.lib
++    LIBX264=x264.lib
+     RANLIB=
+     [ -n "$RC" ] && RCFLAGS="$RCFLAGS -nologo -I. -I\$(SRCPATH)/extras -fo"
+     STRIP=